lib/PublicInbox/DS.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # This is a fork of the (for now) unmaintained Danga::Socket 1.61.
   7 # Unused features will be removed, and updates will be made to take
   8 # advantage of newer kernels.
   9 #
  10 # API changes to diverge from Danga::Socket will happen to better
  11 # accomodate new features and improve scalability.  Do not expect
  12 # this to be a stable API like Danga::Socket.
  13 # Bugs encountered (and likely fixed) are reported to
  14 # bug-Danga-Socket@rt.cpan.org and visible at:
  15 # https://rt.cpan.org/Public/Dist/Display.html?Name=Danga-Socket
  16 package PublicInbox::DS;
  17 use strict;
  18 use bytes;
  19 use POSIX ();
  20 use Time::HiRes ();
  21 use IO::Handle qw();
  22 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
  23
  24 use warnings;
  25
  26 use PublicInbox::Syscall qw(:epoll);
  27
  28 use fields ('sock',              # underlying socket
  29             'wbuf',              # arrayref of scalars, scalarrefs, or coderefs to write
  30             'wbuf_off',  # offset into first element of wbuf to start writing at
  31             'closed',            # bool: socket is closed
  32             'event_watch',       # bitmask of events the client is interested in (POLLIN,OUT,etc.)
  33             );
  34
  35 use Errno  qw(EAGAIN EINVAL);
  36 use Carp   qw(croak confess);
  37
  38 use constant DebugLevel => 0;
  39
  40 use constant POLLIN        => 1;
  41 use constant POLLOUT       => 4;
  42 use constant POLLERR       => 8;
  43 use constant POLLHUP       => 16;
  44 use constant POLLNVAL      => 32;
  45
  46 our $HAVE_KQUEUE = eval { require IO::KQueue; 1 };
  47
  48 our (
  49      $HaveEpoll,                 # Flag -- is epoll available?  initially undefined.
  50      $HaveKQueue,
  51      %DescriptorMap,             # fd (num) -> PublicInbox::DS object
  52      $Epoll,                     # Global epoll fd (for epoll mode only)
  53      $KQueue,                    # Global kqueue fd ref (for kqueue mode only)
  54      $_io,                       # IO::Handle for Epoll
  55      @ToClose,                   # sockets to close when event loop is done
  56
  57      $PostLoopCallback,          # subref to call at the end of each loop, if defined (global)
  58
  59      $LoopTimeout,               # timeout of event loop in milliseconds
  60      $DoneInit,                  # if we've done the one-time module init yet
  61      @Timers,                    # timers
  62      );
  63
  64 # this may be set to zero with old kernels
  65 our $EPOLLEXCLUSIVE = EPOLLEXCLUSIVE;
  66 Reset();
  67
  68 #####################################################################
  69 ### C L A S S   M E T H O D S
  70 #####################################################################
  71
  72 =head2 C<< CLASS->Reset() >>
  73
  74 Reset all state
  75
  76 =cut
  77 sub Reset {
  78     %DescriptorMap = ();
  79     @ToClose = ();
  80     $LoopTimeout = -1;  # no timeout by default
  81     @Timers = ();
  82
  83     $PostLoopCallback = undef;
  84     $DoneInit = 0;
  85
  86     # NOTE kqueue is close-on-fork, and we don't account for it, yet
  87     # OTOH, we (public-inbox) don't need this sub outside of tests...
  88     POSIX::close($$KQueue) if !$_io && $KQueue && $$KQueue >= 0;
  89     $KQueue = undef;
  90
  91     $_io = undef; # close $Epoll
  92     $Epoll = undef;
  93
  94     *EventLoop = *FirstTimeEventLoop;
  95 }
  96
  97 =head2 C<< CLASS->SetLoopTimeout( $timeout ) >>
  98
  99 Set the loop timeout for the event loop to some value in milliseconds.
 100
 101 A timeout of 0 (zero) means poll forever. A timeout of -1 means poll and return
 102 immediately.
 103
 104 =cut
 105 sub SetLoopTimeout {
 106     return $LoopTimeout = $_[1] + 0;
 107 }
 108
 109 =head2 C<< CLASS->DebugMsg( $format, @args ) >>
 110
 111 Print the debugging message specified by the C<sprintf>-style I<format> and
 112 I<args>
 113
 114 =cut
 115 sub DebugMsg {
 116     my ( $class, $fmt, @args ) = @_;
 117     chomp $fmt;
 118     printf STDERR ">>> $fmt\n", @args;
 119 }
 120
 121 =head2 C<< CLASS->AddTimer( $seconds, $coderef ) >>
 122
 123 Add a timer to occur $seconds from now. $seconds may be fractional, but timers
 124 are not guaranteed to fire at the exact time you ask for.
 125
 126 Returns a timer object which you can call C<< $timer->cancel >> on if you need to.
 127
 128 =cut
 129 sub AddTimer {
 130     my $class = shift;
 131     my ($secs, $coderef) = @_;
 132
 133     my $fire_time = Time::HiRes::time() + $secs;
 134
 135     my $timer = bless [$fire_time, $coderef], "PublicInbox::DS::Timer";
 136
 137     if (!@Timers || $fire_time >= $Timers[-1][0]) {
 138         push @Timers, $timer;
 139         return $timer;
 140     }
 141
 142     # Now, where do we insert?  (NOTE: this appears slow, algorithm-wise,
 143     # but it was compared against calendar queues, heaps, naive push/sort,
 144     # and a bunch of other versions, and found to be fastest with a large
 145     # variety of datasets.)
 146     for (my $i = 0; $i < @Timers; $i++) {
 147         if ($Timers[$i][0] > $fire_time) {
 148             splice(@Timers, $i, 0, $timer);
 149             return $timer;
 150         }
 151     }
 152
 153     die "Shouldn't get here.";
 154 }
 155
 156 # keeping this around in case we support other FD types for now,
 157 # epoll_create1(EPOLL_CLOEXEC) requires Linux 2.6.27+...
 158 sub set_cloexec ($) {
 159     my ($fd) = @_;
 160
 161     $_io = IO::Handle->new_from_fd($fd, 'r+') or return;
 162     defined(my $fl = fcntl($_io, F_GETFD, 0)) or return;
 163     fcntl($_io, F_SETFD, $fl | FD_CLOEXEC);
 164 }
 165
 166 sub _InitPoller
 167 {
 168     return if $DoneInit;
 169     $DoneInit = 1;
 170
 171     if ($HAVE_KQUEUE) {
 172         $KQueue = IO::KQueue->new();
 173         $HaveKQueue = defined $KQueue;
 174         if ($HaveKQueue) {
 175             *EventLoop = *KQueueEventLoop;
 176         }
 177     }
 178     elsif (PublicInbox::Syscall::epoll_defined()) {
 179         $Epoll = eval { epoll_create(1024); };
 180         $HaveEpoll = defined $Epoll && $Epoll >= 0;
 181         if ($HaveEpoll) {
 182             set_cloexec($Epoll);
 183             *EventLoop = *EpollEventLoop;
 184         }
 185     }
 186
 187     if (!$HaveEpoll && !$HaveKQueue) {
 188         require IO::Poll;
 189         *EventLoop = *PollEventLoop;
 190     }
 191 }
 192
 193 =head2 C<< CLASS->EventLoop() >>
 194
 195 Start processing IO events. In most daemon programs this never exits. See
 196 C<PostLoopCallback> below for how to exit the loop.
 197
 198 =cut
 199 sub FirstTimeEventLoop {
 200     my $class = shift;
 201
 202     _InitPoller();
 203
 204     if ($HaveEpoll) {
 205         EpollEventLoop($class);
 206     } elsif ($HaveKQueue) {
 207         KQueueEventLoop($class);
 208     } else {
 209         PollEventLoop($class);
 210     }
 211 }
 212
 213 # runs timers and returns milliseconds for next one, or next event loop
 214 sub RunTimers {
 215     return $LoopTimeout unless @Timers;
 216
 217     my $now = Time::HiRes::time();
 218
 219     # Run expired timers
 220     while (@Timers && $Timers[0][0] <= $now) {
 221         my $to_run = shift(@Timers);
 222         $to_run->[1]->($now) if $to_run->[1];
 223     }
 224
 225     return $LoopTimeout unless @Timers;
 226
 227     # convert time to an even number of milliseconds, adding 1
 228     # extra, otherwise floating point fun can occur and we'll
 229     # call RunTimers like 20-30 times, each returning a timeout
 230     # of 0.0000212 seconds
 231     my $timeout = int(($Timers[0][0] - $now) * 1000) + 1;
 232
 233     # -1 is an infinite timeout, so prefer a real timeout
 234     return $timeout     if $LoopTimeout == -1;
 235
 236     # otherwise pick the lower of our regular timeout and time until
 237     # the next timer
 238     return $LoopTimeout if $LoopTimeout < $timeout;
 239     return $timeout;
 240 }
 241
 242 # Placeholder callback when we hit POLLERR/POLLHUP or other unrecoverable
 243 # errors.  Shouldn't be needed in the future.
 244 sub event_end ($) {
 245     my ($self) = @_;
 246     return if $self->{closed};
 247     $self->{wbuf} = [];
 248     $self->{wbuf_off} = 0;
 249
 250     # we're screwed if a read handler can't handle POLLERR/POLLHUP-type errors
 251     $self->event_read;
 252 }
 253
 254 ### The epoll-based event loop. Gets installed as EventLoop if IO::Epoll loads
 255 ### okay.
 256 sub EpollEventLoop {
 257     my $class = shift;
 258
 259     while (1) {
 260         my @events;
 261         my $i;
 262         my $timeout = RunTimers();
 263
 264         # get up to 1000 events
 265         my $evcount = epoll_wait($Epoll, 1000, $timeout, \@events);
 266         for ($i=0; $i<$evcount; $i++) {
 267             my $ev = $events[$i];
 268
 269             # it's possible epoll_wait returned many events, including some at the end
 270             # that ones in the front triggered unregister-interest actions.  if we
 271             # can't find the %sock entry, it's because we're no longer interested
 272             # in that event.
 273             my PublicInbox::DS $pob = $DescriptorMap{$ev->[0]};
 274             my $code;
 275             my $state = $ev->[1];
 276
 277             DebugLevel >= 1 && $class->DebugMsg("Event: fd=%d (%s), state=%d \@ %s\n",
 278                                                 $ev->[0], ref($pob), $ev->[1], time);
 279
 280             # standard non-profiling codepat
 281             $pob->event_read   if $state & EPOLLIN && ! $pob->{closed};
 282             $pob->event_write  if $state & EPOLLOUT && ! $pob->{closed};
 283             if ($state & (EPOLLERR|EPOLLHUP) && ! $pob->{closed}) {
 284                 event_end($pob);
 285             }
 286         }
 287         return unless PostEventLoop();
 288     }
 289     exit 0;
 290 }
 291
 292 ### The fallback IO::Poll-based event loop. Gets installed as EventLoop if
 293 ### IO::Epoll fails to load.
 294 sub PollEventLoop {
 295     my $class = shift;
 296
 297     my PublicInbox::DS $pob;
 298
 299     while (1) {
 300         my $timeout = RunTimers();
 301
 302         # the following sets up @poll as a series of ($poll,$event_mask)
 303         # items, then uses IO::Poll::_poll, implemented in XS, which
 304         # modifies the array in place with the even elements being
 305         # replaced with the event masks that occured.
 306         my @poll;
 307         while ( my ($fd, $sock) = each %DescriptorMap ) {
 308             push @poll, $fd, $sock->{event_watch};
 309         }
 310
 311         # if nothing to poll, either end immediately (if no timeout)
 312         # or just keep calling the callback
 313         unless (@poll) {
 314             select undef, undef, undef, ($timeout / 1000);
 315             return unless PostEventLoop();
 316             next;
 317         }
 318
 319         my $count = IO::Poll::_poll($timeout, @poll);
 320         unless ($count >= 0) {
 321             return unless PostEventLoop();
 322             next;
 323         }
 324
 325         # Fetch handles with read events
 326         while (@poll) {
 327             my ($fd, $state) = splice(@poll, 0, 2);
 328             next unless $state;
 329
 330             $pob = $DescriptorMap{$fd};
 331
 332             $pob->event_read   if $state & POLLIN && ! $pob->{closed};
 333             $pob->event_write  if $state & POLLOUT && ! $pob->{closed};
 334             event_end($pob) if $state & (POLLERR|POLLHUP) && ! $pob->{closed};
 335         }
 336
 337         return unless PostEventLoop();
 338     }
 339
 340     exit 0;
 341 }
 342
 343 ### The kqueue-based event loop. Gets installed as EventLoop if IO::KQueue works
 344 ### okay.
 345 sub KQueueEventLoop {
 346     my $class = shift;
 347
 348     while (1) {
 349         my $timeout = RunTimers();
 350         my @ret = eval { $KQueue->kevent($timeout) };
 351         if (my $err = $@) {
 352             # workaround https://rt.cpan.org/Ticket/Display.html?id=116615
 353             if ($err =~ /Interrupted system call/) {
 354                 @ret = ();
 355             } else {
 356                 die $err;
 357             }
 358         }
 359
 360         foreach my $kev (@ret) {
 361             my ($fd, $filter, $flags, $fflags) = @$kev;
 362             my PublicInbox::DS $pob = $DescriptorMap{$fd};
 363
 364             DebugLevel >= 1 && $class->DebugMsg("Event: fd=%d (%s), flags=%d \@ %s\n",
 365                                                         $fd, ref($pob), $flags, time);
 366
 367             $pob->event_read  if $filter == IO::KQueue::EVFILT_READ()  && !$pob->{closed};
 368             $pob->event_write if $filter == IO::KQueue::EVFILT_WRITE() && !$pob->{closed};
 369             if ($flags ==  IO::KQueue::EV_EOF() && !$pob->{closed}) {
 370                 event_end($pob);
 371             }
 372         }
 373         return unless PostEventLoop();
 374     }
 375
 376     exit(0);
 377 }
 378
 379 =head2 C<< CLASS->SetPostLoopCallback( CODEREF ) >>
 380
 381 Sets post loop callback function.  Pass a subref and it will be
 382 called every time the event loop finishes.
 383
 384 Return 1 (or any true value) from the sub to make the loop continue, 0 or false
 385 and it will exit.
 386
 387 The callback function will be passed two parameters: \%DescriptorMap
 388
 389 =cut
 390 sub SetPostLoopCallback {
 391     my ($class, $ref) = @_;
 392
 393     # global callback
 394     $PostLoopCallback = (defined $ref && ref $ref eq 'CODE') ? $ref : undef;
 395 }
 396
 397 # Internal function: run the post-event callback, send read events
 398 # for pushed-back data, and close pending connections.  returns 1
 399 # if event loop should continue, or 0 to shut it all down.
 400 sub PostEventLoop {
 401     # now we can close sockets that wanted to close during our event processing.
 402     # (we didn't want to close them during the loop, as we didn't want fd numbers
 403     #  being reused and confused during the event loop)
 404     while (my $sock = shift @ToClose) {
 405         my $fd = fileno($sock);
 406
 407         # close the socket.  (not a PublicInbox::DS close)
 408         $sock->close;
 409
 410         # and now we can finally remove the fd from the map.  see
 411         # comment above in _cleanup.
 412         delete $DescriptorMap{$fd};
 413     }
 414
 415
 416     # by default we keep running, unless a postloop callback (either per-object
 417     # or global) cancels it
 418     my $keep_running = 1;
 419
 420     # now we're at the very end, call callback if defined
 421     if (defined $PostLoopCallback) {
 422         $keep_running &&= $PostLoopCallback->(\%DescriptorMap);
 423     }
 424
 425     return $keep_running;
 426 }
 427
 428 #####################################################################
 429 ### PublicInbox::DS-the-object code
 430 #####################################################################
 431
 432 =head2 OBJECT METHODS
 433
 434 =head2 C<< CLASS->new( $socket ) >>
 435
 436 Create a new PublicInbox::DS subclass object for the given I<socket> which will
 437 react to events on it during the C<EventLoop>.
 438
 439 This is normally (always?) called from your subclass via:
 440
 441   $class->SUPER::new($socket);
 442
 443 =cut
 444 sub new {
 445     my ($self, $sock, $exclusive) = @_;
 446     $self = fields::new($self) unless ref $self;
 447
 448     $self->{sock} = $sock;
 449     my $fd = fileno($sock);
 450
 451     Carp::cluck("undef sock and/or fd in PublicInbox::DS->new.  sock=" . ($sock || "") . ", fd=" . ($fd || ""))
 452         unless $sock && $fd;
 453
 454     $self->{wbuf} = [];
 455     $self->{wbuf_off} = 0;
 456     $self->{closed} = 0;
 457
 458     my $ev = $self->{event_watch} = POLLERR|POLLHUP|POLLNVAL;
 459
 460     _InitPoller();
 461
 462     if ($HaveEpoll) {
 463         if ($exclusive) {
 464             $ev = $self->{event_watch} = EPOLLIN|EPOLLERR|EPOLLHUP|$EPOLLEXCLUSIVE;
 465         }
 466 retry:
 467         if (epoll_ctl($Epoll, EPOLL_CTL_ADD, $fd, $ev)) {
 468             if ($! == EINVAL && ($ev & $EPOLLEXCLUSIVE)) {
 469                 $EPOLLEXCLUSIVE = 0; # old kernel
 470                 $ev = $self->{event_watch} = EPOLLIN|EPOLLERR|EPOLLHUP;
 471                 goto retry;
 472             }
 473             die "couldn't add epoll watch for $fd: $!\n";
 474         }
 475     }
 476     elsif ($HaveKQueue) {
 477         # Add them to the queue but disabled for now
 478         $KQueue->EV_SET($fd, IO::KQueue::EVFILT_READ(),
 479                         IO::KQueue::EV_ADD() | IO::KQueue::EV_DISABLE());
 480         $KQueue->EV_SET($fd, IO::KQueue::EVFILT_WRITE(),
 481                         IO::KQueue::EV_ADD() | IO::KQueue::EV_DISABLE());
 482     }
 483
 484     Carp::cluck("PublicInbox::DS::new blowing away existing descriptor map for fd=$fd ($DescriptorMap{$fd})")
 485         if $DescriptorMap{$fd};
 486
 487     $DescriptorMap{$fd} = $self;
 488     return $self;
 489 }
 490
 491
 492 #####################################################################
 493 ### I N S T A N C E   M E T H O D S
 494 #####################################################################
 495
 496 =head2 C<< $obj->close >>
 497
 498 Close the socket.
 499
 500 =cut
 501 sub close {
 502     my PublicInbox::DS $self = $_[0];
 503     return if $self->{closed};
 504
 505     # this does most of the work of closing us
 506     $self->_cleanup();
 507
 508     # defer closing the actual socket until the event loop is done
 509     # processing this round of events.  (otherwise we might reuse fds)
 510     if (my $sock = delete $self->{sock}) {
 511         push @ToClose, $sock;
 512     }
 513
 514     return 0;
 515 }
 516
 517 ### METHOD: _cleanup()
 518 ### Called by our closers so we can clean internal data structures.
 519 sub _cleanup {
 520     my PublicInbox::DS $self = $_[0];
 521
 522     # we're effectively closed; we have no fd and sock when we leave here
 523     $self->{closed} = 1;
 524
 525     # we need to flush our write buffer, as there may
 526     # be self-referential closures (sub { $client->close })
 527     # preventing the object from being destroyed
 528     @{$self->{wbuf}} = ();
 529
 530     # if we're using epoll, we have to remove this from our epoll fd so we stop getting
 531     # notifications about it
 532     if ($HaveEpoll && $self->{sock}) {
 533         my $fd = fileno($self->{sock});
 534         epoll_ctl($Epoll, EPOLL_CTL_DEL, $fd, $self->{event_watch}) and
 535             confess("EPOLL_CTL_DEL: $!");
 536     }
 537
 538     # we explicitly don't delete from DescriptorMap here until we
 539     # actually close the socket, as we might be in the middle of
 540     # processing an epoll_wait/etc that returned hundreds of fds, one
 541     # of which is not yet processed and is what we're closing.  if we
 542     # keep it in DescriptorMap, then the event harnesses can just
 543     # looked at $pob->{closed} and ignore it.  but if it's an
 544     # un-accounted for fd, then it (understandably) freak out a bit
 545     # and emit warnings, thinking their state got off.
 546 }
 547
 548 =head2 C<< $obj->sock() >>
 549
 550 Returns the underlying IO::Handle for the object.
 551
 552 =cut
 553 sub sock {
 554     my PublicInbox::DS $self = shift;
 555     return $self->{sock};
 556 }
 557
 558 =head2 C<< $obj->write( $data ) >>
 559
 560 Write the specified data to the underlying handle.  I<data> may be scalar,
 561 scalar ref, code ref (to run when there), or undef just to kick-start.
 562 Returns 1 if writes all went through, or 0 if there are writes in queue. If
 563 it returns 1, caller should stop waiting for 'writable' events)
 564
 565 =cut
 566 sub write {
 567     my PublicInbox::DS $self;
 568     my $data;
 569     ($self, $data) = @_;
 570
 571     # nobody should be writing to closed sockets, but caller code can
 572     # do two writes within an event, have the first fail and
 573     # disconnect the other side (whose destructor then closes the
 574     # calling object, but it's still in a method), and then the
 575     # now-dead object does its second write.  that is this case.  we
 576     # just lie and say it worked.  it'll be dead soon and won't be
 577     # hurt by this lie.
 578     return 1 if $self->{closed};
 579
 580     my $bref;
 581
 582     # just queue data if there's already a wait
 583     my $need_queue;
 584     my $wbuf = $self->{wbuf};
 585
 586     if (defined $data) {
 587         $bref = ref $data ? $data : \$data;
 588         if (scalar @$wbuf) {
 589             push @$wbuf, $bref;
 590             return 0;
 591         }
 592
 593         # this flag says we're bypassing the queue system, knowing we're the
 594         # only outstanding write, and hoping we don't ever need to use it.
 595         # if so later, though, we'll need to queue
 596         $need_queue = 1;
 597     }
 598
 599   WRITE:
 600     while (1) {
 601         return 1 unless $bref ||= $wbuf->[0];
 602
 603         my $len;
 604         eval {
 605             $len = length($$bref); # this will die if $bref is a code ref, caught below
 606         };
 607         if ($@) {
 608             if (UNIVERSAL::isa($bref, "CODE")) {
 609                 unless ($need_queue) {
 610                     shift @$wbuf;
 611                 }
 612                 $bref->();
 613
 614                 # code refs are just run and never get reenqueued
 615                 # (they're one-shot), so turn off the flag indicating the
 616                 # outstanding data needs queueing.
 617                 $need_queue = 0;
 618
 619                 undef $bref;
 620                 next WRITE;
 621             }
 622             die "Write error: $@ <$bref>";
 623         }
 624
 625         my $to_write = $len - $self->{wbuf_off};
 626         my $written = syswrite($self->{sock}, $$bref, $to_write,
 627                                $self->{wbuf_off});
 628
 629         if (! defined $written) {
 630             if ($! == EAGAIN) {
 631                 # since connection has stuff to write, it should now be
 632                 # interested in pending writes:
 633                 if ($need_queue) {
 634                     push @$wbuf, $bref;
 635                 }
 636                 $self->watch_write(1);
 637                 return 0;
 638             }
 639
 640             return $self->close;
 641         } elsif ($written != $to_write) {
 642             if ($need_queue) {
 643                 push @$wbuf, $bref;
 644             }
 645             # since connection has stuff to write, it should now be
 646             # interested in pending writes:
 647             $self->{wbuf_off} += $written;
 648             $self->on_incomplete_write;
 649             return 0;
 650         } elsif ($written == $to_write) {
 651             $self->{wbuf_off} = 0;
 652             $self->watch_write(0);
 653
 654             # this was our only write, so we can return immediately
 655             # since we avoided incrementing the buffer size or
 656             # putting it in the buffer.  we also know there
 657             # can't be anything else to write.
 658             return 1 if $need_queue;
 659
 660             shift @$wbuf;
 661             undef $bref;
 662             next WRITE;
 663         }
 664     }
 665 }
 666
 667 sub on_incomplete_write {
 668     my PublicInbox::DS $self = shift;
 669     $self->watch_write(1);
 670 }
 671
 672 =head2 (VIRTUAL) C<< $obj->event_read() >>
 673
 674 Readable event handler. Concrete deriviatives of PublicInbox::DS should
 675 provide an implementation of this. The default implementation will die if
 676 called.
 677
 678 =cut
 679 sub event_read  { die "Base class event_read called for $_[0]\n"; }
 680
 681 =head2 C<< $obj->event_write() >>
 682
 683 Writable event handler. Concrete deriviatives of PublicInbox::DS may wish to
 684 provide an implementation of this. The default implementation calls
 685 C<write()> with an C<undef>.
 686
 687 =cut
 688 sub event_write {
 689     my $self = shift;
 690     $self->write(undef);
 691 }
 692
 693 =head2 C<< $obj->watch_read( $boolean ) >>
 694
 695 Turn 'readable' event notification on or off.
 696
 697 =cut
 698 sub watch_read {
 699     my PublicInbox::DS $self = shift;
 700     return if $self->{closed} || !$self->{sock};
 701
 702     my $val = shift;
 703     my $event = $self->{event_watch};
 704
 705     $event &= ~POLLIN if ! $val;
 706     $event |=  POLLIN if   $val;
 707
 708     my $fd = fileno($self->{sock});
 709     # If it changed, set it
 710     if ($event != $self->{event_watch}) {
 711         if ($HaveKQueue) {
 712             $KQueue->EV_SET($fd, IO::KQueue::EVFILT_READ(),
 713                             $val ? IO::KQueue::EV_ENABLE() : IO::KQueue::EV_DISABLE());
 714         }
 715         elsif ($HaveEpoll) {
 716             epoll_ctl($Epoll, EPOLL_CTL_MOD, $fd, $event) and
 717                 confess("EPOLL_CTL_MOD: $!");
 718         }
 719         $self->{event_watch} = $event;
 720     }
 721 }
 722
 723 =head2 C<< $obj->watch_write( $boolean ) >>
 724
 725 Turn 'writable' event notification on or off.
 726
 727 =cut
 728 sub watch_write {
 729     my PublicInbox::DS $self = shift;
 730     return if $self->{closed} || !$self->{sock};
 731
 732     my $val = shift;
 733     my $event = $self->{event_watch};
 734
 735     $event &= ~POLLOUT if ! $val;
 736     $event |=  POLLOUT if   $val;
 737     my $fd = fileno($self->{sock});
 738
 739     # If it changed, set it
 740     if ($event != $self->{event_watch}) {
 741         if ($HaveKQueue) {
 742             $KQueue->EV_SET($fd, IO::KQueue::EVFILT_WRITE(),
 743                             $val ? IO::KQueue::EV_ENABLE() : IO::KQueue::EV_DISABLE());
 744         }
 745         elsif ($HaveEpoll) {
 746             epoll_ctl($Epoll, EPOLL_CTL_MOD, $fd, $event) and
 747                     confess "EPOLL_CTL_MOD: $!";
 748         }
 749         $self->{event_watch} = $event;
 750     }
 751 }
 752
 753 =head2 C<< $obj->dump_error( $message ) >>
 754
 755 Prints to STDERR a backtrace with information about this socket and what lead
 756 up to the dump_error call.
 757
 758 =cut
 759 sub dump_error {
 760     my $i = 0;
 761     my @list;
 762     while (my ($file, $line, $sub) = (caller($i++))[1..3]) {
 763         push @list, "\t$file:$line called $sub\n";
 764     }
 765
 766     warn "ERROR: $_[1]\n" .
 767         "\t$_[0] = " . $_[0]->as_string . "\n" .
 768         join('', @list);
 769 }
 770
 771 =head2 C<< $obj->debugmsg( $format, @args ) >>
 772
 773 Print the debugging message specified by the C<sprintf>-style I<format> and
 774 I<args>.
 775
 776 =cut
 777 sub debugmsg {
 778     my ( $self, $fmt, @args ) = @_;
 779     confess "Not an object" unless ref $self;
 780
 781     chomp $fmt;
 782     printf STDERR ">>> $fmt\n", @args;
 783 }
 784
 785 =head2 C<< $obj->as_string() >>
 786
 787 Returns a string describing this socket.
 788
 789 =cut
 790 sub as_string {
 791     my PublicInbox::DS $self = shift;
 792     my $rw = "(" . ($self->{event_watch} & POLLIN ? 'R' : '') .
 793                    ($self->{event_watch} & POLLOUT ? 'W' : '') . ")";
 794     my $ret = ref($self) . "$rw: " . ($self->{closed} ? "closed" : "open");
 795     return $ret;
 796 }
 797
 798 package PublicInbox::DS::Timer;
 799 # [$abs_float_firetime, $coderef];
 800 sub cancel {
 801     $_[0][1] = undef;
 802 }
 803
 804 1;
 805
 806 =head1 AUTHORS (Danga::Socket)
 807
 808 Brad Fitzpatrick <brad@danga.com> - author
 809
 810 Michael Granger <ged@danga.com> - docs, testing
 811
 812 Mark Smith <junior@danga.com> - contributor, heavy user, testing
 813
 814 Matt Sergeant <matt@sergeant.org> - kqueue support, docs, timers, other bits