lib/PublicInbox/NNTP.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a NNTP client socket
   5 # fields:
   6 # nntpd: PublicInbox::NNTPD ref
   7 # article: per-session current article number
   8 # ibx: PublicInbox::Inbox ref
   9 # long_cb: long_response private data
  10 package PublicInbox::NNTP;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(PublicInbox::DS);
  14 use PublicInbox::MID qw(mid_escape $MID_EXTRACT);
  15 use PublicInbox::Eml;
  16 use POSIX qw(strftime);
  17 use PublicInbox::DS qw(now);
  18 use Digest::SHA qw(sha1_hex);
  19 use Time::Local qw(timegm timelocal);
  20 use PublicInbox::GitAsyncCat;
  21 use PublicInbox::Address;
  22
  23 use constant {
  24         LINE_MAX => 512, # RFC 977 section 2.3
  25         r501 => "501 command syntax error\r\n",
  26         r502 => "502 Command unavailable\r\n",
  27         r221 => "221 Header follows\r\n",
  28         r225 => "225 Headers follow (multi-line)\r\n",
  29         r430 => "430 No article with that message-id\r\n",
  30 };
  31 use Errno qw(EAGAIN);
  32 my $ONE_MSGID = qr/\A$MID_EXTRACT\z/;
  33 my @OVERVIEW = qw(Subject From Date Message-ID References);
  34 my $OVERVIEW_FMT = join(":\r\n", @OVERVIEW, qw(Bytes Lines), '') .
  35                 "Xref:full\r\n.\r\n";
  36 my $LIST_HEADERS = join("\r\n", @OVERVIEW,
  37                         qw(:bytes :lines Xref To Cc)) . "\r\n.\r\n";
  38 my $CAPABILITIES = <<"";
  39 101 Capability list:\r
  40 VERSION 2\r
  41 READER\r
  42 NEWNEWS\r
  43 LIST ACTIVE ACTIVE.TIMES NEWSGROUPS OVERVIEW.FMT\r
  44 HDR\r
  45 OVER\r
  46 COMPRESS DEFLATE\r
  47
  48 sub do_greet ($) { $_[0]->write($_[0]->{nntpd}->{greet}) };
  49
  50 sub new {
  51         my ($cls, $sock, $nntpd) = @_;
  52         (bless { nntpd => $nntpd }, $cls)->greet($sock)
  53 }
  54
  55 sub args_ok ($$) {
  56         my ($cb, $argc) = @_;
  57         my $tot = prototype $cb;
  58         my ($nreq, undef) = split(/;/, $tot);
  59         $nreq = ($nreq =~ tr/$//) - 1;
  60         $tot = ($tot =~ tr/$//) - 1;
  61         ($argc <= $tot && $argc >= $nreq);
  62 }
  63
  64 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
  65 sub process_line ($$) {
  66         my ($self, $l) = @_;
  67         my ($req, @args) = split(/[ \t]+/, $l);
  68         return 1 unless defined($req); # skip blank line
  69         $req = $self->can('cmd_'.lc($req)) //
  70                 return $self->write(\"500 command not recognized\r\n");
  71         return $self->write(\r501) unless args_ok($req, scalar @args);
  72         my $res = eval { $req->($self, @args) };
  73         my $err = $@;
  74         if ($err && $self->{sock}) {
  75                 local $/ = "\n";
  76                 chomp($l);
  77                 err($self, 'error from: %s (%s)', $l, $err);
  78                 $res = \"503 program fault - command not performed\r\n";
  79         }
  80         defined($res) ? $self->write($res) : 0;
  81 }
  82
  83 # The keyword argument is not used (rfc3977 5.2.2)
  84 sub cmd_capabilities ($;$) {
  85         my ($self, undef) = @_;
  86         my $res = $CAPABILITIES;
  87         if (!$self->{sock}->can('accept_SSL') &&
  88                         $self->{nntpd}->{accept_tls}) {
  89                 $res .= "STARTTLS\r\n";
  90         }
  91         $res .= ".\r\n";
  92 }
  93
  94 sub cmd_mode ($$) {
  95         my ($self, $arg) = @_;
  96         uc($arg) eq 'READER' ? \"201 Posting prohibited\r\n" : \r501;
  97 }
  98
  99 sub cmd_slave ($) { \"202 slave status noted\r\n" }
 100
 101 sub cmd_xgtitle ($;$) {
 102         my ($self, $wildmat) = @_;
 103         $self->msg_more("282 list of groups and descriptions follows\r\n");
 104         list_newsgroups($self, $wildmat);
 105 }
 106
 107 sub list_overview_fmt ($) { $OVERVIEW_FMT }
 108
 109 sub list_headers ($;$) { $LIST_HEADERS }
 110
 111 sub list_active_i { # "LIST ACTIVE" and also just "LIST" (no args)
 112         my ($self, $groupnames) = @_;
 113         my @window = splice(@$groupnames, 0, 100) or return 0;
 114         my $ibx;
 115         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 116         for my $ngname (@window) {
 117                 $ibx = $groups->{$ngname} and group_line($self, $ibx);
 118         }
 119         scalar(@$groupnames); # continue if there's more
 120 }
 121
 122 sub list_active ($;$) { # called by cmd_list
 123         my ($self, $wildmat) = @_;
 124         wildmat2re($wildmat);
 125         long_response($self, \&list_active_i, [
 126                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 127 }
 128
 129 sub list_active_times_i {
 130         my ($self, $groupnames) = @_;
 131         my @window = splice(@$groupnames, 0, 100) or return 0;
 132         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 133         for my $ngname (@window) {
 134                 my $ibx = $groups->{$ngname} or next;
 135                 my $c = eval { $ibx->uidvalidity } // time;
 136                 $self->msg_more("$ngname $c <$ibx->{-primary_address}>\r\n");
 137         }
 138         scalar(@$groupnames); # continue if there's more
 139 }
 140
 141 sub list_active_times ($;$) { # called by cmd_list
 142         my ($self, $wildmat) = @_;
 143         wildmat2re($wildmat);
 144         long_response($self, \&list_active_times_i, [
 145                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 146 }
 147
 148 sub list_newsgroups_i {
 149         my ($self, $groupnames) = @_;
 150         my @window = splice(@$groupnames, 0, 100) or return 0;
 151         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 152         my $ibx;
 153         for my $ngname (@window) {
 154                 $ibx = $groups->{$ngname} and
 155                         $self->msg_more("$ngname ".$ibx->description."\r\n");
 156         }
 157         scalar(@$groupnames); # continue if there's more
 158 }
 159
 160 sub list_newsgroups ($;$) { # called by cmd_list
 161         my ($self, $wildmat) = @_;
 162         wildmat2re($wildmat);
 163         long_response($self, \&list_newsgroups_i, [
 164                 grep(/$wildmat/, @{$self->{nntpd}->{groupnames}}) ]);
 165 }
 166
 167 # LIST SUBSCRIPTIONS, DISTRIB.PATS are not supported
 168 sub cmd_list ($;$$) {
 169         my ($self, @args) = @_;
 170         if (scalar @args) {
 171                 my $arg = shift @args;
 172                 $arg =~ tr/A-Z./a-z_/;
 173                 my $ret = $arg eq 'active';
 174                 $arg = "list_$arg";
 175                 $arg = $self->can($arg);
 176                 return r501 unless $arg && args_ok($arg, scalar @args);
 177                 $self->msg_more("215 information follows\r\n");
 178                 $arg->($self, @args);
 179         } else {
 180                 $self->msg_more("215 list of newsgroups follows\r\n");
 181                 long_response($self, \&list_active_i, [ # copy array
 182                         @{$self->{nntpd}->{groupnames}} ]);
 183         }
 184 }
 185
 186 sub listgroup_range_i {
 187         my ($self, $beg, $end) = @_;
 188         my $r = $self->{ibx}->mm(1)->msg_range($beg, $end, 'num');
 189         scalar(@$r) or return;
 190         $self->msg_more(join("\r\n", @$r, ''));
 191         1;
 192 }
 193
 194 sub listgroup_all_i {
 195         my ($self, $num) = @_;
 196         my $ary = $self->{ibx}->over(1)->ids_after($num);
 197         scalar(@$ary) or return;
 198         $self->msg_more(join("\r\n", @$ary, ''));
 199         1;
 200 }
 201
 202 sub cmd_listgroup ($;$$) {
 203         my ($self, $group, $range) = @_;
 204         if (defined $group) {
 205                 my $res = cmd_group($self, $group);
 206                 return $res if ref($res); # error if const strref
 207                 $self->msg_more($res);
 208         }
 209         $self->{ibx} or return \"412 no newsgroup selected\r\n";
 210         if (defined $range) {
 211                 my $r = get_range($self, $range);
 212                 return $r unless ref $r;
 213                 long_response($self, \&listgroup_range_i, @$r);
 214         } else { # grab every article number
 215                 long_response($self, \&listgroup_all_i, \(my $num = 0));
 216         }
 217 }
 218
 219 sub parse_time ($$;$) {
 220         my ($date, $time, $gmt) = @_;
 221         my ($hh, $mm, $ss) = unpack('A2A2A2', $time);
 222         if (defined $gmt) {
 223                 $gmt =~ /\A(?:UTC|GMT)\z/i or die "GM invalid: $gmt";
 224                 $gmt = 1;
 225         }
 226         my ($YYYY, $MM, $DD);
 227         if (length($date) == 8) { # RFC 3977 allows YYYYMMDD
 228                 ($YYYY, $MM, $DD) = unpack('A4A2A2', $date);
 229         } else { # legacy clients send YYMMDD
 230                 my $YY;
 231                 ($YY, $MM, $DD) = unpack('A2A2A2', $date);
 232                 my @now = $gmt ? gmtime : localtime;
 233                 my $cur_year = $now[5] + 1900;
 234                 my $cur_cent = int($cur_year / 100) * 100;
 235                 $YYYY = (($YY + $cur_cent) > $cur_year) ?
 236                         ($YY + 1900) : ($YY + $cur_cent);
 237         }
 238         if ($gmt) {
 239                 timegm($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 240         } else {
 241                 timelocal($ss, $mm, $hh, $DD, $MM - 1, $YYYY);
 242         }
 243 }
 244
 245 sub group_line ($$) {
 246         my ($self, $ibx) = @_;
 247         my ($min, $max) = $ibx->mm(1)->minmax;
 248         $self->msg_more("$ibx->{newsgroup} $max $min n\r\n");
 249 }
 250
 251 sub newgroups_i {
 252         my ($self, $ts, $i, $groupnames) = @_;
 253         my $end = $$i + 100;
 254         my $groups = $self->{nntpd}->{pi_cfg}->{-by_newsgroup};
 255         while ($$i < $end) {
 256                 my $ngname = $groupnames->[$$i++] // return;
 257                 my $ibx = $groups->{$ngname} or next; # expired on reload
 258                 next unless (eval { $ibx->uidvalidity } // 0) > $ts;
 259                 group_line($self, $ibx);
 260         }
 261         1;
 262 }
 263
 264 sub cmd_newgroups ($$$;$$) {
 265         my ($self, $date, $time, $gmt, $dists) = @_;
 266         my $ts = eval { parse_time($date, $time, $gmt) };
 267         return r501 if $@;
 268
 269         # TODO dists
 270         $self->msg_more("231 list of new newsgroups follows\r\n");
 271         long_response($self, \&newgroups_i, $ts, \(my $i = 0),
 272                                 $self->{nntpd}->{groupnames});
 273 }
 274
 275 sub wildmat2re (;$) {
 276         return $_[0] = qr/.*/ if (!defined $_[0] || $_[0] eq '*');
 277         my %keep;
 278         my $salt = rand;
 279         my $tmp = $_[0];
 280
 281         $tmp =~ s#(?<!\\)\[(.+)(?<!\\)\]#
 282                 my $orig = $1;
 283                 my $key = sha1_hex($orig . $salt);
 284                 $orig =~ s/([^\w\-])+/\Q$1/g;
 285                 $keep{$key} = $orig;
 286                 $key
 287                 #gex;
 288         my %map = ('*' => '.*', '?' => '.' );
 289         $tmp =~ s#(?<!\\)([^\w\\])#$map{$1} || "\Q$1"#ge;
 290         if (scalar %keep) {
 291                 $tmp =~ s#([a-f0-9]{40})#
 292                         my $orig = $keep{$1};
 293                         defined $orig ? $orig : $1;
 294                         #ge;
 295         }
 296         $_[0] = qr/\A$tmp\z/;
 297 }
 298
 299 sub ngpat2re (;$) {
 300         return $_[0] = qr/\A\z/ unless defined $_[0];
 301         my %map = ('*' => '.*', ',' => '|');
 302         $_[0] =~ s!(.)!$map{$1} || "\Q$1"!ge;
 303         $_[0] = qr/\A(?:$_[0])\z/;
 304 }
 305
 306 sub newnews_i {
 307         my ($self, $names, $ts, $prev) = @_;
 308         my $ngname = $names->[0];
 309         if (my $ibx = $self->{nntpd}->{pi_cfg}->{-by_newsgroup}->{$ngname}) {
 310                 if (my $over = $ibx->over) {
 311                         my $msgs = $over->query_ts($ts, $$prev);
 312                         if (scalar @$msgs) {
 313                                 $self->msg_more(join('', map {
 314                                                         "<$_->{mid}>\r\n";
 315                                                 } @$msgs));
 316                                 $$prev = $msgs->[-1]->{num};
 317                                 return 1; # continue on current group
 318                         }
 319                 }
 320         }
 321         shift @$names;
 322         if (@$names) { # continue onto next newsgroup
 323                 $$prev = 0;
 324                 1;
 325         } else { # all done, break out of the long_response
 326                 undef;
 327         }
 328 }
 329
 330 sub cmd_newnews ($$$$;$$) {
 331         my ($self, $newsgroups, $date, $time, $gmt, $dists) = @_;
 332         my $ts = eval { parse_time($date, $time, $gmt) };
 333         return r501 if $@;
 334         $self->msg_more("230 list of new articles by message-id follows\r\n");
 335         my ($keep, $skip) = split(/!/, $newsgroups, 2);
 336         ngpat2re($keep);
 337         ngpat2re($skip);
 338         my @names = grep(!/$skip/, grep(/$keep/,
 339                                 @{$self->{nntpd}->{groupnames}}));
 340         return ".\r\n" unless scalar(@names);
 341         my $prev = 0;
 342         long_response($self, \&newnews_i, \@names, $ts, \$prev);
 343 }
 344
 345 sub cmd_group ($$) {
 346         my ($self, $group) = @_;
 347         my $nntpd = $self->{nntpd};
 348         my $ibx = $nntpd->{pi_cfg}->{-by_newsgroup}->{$group} or
 349                 return \"411 no such news group\r\n";
 350         $nntpd->idler_start;
 351
 352         $self->{ibx} = $ibx;
 353         my ($min, $max) = $ibx->mm(1)->minmax;
 354         $self->{article} = $min;
 355         my $est_size = $max - $min;
 356         "211 $est_size $min $max $group\r\n";
 357 }
 358
 359 sub article_adj ($$) {
 360         my ($self, $off) = @_;
 361         my $ibx = $self->{ibx} // return \"412 no newsgroup selected\r\n";
 362         my $n = $self->{article} //
 363                 return \"420 no current article has been selected\r\n";
 364
 365         $n += $off;
 366         my $mid = $ibx->mm(1)->mid_for($n) // do {
 367                 $n = $off > 0 ? 'next' : 'previous';
 368                 return "421 no $n article in this group\r\n";
 369         };
 370         $self->{article} = $n;
 371         "223 $n <$mid> article retrieved - request text separately\r\n";
 372 }
 373
 374 sub cmd_next ($) { article_adj($_[0], 1) }
 375 sub cmd_last ($) { article_adj($_[0], -1) }
 376
 377 # We want to encourage using email and CC-ing everybody involved to avoid
 378 # the single-point-of-failure a single server provides.
 379 sub cmd_post ($) {
 380         my ($self) = @_;
 381         my $ibx = $self->{ibx};
 382         $ibx ? "440 mailto:$ibx->{-primary_address} to post\r\n"
 383                 : \"440 posting not allowed\r\n"
 384 }
 385
 386 sub cmd_quit ($) {
 387         my ($self) = @_;
 388         $self->write(\"205 closing connection - goodbye!\r\n");
 389         $self->shutdn;
 390         undef;
 391 }
 392
 393 sub xref_by_tc ($$$) {
 394         my ($xref, $pi_cfg, $smsg) = @_;
 395         my $by_addr = $pi_cfg->{-by_addr};
 396         my $mid = $smsg->{mid};
 397         for my $f (qw(to cc)) {
 398                 my @ibxs = map {
 399                         $by_addr->{lc($_)} // ()
 400                 } (PublicInbox::Address::emails($smsg->{$f} // ''));
 401                 for my $ibx (@ibxs) {
 402                         $xref->{$ibx->{newsgroup}} //=
 403                                                 $ibx->mm(1)->num_for($mid);
 404                 }
 405         }
 406 }
 407
 408 sub xref ($$$) {
 409         my ($self, $cur_ibx, $smsg) = @_;
 410         my $nntpd = $self->{nntpd};
 411         my $cur_ng = $cur_ibx->{newsgroup};
 412         my $xref;
 413         if (my $ALL = $nntpd->{pi_cfg}->ALL) {
 414                 $xref = $ALL->nntp_xref_for($cur_ibx, $smsg);
 415                 xref_by_tc($xref, $nntpd->{pi_cfg}, $smsg);
 416         } else { # slow path
 417                 $xref = { $cur_ng => $smsg->{num} };
 418                 my $mid = $smsg->{mid};
 419                 for my $ibx (values %{$nntpd->{pi_cfg}->{-by_newsgroup}}) {
 420                         $xref->{$ibx->{newsgroup}} //=
 421                                                  $ibx->mm(1)->num_for($mid);
 422                 }
 423         }
 424         my $ret = "$nntpd->{servername} $cur_ng:".delete($xref->{$cur_ng});
 425         for my $ng (sort keys %$xref) {
 426                 my $num = $xref->{$ng} // next;
 427                 $ret .= " $ng:$num";
 428         }
 429         $ret;
 430 }
 431
 432 sub set_nntp_headers ($$) {
 433         my ($hdr, $smsg) = @_;
 434         my ($mid) = $smsg->{mid};
 435
 436         # leafnode (and maybe other NNTP clients) have trouble dealing
 437         # with v2 messages which have multiple Message-IDs (either due
 438         # to our own content-based dedupe or buggy git-send-email versions).
 439         my @mids = $hdr->header_raw('Message-ID');
 440         if (scalar(@mids) > 1) {
 441                 my $mid0 = "<$mid>";
 442                 $hdr->header_set('Message-ID', $mid0);
 443                 my @alt = $hdr->header_raw('X-Alt-Message-ID');
 444                 my %seen = map { $_ => 1 } (@alt, $mid0);
 445                 push(@alt, grep { !$seen{$_}++ } @mids);
 446                 $hdr->header_set('X-Alt-Message-ID', @alt);
 447         }
 448
 449         # clobber some existing headers
 450         my $ibx = $smsg->{-ibx};
 451         my $xref = xref($smsg->{nntp}, $ibx, $smsg);
 452         $hdr->header_set('Xref', $xref);
 453
 454         # RFC 5536 3.1.4
 455         my ($server_name, $newsgroups) = split(/ /, $xref, 2);
 456         $newsgroups =~ s/:[0-9]+\b//g; # drop NNTP article numbers
 457         $newsgroups =~ tr/ /,/;
 458         $hdr->header_set('Newsgroups', $newsgroups);
 459
 460         # *something* here is required for leafnode, try to follow
 461         # RFC 5536 3.1.5...
 462         $hdr->header_set('Path', $server_name . '!not-for-mail');
 463 }
 464
 465 sub art_lookup ($$$) {
 466         my ($self, $art, $code) = @_;
 467         my ($ibx, $n);
 468         my $err;
 469         if (defined $art) {
 470                 if ($art =~ /\A[0-9]+\z/) {
 471                         $err = \"423 no such article number in this group\r\n";
 472                         $n = int($art);
 473                         goto find_ibx;
 474                 } elsif ($art =~ $ONE_MSGID) {
 475                         ($ibx, $n) = mid_lookup($self, $1);
 476                         goto found if $ibx;
 477                         return \r430;
 478                 } else {
 479                         return \r501;
 480                 }
 481         } else {
 482                 $err = \"420 no current article has been selected\r\n";
 483                 $n = $self->{article} // return $err;
 484 find_ibx:
 485                 $ibx = $self->{ibx} or
 486                         return \"412 no newsgroup has been selected\r\n";
 487         }
 488 found:
 489         my $smsg = $ibx->over(1)->get_art($n) or return $err;
 490         $smsg->{-ibx} = $ibx;
 491         if ($code == 223) { # STAT
 492                 set_art($self, $n);
 493                 "223 $n <$smsg->{mid}> article retrieved - " .
 494                         "request text separately\r\n";
 495         } else { # HEAD | BODY | ARTICLE
 496                 $smsg->{nntp} = $self;
 497                 $smsg->{nntp_code} = $code;
 498                 set_art($self, $art);
 499                 # this dereferences to `undef'
 500                 ${ibx_async_cat($ibx, $smsg->{blob}, \&blob_cb, $smsg)};
 501         }
 502 }
 503
 504 sub msg_body_write ($$) {
 505         my ($self, $msg) = @_;
 506
 507         # these can momentarily double the memory consumption :<
 508         $$msg =~ s/^\./../smg;
 509         $$msg =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 510         $$msg .= "\r\n" unless $$msg =~ /\r\n\z/s;
 511         $self->msg_more($$msg);
 512 }
 513
 514 sub set_art {
 515         my ($self, $art) = @_;
 516         $self->{article} = $art if defined $art && $art =~ /\A[0-9]+\z/;
 517 }
 518
 519 sub msg_hdr_write ($$) {
 520         my ($eml, $smsg) = @_;
 521         set_nntp_headers($eml, $smsg);
 522
 523         my $hdr = $eml->{hdr} // \(my $x = '');
 524         # fixup old bug from import (pre-a0c07cba0e5d8b6a)
 525         $$hdr =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 526         $$hdr =~ s/(?<!\r)\n/\r\n/sg; # Alpine barfs without this
 527
 528         # for leafnode compatibility, we need to ensure Message-ID headers
 529         # are only a single line.
 530         $$hdr =~ s/^(Message-ID:)[ \t]*\r\n[ \t]+([^\r]+)\r\n/$1 $2\r\n/igsm;
 531         $smsg->{nntp}->msg_more($$hdr);
 532 }
 533
 534 sub blob_cb { # called by git->cat_async via ibx_async_cat
 535         my ($bref, $oid, $type, $size, $smsg) = @_;
 536         my $self = $smsg->{nntp};
 537         my $code = $smsg->{nntp_code};
 538         if (!defined($oid)) {
 539                 # it's possible to have TOCTOU if an admin runs
 540                 # public-inbox-(edit|purge), just move onto the next message
 541                 warn "E: $smsg->{blob} missing in $smsg->{-ibx}->{inboxdir}\n";
 542                 return $self->requeue;
 543         } elsif ($smsg->{blob} ne $oid) {
 544                 $self->close;
 545                 die "BUG: $smsg->{blob} != $oid";
 546         }
 547         my $r = "$code $smsg->{num} <$smsg->{mid}> article retrieved - ";
 548         my $eml = PublicInbox::Eml->new($bref);
 549         if ($code == 220) {
 550                 $self->msg_more($r .= "head and body follow\r\n");
 551                 msg_hdr_write($eml, $smsg);
 552                 $self->msg_more("\r\n");
 553                 msg_body_write($self, $bref);
 554         } elsif ($code == 221) {
 555                 $self->msg_more($r .= "head follows\r\n");
 556                 msg_hdr_write($eml, $smsg);
 557         } elsif ($code == 222) {
 558                 $self->msg_more($r .= "body follows\r\n");
 559                 msg_body_write($self, $bref);
 560         } else {
 561                 $self->close;
 562                 die "BUG: bad code: $r";
 563         }
 564         $self->write(\".\r\n"); # flushes (includes ->zflush)
 565         $self->requeue;
 566 }
 567
 568 sub cmd_article ($;$) {
 569         my ($self, $art) = @_;
 570         art_lookup($self, $art, 220);
 571 }
 572
 573 sub cmd_head ($;$) {
 574         my ($self, $art) = @_;
 575         art_lookup($self, $art, 221);
 576 }
 577
 578 sub cmd_body ($;$) {
 579         my ($self, $art) = @_;
 580         art_lookup($self, $art, 222);
 581 }
 582
 583 sub cmd_stat ($;$) {
 584         my ($self, $art) = @_;
 585         art_lookup($self, $art, 223); # art may be msgid
 586 }
 587
 588 sub cmd_ihave ($) { \"435 article not wanted - do not send it\r\n" }
 589
 590 sub cmd_date ($) { '111 '.strftime('%Y%m%d%H%M%S', gmtime(time))."\r\n" }
 591
 592 sub cmd_help ($) { \"100 help text follows\r\n.\r\n" }
 593
 594 # returns a ref on success
 595 sub get_range ($$) {
 596         my ($self, $range) = @_;
 597         my $ibx = $self->{ibx} //
 598                 return "412 no news group has been selected\r\n";
 599         $range // return "420 No article(s) selected\r\n";
 600         my ($beg, $end);
 601         my ($min, $max) = $ibx->mm(1)->minmax;
 602         if ($range =~ /\A([0-9]+)\z/) {
 603                 $beg = $end = $1;
 604         } elsif ($range =~ /\A([0-9]+)-\z/) {
 605                 ($beg, $end) = ($1, $max);
 606         } elsif ($range =~ /\A([0-9]+)-([0-9]+)\z/) {
 607                 ($beg, $end) = ($1, $2);
 608         } else {
 609                 return r501;
 610         }
 611         $beg = $min if ($beg < $min);
 612         $end = $max if ($end > $max);
 613         $beg > $end ? "420 No article(s) selected\r\n" : [ \$beg, $end ];
 614 }
 615
 616 sub long_step {
 617         my ($self) = @_;
 618         # wbuf is unset or empty, here; {long} may add to it
 619         my ($fd, $cb, $t0, @args) = @{$self->{long_cb}};
 620         my $more = eval { $cb->($self, @args) };
 621         if ($@ || !$self->{sock}) { # something bad happened...
 622                 delete $self->{long_cb};
 623                 my $elapsed = now() - $t0;
 624                 if ($@) {
 625                         err($self,
 626                             "%s during long response[$fd] - %0.6f",
 627                             $@, $elapsed);
 628                 }
 629                 out($self, " deferred[$fd] aborted - %0.6f", $elapsed);
 630                 $self->close;
 631         } elsif ($more) { # $self->{wbuf}:
 632                 # control passed to ibx_async_cat if $more == \undef
 633                 $self->requeue_once if !ref($more);
 634         } else { # all done!
 635                 delete $self->{long_cb};
 636                 $self->write(\".\r\n"); # TODO get rid of this
 637                 my $elapsed = now() - $t0;
 638                 my $fd = fileno($self->{sock});
 639                 out($self, " deferred[$fd] done - %0.6f", $elapsed);
 640                 my $wbuf = $self->{wbuf}; # do NOT autovivify
 641                 $self->requeue unless $wbuf && @$wbuf;
 642         }
 643 }
 644
 645 sub long_response ($$;@) {
 646         my ($self, $cb, @args) = @_; # cb returns true if more, false if done
 647
 648         my $sock = $self->{sock} or return;
 649         # make sure we disable reading during a long response,
 650         # clients should not be sending us stuff and making us do more
 651         # work while we are stream a response to them
 652         $self->{long_cb} = [ fileno($sock), $cb, now(), @args ];
 653         long_step($self); # kick off!
 654         undef;
 655 }
 656
 657 sub hdr_msgid_range_i {
 658         my ($self, $beg, $end) = @_;
 659         my $r = $self->{ibx}->mm(1)->msg_range($beg, $end);
 660         @$r or return;
 661         $self->msg_more(join('', map { "$_->[0] <$_->[1]>\r\n" } @$r));
 662         1;
 663 }
 664
 665 sub hdr_message_id ($$$) { # optimize XHDR Message-ID [range] for slrnpull.
 666         my ($self, $xhdr, $range) = @_;
 667
 668         if (defined $range && $range =~ $ONE_MSGID) {
 669                 my ($ibx, $n) = mid_lookup($self, $1);
 670                 return r430 unless $n;
 671                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $range);
 672         } else { # numeric range
 673                 $range = $self->{article} unless defined $range;
 674                 my $r = get_range($self, $range);
 675                 return $r unless ref $r;
 676                 $self->msg_more($xhdr ? r221 : r225);
 677                 long_response($self, \&hdr_msgid_range_i, @$r);
 678         }
 679 }
 680
 681 sub mid_lookup ($$) {
 682         my ($self, $mid) = @_;
 683         my $cur_ibx = $self->{ibx};
 684         if ($cur_ibx) {
 685                 my $n = $cur_ibx->mm(1)->num_for($mid);
 686                 return ($cur_ibx, $n) if defined $n;
 687         }
 688         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 689         if (my $ALL = $pi_cfg->ALL) {
 690                 my ($id, $prev);
 691                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 692                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 693                         if (my @x = grep(/:$smsg->{blob}\z/, @$xr3)) {
 694                                 my ($ngname, $xnum) = split(/:/, $x[0]);
 695                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 696                                 return ($ibx, $xnum) if $ibx;
 697                                 # fall through to trying all xref3s
 698                         } else {
 699                                 warn <<EOF;
 700 W: xref3 missing for <$mid> ($smsg->{blob}) in $ALL->{topdir}, -extindex bug?
 701 EOF
 702                         }
 703                         # try all xref3s
 704                         for my $x (@$xr3) {
 705                                 my ($ngname, $xnum) = split(/:/, $x);
 706                                 my $ibx = $pi_cfg->{-by_newsgroup}->{$ngname};
 707                                 return ($ibx, $xnum) if $ibx;
 708                                 warn "W: `$ngname' does not exist for #$xnum\n";
 709                         }
 710                 }
 711                 # no warning here, $mid is just invalid
 712         } else { # slow path for non-ALL users
 713                 for my $ibx (values %{$pi_cfg->{-by_newsgroup}}) {
 714                         next if defined $cur_ibx && $ibx eq $cur_ibx;
 715                         my $n = $ibx->mm(1)->num_for($mid);
 716                         return ($ibx, $n) if defined $n;
 717                 }
 718         }
 719         (undef, undef);
 720 }
 721
 722 sub xref_range_i {
 723         my ($self, $beg, $end) = @_;
 724         my $ibx = $self->{ibx};
 725         my $msgs = $ibx->over(1)->query_xover($$beg, $end);
 726         scalar(@$msgs) or return;
 727         $$beg = $msgs->[-1]->{num} + 1;
 728         $self->msg_more(join('', map {
 729                 "$_->{num} ".xref($self, $ibx, $_) . "\r\n";
 730         } @$msgs));
 731         1;
 732 }
 733
 734 sub hdr_xref ($$$) { # optimize XHDR Xref [range] for rtin
 735         my ($self, $xhdr, $range) = @_;
 736
 737         if (defined $range && $range =~ $ONE_MSGID) {
 738                 my $mid = $1;
 739                 my ($ibx, $n) = mid_lookup($self, $mid);
 740                 return r430 unless $n;
 741                 my $smsg = $ibx->over(1)->get_art($n) or return;
 742                 hdr_mid_response($self, $xhdr, $ibx, $n, $range,
 743                                 xref($self, $ibx, $smsg));
 744         } else { # numeric range
 745                 $range = $self->{article} unless defined $range;
 746                 my $r = get_range($self, $range);
 747                 return $r unless ref $r;
 748                 $self->msg_more($xhdr ? r221 : r225);
 749                 long_response($self, \&xref_range_i, @$r);
 750         }
 751 }
 752
 753 sub over_header_for {
 754         my ($ibx, $num, $field) = @_;
 755         my $smsg = $ibx->over(1)->get_art($num) or return;
 756         return PublicInbox::Smsg::date($smsg) if $field eq 'date';
 757         $smsg->{$field};
 758 }
 759
 760 sub smsg_range_i {
 761         my ($self, $beg, $end, $field) = @_;
 762         my $msgs = $self->{ibx}->over(1)->query_xover($$beg, $end);
 763         scalar(@$msgs) or return;
 764         my $tmp = '';
 765
 766         # ->{$field} is faster than ->$field invocations, so favor that.
 767         if ($field eq 'date') {
 768                 for my $s (@$msgs) {
 769                         $tmp .= "$s->{num} ".PublicInbox::Smsg::date($s)."\r\n"
 770                 }
 771         } else {
 772                 for my $s (@$msgs) {
 773                         $tmp .= "$s->{num} $s->{$field}\r\n";
 774                 }
 775         }
 776         utf8::encode($tmp);
 777         $self->msg_more($tmp);
 778         $$beg = $msgs->[-1]->{num} + 1;
 779 }
 780
 781 sub hdr_smsg ($$$$) {
 782         my ($self, $xhdr, $field, $range) = @_;
 783         if (defined $range && $range =~ $ONE_MSGID) {
 784                 my ($ibx, $n) = mid_lookup($self, $1);
 785                 return r430 unless defined $n;
 786                 my $v = over_header_for($ibx, $n, $field);
 787                 hdr_mid_response($self, $xhdr, $ibx, $n, $range, $v);
 788         } else { # numeric range
 789                 $range = $self->{article} unless defined $range;
 790                 my $r = get_range($self, $range);
 791                 return $r unless ref $r;
 792                 $self->msg_more($xhdr ? r221 : r225);
 793                 long_response($self, \&smsg_range_i, @$r, $field);
 794         }
 795 }
 796
 797 sub do_hdr ($$$;$) {
 798         my ($self, $xhdr, $header, $range) = @_;
 799         my $sub = lc $header;
 800         if ($sub eq 'message-id') {
 801                 hdr_message_id($self, $xhdr, $range);
 802         } elsif ($sub eq 'xref') {
 803                 hdr_xref($self, $xhdr, $range);
 804         } elsif ($sub =~ /\A(?:subject|references|date|from|to|cc|
 805                                 bytes|lines)\z/x) {
 806                 hdr_smsg($self, $xhdr, $sub, $range);
 807         } elsif ($sub =~ /\A:(bytes|lines)\z/) {
 808                 hdr_smsg($self, $xhdr, $1, $range);
 809         } else {
 810                 $xhdr ? (r221.".\r\n") : "503 HDR not permitted on $header\r\n";
 811         }
 812 }
 813
 814 # RFC 3977
 815 sub cmd_hdr ($$;$) {
 816         my ($self, $header, $range) = @_;
 817         do_hdr($self, 0, $header, $range);
 818 }
 819
 820 # RFC 2980
 821 sub cmd_xhdr ($$;$) {
 822         my ($self, $header, $range) = @_;
 823         do_hdr($self, 1, $header, $range);
 824 }
 825
 826 sub hdr_mid_prefix ($$$$$) {
 827         my ($self, $xhdr, $ibx, $n, $mid) = @_;
 828         return $mid if $xhdr;
 829
 830         # HDR for RFC 3977 users
 831         if (my $cur_ibx = $self->{ibx}) {
 832                 ($cur_ibx eq $ibx) ? $n : '0';
 833         } else {
 834                 '0';
 835         }
 836 }
 837
 838 sub hdr_mid_response ($$$$$$) {
 839         my ($self, $xhdr, $ibx, $n, $mid, $v) = @_;
 840         $self->write(($xhdr ? r221.$mid :
 841                    r225.hdr_mid_prefix($self, $xhdr, $ibx, $n, $mid)) .
 842                 " $v\r\n.\r\n");
 843         undef;
 844 }
 845
 846 sub xrover_i {
 847         my ($self, $beg, $end) = @_;
 848         my $h = over_header_for($self->{ibx}, $$beg, 'references');
 849         $self->msg_more("$$beg $h\r\n") if defined($h);
 850         $$beg++ < $end;
 851 }
 852
 853 sub cmd_xrover ($;$) {
 854         my ($self, $range) = @_;
 855         my $ibx = $self->{ibx} or return \"412 no newsgroup selected\r\n";
 856         (defined $range && $range =~ /[<>]/) and
 857                 return \"420 No article(s) selected\r\n"; # no message IDs
 858
 859         $range = $self->{article} unless defined $range;
 860         my $r = get_range($self, $range);
 861         return $r unless ref $r;
 862         $self->msg_more("224 Overview information follows\r\n");
 863         long_response($self, \&xrover_i, @$r);
 864 }
 865
 866 sub over_line ($$$) {
 867         my ($self, $ibx, $smsg) = @_;
 868         # n.b. field access and procedural calls can be
 869         # 10%-15% faster than OO method calls:
 870         my $s = join("\t", $smsg->{num},
 871                 $smsg->{subject},
 872                 $smsg->{from},
 873                 PublicInbox::Smsg::date($smsg),
 874                 "<$smsg->{mid}>",
 875                 $smsg->{references},
 876                 $smsg->{bytes},
 877                 $smsg->{lines},
 878                 "Xref: " . xref($self, $ibx, $smsg));
 879         utf8::encode($s);
 880         $s .= "\r\n";
 881 }
 882
 883 sub cmd_over ($;$) {
 884         my ($self, $range) = @_;
 885         if ($range && $range =~ $ONE_MSGID) {
 886                 my ($ibx, $n) = mid_lookup($self, $1);
 887                 defined $n or return r430;
 888                 my $smsg = $ibx->over(1)->get_art($n) or return r430;
 889                 $self->msg_more(
 890                         "224 Overview information follows (multi-line)\r\n");
 891
 892                 # Only set article number column if it's the current group
 893                 # (RFC 3977 8.3.2)
 894                 my $cur_ibx = $self->{ibx};
 895                 if (!$cur_ibx || $cur_ibx ne $ibx) {
 896                         # set {-orig_num} for nntp_xref_for
 897                         $smsg->{-orig_num} = $smsg->{num};
 898                         $smsg->{num} = 0;
 899                 }
 900                 over_line($self, $ibx, $smsg).".\r\n";
 901         } else {
 902                 cmd_xover($self, $range);
 903         }
 904 }
 905
 906 sub xover_i {
 907         my ($self, $beg, $end) = @_;
 908         my $ibx = $self->{ibx};
 909         my $msgs = $ibx->over(1)->query_xover($$beg, $end);
 910         my $nr = scalar @$msgs or return;
 911
 912         # OVERVIEW.FMT
 913         $self->msg_more(join('', map {
 914                 over_line($self, $ibx, $_);
 915                 } @$msgs));
 916         $$beg = $msgs->[-1]->{num} + 1;
 917 }
 918
 919 sub cmd_xover ($;$) {
 920         my ($self, $range) = @_;
 921         $range = $self->{article} unless defined $range;
 922         my $r = get_range($self, $range);
 923         return $r unless ref $r;
 924         my ($beg, $end) = @$r;
 925         $self->msg_more(
 926                 "224 Overview information follows for $$beg to $end\r\n");
 927         long_response($self, \&xover_i, @$r);
 928 }
 929
 930 sub compressed { undef }
 931
 932 sub cmd_starttls ($) {
 933         my ($self) = @_;
 934         my $sock = $self->{sock} or return;
 935         # RFC 4642 2.2.1
 936         return r502 if ($sock->can('accept_SSL') || $self->compressed);
 937         my $opt = $self->{nntpd}->{accept_tls} or
 938                 return \"580 can not initiate TLS negotiation\r\n";
 939         $self->write(\"382 Continue with TLS negotiation\r\n");
 940         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 941         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 942         undef;
 943 }
 944
 945 # RFC 8054
 946 sub cmd_compress ($$) {
 947         my ($self, $alg) = @_;
 948         return "503 Only DEFLATE is supported\r\n" if uc($alg) ne 'DEFLATE';
 949         return r502 if $self->compressed;
 950         PublicInbox::NNTPdeflate->enable($self);
 951         $self->requeue;
 952         undef
 953 }
 954
 955 sub cmd_xpath ($$) {
 956         my ($self, $mid) = @_;
 957         return r501 unless $mid =~ $ONE_MSGID;
 958         $mid = $1;
 959         my @paths;
 960         my $pi_cfg = $self->{nntpd}->{pi_cfg};
 961         my $groups = $pi_cfg->{-by_newsgroup};
 962         if (my $ALL = $pi_cfg->ALL) {
 963                 my ($id, $prev, %seen);
 964                 while (my $smsg = $ALL->over->next_by_mid($mid, \$id, \$prev)) {
 965                         my $xr3 = $ALL->over->get_xref3($smsg->{num});
 966                         for my $x (@$xr3) {
 967                                 my ($ngname, $n) = split(/:/, $x);
 968                                 $x = "$ngname/$n";
 969                                 if ($groups->{$ngname} && !$seen{$x}++) {
 970                                         push(@paths, $x);
 971                                 }
 972                         }
 973                 }
 974         } else { # slow path, no point in using long_response
 975                 for my $ibx (values %$groups) {
 976                         my $n = $ibx->mm(1)->num_for($mid) // next;
 977                         push @paths, "$ibx->{newsgroup}/$n";
 978                 }
 979         }
 980         return \"430 no such article on server\r\n" unless @paths;
 981         '223 '.join(' ', sort(@paths))."\r\n";
 982 }
 983
 984 sub err ($$;@) {
 985         my ($self, $fmt, @args) = @_;
 986         printf { $self->{nntpd}->{err} } $fmt."\n", @args;
 987 }
 988
 989 sub out ($$;@) {
 990         my ($self, $fmt, @args) = @_;
 991         printf { $self->{nntpd}->{out} } $fmt."\n", @args;
 992 }
 993
 994 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 995 sub event_step {
 996         my ($self) = @_;
 997
 998         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
 999
1000         # only read more requests if we've drained the write buffer,
1001         # otherwise we can be buffering infinitely w/o backpressure
1002
1003         my $rbuf = $self->{rbuf} // \(my $x = '');
1004         my $line = index($$rbuf, "\n");
1005         while ($line < 0) {
1006                 return $self->close if length($$rbuf) >= LINE_MAX;
1007                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
1008                 $line = index($$rbuf, "\n");
1009         }
1010         $line = substr($$rbuf, 0, $line + 1, '');
1011         $line =~ s/\r?\n\z//s;
1012         return $self->close if $line =~ /[[:cntrl:]]/s;
1013
1014         my $t0 = now();
1015         my $fd = fileno($self->{sock});
1016         my $r = eval { process_line($self, $line) };
1017         my $pending = $self->{wbuf} ? ' pending' : '';
1018         out($self, "[$fd] %s - %0.6f$pending", $line, now() - $t0);
1019         return $self->close if $r < 0;
1020         $self->rbuf_idle($rbuf);
1021
1022         # maybe there's more pipelined data, or we'll have
1023         # to register it for socket-readiness notifications
1024         $self->requeue unless $pending;
1025 }
1026
1027 sub busy { # for graceful shutdown in PublicInbox::Daemon:
1028         my ($self) = @_;
1029         defined($self->{rbuf}) || defined($self->{wbuf})
1030 }
1031
1032 1;