#!/usr/bin/perl -w
# Copyright (C) 2019 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
#
# Used for purging messages entirely from a public-inbox.  Currently
# supports v2 inboxes only, for now.
use strict;
use warnings;
use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
use PublicInbox::AdminEdit;
PublicInbox::Admin::check_require('-index');
require PublicInbox::Filter::Base;
require PublicInbox::MIME;
require PublicInbox::V2Writable;

{ no warnings 'once'; *REJECT = *PublicInbox::Filter::Base::REJECT }

my $usage = "$0 [--all] [INBOX_DIRS] </path/to/message";
my $opt = { verbose => 1, all => 0, -min_inbox_version => 2 };
GetOptions($opt, @PublicInbox::AdminEdit::OPT) or
	die "bad command-line args\n$usage\n";

my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, $opt);

foreach my $ibx (@ibxs) {
	my $lvl = $ibx->{indexlevel};
	if (defined $lvl) {
		PublicInbox::Admin::indexlevel_ok_or_die($lvl);
		next;
	}

	# Undefined indexlevel, so `full'...
	# Search::Xapian exists and the DB can be read, at least, fine
	$ibx->search and next;

	# it's possible for a Xapian directory to exist, but Search::Xapian
	# to go missing/broken.  Make sure it's purged in that case:
	$ibx->over or die "no over.sqlite3 in $ibx->{mainrepo}\n";

	# $ibx->{search} is populated by $ibx->over call
	my $xdir_ro = $ibx->{search}->xdir(1);
	my $npart = 0;
	foreach my $part (<$xdir_ro/*>) {
		if (-d $part && $part =~ m!/[0-9]+\z!) {
			my $bytes = 0;
			$bytes += -s $_ foreach glob("$part/*");
			$npart++ if $bytes;
		}
	}
	if ($npart) {
		PublicInbox::Admin::require_or_die('-search');
	} else {
		# somebody could "rm -r" all the Xapian directories;
		# let them purge the overview, at least
		$ibx->{indexlevel} ||= 'basic';
	}
}

my $data = do { local $/; scalar <STDIN> };
$data =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
my $n_purged = 0;

foreach my $ibx (@ibxs) {
	my $mime = PublicInbox::MIME->new($data);
	my $v2w = PublicInbox::V2Writable->new($ibx, 0);

	my $commits = $v2w->purge($mime) || [];

	if (my $scrub = $ibx->filter($v2w)) {
		my $scrubbed = $scrub->scrub($mime, 1);

		if ($scrubbed && $scrubbed != REJECT()) {
			my $scrub_commits = $v2w->purge($scrubbed);
			push @$commits, @$scrub_commits if $scrub_commits;
		}
	}

	$v2w->done;

	if ($opt->{verbose}) { # should we consider this machine-parseable?
		print "$ibx->{mainrepo}:";
		if (scalar @$commits) {
			print join("\n\t", '', @$commits), "\n";
		} else {
			print " NONE\n";
		}
	}
	$n_purged += scalar @$commits;
}

# behave like "rm -f"
exit(0) if ($opt->{force} || $n_purged);

warn "Not found\n" if $opt->{verbose};
exit(1);