lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 our $SO_ACCEPTFILTER = 0x1000;
  26 my @CMD;
  27 my ($set_user, $oldset);
  28 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  29 my $worker_processes = 1;
  30 my @listeners;
  31 my (%pids, %logs);
  32 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  33 my $reexec_pid;
  34 my ($uid, $gid);
  35 my ($default_cert, $default_key);
  36 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  37 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  38
  39 sub listener_opt ($) {
  40         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  41         my $o = {};
  42         # allow ',' as delimiter since '&' is shell-unfriendly
  43         for (split(/[,&]/, $str)) {
  44                 my ($k, $v) = split(/=/, $_, 2);
  45                 push @{$o->{$k}}, $v;
  46         }
  47
  48         # key may be a part of cert.  At least
  49         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  50         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  51         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  52         $o;
  53 }
  54
  55 sub accept_tls_opt ($) {
  56         my ($opt) = @_;
  57         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  58         return if !defined($o->{cert});
  59         require PublicInbox::TLS;
  60         my %ctx_opt = (SSL_server => 1);
  61         # parse out hostname:/path/to/ mappings:
  62         for my $k (qw(cert key)) {
  63                 $o->{$k} // next;
  64                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  65                 foreach my $path (@{$o->{$k}}) {
  66                         my $host = '';
  67                         $path =~ s/\A([^:]+):// and $host = $1;
  68                         $x->{$host} = $path;
  69                 }
  70         }
  71         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  72                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  73
  74         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  75         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  76         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  77         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  78         if ($mode && $ctx->{context}) {
  79                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  80                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  81         }
  82
  83         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  84 }
  85
  86 sub check_absolute ($$) {
  87         my ($var, $val) = @_;
  88         die <<EOM if index($val // '/', '/') != 0;
  89 $var must be an absolute path when using --daemonize: $val
  90 EOM
  91 }
  92
  93 sub do_chown ($) {
  94         $uid // return;
  95         my ($path) = @_;
  96         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  97 }
  98
  99 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
 100         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
 101         $_[0]->autoflush(1);
 102         do_chown($_[1]);
 103 }
 104
 105 sub load_mod ($;$) {
 106         my ($scheme, $opt) = @_;
 107         my $modc = "PublicInbox::\U$scheme";
 108         my $mod = $modc.'D';
 109         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 110         die $@ if $@;
 111         my %xn;
 112         my $tlsd = $xn{tlsd} = $mod->new;
 113         my %env = map {
 114                 substr($_, length('env.')) => $opt->{$_}->[-1];
 115         } grep(/\Aenv\./, keys %$opt);
 116         $xn{refresh} = sub {
 117                 my ($sig) = @_;
 118                 local @ENV{keys %env} = values %env;
 119                 $tlsd->refresh_groups($sig);
 120         };
 121         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 122                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 123         my @paths = qw(out err);
 124         if ($modc eq 'PublicInbox::HTTP') {
 125                 @paths = qw(err);
 126                 $xn{af_default} = 'httpready';
 127                 if (my $p = $opt->{psgi}) {
 128                         die "multiple psgi= options specified\n" if @$p > 1;
 129                         check_absolute('psgi=', $p->[0]) if $daemonize;
 130                         $tlsd->{psgi} = $p->[0];
 131                 }
 132         }
 133         for my $f (@paths) {
 134                 my $p = $opt->{$f} or next;
 135                 die "multiple $f= options specified\n" if @$p > 1;
 136                 check_absolute("$f=", $p->[0]) if $daemonize;
 137                 $p = File::Spec->canonpath($p->[0]);
 138                 open_log_path(my $fh, $p);
 139                 $tlsd->{$f} = $logs{$p} = $fh;
 140         }
 141         \%xn;
 142 }
 143
 144 sub daemon_prepare ($$) {
 145         my ($default_listen, $xnetd) = @_;
 146         my $listener_names = {}; # sockname => IO::Handle
 147         $oldset = PublicInbox::DS::block_signals();
 148         @CMD = ($0, @ARGV);
 149         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 150         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 151         my $help = <<EOF;
 152 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 153
 154 options:
 155
 156   -l ADDRESS    address to listen on$dh
 157   --cert=FILE   default SSL/TLS certificate
 158   --key=FILE    default SSL/TLS certificate
 159   -W WORKERS    number of worker processes to spawn (default: 1)
 160
 161 See public-inbox-daemon(8) and $prog(1) man pages for more.
 162 EOF
 163         my %opt = (
 164                 'l|listen=s' => \@cfg_listen,
 165                 '1|stdout=s' => \$stdout,
 166                 '2|stderr=s' => \$stderr,
 167                 'W|worker-processes=i' => \$worker_processes,
 168                 'P|pid-file=s' => \$pid_file,
 169                 'u|user=s' => \$user,
 170                 'g|group=s' => \$group,
 171                 'D|daemonize' => \$daemonize,
 172                 'cert=s' => \$default_cert,
 173                 'key=s' => \$default_key,
 174                 'help|h' => \(my $show_help),
 175         );
 176         GetOptions(%opt) or die $help;
 177         if ($show_help) { print $help; exit 0 };
 178
 179         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 180         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 181                 die "--pid-file cannot end with '.oldbin'\n";
 182         }
 183         @listeners = inherit($listener_names);
 184
 185         # allow socket-activation users to set certs once and not
 186         # have to configure each socket:
 187         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 188
 189         # ignore daemonize when inheriting
 190         $daemonize = undef if scalar @listeners;
 191
 192         unless (@listeners || @cfg_listen) {
 193                 $default_listen // die "no listeners specified\n";
 194                 push @cfg_listen, $default_listen
 195         }
 196
 197         foreach my $l (@cfg_listen) {
 198                 my $orig = $l;
 199                 my $scheme = '';
 200                 if ($l =~ s!\A([^:]+)://!!) {
 201                         $scheme = $1;
 202                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 203                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 204                         $scheme = $s if defined $s;
 205                 }
 206                 my $opt; # non-TLS options
 207                 if ($l =~ s!/?\?(.+)\z!!) {
 208                         $opt = listener_opt($1);
 209                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 210                 } elsif (defined($default_cert)) {
 211                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 212                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 213                         die "$orig specified w/o cert=\n";
 214                 }
 215                 $scheme =~ /\A(http|imap|nntp|pop3)/ and
 216                         $xnetd->{$l} = load_mod($1, $opt);
 217
 218                 next if $listener_names->{$l}; # already inherited
 219                 my (%o, $sock_pkg);
 220                 if (index($l, '/') == 0) {
 221                         $sock_pkg = 'IO::Socket::UNIX';
 222                         eval "use $sock_pkg";
 223                         die $@ if $@;
 224                         %o = (Type => SOCK_STREAM, Peer => $l);
 225                         if (-S $l) {
 226                                 my $c = $sock_pkg->new(%o);
 227                                 if (!defined($c) && $!{ECONNREFUSED}) {
 228                                         unlink $l or die
 229 "failed to unlink stale socket=$l: $!\n";
 230                                 } # else: let the bind fail
 231                         }
 232                         $o{Local} = delete $o{Peer};
 233                 } else {
 234                         # both work for IPv4, too
 235                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 236                                 $sock_pkg = $_;
 237                                 eval "use $sock_pkg";
 238                                 $@ or last;
 239                         }
 240                         die $@ if $@;
 241                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 242                 }
 243                 $o{Listen} = 1024;
 244                 my $prev = umask 0000;
 245                 my $s = eval { $sock_pkg->new(%o) };
 246                 warn "error binding $l: $! ($@)\n" unless $s;
 247                 umask $prev;
 248                 if ($s) {
 249                         $listener_names->{sockname($s)} = $s;
 250                         $s->blocking(0);
 251                         push @listeners, $s;
 252                 }
 253         }
 254
 255         # cert/key options in @cfg_listen takes precedence when inheriting,
 256         # but map well-known inherited ports if --listen isn't specified
 257         # at all
 258         for my $sockname (@inherited_names) {
 259                 $sockname =~ /:([0-9]+)\z/ or next;
 260                 if (my $scheme = $KNOWN_TLS{$1}) {
 261                         $xnetd->{$sockname} = load_mod(substr($scheme, 0, -1));
 262                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 263                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 264                         $xnetd->{$sockname} = load_mod($scheme);
 265                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 266                         $tls_opt{''} ||= accept_tls_opt('');
 267                 }
 268         }
 269         my @d;
 270         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 271         delete @tls_opt{@d};
 272         die "No listeners bound\n" unless @listeners;
 273 }
 274
 275 sub daemonize () {
 276         if ($daemonize) {
 277                 require Cwd;
 278                 foreach my $i (0..$#ARGV) {
 279                         my $arg = $ARGV[$i];
 280                         next unless -e $arg;
 281                         $ARGV[$i] = Cwd::abs_path($arg);
 282                 }
 283                 check_absolute('--stdout', $stdout);
 284                 check_absolute('--stderr', $stderr);
 285                 check_absolute('--pid-file', $pid_file);
 286
 287                 chdir '/' or die "chdir failed: $!";
 288         }
 289         if (defined($pid_file) || defined($group) || defined($user)) {
 290                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 291 Net::Server required for --pid-file, --group, --user
 292 $@
 293 EOF
 294         }
 295         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 296         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 297         if (defined $group) {
 298                 $gid = Net::Server::Daemonize::get_gid($group);
 299                 $gid = (split /\s+/, $gid)[0];
 300         } elsif (defined $uid) {
 301                 $gid = (getpwuid($uid))[3];
 302         }
 303
 304         # We change users in the worker to ensure upgradability,
 305         # The upgrade will create the ".oldbin" pid file in the
 306         # same directory as the given pid file.
 307         $uid and $set_user = sub {
 308                 $set_user = undef;
 309                 Net::Server::Daemonize::set_user($uid, $gid);
 310         };
 311
 312         if ($daemonize) {
 313                 my $pid = fork // die "fork: $!";
 314                 exit if $pid;
 315
 316                 open(STDIN, '+<', '/dev/null') or
 317                                         die "redirect stdin failed: $!\n";
 318                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 319                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 320                 POSIX::setsid();
 321                 $pid = fork // die "fork: $!";
 322                 exit if $pid;
 323         }
 324         return unless defined $pid_file;
 325
 326         write_pid($pid_file);
 327         # for ->DESTROY:
 328         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 329 }
 330
 331 sub worker_quit { # $_[0] = signal name or number (unused)
 332         # killing again terminates immediately:
 333         exit unless @listeners;
 334
 335         $_->close foreach @listeners; # call PublicInbox::DS::close
 336         @listeners = ();
 337         my $proc_name;
 338         my $warn = 0;
 339         # drop idle connections and try to quit gracefully
 340         PublicInbox::DS->SetPostLoopCallback(sub {
 341                 my ($dmap, undef) = @_;
 342                 my $n = 0;
 343                 my $now = now();
 344                 for my $s (values %$dmap) {
 345                         $s->can('busy') or next;
 346                         if ($s->busy) {
 347                                 ++$n;
 348                         } else { # close as much as possible, early as possible
 349                                 $s->close;
 350                         }
 351                 }
 352                 if ($n) {
 353                         if (($warn + 5) < now()) {
 354                                 warn "$$ quitting, $n client(s) left\n";
 355                                 $warn = now();
 356                         }
 357                         unless (defined $proc_name) {
 358                                 $proc_name = (split(/\s+/, $0))[0];
 359                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 360                         }
 361                         $0 = "$proc_name quitting, $n client(s) left";
 362                 }
 363                 $n; # true: loop continues, false: loop breaks
 364         });
 365 }
 366
 367 sub reopen_logs {
 368         $logs{$stdout} //= \*STDOUT if defined $stdout;
 369         $logs{$stderr} //= \*STDERR if defined $stderr;
 370         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 371 }
 372
 373 sub sockname ($) {
 374         my ($s) = @_;
 375         my $addr = getsockname($s) or return;
 376         my ($host, $port) = host_with_port($addr);
 377         if ($port == 0 && $host eq '127.0.0.1') {
 378                 my ($path) = Socket::sockaddr_un($addr);
 379                 return $path;
 380         }
 381         "$host:$port";
 382 }
 383
 384 sub unpack_ipv6 ($) {
 385         my ($addr) = @_;
 386         my ($port, $host);
 387
 388         # Socket.pm in Perl 5.14+ supports IPv6:
 389         eval {
 390                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 391                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 392         };
 393
 394         if ($@) {
 395                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 396                 # Socket6, so it may be installed on our system, already
 397                 # (otherwise die here):
 398                 require Socket6;
 399
 400                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 401                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 402         }
 403         ($host, $port);
 404 }
 405
 406 sub host_with_port ($) {
 407         my ($addr) = @_;
 408         my ($port, $host);
 409
 410         # this eval will die on Unix sockets:
 411         eval {
 412                 if (length($addr) >= 28) {
 413                         ($host, $port) = unpack_ipv6($addr);
 414                         $host = "[$host]";
 415                 } else {
 416                         ($port, $host) = Socket::sockaddr_in($addr);
 417                         $host = Socket::inet_ntoa($host);
 418                 }
 419         };
 420         $@ ? ('127.0.0.1', 0) : ($host, $port);
 421 }
 422
 423 sub inherit ($) {
 424         my ($listener_names) = @_;
 425         return () if ($ENV{LISTEN_PID} || 0) != $$;
 426         my $fds = $ENV{LISTEN_FDS} or return ();
 427         my $end = $fds + 2; # LISTEN_FDS_START - 1
 428         my @rv = ();
 429         foreach my $fd (3..$end) {
 430                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 431                 if (my $k = sockname($s)) {
 432                         my $prev_was_blocking = $s->blocking(0);
 433                         warn <<"" if $prev_was_blocking;
 434 Inherited socket (fd=$fd) is blocking, making it non-blocking.
 435 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 436 processes when multiple service instances start.
 437
 438                         $listener_names->{$k} = $s;
 439                         push @rv, $s;
 440                 } else {
 441                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 442                 }
 443         }
 444         @rv
 445 }
 446
 447 sub upgrade { # $_[0] = signal name or number (unused)
 448         if ($reexec_pid) {
 449                 warn "upgrade in-progress: $reexec_pid\n";
 450                 return;
 451         }
 452         if (defined $pid_file) {
 453                 if ($pid_file =~ /\.oldbin\z/) {
 454                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 455                         return;
 456                 }
 457                 unlink_pid_file_safe_ish($$, $pid_file);
 458                 $pid_file .= '.oldbin';
 459                 write_pid($pid_file);
 460         }
 461         my $pid = fork;
 462         unless (defined $pid) {
 463                 warn "fork failed: $!\n";
 464                 return;
 465         }
 466         if ($pid == 0) {
 467                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 468                 $ENV{LISTEN_FDS} = scalar @listeners;
 469                 $ENV{LISTEN_PID} = $$;
 470                 foreach my $s (@listeners) {
 471                         # @listeners are globs with workers, PI::L w/o workers
 472                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 473
 474                         my $fl = fcntl($s, F_GETFD, 0);
 475                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 476                 }
 477                 exec @CMD;
 478                 die "Failed to exec: $!\n";
 479         }
 480         $reexec_pid = $pid;
 481 }
 482
 483 sub kill_workers ($) {
 484         my ($sig) = @_;
 485         kill $sig, keys(%pids);
 486 }
 487
 488 sub upgrade_aborted ($) {
 489         my ($p) = @_;
 490         warn "reexec PID($p) died with: $?\n";
 491         $reexec_pid = undef;
 492         return unless $pid_file;
 493
 494         my $file = $pid_file;
 495         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 496         unlink_pid_file_safe_ish($$, $pid_file);
 497         $pid_file = $file;
 498         eval { write_pid($pid_file) };
 499         warn $@, "\n" if $@;
 500 }
 501
 502 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 503         while (1) {
 504                 my $p = waitpid(-1, WNOHANG) or return;
 505                 if (defined $reexec_pid && $p == $reexec_pid) {
 506                         upgrade_aborted($p);
 507                 } elsif (defined(my $id = delete $pids{$p})) {
 508                         warn "worker[$id] PID($p) died with: $?\n";
 509                 } elsif ($p > 0) {
 510                         warn "unknown PID($p) reaped: $?\n";
 511                 } else {
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 sub unlink_pid_file_safe_ish ($$) {
 518         my ($unlink_pid, $file) = @_;
 519         return unless defined $unlink_pid && $unlink_pid == $$;
 520
 521         open my $fh, '<', $file or return;
 522         local $/ = "\n";
 523         defined(my $read_pid = <$fh>) or return;
 524         chomp $read_pid;
 525         if ($read_pid == $unlink_pid) {
 526                 Net::Server::Daemonize::unlink_pid_file($file);
 527         }
 528 }
 529
 530 sub master_quit ($) {
 531         exit unless @listeners;
 532         @listeners = ();
 533         kill_workers($_[0]);
 534 }
 535
 536 sub master_loop {
 537         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 538         my $set_workers = $worker_processes;
 539         reopen_logs();
 540         my $ignore_winch;
 541         my $sig = {
 542                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 543                 USR2 => \&upgrade,
 544                 QUIT => \&master_quit,
 545                 INT => \&master_quit,
 546                 TERM => \&master_quit,
 547                 WINCH => sub {
 548                         return if $ignore_winch || !@listeners;
 549                         if (-t STDIN || -t STDOUT || -t STDERR) {
 550                                 $ignore_winch = 1;
 551                                 warn <<EOF;
 552 ignoring SIGWINCH since we are not daemonized
 553 EOF
 554                         } else {
 555                                 $worker_processes = 0;
 556                         }
 557                 },
 558                 HUP => sub {
 559                         return unless @listeners;
 560                         $worker_processes = $set_workers;
 561                         kill_workers($_[0]);
 562                 },
 563                 TTIN => sub {
 564                         return unless @listeners;
 565                         if ($set_workers > $worker_processes) {
 566                                 ++$worker_processes;
 567                         } else {
 568                                 $worker_processes = ++$set_workers;
 569                         }
 570                 },
 571                 TTOU => sub {
 572                         $worker_processes = --$set_workers if $set_workers > 0;
 573                 },
 574                 CHLD => \&reap_children,
 575         };
 576         my $sigfd = PublicInbox::Sigfd->new($sig);
 577         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 578         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 579         while (1) { # main loop
 580                 my $n = scalar keys %pids;
 581                 unless (@listeners) {
 582                         exit if $n == 0;
 583                         $set_workers = $worker_processes = $n = 0;
 584                 }
 585
 586                 if ($n > $worker_processes) {
 587                         while (my ($k, $v) = each %pids) {
 588                                 kill('TERM', $k) if $v >= $worker_processes;
 589                         }
 590                         $n = $worker_processes;
 591                 }
 592                 my $want = $worker_processes - 1;
 593                 if ($n <= $want) {
 594                         PublicInbox::DS::block_signals() if !$sigfd;
 595                         for my $i ($n..$want) {
 596                                 my $seed = rand(0xffffffff);
 597                                 my $pid = fork;
 598                                 if (!defined $pid) {
 599                                         warn "failed to fork worker[$i]: $!\n";
 600                                 } elsif ($pid == 0) {
 601                                         srand($seed);
 602                                         eval { Net::SSLeay::randomize() };
 603                                         $set_user->() if $set_user;
 604                                         return $p0; # run normal work code
 605                                 } else {
 606                                         warn "PID=$pid is worker[$i]\n";
 607                                         $pids{$pid} = $i;
 608                                 }
 609                         }
 610                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 611                 }
 612
 613                 if ($sigfd) { # Linux and IO::KQueue users:
 614                         $sigfd->wait_once;
 615                 } else { # wake up every second
 616                         sleep(1);
 617                 }
 618         }
 619         exit # never gets here, just for documentation
 620 }
 621
 622 sub tls_start_cb ($$) {
 623         my ($opt, $orig_post_accept) = @_;
 624         sub {
 625                 my ($io, $addr, $srv) = @_;
 626                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 627                 $orig_post_accept->($ssl, $addr, $srv);
 628         }
 629 }
 630
 631 sub defer_accept ($$) {
 632         my ($s, $af_name) = @_;
 633         return unless defined $af_name;
 634         if ($^O eq 'linux') {
 635                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 636                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 637                 return unless defined $x; # may be Unix socket
 638                 my $sec = unpack('i', $x);
 639                 return if $sec > 0; # systemd users may set a higher value
 640                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 641         } elsif ($^O eq 'freebsd') {
 642                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 643                 return if defined $x; # don't change if set
 644                 my $accf_arg = pack('a16a240', $af_name, '');
 645                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 646         }
 647 }
 648
 649 sub daemon_loop ($) {
 650         my ($xnetd) = @_;
 651         my $refresh = sub {
 652                 my ($sig) = @_;
 653                 for my $xn (values %$xnetd) {
 654                         eval { $xn->{refresh}->($sig) };
 655                         warn "refresh $@\n" if $@;
 656                 }
 657         };
 658         my %post_accept;
 659         while (my ($k, $v) = each %tls_opt) {
 660                 my $l = $k;
 661                 $l =~ s!\A([^:]+)://!!;
 662                 my $scheme = $1 // '';
 663                 my $xn = $xnetd->{$l} // $xnetd->{''};
 664                 if ($scheme =~ m!\A(?:https|imaps|nntps|pop3s)!) {
 665                         $post_accept{$l} = tls_start_cb($v, $xn->{post_accept});
 666                 } elsif ($xn->{tlsd}) { # STARTTLS, $k eq '' is OK
 667                         $xn->{tlsd}->{accept_tls} = $v;
 668                 }
 669         }
 670         my $sig = {
 671                 HUP => $refresh,
 672                 INT => \&worker_quit,
 673                 QUIT => \&worker_quit,
 674                 TERM => \&worker_quit,
 675                 TTIN => 'IGNORE',
 676                 TTOU => 'IGNORE',
 677                 USR1 => \&reopen_logs,
 678                 USR2 => 'IGNORE',
 679                 WINCH => 'IGNORE',
 680                 CHLD => \&PublicInbox::DS::enqueue_reap,
 681         };
 682         if ($worker_processes > 0) {
 683                 $refresh->(); # preload by default
 684                 my $fh = master_loop(); # returns if in child process
 685                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 686         } else {
 687                 reopen_logs();
 688                 $set_user->() if $set_user;
 689                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 690                 $refresh->();
 691         }
 692         $uid = $gid = undef;
 693         reopen_logs();
 694         @listeners = map {;
 695                 my $l = sockname($_);
 696                 my $tls_cb = $post_accept{$l};
 697                 my $xn = $xnetd->{$l} // $xnetd->{''};
 698
 699                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 700                 # IMAP, NNTP and POP3 are server-first
 701                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 702
 703                 # this calls epoll_create:
 704                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 705         } @listeners;
 706         PublicInbox::DS::event_loop($sig, $oldset);
 707 }
 708
 709 sub run {
 710         my ($default_listen) = @_;
 711         my $xnetd = {};
 712         if ($default_listen) {
 713                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 714                         die "BUG: $default_listen";
 715                 $xnetd->{''} = load_mod($1);
 716         }
 717         daemon_prepare($default_listen, $xnetd);
 718         my $for_destroy = daemonize();
 719
 720         # localize GCF2C for tests:
 721         local $PublicInbox::GitAsyncCat::GCF2C;
 722         local $PublicInbox::Git::async_warn = 1;
 723         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 724
 725         daemon_loop($xnetd);
 726         PublicInbox::DS->Reset;
 727         # ->DESTROY runs when $for_destroy goes out-of-scope
 728 }
 729
 730 sub write_pid ($) {
 731         my ($path) = @_;
 732         Net::Server::Daemonize::create_pid_file($path);
 733         do_chown($path);
 734 }
 735
 736 sub DESTROY {
 737         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 738 }
 739
 740 1;