lib/PublicInbox/WwwStream.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # HTML body stream for which yields getline+close methods for
   5 # generic PSGI servers and callbacks for public-inbox-httpd.
   6 #
   7 # See PublicInbox::GzipFilter parent class for more info.
   8 package PublicInbox::WwwStream;
   9 use strict;
  10 use parent qw(Exporter PublicInbox::GzipFilter);
  11 our @EXPORT_OK = qw(html_oneshot);
  12 use bytes (); # length
  13 use PublicInbox::Hval qw(ascii_html prurl ts2str);
  14 our $TOR_URL = 'https://www.torproject.org/';
  15 our $CODE_URL = 'https://public-inbox.org/public-inbox.git';
  16
  17 sub base_url ($) {
  18         my $ctx = shift;
  19         my $base_url = $ctx->{-inbox}->base_url($ctx->{env});
  20         chop $base_url; # no trailing slash for clone
  21         $base_url;
  22 }
  23
  24 sub init {
  25         my ($ctx, $cb) = @_;
  26         $ctx->{cb} = $cb;
  27         $ctx->{base_url} = base_url($ctx);
  28         bless $ctx, __PACKAGE__;
  29 }
  30
  31 sub async_eml { # for async_blob_cb
  32         my ($ctx, $eml) = @_;
  33         $ctx->{http_out}->write($ctx->translate($ctx->{cb}->($ctx, $eml)));
  34 }
  35
  36 sub html_top ($) {
  37         my ($ctx) = @_;
  38         my $ibx = $ctx->{-inbox};
  39         my $desc = ascii_html($ibx->description);
  40         my $title = delete($ctx->{-title_html}) // $desc;
  41         my $upfx = $ctx->{-upfx} || '';
  42         my $help = $upfx.'_/text/help';
  43         my $color = $upfx.'_/text/color';
  44         my $atom = $ctx->{-atom} || $upfx.'new.atom';
  45         my $top = "<b>$desc</b>";
  46         if (my $t_max = $ctx->{-t_max}) {
  47                 $t_max = ts2str($t_max);
  48                 $top = qq(<a\nhref="$upfx?t=$t_max">$top</a>);
  49         # we had some kind of query, link to /$INBOX/?t=YYYYMMDDhhmmss
  50         } elsif ($ctx->{qp}->{t}) {
  51                 $top = qq(<a\nhref="./">$top</a>);
  52         }
  53         my $links = qq(<a\nhref="$help">help</a> / ).
  54                         qq(<a\nhref="$color">color</a> / ).
  55                         qq(<a\nhref=#mirror>mirror</a> / ).
  56                         q(<a\nhref="$atom">Atom feed</a>);
  57         if ($ibx->search) {
  58                 my $q_val = delete($ctx->{-q_value_html}) // '';
  59                 $q_val = qq(\nvalue="$q_val") if $q_val ne '';
  60                 # XXX gross, for SearchView.pm
  61                 my $extra = delete($ctx->{-extra_form_html}) // '';
  62                 my $action = $upfx eq '' ? './' : $upfx;
  63                 $top = qq{<form\naction="$action"><pre>$top} .
  64                           qq{\n<input\nname=q\ntype=text$q_val />} .
  65                           $extra .
  66                           qq{<input\ntype=submit\nvalue=search />} .
  67                           ' ' . $links .
  68                           q{</pre></form>}
  69         } else {
  70                 $top = '<pre>' . $top . "\n" . $links . '</pre>';
  71         }
  72         "<html><head><title>$title</title>" .
  73                 qq(<link\nrel=alternate\ntitle="Atom feed"\n).
  74                 qq(href="$atom"\ntype="application/atom+xml"/>) .
  75                 $ctx->{www}->style($upfx) .
  76                 '</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
  77 }
  78
  79 sub code_footer ($) {
  80         my ($env) = @_;
  81         my $u = prurl($env, $CODE_URL);
  82         qq(AGPL code for this site: git clone <a\nhref="$u">$u</a>)
  83 }
  84
  85 sub _html_end {
  86         my ($ctx) = @_;
  87         my $urls = <<EOF;
  88 <a
  89 id=mirror>This inbox may be cloned and mirrored by anyone:</a>
  90 EOF
  91
  92         my $ibx = $ctx->{-inbox};
  93         my $desc = ascii_html($ibx->description);
  94
  95         my @urls;
  96         my $http = $ctx->{base_url};
  97         my $max = $ibx->max_git_epoch;
  98         my $dir = (split(m!/!, $http))[-1];
  99         my %seen = ($http => 1);
 100         if (defined($max)) { # v2
 101                 for my $i (0..$max) {
 102                         # old epochs my be deleted:
 103                         -d "$ibx->{inboxdir}/git/$i.git" or next;
 104                         my $url = "$http/$i";
 105                         $seen{$url} = 1;
 106                         push @urls, "$url $dir/git/$i.git";
 107                 }
 108                 my $nr = scalar(@urls);
 109                 if ($nr > 1) {
 110                         $urls .= "\n\t# this inbox consists of $nr epochs:";
 111                         $urls[0] .= "\t# oldest";
 112                         $urls[-1] .= "\t# newest";
 113                 }
 114         } else { # v1
 115                 push @urls, $http;
 116         }
 117
 118         # FIXME: epoch splits can be different in other repositories,
 119         # use the "cloneurl" file as-is for now:
 120         foreach my $u (@{$ibx->cloneurl}) {
 121                 next if $seen{$u}++;
 122                 push @urls, $u =~ /\Ahttps?:/ ? qq(<a\nhref="$u">$u</a>) : $u;
 123         }
 124
 125         $urls .= "\n" .  join("\n", map { "\tgit clone --mirror $_" } @urls);
 126         if (defined $max) {
 127                 my $addrs = $ibx->{address};
 128                 $addrs = join(' ', @$addrs) if ref($addrs) eq 'ARRAY';
 129                 $urls .=  <<EOF
 130
 131
 132         # If you have public-inbox 1.1+ installed, you may
 133         # initialize and index your mirror using the following commands:
 134         public-inbox-init -V2 $ibx->{name} $dir/ $http \\
 135                 $addrs
 136         public-inbox-index $dir
 137 EOF
 138         } else { # v1
 139                 $urls .= "\n";
 140         }
 141
 142         my $cfg_link = ($ctx->{-upfx} // '').'_/text/config/raw';
 143         $urls .= <<EOF;
 144
 145 Example <a
 146 href="$cfg_link">config snippet</a> for mirrors.
 147 EOF
 148         my @nntp = map { qq(<a\nhref="$_">$_</a>) } @{$ibx->nntp_url};
 149         if (@nntp) {
 150                 $urls .= @nntp == 1 ? 'Newsgroup' : 'Newsgroups are';
 151                 $urls .= ' available over NNTP:';
 152                 $urls .= "\n\t" . join("\n\t", @nntp) . "\n";
 153         }
 154         if ($urls =~ m!\b[^:]+://\w+\.onion/!) {
 155                 $urls .= " note: .onion URLs require Tor: ";
 156                 $urls .= qq[<a\nhref="$TOR_URL">$TOR_URL</a>];
 157         }
 158         '<hr><pre>'.join("\n\n",
 159                 $desc,
 160                 $urls,
 161                 code_footer($ctx->{env})
 162         ).'</pre></body></html>';
 163 }
 164
 165 # callback for HTTP.pm (and any other PSGI servers)
 166 sub getline {
 167         my ($ctx) = @_;
 168         my $cb = $ctx->{cb} or return;
 169         while (defined(my $x = $cb->($ctx))) { # x = smsg or scalar non-ref
 170                 if (ref($x)) { # smsg
 171                         my $eml = $ctx->{-inbox}->smsg_eml($x) or next;
 172                         $ctx->{smsg} = $x;
 173                         return $ctx->translate($cb->($ctx, $eml));
 174                 } else { # scalar
 175                         return $ctx->translate($x);
 176                 }
 177         }
 178         delete $ctx->{cb};
 179         $ctx->zflush(_html_end($ctx));
 180 }
 181
 182 sub html_oneshot ($$;$) {
 183         my ($ctx, $code, $sref) = @_;
 184         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8',
 185                 'Content-Length' => undef ];
 186         bless $ctx, __PACKAGE__;
 187         $ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($res_hdr, $ctx->{env});
 188         $ctx->{base_url} //= do {
 189                 $ctx->zmore(html_top($ctx));
 190                 base_url($ctx);
 191         };
 192         $ctx->zmore($$sref) if $sref;
 193         my $bdy = $ctx->zflush(_html_end($ctx));
 194         $res_hdr->[3] = bytes::length($bdy);
 195         [ $code, $res_hdr, [ $bdy ] ]
 196 }
 197
 198 sub async_next ($) {
 199         my ($http) = @_; # PublicInbox::HTTP
 200         my $ctx = $http->{forward} or return;
 201         eval {
 202                 if (my $smsg = $ctx->{smsg} = $ctx->{cb}->($ctx)) {
 203                         $ctx->smsg_blob($smsg);
 204                 } else {
 205                         $ctx->{http_out}->write(
 206                                         $ctx->translate(_html_end($ctx)));
 207                         $ctx->close; # GzipFilter->close
 208                 }
 209         };
 210         warn "E: $@" if $@;
 211 }
 212
 213 sub aresponse {
 214         my ($ctx, $code, $cb) = @_;
 215         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8' ];
 216         init($ctx, $cb);
 217         $ctx->psgi_response($code, $res_hdr);
 218 }
 219
 220 1;