lib/PublicInbox/WwwStream.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # HTML body stream for which yields getline+close methods for
   5 # generic PSGI servers and callbacks for public-inbox-httpd.
   6 #
   7 # See PublicInbox::GzipFilter parent class for more info.
   8 package PublicInbox::WwwStream;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(Exporter PublicInbox::GzipFilter);
  12 our @EXPORT_OK = qw(html_oneshot);
  13 use PublicInbox::Hval qw(ascii_html prurl ts2str);
  14 our $TOR_URL = 'https://www.torproject.org/';
  15
  16 our $CODE_URL = [ qw(
  17 http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git
  18 https://public-inbox.org/public-inbox.git) ];
  19
  20 sub base_url ($) {
  21         my $ctx = shift;
  22         my $base_url = $ctx->{ibx}->base_url($ctx->{env});
  23         chop $base_url; # no trailing slash for clone
  24         $base_url;
  25 }
  26
  27 sub init {
  28         my ($ctx, $cb) = @_;
  29         $ctx->{cb} = $cb;
  30         $ctx->{base_url} = base_url($ctx);
  31         bless $ctx, __PACKAGE__;
  32 }
  33
  34 sub async_eml { # for async_blob_cb
  35         my ($ctx, $eml) = @_;
  36         $ctx->{http_out}->write($ctx->translate($ctx->{cb}->($ctx, $eml)));
  37 }
  38
  39 sub html_top ($) {
  40         my ($ctx) = @_;
  41         my $ibx = $ctx->{ibx};
  42         my $desc = ascii_html($ibx->description);
  43         my $title = delete($ctx->{-title_html}) // $desc;
  44         my $upfx = $ctx->{-upfx} || '';
  45         my $help = $upfx.'_/text/help/';
  46         my $color = $upfx.'_/text/color/';
  47         my $atom = $ctx->{-atom} || $upfx.'new.atom';
  48         my $top = "<b>$desc</b>";
  49         if (my $t_max = $ctx->{-t_max}) {
  50                 $t_max = ts2str($t_max);
  51                 $top = qq(<a\nhref="$upfx?t=$t_max">$top</a>);
  52         # we had some kind of query, link to /$INBOX/?t=YYYYMMDDhhmmss
  53         } elsif ($ctx->{qp}->{t}) {
  54                 $top = qq(<a\nhref="./">$top</a>);
  55         }
  56         my $code = $ibx->{coderepo} ? qq( / <a\nhref=#code>code</a>) : '';
  57         my $links = qq(<a\nhref="$help">help</a> / ).
  58                         qq(<a\nhref="$color">color</a> / ).
  59                         qq(<a\nhref=#mirror>mirror</a>$code / ).
  60                         qq(<a\nhref="$atom">Atom feed</a>);
  61         if ($ibx->isrch) {
  62                 my $q_val = delete($ctx->{-q_value_html}) // '';
  63                 $q_val = qq(\nvalue="$q_val") if $q_val ne '';
  64                 # XXX gross, for SearchView.pm
  65                 my $extra = delete($ctx->{-extra_form_html}) // '';
  66                 my $action = $upfx eq '' ? './' : $upfx;
  67                 $top = qq{<form\naction="$action"><pre>$top} .
  68                           qq{\n<input\nname=q\ntype=text$q_val />} .
  69                           $extra .
  70                           qq{<input\ntype=submit\nvalue=search />} .
  71                           ' ' . $links .
  72                           q{</pre></form>}
  73         } else {
  74                 $top = '<pre>' . $top . "\n" . $links . '</pre>';
  75         }
  76         "<html><head><title>$title</title>" .
  77                 qq(<link\nrel=alternate\ntitle="Atom feed"\n).
  78                 qq(href="$atom"\ntype="application/atom+xml"/>) .
  79                 $ctx->{www}->style($upfx) .
  80                 '</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
  81 }
  82
  83 sub coderepos ($) {
  84         my ($ctx) = @_;
  85         my $cr = $ctx->{ibx}->{coderepo} // return ();
  86         my $cfg = $ctx->{www}->{pi_cfg};
  87         my $upfx = ($ctx->{-upfx} // ''). '../';
  88         my @ret;
  89         for my $cr_name (@$cr) {
  90                 $ret[0] //= <<EOF;
  91 <a id=code>code repositories for project(s) associated with this inbox:
  92 EOF
  93                 my $urls = $cfg->get_all("coderepo.$cr_name.cgiturl");
  94                 if ($urls) {
  95                         for (@$urls) {
  96                                 # relative or absolute URL?, prefix relative
  97                                 # "foo.git" with appropriate number of "../"
  98                                 my $u = m!\A(?:[a-z\+]+:)?//! ? $_ : $upfx.$_;
  99                                 $u = ascii_html(prurl($ctx->{env}, $u));
 100                                 $ret[0] .= qq(\n\t<a\nhref="$u">$u</a>);
 101                         }
 102                 } else {
 103                         $ret[0] .= qq[\n\t$cr_name.git (no URL configured)];
 104                 }
 105         }
 106         @ret; # may be empty, this sub is called as an arg for join()
 107 }
 108
 109 sub code_footer ($) {
 110         my ($env) = @_;
 111         my $u = prurl($env, $CODE_URL);
 112         my $arg = $u;
 113         if ($arg =~ s!\A(https?://)([^/\.]+)\.onion/!$1\$hostname\.onion/!i) {
 114                 "AGPL code for this site:\n\thostname=$2\n\t" .
 115                 qq(torsocks git clone <a\nhref="$u">$arg</a>)
 116         } else {
 117                 qq(AGPL code for this site: git clone <a\nhref="$u">$u</a>)
 118         }
 119 }
 120
 121 sub _html_end {
 122         my ($ctx) = @_;
 123         my $urls = <<EOF;
 124 <a
 125 id=mirror>This inbox may be cloned and mirrored by anyone:</a>
 126 EOF
 127
 128         my $ibx = $ctx->{ibx};
 129         my $desc = ascii_html($ibx->description);
 130
 131         my @urls;
 132         my $http = $ctx->{base_url};
 133         my $max = $ibx->max_git_epoch;
 134         my $dir = (split(m!/!, $http))[-1];
 135         my %seen = ($http => 1);
 136         # TODO: some of these URLs may be too long and we may need to
 137         # do something like code_footer() above, but these are local
 138         # admin-defined
 139         if (defined($max)) { # v2
 140                 for my $i (0..$max) {
 141                         # old epochs my be deleted:
 142                         -d "$ibx->{inboxdir}/git/$i.git" or next;
 143                         my $url = "$http/$i";
 144                         $seen{$url} = 1;
 145                         push @urls, "$url $dir/git/$i.git";
 146                 }
 147                 my $nr = scalar(@urls);
 148                 if ($nr > 1) {
 149                         $urls .= "\n\t# this inbox consists of $nr epochs:";
 150                         $urls[0] .= "\t# oldest";
 151                         $urls[-1] .= "\t# newest";
 152                 }
 153         } else { # v1
 154                 push @urls, $http;
 155         }
 156
 157         # FIXME: epoch splits can be different in other repositories,
 158         # use the "cloneurl" file as-is for now:
 159         foreach my $u (@{$ibx->cloneurl}) {
 160                 next if $seen{$u}++;
 161                 push @urls, $u =~ /\Ahttps?:/ ? qq(<a\nhref="$u">$u</a>) : $u;
 162         }
 163
 164         $urls .= "\n" . join('', map { "\tgit clone --mirror $_\n" } @urls);
 165         if (my $addrs = $ibx->{address}) {
 166                 $addrs = join(' ', @$addrs) if ref($addrs) eq 'ARRAY';
 167                 my $v = defined $max ? '-V2' : '-V1';
 168                 $urls .= <<EOF;
 169
 170         # If you have public-inbox 1.1+ installed, you may
 171         # initialize and index your mirror using the following commands:
 172         public-inbox-init $v $ibx->{name} $dir/ $http \\
 173                 $addrs
 174         public-inbox-index $dir
 175 EOF
 176         }
 177         my $cfg_link = ($ctx->{-upfx} // '').'_/text/config/raw';
 178         $urls .= <<EOF;
 179
 180 Example <a
 181 href="$cfg_link">config snippet</a> for mirrors.
 182 EOF
 183         my @nntp = map { qq(<a\nhref="$_">$_</a>) } @{$ibx->nntp_url};
 184         if (@nntp) {
 185                 $urls .= @nntp == 1 ? 'Newsgroup' : 'Newsgroups are';
 186                 $urls .= ' available over NNTP:';
 187                 $urls .= "\n\t" . join("\n\t", @nntp) . "\n";
 188         }
 189         if ($urls =~ m!\b[^:]+://\w+\.onion/!) {
 190                 $urls .= " note: .onion URLs require Tor: ";
 191                 $urls .= qq[<a\nhref="$TOR_URL">$TOR_URL</a>];
 192         }
 193         '<hr><pre>'.join("\n\n",
 194                 $desc,
 195                 $urls,
 196                 coderepos($ctx),
 197                 code_footer($ctx->{env})
 198         ).'</pre></body></html>';
 199 }
 200
 201 # callback for HTTP.pm (and any other PSGI servers)
 202 sub getline {
 203         my ($ctx) = @_;
 204         my $cb = $ctx->{cb} or return;
 205         while (defined(my $x = $cb->($ctx))) { # x = smsg or scalar non-ref
 206                 if (ref($x)) { # smsg
 207                         my $eml = $ctx->{ibx}->smsg_eml($x) or next;
 208                         $ctx->{smsg} = $x;
 209                         return $ctx->translate($cb->($ctx, $eml));
 210                 } else { # scalar
 211                         return $ctx->translate($x);
 212                 }
 213         }
 214         delete $ctx->{cb};
 215         $ctx->zflush(_html_end($ctx));
 216 }
 217
 218 sub html_oneshot ($$;$) {
 219         my ($ctx, $code, $sref) = @_;
 220         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8',
 221                 'Content-Length' => undef ];
 222         bless $ctx, __PACKAGE__;
 223         $ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($res_hdr, $ctx->{env});
 224         $ctx->{base_url} //= do {
 225                 $ctx->zmore(html_top($ctx));
 226                 base_url($ctx);
 227         };
 228         $ctx->zmore($$sref) if $sref;
 229         my $bdy = $ctx->zflush(_html_end($ctx));
 230         $res_hdr->[3] = length($bdy);
 231         [ $code, $res_hdr, [ $bdy ] ]
 232 }
 233
 234 sub async_next ($) {
 235         my ($http) = @_; # PublicInbox::HTTP
 236         my $ctx = $http->{forward} or return;
 237         eval {
 238                 if (my $smsg = $ctx->{smsg} = $ctx->{cb}->($ctx)) {
 239                         $ctx->smsg_blob($smsg);
 240                 } else {
 241                         $ctx->{http_out}->write(
 242                                         $ctx->translate(_html_end($ctx)));
 243                         $ctx->close; # GzipFilter->close
 244                 }
 245         };
 246         warn "E: $@" if $@;
 247 }
 248
 249 sub aresponse {
 250         my ($ctx, $code, $cb) = @_;
 251         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8' ];
 252         init($ctx, $cb);
 253         $ctx->psgi_response($code, $res_hdr);
 254 }
 255
 256 1;