lib/PublicInbox/WwwStream.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # HTML body stream for which yields getline+close methods for
   5 # generic PSGI servers and callbacks for public-inbox-httpd.
   6 #
   7 # See PublicInbox::GzipFilter parent class for more info.
   8 package PublicInbox::WwwStream;
   9 use strict;
  10 use parent qw(Exporter PublicInbox::GzipFilter);
  11 our @EXPORT_OK = qw(html_oneshot);
  12 use bytes (); # length
  13 use PublicInbox::Hval qw(ascii_html prurl ts2str);
  14 our $TOR_URL = 'https://www.torproject.org/';
  15 our $CODE_URL = [ qw(http://ou63pmih66umazou.onion/public-inbox.git
  16         https://public-inbox.org/public-inbox.git) ];
  17
  18 sub base_url ($) {
  19         my $ctx = shift;
  20         my $base_url = $ctx->{ibx}->base_url($ctx->{env});
  21         chop $base_url; # no trailing slash for clone
  22         $base_url;
  23 }
  24
  25 sub init {
  26         my ($ctx, $cb) = @_;
  27         $ctx->{cb} = $cb;
  28         $ctx->{base_url} = base_url($ctx);
  29         bless $ctx, __PACKAGE__;
  30 }
  31
  32 sub async_eml { # for async_blob_cb
  33         my ($ctx, $eml) = @_;
  34         $ctx->{http_out}->write($ctx->translate($ctx->{cb}->($ctx, $eml)));
  35 }
  36
  37 sub html_top ($) {
  38         my ($ctx) = @_;
  39         my $ibx = $ctx->{ibx};
  40         my $desc = ascii_html($ibx->description);
  41         my $title = delete($ctx->{-title_html}) // $desc;
  42         my $upfx = $ctx->{-upfx} || '';
  43         my $help = $upfx.'_/text/help';
  44         my $color = $upfx.'_/text/color';
  45         my $atom = $ctx->{-atom} || $upfx.'new.atom';
  46         my $top = "<b>$desc</b>";
  47         if (my $t_max = $ctx->{-t_max}) {
  48                 $t_max = ts2str($t_max);
  49                 $top = qq(<a\nhref="$upfx?t=$t_max">$top</a>);
  50         # we had some kind of query, link to /$INBOX/?t=YYYYMMDDhhmmss
  51         } elsif ($ctx->{qp}->{t}) {
  52                 $top = qq(<a\nhref="./">$top</a>);
  53         }
  54         my $links = qq(<a\nhref="$help">help</a> / ).
  55                         qq(<a\nhref="$color">color</a> / ).
  56                         qq(<a\nhref=#mirror>mirror</a> / ).
  57                         qq(<a\nhref="$atom">Atom feed</a>);
  58         if ($ibx->isrch) {
  59                 my $q_val = delete($ctx->{-q_value_html}) // '';
  60                 $q_val = qq(\nvalue="$q_val") if $q_val ne '';
  61                 # XXX gross, for SearchView.pm
  62                 my $extra = delete($ctx->{-extra_form_html}) // '';
  63                 my $action = $upfx eq '' ? './' : $upfx;
  64                 $top = qq{<form\naction="$action"><pre>$top} .
  65                           qq{\n<input\nname=q\ntype=text$q_val />} .
  66                           $extra .
  67                           qq{<input\ntype=submit\nvalue=search />} .
  68                           ' ' . $links .
  69                           q{</pre></form>}
  70         } else {
  71                 $top = '<pre>' . $top . "\n" . $links . '</pre>';
  72         }
  73         "<html><head><title>$title</title>" .
  74                 qq(<link\nrel=alternate\ntitle="Atom feed"\n).
  75                 qq(href="$atom"\ntype="application/atom+xml"/>) .
  76                 $ctx->{www}->style($upfx) .
  77                 '</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
  78 }
  79
  80 sub coderepos ($) {
  81         my ($ctx) = @_;
  82         my $cr = $ctx->{ibx}->{coderepo} // return ();
  83         my $cfg = $ctx->{www}->{pi_cfg};
  84         my $upfx = ($ctx->{-upfx} // ''). '../';
  85         my @ret;
  86         for my $cr_name (@$cr) {
  87                 my $urls = $cfg->{"coderepo.$cr_name.cgiturl"} // next;
  88                 $ret[0] //= <<EOF;
  89 code repositories for the project(s) associated with this inbox:
  90 EOF
  91                 for (@$urls) {
  92                         # relative or absolute URL?, prefix relative "foo.git"
  93                         # with appropriate number of "../"
  94                         my $u = m!\A(?:[a-z\+]+:)?//! ? $_ : $upfx.$_;
  95                         $u = ascii_html(prurl($ctx->{env}, $u));
  96                         $ret[0] .= qq(\n\t<a\nhref="$u">$u</a>);
  97                 }
  98         }
  99         @ret; # may be empty, this sub is called as an arg for join()
 100 }
 101
 102 sub code_footer ($) {
 103         my ($env) = @_;
 104         my $u = prurl($env, $CODE_URL);
 105         qq(AGPL code for this site: git clone <a\nhref="$u">$u</a>)
 106 }
 107
 108 sub _html_end {
 109         my ($ctx) = @_;
 110         my $urls = <<EOF;
 111 <a
 112 id=mirror>This inbox may be cloned and mirrored by anyone:</a>
 113 EOF
 114
 115         my $ibx = $ctx->{ibx};
 116         my $desc = ascii_html($ibx->description);
 117
 118         my @urls;
 119         my $http = $ctx->{base_url};
 120         my $max = $ibx->max_git_epoch;
 121         my $dir = (split(m!/!, $http))[-1];
 122         my %seen = ($http => 1);
 123         if (defined($max)) { # v2
 124                 for my $i (0..$max) {
 125                         # old epochs my be deleted:
 126                         -d "$ibx->{inboxdir}/git/$i.git" or next;
 127                         my $url = "$http/$i";
 128                         $seen{$url} = 1;
 129                         push @urls, "$url $dir/git/$i.git";
 130                 }
 131                 my $nr = scalar(@urls);
 132                 if ($nr > 1) {
 133                         $urls .= "\n\t# this inbox consists of $nr epochs:";
 134                         $urls[0] .= "\t# oldest";
 135                         $urls[-1] .= "\t# newest";
 136                 }
 137         } else { # v1
 138                 push @urls, $http;
 139         }
 140
 141         # FIXME: epoch splits can be different in other repositories,
 142         # use the "cloneurl" file as-is for now:
 143         foreach my $u (@{$ibx->cloneurl}) {
 144                 next if $seen{$u}++;
 145                 push @urls, $u =~ /\Ahttps?:/ ? qq(<a\nhref="$u">$u</a>) : $u;
 146         }
 147
 148         $urls .= "\n" . join('', map { "\tgit clone --mirror $_\n" } @urls);
 149         if (my $addrs = $ibx->{address}) {
 150                 $addrs = join(' ', @$addrs) if ref($addrs) eq 'ARRAY';
 151                 my $v = defined $max ? '-V2' : '-V1';
 152                 $urls .= <<EOF;
 153
 154         # If you have public-inbox 1.1+ installed, you may
 155         # initialize and index your mirror using the following commands:
 156         public-inbox-init $v $ibx->{name} $dir/ $http \\
 157                 $addrs
 158         public-inbox-index $dir
 159 EOF
 160         }
 161         my $cfg_link = ($ctx->{-upfx} // '').'_/text/config/raw';
 162         $urls .= <<EOF;
 163
 164 Example <a
 165 href="$cfg_link">config snippet</a> for mirrors.
 166 EOF
 167         my @nntp = map { qq(<a\nhref="$_">$_</a>) } @{$ibx->nntp_url};
 168         if (@nntp) {
 169                 $urls .= @nntp == 1 ? 'Newsgroup' : 'Newsgroups are';
 170                 $urls .= ' available over NNTP:';
 171                 $urls .= "\n\t" . join("\n\t", @nntp) . "\n";
 172         }
 173         if ($urls =~ m!\b[^:]+://\w+\.onion/!) {
 174                 $urls .= " note: .onion URLs require Tor: ";
 175                 $urls .= qq[<a\nhref="$TOR_URL">$TOR_URL</a>];
 176         }
 177         '<hr><pre>'.join("\n\n",
 178                 $desc,
 179                 $urls,
 180                 coderepos($ctx),
 181                 code_footer($ctx->{env})
 182         ).'</pre></body></html>';
 183 }
 184
 185 # callback for HTTP.pm (and any other PSGI servers)
 186 sub getline {
 187         my ($ctx) = @_;
 188         my $cb = $ctx->{cb} or return;
 189         while (defined(my $x = $cb->($ctx))) { # x = smsg or scalar non-ref
 190                 if (ref($x)) { # smsg
 191                         my $eml = $ctx->{ibx}->smsg_eml($x) or next;
 192                         $ctx->{smsg} = $x;
 193                         return $ctx->translate($cb->($ctx, $eml));
 194                 } else { # scalar
 195                         return $ctx->translate($x);
 196                 }
 197         }
 198         delete $ctx->{cb};
 199         $ctx->zflush(_html_end($ctx));
 200 }
 201
 202 sub html_oneshot ($$;$) {
 203         my ($ctx, $code, $sref) = @_;
 204         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8',
 205                 'Content-Length' => undef ];
 206         bless $ctx, __PACKAGE__;
 207         $ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($res_hdr, $ctx->{env});
 208         $ctx->{base_url} //= do {
 209                 $ctx->zmore(html_top($ctx));
 210                 base_url($ctx);
 211         };
 212         $ctx->zmore($$sref) if $sref;
 213         my $bdy = $ctx->zflush(_html_end($ctx));
 214         $res_hdr->[3] = bytes::length($bdy);
 215         [ $code, $res_hdr, [ $bdy ] ]
 216 }
 217
 218 sub async_next ($) {
 219         my ($http) = @_; # PublicInbox::HTTP
 220         my $ctx = $http->{forward} or return;
 221         eval {
 222                 if (my $smsg = $ctx->{smsg} = $ctx->{cb}->($ctx)) {
 223                         $ctx->smsg_blob($smsg);
 224                 } else {
 225                         $ctx->{http_out}->write(
 226                                         $ctx->translate(_html_end($ctx)));
 227                         $ctx->close; # GzipFilter->close
 228                 }
 229         };
 230         warn "E: $@" if $@;
 231 }
 232
 233 sub aresponse {
 234         my ($ctx, $code, $cb) = @_;
 235         my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8' ];
 236         init($ctx, $cb);
 237         $ctx->psgi_response($code, $res_hdr);
 238 }
 239
 240 1;