lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the unmaintained Danga::Socket (1.61) with
   7 # significant changes.  See Documentation/technical/ds.txt in our
   8 # source for details.
   9 #
  10 # Do not expect this to be a stable API like Danga::Socket,
  11 # but it will evolve to suite our needs and to take advantage of
  12 # newer Linux and *BSD features.
  13 # Bugs encountered were reported to bug-Danga-Socket@rt.cpan.org,
  14 # fixed in Danga::Socket 1.62 and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 #
  17 # fields:
  18 # sock: underlying socket
  19 # rbuf: scalarref, usually undef
  20 # wbuf: arrayref of coderefs or tmpio (autovivified))
  21 #        (tmpio = [ GLOB, offset, [ length ] ])
  22 package PublicInbox::DS;
  23 use strict;
  24 use v5.10.1;
  25 use parent qw(Exporter);
  26 use bytes qw(length substr); # FIXME(?): needed for PublicInbox::NNTP
  27 use POSIX qw(WNOHANG sigprocmask SIG_SETMASK);
  28 use Fcntl qw(SEEK_SET :DEFAULT O_APPEND);
  29 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  30 use Scalar::Util qw(blessed);
  31 use PublicInbox::Syscall qw(:epoll);
  32 use PublicInbox::Tmpfile;
  33 use Errno qw(EAGAIN EINVAL);
  34 use Carp qw(carp croak);
  35 our @EXPORT_OK = qw(now msg_more dwaitpid add_timer);
  36
  37 my %Stack;
  38 my $nextq; # queue for next_tick
  39 my $wait_pids; # list of [ pid, callback, callback_arg ]
  40 my $later_q; # list of callbacks to run at some later interval
  41 my $EXPMAP; # fd -> idle_time
  42 our $EXPTIME = 180; # 3 minutes
  43 my ($later_timer, $reap_armed, $exp_timer);
  44 my $ToClose; # sockets to close when event loop is done
  45 our (
  46      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  47      $Epoll,                     # Global epoll fd (or DSKQXS ref)
  48      $_io,                       # IO::Handle for Epoll
  49
  50      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  51
  52      $LoopTimeout,               # timeout of event loop in milliseconds
  53      @Timers,                    # timers
  54      $in_loop,
  55      );
  56
  57 Reset();
  58
  59 #####################################################################
  60 ### C L A S S   M E T H O D S
  61 #####################################################################
  62
  63 =head2 C<< CLASS->Reset() >>
  64
  65 Reset all state
  66
  67 =cut
  68 sub Reset {
  69         do {
  70                 $in_loop = undef; # first in case DESTROY callbacks use this
  71                 %DescriptorMap = ();
  72                 @Timers = ();
  73                 $PostLoopCallback = undef;
  74
  75                 # we may be iterating inside one of these on our stack
  76                 my @q = delete @Stack{keys %Stack};
  77                 for my $q (@q) { @$q = () }
  78                 $EXPMAP = {};
  79                 $wait_pids = $later_q = $nextq = $ToClose = undef;
  80                 $_io = undef; # closes real $Epoll FD
  81                 $Epoll = undef; # may call DSKQXS::DESTROY
  82         } while (@Timers || keys(%Stack) || $nextq || $wait_pids ||
  83                 $later_q || $ToClose || keys(%DescriptorMap) ||
  84                 $PostLoopCallback);
  85
  86         $reap_armed = $later_timer = $exp_timer = undef;
  87         $LoopTimeout = -1;  # no timeout by default
  88 }
  89
  90 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  91
  92 Set the loop timeout for the event loop to some value in milliseconds.
  93
  94 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
  95 immediately.
  96
  97 =cut
  98 sub SetLoopTimeout { $LoopTimeout = $_[1] + 0 }
  99
 100 =head2 C<< PublicInbox::DS::add_timer( $seconds, $coderef, $arg) >>
 101
 102 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 103 are not guaranteed to fire at the exact time you ask for.
 104
 105 =cut
 106 sub add_timer ($$;@) {
 107     my ($secs, $coderef, @args) = @_;
 108
 109     my $fire_time = now() + $secs;
 110
 111     my $timer = [$fire_time, $coderef, @args];
 112
 113     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 114         push @Timers, $timer;
 115         return $timer;
 116     }
 117
 118     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 119     # but it was compared against calendar queues, heaps, naive push/sort,
 120     # and a bunch of other versions, and found to be fastest with a large
 121     # variety of datasets.)
 122     for (my $i = 0; $i < @Timers; $i++) {
 123         if ($Timers[$i][0] > $fire_time) {
 124             splice(@Timers, $i, 0, $timer);
 125             return $timer;
 126         }
 127     }
 128
 129     die "Shouldn't get here.";
 130 }
 131
 132 # keeping this around in case we support other FD types for now,
 133 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 134 sub set_cloexec ($) {
 135     my ($fd) = @_;
 136
 137     open($_io, '+<&=', $fd) or return;
 138     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 139     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 140 }
 141
 142 # caller sets return value to $Epoll
 143 sub _InitPoller
 144 {
 145     if (PublicInbox::Syscall::epoll_defined())  {
 146         my $fd = epoll_create();
 147         set_cloexec($fd) if (defined($fd) && $fd >= 0);
 148         $fd;
 149     } else {
 150         my $cls;
 151         for (qw(DSKQXS DSPoll)) {
 152             $cls = "PublicInbox::$_";
 153             last if eval "require $cls";
 154         }
 155         $cls->import(qw(epoll_ctl epoll_wait));
 156         $cls->new;
 157     }
 158 }
 159
 160 =head2 C<< CLASS->EventLoop() >>
 161
 162 Start processing IO events. In most daemon programs this never exits. See
 163 C<PostLoopCallback> below for how to exit the loop.
 164
 165 =cut
 166
 167 sub now () { clock_gettime(CLOCK_MONOTONIC) }
 168
 169 sub next_tick () {
 170         my $q = $nextq or return;
 171         $nextq = undef;
 172         $Stack{cur_runq} = $q;
 173         for my $obj (@$q) {
 174                 # avoid "ref" on blessed refs to workaround a Perl 5.16.3 leak:
 175                 # https://rt.perl.org/Public/Bug/Display.html?id=114340
 176                 if (blessed($obj)) {
 177                         $obj->event_step;
 178                 } else {
 179                         $obj->();
 180                 }
 181         }
 182         delete $Stack{cur_runq};
 183 }
 184
 185 # runs timers and returns milliseconds for next one, or next event loop
 186 sub RunTimers {
 187     next_tick();
 188
 189     return (($nextq || $ToClose) ? 0 : $LoopTimeout) unless @Timers;
 190
 191     my $now = now();
 192
 193     # Run expired timers
 194     while (@Timers && $Timers[0][0] <= $now) {
 195         my $to_run = shift(@Timers);
 196         $to_run->[1]->(@$to_run[2..$#$to_run]);
 197     }
 198
 199     # timers may enqueue into nextq:
 200     return 0 if ($nextq || $ToClose);
 201
 202     return $LoopTimeout unless @Timers;
 203
 204     # convert time to an even number of milliseconds, adding 1
 205     # extra, otherwise floating point fun can occur and we'll
 206     # call RunTimers like 20-30 times, each returning a timeout
 207     # of 0.0000212 seconds
 208     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 209
 210     # -1 is an infinite timeout, so prefer a real timeout
 211     ($LoopTimeout < 0 || $LoopTimeout >= $timeout) ? $timeout : $LoopTimeout;
 212 }
 213
 214 sub sig_setmask { sigprocmask(SIG_SETMASK, @_) or die "sigprocmask: $!" }
 215
 216 sub block_signals () {
 217         my $oldset = POSIX::SigSet->new;
 218         my $newset = POSIX::SigSet->new;
 219         $newset->fillset or die "fillset: $!";
 220         sig_setmask($newset, $oldset);
 221         $oldset;
 222 }
 223
 224 # We can't use waitpid(-1) safely here since it can hit ``, system(),
 225 # and other things.  So we scan the $wait_pids list, which is hopefully
 226 # not too big.  We keep $wait_pids small by not calling dwaitpid()
 227 # until we've hit EOF when reading the stdout of the child.
 228
 229 sub reap_pids {
 230         $reap_armed = undef;
 231         my $tmp = $wait_pids or return;
 232         $wait_pids = undef;
 233         $Stack{reap_runq} = $tmp;
 234         my $oldset = block_signals();
 235         foreach my $ary (@$tmp) {
 236                 my ($pid, $cb, $arg) = @$ary;
 237                 my $ret = waitpid($pid, WNOHANG);
 238                 if ($ret == 0) {
 239                         push @$wait_pids, $ary; # autovivifies @$wait_pids
 240                 } elsif ($ret == $pid) {
 241                         if ($cb) {
 242                                 eval { $cb->($arg, $pid) };
 243                                 warn "E: dwaitpid($pid) in_loop: $@" if $@;
 244                         }
 245                 } else {
 246                         warn "waitpid($pid, WNOHANG) = $ret, \$!=$!, \$?=$?";
 247                 }
 248         }
 249         sig_setmask($oldset);
 250         delete $Stack{reap_runq};
 251 }
 252
 253 # reentrant SIGCHLD handler (since reap_pids is not reentrant)
 254 sub enqueue_reap () { $reap_armed //= requeue(\&reap_pids) }
 255
 256 sub in_loop () { $in_loop }
 257
 258 # Internal function: run the post-event callback, send read events
 259 # for pushed-back data, and close pending connections.  returns 1
 260 # if event loop should continue, or 0 to shut it all down.
 261 sub PostEventLoop () {
 262         # now we can close sockets that wanted to close during our event
 263         # processing.  (we didn't want to close them during the loop, as we
 264         # didn't want fd numbers being reused and confused during the event
 265         # loop)
 266         if (my $close_now = $ToClose) {
 267                 $ToClose = undef; # will be autovivified on push
 268                 @$close_now = map { fileno($_) } @$close_now;
 269
 270                 # order matters, destroy expiry times, first:
 271                 delete @$EXPMAP{@$close_now};
 272
 273                 # ->DESTROY methods may populate ToClose
 274                 delete @DescriptorMap{@$close_now};
 275         }
 276
 277         # by default we keep running, unless a postloop callback cancels it
 278         $PostLoopCallback ? $PostLoopCallback->(\%DescriptorMap) : 1;
 279 }
 280
 281 sub EventLoop {
 282     $Epoll //= _InitPoller();
 283     local $in_loop = 1;
 284     my @events;
 285     do {
 286         my $timeout = RunTimers();
 287
 288         # get up to 1000 events
 289         epoll_wait($Epoll, 1000, $timeout, \@events);
 290         for my $fd (@events) {
 291             # it's possible epoll_wait returned many events, including some at the end
 292             # that ones in the front triggered unregister-interest actions.  if we
 293             # can't find the %sock entry, it's because we're no longer interested
 294             # in that event.
 295
 296             # guard stack-not-refcounted w/ Carp + @DB::args
 297             my $obj = $DescriptorMap{$fd};
 298             $obj->event_step;
 299         }
 300     } while (PostEventLoop());
 301     _run_later();
 302 }
 303
 304 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 305
 306 Sets post loop callback function.  Pass a subref and it will be
 307 called every time the event loop finishes.
 308
 309 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 310 and it will exit.
 311
 312 The callback function will be passed two parameters: \%DescriptorMap
 313
 314 =cut
 315 sub SetPostLoopCallback {
 316     my ($class, $ref) = @_;
 317
 318     # global callback
 319     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 320 }
 321
 322 #####################################################################
 323 ### PublicInbox::DS-the-object code
 324 #####################################################################
 325
 326 =head2 OBJECT METHODS
 327
 328 =head2 C<< CLASS->new( $socket ) >>
 329
 330 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 331 react to events on it during the C<EventLoop>.
 332
 333 This is normally (always?) called from your subclass via:
 334
 335   $class->SUPER::new($socket);
 336
 337 =cut
 338 sub new {
 339     my ($self, $sock, $ev) = @_;
 340     $self->{sock} = $sock;
 341     my $fd = fileno($sock);
 342
 343     $Epoll //= _InitPoller();
 344 retry:
 345     if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 346         if ($! == EINVAL && ($ev & EPOLLEXCLUSIVE)) {
 347             $ev &= ~EPOLLEXCLUSIVE;
 348             goto retry;
 349         }
 350         die "EPOLL_CTL_ADD $self/$sock/$fd: $!";
 351     }
 352     croak("FD:$fd in use by $DescriptorMap{$fd} (for $self/$sock)")
 353         if defined($DescriptorMap{$fd});
 354
 355     $DescriptorMap{$fd} = $self;
 356 }
 357
 358
 359 #####################################################################
 360 ### I N S T A N C E   M E T H O D S
 361 #####################################################################
 362
 363 sub requeue ($) { push @$nextq, $_[0] } # autovivifies
 364
 365 =head2 C<< $obj->close >>
 366
 367 Close the socket.
 368
 369 =cut
 370 sub close {
 371     my ($self) = @_;
 372     my $sock = delete $self->{sock} or return;
 373
 374     # we need to flush our write buffer, as there may
 375     # be self-referential closures (sub { $client->close })
 376     # preventing the object from being destroyed
 377     delete $self->{wbuf};
 378
 379     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 380     # notifications about it
 381     my $fd = fileno($sock);
 382     epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, 0) and
 383         croak("EPOLL_CTL_DEL($self/$sock): $!");
 384
 385     # we explicitly don't delete from DescriptorMap here until we
 386     # actually close the socket, as we might be in the middle of
 387     # processing an epoll_wait/etc that returned hundreds of fds, one
 388     # of which is not yet processed and is what we're closing.  if we
 389     # keep it in DescriptorMap, then the event harnesses can just
 390     # looked at $pob->{sock} == undef and ignore it.  but if it's an
 391     # un-accounted for fd, then it (understandably) freak out a bit
 392     # and emit warnings, thinking their state got off.
 393
 394     # defer closing the actual socket until the event loop is done
 395     # processing this round of events.  (otherwise we might reuse fds)
 396     push @$ToClose, $sock; # autovivifies $ToClose
 397
 398     return 0;
 399 }
 400
 401 # portable, non-thread-safe sendfile emulation (no pread, yet)
 402 sub send_tmpio ($$) {
 403     my ($sock, $tmpio) = @_;
 404
 405     sysseek($tmpio->[0], $tmpio->[1], SEEK_SET) or return;
 406     my $n = $tmpio->[2] // 65536;
 407     $n = 65536 if $n > 65536;
 408     defined(my $to_write = sysread($tmpio->[0], my $buf, $n)) or return;
 409     my $written = 0;
 410     while ($to_write > 0) {
 411         if (defined(my $w = syswrite($sock, $buf, $to_write, $written))) {
 412             $written += $w;
 413             $to_write -= $w;
 414         } else {
 415             return if $written == 0;
 416             last;
 417         }
 418     }
 419     $tmpio->[1] += $written; # offset
 420     $tmpio->[2] -= $written if defined($tmpio->[2]); # length
 421     $written;
 422 }
 423
 424 sub epbit ($$) { # (sock, default)
 425         $_[0]->can('stop_SSL') ? PublicInbox::TLS::epollbit() : $_[1];
 426 }
 427
 428 # returns 1 if done, 0 if incomplete
 429 sub flush_write ($) {
 430     my ($self) = @_;
 431     my $sock = $self->{sock} or return;
 432     my $wbuf = $self->{wbuf} or return 1;
 433
 434 next_buf:
 435     while (my $bref = $wbuf->[0]) {
 436         if (ref($bref) ne 'CODE') {
 437             while ($sock) {
 438                 my $w = send_tmpio($sock, $bref); # bref is tmpio
 439                 if (defined $w) {
 440                     if ($w == 0) {
 441                         shift @$wbuf;
 442                         goto next_buf;
 443                     }
 444                 } elsif ($! == EAGAIN) {
 445                     my $ev = epbit($sock, EPOLLOUT) or return $self->close;
 446                     epwait($sock, $ev | EPOLLONESHOT);
 447                     return 0;
 448                 } else {
 449                     return $self->close;
 450                 }
 451             }
 452         } else { #(ref($bref) eq 'CODE') {
 453             shift @$wbuf;
 454             my $before = scalar(@$wbuf);
 455             $bref->($self);
 456
 457             # bref may be enqueueing more CODE to call (see accept_tls_step)
 458             return 0 if (scalar(@$wbuf) > $before);
 459         }
 460     } # while @$wbuf
 461
 462     delete $self->{wbuf};
 463     1; # all done
 464 }
 465
 466 sub rbuf_idle ($$) {
 467     my ($self, $rbuf) = @_;
 468     if ($$rbuf eq '') { # who knows how long till we can read again
 469         delete $self->{rbuf};
 470     } else {
 471         $self->{rbuf} = $rbuf;
 472     }
 473 }
 474
 475 sub do_read ($$$;$) {
 476     my ($self, $rbuf, $len, $off) = @_;
 477     my $r = sysread(my $sock = $self->{sock}, $$rbuf, $len, $off // 0);
 478     return ($r == 0 ? $self->close : $r) if defined $r;
 479     # common for clients to break connections without warning,
 480     # would be too noisy to log here:
 481     if ($! == EAGAIN) {
 482         my $ev = epbit($sock, EPOLLIN) or return $self->close;
 483         epwait($sock, $ev | EPOLLONESHOT);
 484         rbuf_idle($self, $rbuf);
 485         0;
 486     } else {
 487         $self->close;
 488     }
 489 }
 490
 491 # drop the socket if we hit unrecoverable errors on our system which
 492 # require BOFH attention: ENOSPC, EFBIG, EIO, EMFILE, ENFILE...
 493 sub drop {
 494     my $self = shift;
 495     carp(@_);
 496     $self->close;
 497 }
 498
 499 # n.b.: use ->write/->read for this buffer to allow compatibility with
 500 # PerlIO::mmap or PerlIO::scalar if needed
 501 sub tmpio ($$$) {
 502         my ($self, $bref, $off) = @_;
 503         my $fh = tmpfile('wbuf', $self->{sock}, O_APPEND) or
 504                 return drop($self, "tmpfile $!");
 505         $fh->autoflush(1);
 506         my $len = length($$bref) - $off;
 507         print $fh substr($$bref, $off, $len) or
 508                 return drop($self, "write ($len): $!");
 509         [ $fh, 0 ] # [1] = offset, [2] = length, not set by us
 510 }
 511
 512 =head2 C<< $obj->write( $data ) >>
 513
 514 Write the specified data to the underlying handle.  I<data> may be scalar,
 515 scalar ref, code ref (to run when there).
 516 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 517 it returns 1, caller should stop waiting for 'writable' events)
 518
 519 =cut
 520 sub write {
 521     my ($self, $data) = @_;
 522
 523     # nobody should be writing to closed sockets, but caller code can
 524     # do two writes within an event, have the first fail and
 525     # disconnect the other side (whose destructor then closes the
 526     # calling object, but it's still in a method), and then the
 527     # now-dead object does its second write.  that is this case.  we
 528     # just lie and say it worked.  it'll be dead soon and won't be
 529     # hurt by this lie.
 530     my $sock = $self->{sock} or return 1;
 531     my $ref = ref $data;
 532     my $bref = $ref ? $data : \$data;
 533     my $wbuf = $self->{wbuf};
 534     if ($wbuf && scalar(@$wbuf)) { # already buffering, can't write more...
 535         if ($ref eq 'CODE') {
 536             push @$wbuf, $bref;
 537         } else {
 538             my $tmpio = $wbuf->[-1];
 539             if ($tmpio && !defined($tmpio->[2])) { # append to tmp file buffer
 540                 $tmpio->[0]->print($$bref) or return drop($self, "print: $!");
 541             } else {
 542                 my $tmpio = tmpio($self, $bref, 0) or return 0;
 543                 push @$wbuf, $tmpio;
 544             }
 545         }
 546         return 0;
 547     } elsif ($ref eq 'CODE') {
 548         $bref->($self);
 549         return 1;
 550     } else {
 551         my $to_write = length($$bref);
 552         my $written = syswrite($sock, $$bref, $to_write);
 553
 554         if (defined $written) {
 555             return 1 if $written == $to_write;
 556             requeue($self); # runs: event_step -> flush_write
 557         } elsif ($! == EAGAIN) {
 558             my $ev = epbit($sock, EPOLLOUT) or return $self->close;
 559             epwait($sock, $ev | EPOLLONESHOT);
 560             $written = 0;
 561         } else {
 562             return $self->close;
 563         }
 564
 565         # deal with EAGAIN or partial write:
 566         my $tmpio = tmpio($self, $bref, $written) or return 0;
 567
 568         # wbuf may be an empty array if we're being called inside
 569         # ->flush_write via CODE bref:
 570         push @{$self->{wbuf}}, $tmpio; # autovivifies
 571         return 0;
 572     }
 573 }
 574
 575 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 576
 577 sub msg_more ($$) {
 578     my $self = $_[0];
 579     my $sock = $self->{sock} or return 1;
 580     my $wbuf = $self->{wbuf};
 581
 582     if (MSG_MORE && (!defined($wbuf) || !scalar(@$wbuf)) &&
 583                 !$sock->can('stop_SSL')) {
 584         my $n = send($sock, $_[1], MSG_MORE);
 585         if (defined $n) {
 586             my $nlen = length($_[1]) - $n;
 587             return 1 if $nlen == 0; # all done!
 588             # queue up the unwritten substring:
 589             my $tmpio = tmpio($self, \($_[1]), $n) or return 0;
 590             push @{$self->{wbuf}}, $tmpio; # autovivifies
 591             epwait($sock, EPOLLOUT|EPOLLONESHOT);
 592             return 0;
 593         }
 594     }
 595
 596     # don't redispatch into NNTPdeflate::write
 597     PublicInbox::DS::write($self, \($_[1]));
 598 }
 599
 600 sub epwait ($$) {
 601     my ($sock, $ev) = @_;
 602     epoll_ctl($Epoll, EPOLL_CTL_MOD, fileno($sock), $ev) and
 603         croak("EPOLL_CTL_MOD($sock): $!");
 604 }
 605
 606 # return true if complete, false if incomplete (or failure)
 607 sub accept_tls_step ($) {
 608     my ($self) = @_;
 609     my $sock = $self->{sock} or return;
 610     return 1 if $sock->accept_SSL;
 611     return $self->close if $! != EAGAIN;
 612     my $ev = PublicInbox::TLS::epollbit() or return $self->close;
 613     epwait($sock, $ev | EPOLLONESHOT);
 614     unshift(@{$self->{wbuf}}, \&accept_tls_step); # autovivifies
 615     0;
 616 }
 617
 618 # return true if complete, false if incomplete (or failure)
 619 sub shutdn_tls_step ($) {
 620     my ($self) = @_;
 621     my $sock = $self->{sock} or return;
 622     return $self->close if $sock->stop_SSL(SSL_fast_shutdown => 1);
 623     return $self->close if $! != EAGAIN;
 624     my $ev = PublicInbox::TLS::epollbit() or return $self->close;
 625     epwait($sock, $ev | EPOLLONESHOT);
 626     unshift(@{$self->{wbuf}}, \&shutdn_tls_step); # autovivifies
 627     0;
 628 }
 629
 630 # don't bother with shutdown($sock, 2), we don't fork+exec w/o CLOEXEC
 631 # or fork w/o exec, so no inadvertent socket sharing
 632 sub shutdn ($) {
 633     my ($self) = @_;
 634     my $sock = $self->{sock} or return;
 635     if ($sock->can('stop_SSL')) {
 636         shutdn_tls_step($self);
 637     } else {
 638         $self->close;
 639     }
 640 }
 641
 642 sub dwaitpid ($;$$) {
 643         my ($pid, $cb, $arg) = @_;
 644         if ($in_loop) {
 645                 push @$wait_pids, [ $pid, $cb, $arg ];
 646                 # We could've just missed our SIGCHLD, cover it, here:
 647                 enqueue_reap();
 648         } else {
 649                 my $ret = waitpid($pid, 0);
 650                 if ($ret == $pid) {
 651                         if ($cb) {
 652                                 eval { $cb->($arg, $pid) };
 653                                 carp "E: dwaitpid($pid) !in_loop: $@" if $@;
 654                         }
 655                 } else {
 656                         carp "waitpid($pid, 0) = $ret, \$!=$!, \$?=$?";
 657                 }
 658         }
 659 }
 660
 661 sub _run_later () {
 662         my $q = $later_q or return;
 663         $later_timer = $later_q = undef;
 664         $Stack{later_q} = $q;
 665         $_->() for @$q;
 666         delete $Stack{later_q};
 667 }
 668
 669 sub later ($) {
 670         push @$later_q, $_[0]; # autovivifies @$later_q
 671         $later_timer //= add_timer(60, \&_run_later);
 672 }
 673
 674 sub expire_old () {
 675         my $now = now();
 676         my $exp = $EXPTIME;
 677         my $old = $now - $exp;
 678         my %new;
 679         while (my ($fd, $idle_at) = each %$EXPMAP) {
 680                 if ($idle_at < $old) {
 681                         my $ds_obj = $DescriptorMap{$fd};
 682                         $new{$fd} = $idle_at if !$ds_obj->shutdn;
 683                 } else {
 684                         $new{$fd} = $idle_at;
 685                 }
 686         }
 687         $EXPMAP = \%new;
 688         $exp_timer = scalar(keys %new) ? later(\&expire_old) : undef;
 689 }
 690
 691 sub update_idle_time {
 692         my ($self) = @_;
 693         my $sock = $self->{sock} or return;
 694         $EXPMAP->{fileno($sock)} = now();
 695         $exp_timer //= later(\&expire_old);
 696 }
 697
 698 sub not_idle_long {
 699         my ($self, $now) = @_;
 700         my $sock = $self->{sock} or return;
 701         my $idle_at = $EXPMAP->{fileno($sock)} or return;
 702         ($idle_at + $EXPTIME) > $now;
 703 }
 704
 705 1;
 706
 707 =head1 AUTHORS (Danga::Socket)
 708
 709 Brad Fitzpatrick <brad@danga.com> - author
 710
 711 Michael Granger <ged@danga.com> - docs, testing
 712
 713 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 714
 715 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits