lib/PublicInbox/POP3.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Each instance of this represents a POP3 client connected to
   5 # public-inbox-{netd,pop3d}.  Much of this was taken from IMAP.pm and NNTP.pm
   6 #
   7 # POP3 is one mailbox per-user, so the "USER" command is like the
   8 # format of -imapd and is mapped to $NEWSGROUP.$SLICE (large inboxes
   9 # are sliced into 50K mailboxes in both POP3 and IMAP to avoid overloading
  10 # clients)
  11 #
  12 # Unlike IMAP, the "$NEWSGROUP" mailbox (without $SLICE) is a rolling
  13 # window of the latest messages.  We can do this for POP3 since the
  14 # typical POP3 session is short-lived while long-lived IMAP sessions
  15 # would cause slices to grow on the server side without bounds.
  16 #
  17 # Like IMAP, POP3 also has per-session message sequence numbers (MSN),
  18 # which require mapping to UIDs.  The offset of an entry into our
  19 # per-client cache is: (MSN-1)
  20 #
  21 # fields:
  22 # - uuid - 16-byte (binary) UUID representation (before successful login)
  23 # - cache - one-dimentional arrayref of (UID, bytesize, oidhex)
  24 # - nr_dele - number of deleted messages
  25 # - expire - string of packed unsigned short offsets
  26 # - user_id - user-ID mapped to UUID (on successful login + lock)
  27 # - txn_max_uid - for storing max deleted UID persistently
  28 # - ibx - PublicInbox::Inbox object
  29 # - slice - unsigned integer slice number (0..Inf), -1 => latest
  30 # - salt - pre-auth for APOP
  31 # - uid_dele - maximum deleted from previous session at login (NNTP ARTICLE)
  32 # - uid_base - base UID for mailbox slice (0-based) (same as IMAP)
  33 package PublicInbox::POP3;
  34 use v5.12;
  35 use parent qw(PublicInbox::DS);
  36 use PublicInbox::GitAsyncCat;
  37 use PublicInbox::DS qw(now);
  38 use Errno qw(EAGAIN);
  39 use Digest::MD5 qw(md5);
  40 use PublicInbox::IMAP; # for UID slice stuff
  41
  42 use constant {
  43         LINE_MAX => 512, # XXX unsure
  44 };
  45
  46 # XXX FIXME: duplicated stuff from NNTP.pm and IMAP.pm
  47
  48 sub err ($$;@) {
  49         my ($self, $fmt, @args) = @_;
  50         printf { $self->{pop3d}->{err} } $fmt."\n", @args;
  51 }
  52
  53 sub out ($$;@) {
  54         my ($self, $fmt, @args) = @_;
  55         printf { $self->{pop3d}->{out} } $fmt."\n", @args;
  56 }
  57
  58 sub do_greet {
  59         my ($self) = @_;
  60         my $s = $self->{salt} = sprintf('%x.%x', int(rand(0x7fffffff)), time);
  61         $self->write("+OK POP3 server ready <$s\@public-inbox>\r\n");
  62 }
  63
  64 sub new {
  65         my ($cls, $sock, $pop3d) = @_;
  66         (bless { pop3d => $pop3d }, $cls)->greet($sock)
  67 }
  68
  69 # POP user is $UUID1@$NEWSGROUP.$SLICE
  70 sub cmd_user ($$) {
  71         my ($self, $mailbox) = @_;
  72         $self->{salt} // return \"-ERR already authed\r\n";
  73         $mailbox =~ s/\A([a-f0-9\-]+)\@//i or
  74                 return \"-ERR no UUID@ in mailbox name\r\n";
  75         my $user = $1;
  76         $user =~ tr/-//d; # most have dashes, some (dbus-uuidgen) don't
  77         $user =~ m!\A[a-f0-9]{32}\z!i or return \"-ERR user has no UUID\r\n";
  78         my $slice;
  79         $mailbox =~ s/\.([0-9]+)\z// and $slice = $1 + 0;
  80         my $ibx = $self->{pop3d}->{pi_cfg}->lookup_newsgroup($mailbox) //
  81                 return \"-ERR $mailbox does not exist\r\n";
  82         my $uidmax = $ibx->mm(1)->num_highwater // 0;
  83         if (defined $slice) {
  84                 my $max = int($uidmax / PublicInbox::IMAP::UID_SLICE);
  85                 my $tip = "$mailbox.$max";
  86                 return \"-ERR $mailbox.$slice does not exist ($tip does)\r\n"
  87                         if $slice > $max;
  88                 $self->{uid_base} = $slice * PublicInbox::IMAP::UID_SLICE;
  89                 $self->{slice} = $slice;
  90         } else { # latest 50K messages
  91                 my $base = $uidmax - PublicInbox::IMAP::UID_SLICE;
  92                 $self->{uid_base} = $base < 0 ? 0 : $base;
  93                 $self->{slice} = -1;
  94         }
  95         $self->{ibx} = $ibx;
  96         $self->{uuid} = pack('H*', $user); # deleted by _login_ok
  97         $slice //= '(latest)';
  98         \"+OK $ibx->{newsgroup} slice=$slice selected\r\n";
  99 }
 100
 101 sub _login_ok ($) {
 102         my ($self) = @_;
 103         if ($self->{pop3d}->lock_mailbox($self)) {
 104                 $self->{uid_max} = $self->{ibx}->over(1)->max;
 105                 \"+OK logged in\r\n";
 106         } else {
 107                 \"-ERR [IN-USE] unable to lock maildrop\r\n";
 108         }
 109 }
 110
 111 sub cmd_apop {
 112         my ($self, $mailbox, $hex) = @_;
 113         my $res = cmd_user($self, $mailbox); # sets {uuid}
 114         return $res if substr($$res, 0, 1) eq '-';
 115         my $s = delete($self->{salt}) // die 'BUG: salt missing';
 116         return _login_ok($self) if md5("<$s\@public-inbox>anonymous") eq
 117                                 pack('H*', $hex);
 118         $self->{salt} = $s;
 119         \"-ERR APOP password mismatch\r\n";
 120 }
 121
 122 sub cmd_pass {
 123         my ($self, $pass) = @_;
 124         $self->{ibx} // return \"-ERR mailbox unspecified\r\n";
 125         my $s = delete($self->{salt}) // return \"-ERR already authed\r\n";
 126         return _login_ok($self) if $pass eq 'anonymous';
 127         $self->{salt} = $s;
 128         \"-ERR password is not `anonymous'\r\n";
 129 }
 130
 131 sub cmd_stls {
 132         my ($self) = @_;
 133         my $sock = $self->{sock} or return;
 134         return \"-ERR TLS already enabled\r\n" if $sock->can('stop_SSL');
 135         my $opt = $self->{pop3d}->{accept_tls} or
 136                 return \"-ERR can't start TLS negotiation\r\n";
 137         $self->write(\"+OK begin TLS negotiation now\r\n");
 138         $self->{sock} = IO::Socket::SSL->start_SSL($sock, %$opt);
 139         $self->requeue if PublicInbox::DS::accept_tls_step($self);
 140         undef;
 141 }
 142
 143 sub need_txn ($) {
 144         exists($_[0]->{salt}) ? \"-ERR not in TRANSACTION\r\n" : undef;
 145 }
 146
 147 sub _stat_cache ($) {
 148         my ($self) = @_;
 149         my ($beg, $end) = (($self->{uid_dele} // -1) + 1, $self->{uid_max});
 150         PublicInbox::IMAP::uid_clamp($self, \$beg, \$end);
 151         my $opt = { limit => PublicInbox::IMAP::UID_SLICE };
 152         my $m = $self->{ibx}->over(1)->do_get(<<'', $opt, $beg, $end);
 153 SELECT num,ddd FROM over WHERE num >= ? AND num <= ?
 154 ORDER BY num ASC
 155
 156         [ map { ($_->{num}, $_->{bytes} + 0, $_->{blob}) } @$m ];
 157 }
 158
 159 sub cmd_stat {
 160         my ($self) = @_;
 161         my $err; $err = need_txn($self) and return $err;
 162         my $cache = $self->{cache} //= _stat_cache($self);
 163         my $tot = 0;
 164         for (my $i = 1; $i < scalar(@$cache); $i += 3) { $tot += $cache->[$i] }
 165         my $nr = @$cache / 3 - ($self->{nr_dele} // 0);
 166         "+OK $nr $tot\r\n";
 167 }
 168
 169 # for LIST and UIDL
 170 sub _list {
 171         my ($desc, $idx, $self, $msn) = @_;
 172         my $err; $err = need_txn($self) and return $err;
 173         my $cache = $self->{cache} //= _stat_cache($self);
 174         if (defined $msn) {
 175                 my $base_off = ($msn - 1) * 3;
 176                 my $val = $cache->[$base_off + $idx] //
 177                                 return \"-ERR no such message\r\n";
 178                 "+OK $desc listing follows\r\n$msn $val\r\n.\r\n";
 179         } else { # always +OK, even if no messages
 180                 my $res = "+OK $desc listing follows\r\n";
 181                 my $msn = 0;
 182                 for (my $i = 0; $i < scalar(@$cache); $i += 3) {
 183                         ++$msn;
 184                         defined($cache->[$i]) and
 185                                 $res .= "$msn $cache->[$i + $idx]\r\n";
 186                 }
 187                 $res .= ".\r\n";
 188         }
 189 }
 190
 191 sub cmd_list { _list('scan', 1, @_) }
 192 sub cmd_uidl { _list('unique-id', 2, @_) }
 193
 194 sub mark_dele ($$) {
 195         my ($self, $off) = @_;
 196         my $base_off = $off * 3;
 197         my $cache = $self->{cache};
 198         my $uid = $cache->[$base_off] // return; # already deleted
 199
 200         my $old = $self->{txn_max_uid} //= $uid;
 201         $self->{txn_max_uid} = $uid if $uid > $old;
 202
 203         $cache->[$base_off] = undef; # clobber UID
 204         $cache->[$base_off + 1] = 0; # zero bytes (simplifies cmd_stat)
 205         $cache->[$base_off + 2] = undef; # clobber oidhex
 206         ++$self->{nr_dele};
 207 }
 208
 209 sub retr_cb { # called by git->cat_async via ibx_async_cat
 210         my ($bref, $oid, $type, $size, $args) = @_;
 211         my ($self, $off, $top_nr) = @$args;
 212         my $hex = $self->{cache}->[$off * 3 + 2] //
 213                 die "BUG: no hex (oid=$oid)";
 214         if (!defined($oid)) {
 215                 # it's possible to have TOCTOU if an admin runs
 216                 # public-inbox-(edit|purge), just move onto the next message
 217                 warn "E: $hex missing in $self->{ibx}->{inboxdir}\n";
 218                 $self->write(\"-ERR no such message\r\n");
 219                 return $self->requeue;
 220         } elsif ($hex ne $oid) {
 221                 $self->close;
 222                 die "BUG: $hex != $oid";
 223         }
 224         PublicInbox::IMAP::to_crlf_full($bref);
 225         if (defined $top_nr) {
 226                 my ($hdr, $bdy) = split(/\r\n\r\n/, $$bref, 2);
 227                 $bref = \$hdr;
 228                 $hdr .= "\r\n\r\n";
 229                 my @tmp = split(/^/m, $bdy);
 230                 $hdr .= join('', splice(@tmp, 0, $top_nr));
 231         } elsif (exists $self->{expire}) {
 232                 $self->{expire} .= pack('S', $off + 1);
 233         }
 234         $$bref =~ s/^\./../gms;
 235         $$bref .= substr($$bref, -2, 2) eq "\r\n" ? ".\r\n" : "\r\n.\r\n";
 236         $self->msg_more("+OK message follows\r\n");
 237         $self->write($bref);
 238         $self->requeue;
 239 }
 240
 241 sub cmd_retr {
 242         my ($self, $msn, $top_nr) = @_;
 243         return \"-ERR lines must be a non-negative number\r\n" if
 244                         (defined($top_nr) && $top_nr !~ /\A[0-9]+\z/);
 245         my $err; $err = need_txn($self) and return $err;
 246         my $cache = $self->{cache} //= _stat_cache($self);
 247         my $off = $msn - 1;
 248         my $hex = $cache->[$off * 3 + 2] // return \"-ERR no such message\r\n";
 249         ${ibx_async_cat($self->{ibx}, $hex, \&retr_cb,
 250                         [ $self, $off, $top_nr ])};
 251 }
 252
 253 sub cmd_noop { $_[0]->write(\"+OK\r\n") }
 254
 255 sub cmd_rset {
 256         my ($self) = @_;
 257         my $err; $err = need_txn($self) and return $err;
 258         delete $self->{cache};
 259         delete $self->{txn_max_uid};
 260         \"+OK\r\n";
 261 }
 262
 263 sub cmd_dele {
 264         my ($self, $msn) = @_;
 265         my $err; $err = need_txn($self) and return $err;
 266         $self->{cache} //= _stat_cache($self);
 267         $msn =~ /\A[1-9][0-9]*\z/ or return \"-ERR no such message\r\n";
 268         mark_dele($self, $msn - 1) ? \"+OK\r\n" : \"-ERR no such message\r\n";
 269 }
 270
 271 # RFC 2449
 272 sub cmd_capa {
 273         my ($self) = @_;
 274         my $STLS = !$self->{ibx} && !$self->{sock}->can('stop_SSL') &&
 275                         $self->{pop3d}->{accept_tls} ? "\nSTLS\r" : '';
 276         $self->{expire} = ''; # "EXPIRE 0" allows clients to avoid DELE commands
 277         <<EOM;
 278 +OK Capability list follows\r
 279 TOP\r
 280 USER\r
 281 PIPELINING\r
 282 UIDL\r
 283 EXPIRE 0\r
 284 RESP-CODES\r$STLS
 285 .\r
 286 EOM
 287 }
 288
 289 sub close {
 290         my ($self) = @_;
 291         $self->{pop3d}->unlock_mailbox($self);
 292         $self->SUPER::close;
 293 }
 294
 295 sub cmd_quit {
 296         my ($self) = @_;
 297         if (defined(my $txn_id = $self->{txn_id})) {
 298                 my $user_id = $self->{user_id} // die 'BUG: no {user_id}';
 299                 if (my $exp = delete $self->{expire}) {
 300                         mark_dele($self, $_) for unpack('S*', $exp);
 301                 }
 302                 my $dbh = $self->{pop3d}->{-state_dbh};
 303                 my $lk = $self->{pop3d}->lock_for_scope;
 304                 my $sth;
 305                 $dbh->begin_work;
 306
 307                 if (defined $self->{txn_max_uid}) {
 308                         $sth = $dbh->prepare_cached(<<'');
 309 UPDATE deletes SET uid_dele = ? WHERE txn_id = ? AND uid_dele < ?
 310
 311                         $sth->execute($self->{txn_max_uid}, $txn_id,
 312                                         $self->{txn_max_uid});
 313                 }
 314                 $sth = $dbh->prepare_cached(<<'');
 315 UPDATE users SET last_seen = ? WHERE user_id = ?
 316
 317                 $sth->execute(time, $user_id);
 318                 $dbh->commit;
 319         }
 320         $self->write(\"+OK public-inbox POP3 server signing off\r\n");
 321         $self->close;
 322         undef;
 323 }
 324
 325 # returns 1 if we can continue, 0 if not due to buffered writes or disconnect
 326 sub process_line ($$) {
 327         my ($self, $l) = @_;
 328         my ($req, @args) = split(/[ \t]+/, $l);
 329         return 1 unless defined($req); # skip blank line
 330         $req = $self->can('cmd_'.lc($req));
 331         my $res = $req ? eval { $req->($self, @args) } :
 332                 \"-ERR command not recognized\r\n";
 333         my $err = $@;
 334         if ($err && $self->{sock}) {
 335                 chomp($l);
 336                 err($self, 'error from: %s (%s)', $l, $err);
 337                 $res = \"-ERR program fault - command not performed\r\n";
 338         }
 339         defined($res) ? $self->write($res) : 0;
 340 }
 341
 342 # callback used by PublicInbox::DS for any (e)poll (in/out/hup/err)
 343 sub event_step {
 344         my ($self) = @_;
 345         return unless $self->flush_write && $self->{sock} && !$self->{long_cb};
 346
 347         # only read more requests if we've drained the write buffer,
 348         # otherwise we can be buffering infinitely w/o backpressure
 349         my $rbuf = $self->{rbuf} // \(my $x = '');
 350         my $line = index($$rbuf, "\n");
 351         while ($line < 0) {
 352                 return $self->close if length($$rbuf) >= LINE_MAX;
 353                 $self->do_read($rbuf, LINE_MAX, length($$rbuf)) or return;
 354                 $line = index($$rbuf, "\n");
 355         }
 356         $line = substr($$rbuf, 0, $line + 1, '');
 357         $line =~ s/\r?\n\z//s;
 358         return $self->close if $line =~ /[[:cntrl:]]/s;
 359         my $t0 = now();
 360         my $fd = fileno($self->{sock}); # may become invalid after process_line
 361         my $r = eval { process_line($self, $line) };
 362         my $pending = $self->{wbuf} ? ' pending' : '';
 363         out($self, "[$fd] %s - %0.6f$pending - $r", $line, now() - $t0);
 364         return $self->close if $r < 0;
 365         $self->rbuf_idle($rbuf);
 366
 367         # maybe there's more pipelined data, or we'll have
 368         # to register it for socket-readiness notifications
 369         $self->requeue unless $pending;
 370 }
 371
 372 no warnings 'once';
 373 *cmd_top = \&cmd_retr;
 374
 375 1;