lib/PublicInbox/WwwStream.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # HTML body stream for which yields getline+close methods for
   5 # generic PSGI servers and callbacks for public-inbox-httpd.
   6 #
   7 # See PublicInbox::GzipFilter parent class for more info.
   8 package PublicInbox::WwwStream;
   9 use strict;
  10 use parent qw(Exporter PublicInbox::GzipFilter);
  11 our @EXPORT_OK = qw(html_oneshot);
  12 use bytes (); # length
  13 use PublicInbox::Hval qw(ascii_html prurl ts2str);
  14 our $TOR_URL = 'https://www.torproject.org/';
  15 our $CODE_URL = [ qw(http://ou63pmih66umazou.onion/public-inbox.git
  16         https://public-inbox.org/public-inbox.git) ];
  17
  18 sub base_url ($) {
  19         my $ctx = shift;
  20         my $base_url = $ctx->{ibx}->base_url($ctx->{env});
  21         chop $base_url; # no trailing slash for clone
  22         $base_url;
  23 }
  24
  25 sub init {
  26         my ($ctx, $cb) = @_;
  27         $ctx->{cb} = $cb;
  28         $ctx->{base_url} = base_url($ctx);
  29         bless $ctx, __PACKAGE__;
  30 }
  31
  32 sub async_eml { # for async_blob_cb
  33         my ($ctx, $eml) = @_;
  34         $ctx->{http_out}->write($ctx->translate($ctx->{cb}->($ctx, $eml)));
  35 }
  36
  37 sub html_top ($) {
  38         my ($ctx) = @_;
  39         my $ibx = $ctx->{ibx};
  40         my $desc = ascii_html($ibx->description);
  41         my $title = delete($ctx->{-title_html}) // $desc;
  42         my $upfx = $ctx->{-upfx} || '';
  43         my $help = $upfx.'_/text/help';
  44         my $color = $upfx.'_/text/color';
  45         my $atom = $ctx->{-atom} || $upfx.'new.atom';
  46         my $top = "<b>$desc</b>";
  47         if (my $t_max = $ctx->{-t_max}) {
  48                 $t_max = ts2str($t_max);
  49                 $top = qq(<a\nhref="$upfx?t=$t_max">$top</a>);
  50         # we had some kind of query, link to /$INBOX/?t=YYYYMMDDhhmmss
  51         } elsif ($ctx->{qp}->{t}) {
  52                 $top = qq(<a\nhref="./">$top</a>);
  53         }
  54         my $links = qq(<a\nhref="$help">help</a> / ).
  55                         qq(<a\nhref="$color">color</a> / ).
  56                         qq(<a\nhref=#mirror>mirror</a> / ).
  57                         qq(<a\nhref="$atom">Atom feed</a>);
  58         if ($ibx->isrch) {
  59                 my $q_val = delete($ctx->{-q_value_html}) // '';
  60                 $q_val = qq(\nvalue="$q_val") if $q_val ne '';
  61                 # XXX gross, for SearchView.pm
  62                 my $extra = delete($ctx->{-extra_form_html}) // '';
  63                 my $action = $upfx eq '' ? './' : $upfx;
  64                 $top = qq{<form\naction="$action"><pre>$top} .
  65                           qq{\n<input\nname=q\ntype=text$q_val />} .
  66                           $extra .
  67                           qq{<input\ntype=submit\nvalue=search />} .
  68                           ' ' . $links .
  69                           q{</pre></form>}
  70         } else {
  71                 $top = '<pre>' . $top . "\n" . $links . '</pre>';
  72         }
  73         "<html><head><title>$title</title>" .
  74                 qq(<link\nrel=alternate\ntitle="Atom feed"\n).
  75                 qq(href="$atom"\ntype="application/atom+xml"/>) .
  76                 $ctx->{www}->style($upfx) .
  77                 '</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
  78 }
  79
  80 sub coderepos ($) {
  81         my ($ctx) = @_;
  82         my $cr = $ctx->{ibx}->{coderepo} // return ();
  83         my $cfg = $ctx->{www}->{pi_cfg};
  84         my @ret;
  85         for my $cr_name (@$cr) {
  86                 my $urls = $cfg->{"coderepo.$cr_name.cgiturl"} // next;
  87                 $ret[0] //= <<EOF;
  88 code repositories for the project(s) associated with this inbox:
  89 EOF
  90                 for my $u (@$urls) {
  91                         $u = ascii_html(prurl($ctx->{env}, $u));
  92                         $ret[0] .= qq(\n\t<a\nhref="$u">$u</a>);
  93                 }
  94         }
  95         @ret; # may be empty, this sub is called as an arg for join()
  96 }
  97
  98 sub code_footer ($) {
  99         my ($env) = @_;
 100         my $u = prurl($env, $CODE_URL);
 101         qq(AGPL code for this site: git clone <a\nhref="$u">$u</a>)
 102 }
 103
 104 sub _html_end {
 105         my ($ctx) = @_;
 106         my $urls = <<EOF;
 107 <a
 108 id=mirror>This inbox may be cloned and mirrored by anyone:</a>
 109 EOF
 110
 111         my $ibx = $ctx->{ibx};
 112         my $desc = ascii_html($ibx->description);
 113
 114         my @urls;
 115         my $http = $ctx->{base_url};
 116         my $max = $ibx->max_git_epoch;
 117         my $dir = (split(m!/!, $http))[-1];
 118         my %seen = ($http => 1);
 119         if (defined($max)) { # v2
 120                 for my $i (0..$max) {
 121                         # old epochs my be deleted:
 122                         -d "$ibx->{inboxdir}/git/$i.git" or next;
 123                         my $url = "$http/$i";
 124                         $seen{$url} = 1;
 125                         push @urls, "$url $dir/git/$i.git";
 126                 }
 127                 my $nr = scalar(@urls);
 128                 if ($nr > 1) {
 129                         $urls .= "\n\t# this inbox consists of $nr epochs:";
 130                         $urls[0] .= "\t# oldest";
 131                         $urls[-1] .= "\t# newest";
 132                 }
 133         } else { # v1
 134                 push @urls, $http;
 135         }
 136
 137         # FIXME: epoch splits can be different in other repositories,
 138         # use the "cloneurl" file as-is for now:
 139         foreach my $u (@{$ibx->cloneurl}) {
 140                 next if $seen{$u}++;
 141                 push @urls, $u =~ /\Ahttps?:/ ? qq(<a\nhref="$u">$u</a>) : $u;
 142         }
 143
 144         $urls .= "\n" . join('', map { "\tgit clone --mirror $_\n" } @urls);
 145         if (my $addrs = $ibx->{address}) {
 146                 $addrs = join(' ', @$addrs) if ref($addrs) eq 'ARRAY';
 147                 my $v = defined $max ? '-V2' : '-V1';
 148                 $urls .= <<EOF;
 149
 150         # If you have public-inbox 1.1+ installed, you may
 151         # initialize and index your mirror using the following commands:
 152         public-inbox-init $v $ibx->{name} $dir/ $http \\
 153                 $addrs
 154         public-inbox-index $dir
 155 EOF
 156         }
 157         my $cfg_link = ($ctx->{-upfx} // '').'_/text/config/raw';
 158         $urls .= <<EOF;
 159
 160 Example <a
 161 href="$cfg_link">config snippet</a> for mirrors.
 162 EOF
 163         my @nntp = map { qq(<a\nhref="$_">$_</a>) } @{$ibx->nntp_url};
 164         if (@nntp) {
 165                 $urls .= @nntp == 1 ? 'Newsgroup' : 'Newsgroups are';
 166                 $urls .= ' available over NNTP:';
 167                 $urls .= "\n\t" . join("\n\t", @nntp) . "\n";
 168         }
 169         if ($urls =~ m!\b[^:]+://\w+\.onion/!) {
 170                 $urls .= " note: .onion URLs require Tor: ";
 171                 $urls .= qq[<a\nhref="$TOR_URL">$TOR_URL</a>];
 172         }
 173         '<hr><pre>'.join("\n\n",
 174                 $desc,
 175                 $urls,
 176                 coderepos($ctx),
 177                 code_footer($ctx->{env})
 178         ).'</pre></body></html>';
 179 }
 180
 181 # callback for HTTP.pm (and any other PSGI servers)
 182 sub getline {
 183         my ($ctx) = @_;
 184         my $cb = $ctx->{cb} or return;
 185         while (defined(my $x = $cb->($ctx))) { # x = smsg or scalar non-ref
 186                 if (ref($x)) { # smsg
 187                         my $eml = $ctx->{ibx}->smsg_eml($x) or next;
 188                         $ctx->{smsg} = $x;
 189                         return $ctx->translate($cb->($ctx, $eml));
 190                 } else { # scalar
 191                         return $ctx->translate($x);
 192                 }
 193         }
 194         delete $ctx->{cb};
 195         $ctx->zflush(_html_end($ctx));
 196 }
 197
 198 sub html_oneshot ($$;$) {
 199         my ($ctx, $code, $sref) = @_;
 200         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8',
 201                 'Content-Length' => undef ];
 202         bless $ctx, __PACKAGE__;
 203         $ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($res_hdr, $ctx->{env});
 204         $ctx->{base_url} //= do {
 205                 $ctx->zmore(html_top($ctx));
 206                 base_url($ctx);
 207         };
 208         $ctx->zmore($$sref) if $sref;
 209         my $bdy = $ctx->zflush(_html_end($ctx));
 210         $res_hdr->[3] = bytes::length($bdy);
 211         [ $code, $res_hdr, [ $bdy ] ]
 212 }
 213
 214 sub async_next ($) {
 215         my ($http) = @_; # PublicInbox::HTTP
 216         my $ctx = $http->{forward} or return;
 217         eval {
 218                 if (my $smsg = $ctx->{smsg} = $ctx->{cb}->($ctx)) {
 219                         $ctx->smsg_blob($smsg);
 220                 } else {
 221                         $ctx->{http_out}->write(
 222                                         $ctx->translate(_html_end($ctx)));
 223                         $ctx->close; # GzipFilter->close
 224                 }
 225         };
 226         warn "E: $@" if $@;
 227 }
 228
 229 sub aresponse {
 230         my ($ctx, $code, $cb) = @_;
 231         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8' ];
 232         init($ctx, $cb);
 233         $ctx->psgi_response($code, $res_hdr);
 234 }
 235
 236 1;