lib/PublicInbox/ContentId.pm

   1 # Copyright (C) 2018-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Unstable internal API.
   5 # Used for on-the-fly duplicate detection in V2 inboxes.
   6 # This is not stored in any database anywhere and may change
   7 # as changes in duplicate detection are needed.
   8 # See L<public-inbox-v2-format(5)> manpage for more details.
   9 package PublicInbox::ContentId;
  10 use strict;
  11 use warnings;
  12 use base qw/Exporter/;
  13 our @EXPORT_OK = qw/content_id content_digest/;
  14 use PublicInbox::MID qw(mids references);
  15 use PublicInbox::MsgIter;
  16
  17 # not sure if less-widely supported hash families are worth bothering with
  18 use Digest::SHA;
  19
  20 sub digest_addr ($$$) {
  21         my ($dig, $h, $v) = @_;
  22         $v =~ tr/"//d;
  23         $v =~ s/@([a-z0-9\_\.\-\(\)]*([A-Z])\S*)/'@'.lc($1)/ge;
  24         utf8::encode($v);
  25         $dig->add("$h\0$v\0");
  26 }
  27
  28 sub content_digest ($) {
  29         my ($mime) = @_;
  30         my $dig = Digest::SHA->new(256);
  31         my $hdr = $mime->header_obj;
  32
  33         # References: and In-Reply-To: get used interchangeably
  34         # in some "duplicates" in LKML.  We treat them the same
  35         # in SearchIdx, so treat them the same for this:
  36         my %seen;
  37         foreach my $mid (@{mids($hdr)}) {
  38                 # do NOT consider the Message-ID as part of the content_id
  39                 # if we got here, we've already got Message-ID reuse
  40                 $seen{$mid} = 1;
  41         }
  42         foreach my $mid (@{references($hdr)}) {
  43                 next if $seen{$mid};
  44                 $dig->add("ref\0$mid\0");
  45         }
  46
  47         # Only use Sender: if From is not present
  48         foreach my $h (qw(From Sender)) {
  49                 my @v = $hdr->header($h);
  50                 if (@v) {
  51                         digest_addr($dig, $h, $_) foreach @v;
  52                 }
  53         }
  54         foreach my $h (qw(Subject Date)) {
  55                 my @v = $hdr->header($h);
  56                 foreach my $v (@v) {
  57                         utf8::encode($v);
  58                         $dig->add("$h\0$v\0");
  59                 }
  60         }
  61         # Some mail processors will add " to unquoted names that were
  62         # not in the original message.  For the purposes of deduplication,
  63         # do not take it into account:
  64         foreach my $h (qw(To Cc)) {
  65                 my @v = $hdr->header($h);
  66                 digest_addr($dig, $h, $_) foreach @v;
  67         }
  68         msg_iter($mime, sub {
  69                 my ($part, $depth, @idx) = @{$_[0]};
  70                 $dig->add("\0$depth:".join('.', @idx)."\0");
  71                 my $fn = $part->filename;
  72                 if (defined $fn) {
  73                         utf8::encode($fn);
  74                         $dig->add("fn\0$fn\0");
  75                 }
  76                 my @d = $part->header('Content-Description');
  77                 foreach my $d (@d) {
  78                         utf8::encode($d);
  79                         $dig->add("d\0$d\0");
  80                 }
  81                 $dig->add("b\0");
  82                 my $ct = $part->content_type || 'text/plain';
  83                 my ($s, undef) = msg_part_text($part, $ct);
  84                 if (defined $s) {
  85                         $s =~ s/\r\n/\n/gs;
  86                         $s =~ s/\s*\z//s;
  87                         utf8::encode($s);
  88                 } else {
  89                         $s = $part->body;
  90                 }
  91                 $dig->add($s);
  92         });
  93         $dig;
  94 }
  95
  96 sub content_id ($) {
  97         content_digest($_[0])->digest;
  98 }
  99
 100 1;