#!perl -w
# Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
# Basic tool to create a Xapian search index for a public-inbox.
# Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
# highly recommended: eatmydata public-inbox-index INBOX_DIR

use strict;
use v5.10.1;
use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
my $usage = 'public-inbox-index [options] INBOX_DIR';
my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
usage: $usage

  Create and update search indices

options:

  --no-fsync          speed up indexing, risk corruption on power outage
  --indexlevel=LEVEL  `basic', 'medium', or `full' (default: full)
  --compact | -c      run public-inbox-compact(1) after indexing
  --sequential-shard  index Xapian shards sequentially for slow storage
  --jobs=NUM          set or disable parallelization (NUM=0)
  --batch-size=BYTES  flush changes to OS after a given number of bytes
  --max-size=BYTES    do not index messages larger than the given size
  --reindex           index previously indexed data (if upgrading)
  --rethread          regenerate thread IDs (if upgrading, use sparingly)
  --prune             prune git storage on discontiguous history
  --verbose | -v      increase verbosity (may be repeated)
  --help | -?         show this help

BYTES may use `k', `m', and `g' suffixes (e.g. `10m' for 10 megabytes)
See public-inbox-index(1) man page for full documentation.
EOF
my $compact_opt;
my $opt = { quiet => -1, compact => 0, maxsize => undef, fsync => 1 };
GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune
		fsync|sync! xapianonly|xapian-only
		indexlevel|L=s maxsize|max-size=s batchsize|batch-size=s
		sequentialshard|seq-shard|sequential-shard
		help|?))
	or die "bad command-line args\n$usage";
if ($opt->{help}) { print $help; exit 0 };
die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;

# require lazily to speed up --help
require PublicInbox::Admin;
PublicInbox::Admin::require_or_die('-index');

if ($opt->{compact}) {
	require PublicInbox::Xapcmd;
	PublicInbox::Xapcmd::check_compact();
	$compact_opt = { -coarse_lock => 1, compact => 1 };
	if (defined(my $jobs = $opt->{jobs})) {
		$compact_opt->{jobs} = $jobs;
	}
}

my $cfg = PublicInbox::Config->new; # Config is loaded by Admin
my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
PublicInbox::Admin::require_or_die('-index');
unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }

my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
if (defined $max_size) {
	PublicInbox::Admin::parse_unsigned(\$max_size) or
		die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
}

my $bs = $opt->{batchsize} // $cfg->{lc('publicInbox.indexBatchSize')};
if (defined $bs) {
	PublicInbox::Admin::parse_unsigned(\$bs) or
		die "`publicInbox.indexBatchSize=$bs' not parsed\n";
}
no warnings 'once';
local $PublicInbox::SearchIdx::BATCH_BYTES = $bs if defined($bs);
use warnings 'once';

# out-of-the-box builds of Xapian 1.4.x are still limited to 32-bit
# https://getting-started-with-xapian.readthedocs.io/en/latest/concepts/indexing/limitations.html
local $ENV{XAPIAN_FLUSH_THRESHOLD} ||= '4294967295' if defined($bs);

my $s = $opt->{sequentialshard} //
			$cfg->{lc('publicInbox.indexSequentialShard')};
if (defined $s) {
	my $v = $cfg->git_bool($s);
	defined($v) or
		die "`publicInbox.indexSequentialShard=$s' not boolean\n";
	$opt->{sequentialshard} = $v;
}

my $mods = {};
foreach my $ibx (@ibxs) {
	# XXX: users can shoot themselves in the foot, with opt->{indexlevel}
	$ibx->{indexlevel} //= $opt->{indexlevel} // ($opt->{xapianonly} ?
			'full' : PublicInbox::Admin::detect_indexlevel($ibx));
	$ibx->{index_max_size} = $max_size;
	PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
}

PublicInbox::Admin::require_or_die(keys %$mods);
require PublicInbox::InboxWritable;
PublicInbox::Admin::progress_prepare($opt);
for my $ibx (@ibxs) {
	$ibx = PublicInbox::InboxWritable->new($ibx);
	if ($opt->{compact} >= 2) {
		PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
	}
	$ibx->{-no_fsync} = 1 if !$opt->{fsync};

	my $ibx_opt = $opt;
	if (defined(my $s = $ibx->{indexsequentialshard})) {
		defined(my $v = $cfg->git_bool($s)) or die <<EOL;
publicInbox.$ibx->{name}.indexSequentialShard not boolean
EOL
		$ibx_opt = { %$opt, sequentialshard => $v };
	}
	PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
	if ($compact_opt) {
		local $compact_opt->{jobs} = 0 if $ibx_opt->{sequentialshard};
		PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
	}
}