lib/PublicInbox/DSKQXS.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # Licensed the same as Danga::Socket (and Perl5)
   3 # License: GPL-1.0+ or Artistic-1.0-Perl
   4 #  <https://www.gnu.org/licenses/gpl-1.0.txt>
   5 #  <https://dev.perl.org/licenses/artistic.html>
   6 #
   7 # kqueue support via IO::KQueue XS module.  This makes kqueue look
   8 # like epoll to simplify the code in DS.pm.  This is NOT meant to be
   9 # an all encompassing emulation of epoll via IO::KQueue, but just to
  10 # support cases public-inbox-nntpd/httpd care about.
  11 # A pure-Perl version using syscall() is planned, and it should be
  12 # faster due to the lack of syscall overhead.
  13 package PublicInbox::DSKQXS;
  14 use strict;
  15 use warnings;
  16 use parent qw(IO::KQueue);
  17 use parent qw(Exporter);
  18 use IO::KQueue;
  19 use PublicInbox::Syscall qw(EPOLLONESHOT EPOLLIN EPOLLOUT EPOLLET
  20         EPOLL_CTL_ADD EPOLL_CTL_MOD EPOLL_CTL_DEL);
  21 our @EXPORT_OK = qw(epoll_ctl epoll_wait);
  22 my $owner_pid = -1; # kqueue is close-on-fork (yes, fork, not exec)
  23
  24 # map EPOLL* bits to kqueue EV_* flags for EV_SET
  25 sub kq_flag ($$) {
  26         my ($bit, $ev) = @_;
  27         if ($ev & $bit) {
  28                 my $fl = EV_ENABLE;
  29                 $fl |= EV_CLEAR if $fl & EPOLLET;
  30
  31                 # EV_DISPATCH matches EPOLLONESHOT semantics more closely
  32                 # than EV_ONESHOT, in that EV_ADD is not required to
  33                 # re-enable a disabled watch.
  34                 ($ev & EPOLLONESHOT) ? ($fl | EV_DISPATCH) : $fl;
  35         } else {
  36                 EV_DISABLE;
  37         }
  38 }
  39
  40 sub new {
  41         my ($class) = @_;
  42         die 'non-singleton use not supported' if $owner_pid == $$;
  43         $owner_pid = $$;
  44         $class->SUPER::new;
  45 }
  46
  47 sub epoll_ctl {
  48         my ($self, $op, $fd, $ev) = @_;
  49         if ($op == EPOLL_CTL_MOD) {
  50                 $self->EV_SET($fd, EVFILT_READ, kq_flag(EPOLLIN, $ev));
  51                 $self->EV_SET($fd, EVFILT_WRITE, kq_flag(EPOLLOUT, $ev));
  52         } elsif ($op == EPOLL_CTL_DEL) {
  53                 $self->EV_SET($fd, EVFILT_READ, EV_DISABLE);
  54                 $self->EV_SET($fd, EVFILT_WRITE, EV_DISABLE);
  55         } else {
  56                 $self->EV_SET($fd, EVFILT_READ, EV_ADD|kq_flag(EPOLLIN, $ev));
  57                 $self->EV_SET($fd, EVFILT_WRITE, EV_ADD|kq_flag(EPOLLOUT, $ev));
  58         }
  59         0;
  60 }
  61
  62 sub epoll_wait {
  63         my ($self, $maxevents, $timeout_msec, $events) = @_;
  64         @$events = eval { $self->kevent($timeout_msec) };
  65         if (my $err = $@) {
  66                 # workaround https://rt.cpan.org/Ticket/Display.html?id=116615
  67                 if ($err =~ /Interrupted system call/) {
  68                         @$events = ();
  69                 } else {
  70                         die $err;
  71                 }
  72         }
  73         # caller only cares for $events[$i]->[0]
  74         scalar(@$events);
  75 }
  76
  77 sub DESTROY {
  78         my ($self) = @_;
  79         if ($owner_pid == $$) {
  80                 POSIX::close($$self);
  81                 $owner_pid = -1;
  82         }
  83 }
  84
  85 1;