Makefile.PL

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use ExtUtils::MakeMaker;
   6 open my $m, '<', 'MANIFEST' or die "open(MANIFEST): $!\n";
   7 chomp(my @manifest = (<$m>));
   8 push @manifest, 'lib/PublicInbox.pm'; # generated
   9 my @EXE_FILES = grep(m!^script/!, @manifest);
  10 my $v = {};
  11 my $t = {};
  12
  13 # do not sort
  14 my @RELEASES = qw(v1.6.1 v1.6.0 v1.5.0 v1.4.0 v1.3.0 v1.2.0 v1.1.0-pre1 v1.0.0);
  15
  16 $v->{news_deps} = [ map { "Documentation/RelNotes/$_.eml" } @RELEASES ];
  17 $v->{txt} = [ qw(INSTALL README COPYING TODO HACKING) ];
  18 my @dtxt = grep(m!\ADocumentation/[^/]+\.txt\z!, @manifest);
  19 push @dtxt, 'Documentation/standards.txt';
  20 push @dtxt, 'Documentation/flow.txt';
  21 push @dtxt, @{$v->{txt}};
  22 for my $txt (@dtxt) {
  23         my $html = $txt;
  24         $html =~ s/\.txt\z/.html/ or $html .= '.html';
  25         $t->{"$html : $txt"} = [ "\$(txt2pre) <$txt" ];
  26 }
  27 $v->{t_slash_star_dot_t} = [ grep(m!\At/.*\.t\z!, @manifest) ];
  28 my @scripts = qw(scripts/ssoma-replay); # legacy
  29 my @syn = (@EXE_FILES, grep(m!^lib/.*\.pm$!, @manifest), @scripts);
  30 @syn = grep(!/DSKQXS\.pm/, @syn) if !eval { require IO::KQueue };
  31 @syn = grep(!/Unsubscribe\.pm/, @syn) if !eval { require Crypt::CBC };
  32 @syn = grep(!/SaPlugin/, @syn) if !eval { require Mail::SpamAssasin };
  33 $v->{syn_files} = \@syn;
  34 $v->{my_syntax} = [map { "$_.syntax" } @syn];
  35 my @no_pod;
  36 $v->{-m1} = [ map {
  37                 my $x = (split('/'))[-1];
  38                 my $pod = "Documentation/$x.pod";
  39                 if (-f $pod) {
  40                         $x;
  41                 } else {
  42                         warn "W: $pod missing\n";
  43                         push @no_pod, $x;
  44                         ();
  45                 }
  46         } @EXE_FILES,
  47         qw(
  48         lei-add-external lei-blob lei-config lei-daemon-kill lei-daemon-pid
  49         lei-forget-external lei-import lei-init lei-ls-external lei-ls-label
  50         lei-tag lei-p2q lei-q)];
  51 $v->{-m5} = [ qw(public-inbox-config public-inbox-v1-format
  52                 public-inbox-v2-format public-inbox-extindex-format
  53                 lei-mail-formats
  54                 ) ];
  55 $v->{-m7} = [ qw(lei-overview public-inbox-overview public-inbox-tuning
  56                 public-inbox-glossary) ];
  57 $v->{-m8} = [ qw(public-inbox-daemon) ];
  58 my @sections = (1, 5, 7, 8);
  59 $v->{check_80} = [];
  60 $v->{manuals} = [];
  61 $v->{mantxt} = [];
  62 for my $i (@sections) {
  63         my $ary = $v->{"-m$i"};
  64         $v->{"m$i"} = $ary;
  65         for my $m (@$ary) {
  66                 my $pod = "Documentation/$m.pod";
  67                 my $txt = "Documentation/$m.txt";
  68                 $t->{"$m.$i : $pod"} = [ "\$(podman) -s$i $pod \$@" ];
  69                 $t->{"$txt : $pod"} = [ "\$(podtext) $pod \$\@+",
  70                                         "touch -r $pod \$\@+",
  71                                         "mv \$\@+ \$@" ];
  72                 $t->{"Documentation/$m.html : $txt"} = [ "\$(txt2pre) <$txt" ];
  73                 $t->{".$m.cols : $m.$i"} = [
  74                         "\@echo CHECK80 $m.$i;".
  75                         "COLUMNS=80 \$(MAN) ./$m.$i | \$(check_man)" ];
  76                 $t->{".$m.lexgrog: $m.$i"} = [
  77                         "\@echo LEXGROG $m.$i;" .
  78                         "\$(LEXGROG) ./$m.$i >\$\@+ && mv \$\@+ \$@" ];
  79         }
  80         push @{$v->{check_80}}, map { ".$_.cols" } @$ary;
  81         push @{$v->{check_lexgrog}}, map { ".$_.lexgrog" } @$ary;
  82         my $manuals = $v->{"man$i"} = [ map { "$_.$i" } @$ary ];
  83         push @{$v->{manuals}}, @$manuals;
  84         push @{$v->{mantxt}}, map { "Documentation/$_.txt" } @$ary;
  85 }
  86 push @dtxt, @{$v->{mantxt}};
  87 $v->{docs} = [ @dtxt, 'NEWS' ];
  88 $v->{docs_html} = [ map {;
  89                 my $x = $_;
  90                 $x =~ s/\.txt\z//;
  91                 "$x.html"
  92         } @{$v->{docs}} ];
  93 $v->{gz_docs} = [ map { "$_.gz" } (@{$v->{docs}},@{$v->{docs_html}}) ];
  94 $v->{rsync_docs} = [ @{$v->{gz_docs}}, @{$v->{docs}},
  95         @{$v->{docs_html}}, qw(NEWS.atom NEWS.atom.gz)];
  96
  97 # external manpages which we host ourselves, since some packages
  98 # (currently just Xapian) doesn't host manpages themselves.
  99 my @xman = qw(copydatabase.1 xapian-compact.1);
 100 $v->{xdocs} = [ map { "Documentation/.$_.txt" } @xman ];
 101 $v->{xdocs_html} = [ map { "Documentation/.$_.html" } @xman ];
 102 for (@{$v->{xdocs}}) {
 103         $t->{"$_:"} = [
 104                 '$(PERL) -w Documentation/extman.perl $@ >$@+',
 105                 'mv $@+ $@'
 106         ];
 107         my $html = $_;
 108         $html =~ s/\.txt\z/.html/;
 109         $t->{"$html : $_"} = [ "\$(txt2pre) <$_" ];
 110 }
 111 $v->{gz_xdocs} = [ map { "$_.gz" } (@{$v->{xdocs_html}}, @{$v->{xdocs}}) ];
 112 $v->{rsync_xdocs} = [ @{$v->{gz_xdocs}}, @{$v->{xdocs_html}}, @{$v->{xdocs}} ];
 113
 114 my $TGTS = join("\n", map {;
 115         my $tgt_prereq = $_;
 116         my $cmds = $t->{$_};
 117         "$tgt_prereq\n".join('', map { "\t$_\n" } @$cmds);
 118 } sort keys %$t);
 119
 120 my $VARS = join("\n", map {;
 121         my $varname = $_;
 122         join('', map { "$varname += $_\n" } sort @{$v->{$varname}});
 123 } grep(!/^-/, sort keys %$v));
 124 $VARS .= "\nRELEASES = ".join(' ', @RELEASES)."\n";
 125
 126 # Don't waste user's disk space by installing some pods from
 127 # imported code or internal use only
 128 my %man3 = map {; # semi-colon tells Perl this is a BLOCK (and not EXPR)
 129         my $base = $_;
 130         my $mod = $base;
 131         $mod =~ s!/!::!g;
 132         $mod =~ s/\.\w+\z//;
 133         "lib/PublicInbox/$_" => "blib/man3/PublicInbox::$mod.\$(MAN3EXT)"
 134 } qw(Git.pm Import.pm WWW.pod SaPlugin/ListMirror.pod);
 135 my $warn_no_pod = @no_pod ? "\n\t\@echo W: missing .pod: @no_pod\n" : '';
 136 chomp(my $lexgrog = `which lexgrog 2>/dev/null`);
 137 my $check_lexgrog = $lexgrog ? 'check-lexgrog' : '';
 138
 139 WriteMakefile(
 140         NAME => 'PublicInbox', # n.b. camel-case is not our choice
 141
 142         # XXX drop "PENDING" in .pod before updating this!
 143         VERSION => '1.7.0.PENDING',
 144
 145         AUTHOR => 'Eric Wong <e@80x24.org>',
 146         ABSTRACT => 'public-inbox server infrastructure',
 147         EXE_FILES => \@EXE_FILES,
 148         PREREQ_PM => {
 149                 # note: we use spamc(1), NOT the Perl modules
 150                 # We also depend on git.
 151                 # Keep this sorted and synced to the INSTALL document
 152
 153                 # perl-modules-5.xx or libperl5.xx in Debian-based
 154                 # part of "perl5" on FreeBSD
 155                 'Compress::Raw::Zlib' => 0,
 156                 'Compress::Zlib' => 0,
 157                 'Data::Dumper' => 0,
 158                 'Digest::SHA' => 0, # rpm: perl-Digest-SHA
 159                 'Encode' => 2.35, # 2.35 shipped with 5.10.1
 160                 'IO::Compress::Gzip' => 0,
 161                 'IO::Uncompress::Gunzip' => 0,
 162                 'Storable' => 0, # rpm: perl-Storable
 163                 'Text::ParseWords' => 0, # rpm: perl-Text-ParseWords
 164
 165                 # Plack is needed for public-inbox-httpd and PublicInbox::WWW
 166                 # 'Plack' => 0,
 167
 168                 'URI::Escape' => 0,
 169
 170                 # We have more test dependencies, but do not force
 171                 # users to install them.  See INSTALL
 172
 173                 # All Perl installs I know about have these, but RH-based
 174                 # distros make them separate even though 'perl' pulls them in
 175                 'File::Path' => 0,
 176                 'File::Temp' => '0.19', # for ->tmpdir support
 177                 'Getopt::Long' => 0,
 178                 'Exporter' => 0,
 179                 # ExtUtils::MakeMaker # this file won't run w/o it...
 180         },
 181         MAN3PODS => \%man3,
 182         clean => {
 183                 FILES => 't/home*/setup* t/home*/t* t/home*/.public-inbox '.
 184                         't/data-gen/*'
 185         },
 186 );
 187
 188 sub MY::postamble {
 189         my $N = (`{ getconf _NPROCESSORS_ONLN || nproc; } 2>/dev/null` || 1);
 190         $N += 1; # account for sleeps in some tests (and makes an IV)
 191         <<EOF;
 192 PROVE = prove
 193 # support using eatmydata to speed up tests (apt-get install eatmydata):
 194 # https://www.flamingspork.com/projects/libeatmydata/
 195 EATMYDATA =
 196 N = $N
 197 -include config.mak
 198 $VARS
 199 -include Documentation/include.mk
 200 $TGTS
 201
 202 check-man :: $check_lexgrog$warn_no_pod
 203
 204 # syntax checks are currently GNU make only:
 205 %.syntax :: %
 206         @\$(PERL) -w -I lib -c \$<
 207
 208 syntax:: \$(my_syntax)
 209
 210 changed = \$(shell git ls-files -m)
 211 dsyn :: \$(addsuffix .syntax, \$(filter \$(changed), \$(syn_files)))
 212
 213 check_manifest := if test -e .git && git ls-files >MANIFEST.gen 2>&1; then \\
 214                 diff -u MANIFEST MANIFEST.gen; fi
 215
 216 check-manifest : MANIFEST
 217         \$(check_manifest)
 218
 219 # the traditional way running per-*.t processes:
 220 check-each :: pure_all
 221         \$(EATMYDATA) \$(PROVE) --state=save -bvw -j\$(N)
 222         -@\$(check_manifest)
 223
 224 # lightly-tested way to run tests, relies "--state=save" in check-each
 225 # for best performance
 226 check-run :: pure_all check-man
 227         \$(EATMYDATA) \$(PROVE) -bvw t/run.perl :: -j\$(N)
 228         -@\$(check_manifest)
 229
 230 check :: check-each
 231
 232 lib/PublicInbox/UserContent.pm :: contrib/css/216dark.css
 233         \$(PERL) -I lib \$@ \$?
 234
 235 # Ensure new .pm files will always be installed by updating
 236 # the timestamp of Makefile.PL which forces Makefile to be remade
 237 Makefile.PL : MANIFEST
 238         touch -r MANIFEST \$@
 239         \$(PERLRUN) \$@
 240
 241 # Install symlinks to ~/bin (which is hopefuly in PATH) which point to
 242 # this source tree.
 243 # prefix + bindir matches git.git Makefile:
 244 prefix = \$(HOME)
 245 bindir = \$(prefix)/bin
 246 symlink-install : lib/PublicInbox.pm
 247         mkdir -p \$(bindir)
 248         lei=\$\$(realpath lei.sh) && cd \$(bindir) && \\
 249         for x in \$(EXE_FILES); do \\
 250                 ln -sf "\$\$lei" \$\$(basename "\$\$x"); \\
 251         done
 252
 253 pure_all :: lib/PublicInbox.pm
 254 lib/PublicInbox.pm : FORCE
 255         VERSION=\$(VERSION) \$(PERL) -w ./version-gen.perl
 256
 257 update-copyrights :
 258         \@case '\$(GNULIB_PATH)' in '') echo >&2 GNULIB_PATH unset; false;; esac
 259         git ls-files | UPDATE_COPYRIGHT_HOLDER='all contributors' \\
 260                 UPDATE_COPYRIGHT_USE_INTERVALS=2 \\
 261                 xargs \$(GNULIB_PATH)/build-aux/update-copyright
 262 EOF
 263 }