+# Convert git "approxidate" ranges to something usable with our
+# Xapian indices. At the moment, Xapian only offers a C++-only API
+# and neither the SWIG nor XS bindings allow us to use custom code
+# to parse dates (and libgit2 doesn't expose git__date_parse, either,
+# so we're running git-rev-parse(1)).
+# This replaces things we need to send to $git->date_parse with
+# "\0".$strftime_format.['+'|$idx]."\0" placeholders
+sub date_parse_prepare {
+ my ($to_parse, $pfx, $range) = @_;
+ # are we inside a parenthesized statement?
+ my $end = $range =~ s/([\)\s]*)\z// ? $1 : '';
+ my @r = split(/\.\./, $range, 2);
+
+ # expand "d:20101002" => "d:20101002..20101003" and like
+ # n.b. git doesn't do YYYYMMDD w/o '-', it needs YYYY-MM-DD
+ # We upgrade "d:" to "dt:" to iff using approxidate
+ if ($pfx eq 'd') {
+ my $fmt = "\0%Y%m%d";
+ if (!defined($r[1])) {
+ if ($r[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})\z/) {
+ push @$to_parse, "$1-$2-$3";
+ # we could've handled as-is, but we need
+ # to parse anyways for "d+" below
+ } else {
+ push @$to_parse, $r[0];
+ if ($r[0] !~ /\A[0-9]{4}-[0-9]{2}-[0-9]{2}\z/) {
+ $pfx = 'dt';
+ $fmt = "\0%Y%m%d%H%M%S";
+ }
+ }
+ $r[0] = "$fmt+$#$to_parse\0";
+ $r[1] = "$fmt+\0";
+ } else {
+ for my $x (@r) {
+ next if $x eq '' || $x =~ /\A[0-9]{8}\z/;
+ push @$to_parse, $x;
+ if ($x !~ /\A[0-9]{4}-[0-9]{2}-[0-9]{2}\z/) {
+ $pfx = 'dt';
+ }
+ $x = "$fmt$#$to_parse\0";
+ }
+ if ($pfx eq 'dt') {
+ for (@r) {
+ s/\0%Y%m%d/\0%Y%m%d%H%M%S/;
+ s/\A([0-9]{8})\z/${1}000000/;
+ }
+ }
+ }
+ } elsif ($pfx eq 'dt') {
+ if (!defined($r[1])) { # git needs gaps and not /\d{14}/
+ if ($r[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})
+ ([0-9]{2})([0-9]{2})([0-9]{2})\z/x) {
+ push @$to_parse, "$1-$2-$3 $4:$5:$6";
+ } else {
+ push @$to_parse, $r[0];
+ }
+ $r[0] = "\0%Y%m%d%H%M%S$#$to_parse\0";
+ $r[1] = "\0%Y%m%d%H%M%S+\0";
+ } else {
+ for my $x (@r) {
+ next if $x eq '' || $x =~ /\A[0-9]{14}\z/;
+ push @$to_parse, $x;
+ $x = "\0%Y%m%d%H%M%S$#$to_parse\0";
+ }
+ }
+ } else { # "rt", let git interpret "YYYY", deal with Y10K later :P
+ for my $x (@r) {
+ next if $x eq '' || $x =~ /\A[0-9]{5,}\z/;
+ push @$to_parse, $x;
+ $x = "\0%s$#$to_parse\0";
+ }
+ $r[1] //= "\0%s+\0"; # add 1 day
+ }
+ "$pfx:".join('..', @r).$end;
+}
+
+sub date_parse_finalize {
+ my ($git, $to_parse) = @_;
+ # git-rev-parse can handle any number of args up to system
+ # limits (around (4096*32) bytes on Linux).
+ my @r = $git->date_parse(@$to_parse);
+ # n.b. git respects TZ, times stored in SQLite/Xapian are always UTC,
+ # and gmtime doesn't seem to do the right thing when TZ!=UTC
+ my ($i, $t);
+ $_[2] =~ s/\0(%[%YmdHMSs]+)([0-9\+]+)\0/
+ $t = $2 eq '+' ? ($r[$i]+86400) : $r[$i=$2+0];
+ $1 eq '%s' ? $t : strftime($1, gmtime($t))/sge;
+}
+
+# n.b. argv never has NUL, though we'll need to filter it out
+# if this $argv isn't from a command execution
+sub query_argv_to_string {
+ my (undef, $git, $argv) = @_;
+ my $to_parse;
+ my $tmp = join(' ', map {;
+ if (s!\b(d|rt|dt):(\S+)\z!date_parse_prepare(
+ $to_parse //= [], $1, $2)!sge) {
+ $_;
+ } elsif (/\s/) {
+ s/(.*?)\b(\w+:)// ? qq{$1$2"$_"} : qq{"$_"};
+ } else {
+ $_
+ }
+ } @$argv);
+ date_parse_finalize($git, $to_parse, $tmp) if $to_parse;
+ $tmp
+}
+
+# this is for the WWW "q=" query parameter and "lei q --stdin"
+# it can't do d:"5 days ago", but it will do d:5.days.ago
+sub query_approxidate {
+ my (undef, $git) = @_; # $_[2] = $query_string (modified in-place)
+ my $DQ = qq<"\x{201c}\x{201d}>; # Xapian can use curly quotes
+ $_[2] =~ tr/\x00/ /; # Xapian doesn't do NUL, we use it as a placeholder
+ my ($terms, $phrase, $to_parse);
+ $_[2] =~ s{([^$DQ]*)([$DQ][^$DQ]*[$DQ])?}{
+ ($terms, $phrase) = ($1, $2);
+ $terms =~ s!\b(d|rt|dt):(\S+)!
+ date_parse_prepare($to_parse //= [], $1, $2)!sge;
+ $terms.($phrase // '');
+ }sge;
+ date_parse_finalize($git, $to_parse, $_[2]) if $to_parse;
+}
+