lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 our $SO_ACCEPTFILTER = 0x1000;
  26 my @CMD;
  27 my ($set_user, $oldset);
  28 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  29 my $worker_processes = 1;
  30 my @listeners;
  31 my (%pids, %logs);
  32 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL->start_SSL
  33 my $reexec_pid;
  34 my ($uid, $gid);
  35 my ($default_cert, $default_key);
  36 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  37 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  38
  39 sub listener_opt ($) {
  40         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  41         my $o = {};
  42         # allow ',' as delimiter since '&' is shell-unfriendly
  43         for (split(/[,&]/, $str)) {
  44                 my ($k, $v) = split(/=/, $_, 2);
  45                 push @{$o->{$k}}, $v;
  46         }
  47
  48         # key may be a part of cert.  At least
  49         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  50         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  51         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  52         $o;
  53 }
  54
  55 sub accept_tls_opt ($) {
  56         my ($opt) = @_;
  57         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  58         return if !defined($o->{cert});
  59         require PublicInbox::TLS;
  60         my %ctx_opt = (SSL_server => 1);
  61         # parse out hostname:/path/to/ mappings:
  62         for my $k (qw(cert key)) {
  63                 $o->{$k} // next;
  64                 my $x = $ctx_opt{'SSL_'.$k.'_file'} = {};
  65                 foreach my $path (@{$o->{$k}}) {
  66                         my $host = '';
  67                         $path =~ s/\A([^:]+):// and $host = $1;
  68                         $x->{$host} = $path;
  69                         check_absolute($k, $path) if $daemonize;
  70                 }
  71         }
  72         my $ctx = IO::Socket::SSL::SSL_Context->new(%ctx_opt) or
  73                 die 'SSL_Context->new: '.PublicInbox::TLS::err();
  74
  75         # save ~34K per idle connection (cf. SSL_CTX_set_mode(3ssl))
  76         # RSS goes from 346MB to 171MB with 10K idle NNTPS clients on amd64
  77         # cf. https://rt.cpan.org/Ticket/Display.html?id=129463
  78         my $mode = eval { Net::SSLeay::MODE_RELEASE_BUFFERS() };
  79         if ($mode && $ctx->{context}) {
  80                 eval { Net::SSLeay::CTX_set_mode($ctx->{context}, $mode) };
  81                 warn "W: $@ (setting SSL_MODE_RELEASE_BUFFERS)\n" if $@;
  82         }
  83
  84         { SSL_server => 1, SSL_startHandshake => 0, SSL_reuse_ctx => $ctx };
  85 }
  86
  87 sub check_absolute ($$) {
  88         my ($var, $val) = @_;
  89         die <<EOM if index($val // '/', '/') != 0;
  90 $var must be an absolute path when using --daemonize: $val
  91 EOM
  92 }
  93
  94 sub do_chown ($) {
  95         $uid // return;
  96         my ($path) = @_;
  97         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  98 }
  99
 100 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
 101         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
 102         $_[0]->autoflush(1);
 103         do_chown($_[1]);
 104 }
 105
 106 sub load_mod ($;$) {
 107         my ($scheme, $opt) = @_;
 108         my $modc = "PublicInbox::\U$scheme";
 109         my $mod = $modc.'D';
 110         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 111         die $@ if $@;
 112         my %xn;
 113         my $tlsd = $xn{tlsd} = $mod->new;
 114         my %env = map {
 115                 substr($_, length('env.')) => $opt->{$_}->[-1];
 116         } grep(/\Aenv\./, keys %$opt);
 117         $xn{refresh} = sub {
 118                 my ($sig) = @_;
 119                 local @ENV{keys %env} = values %env;
 120                 $tlsd->refresh_groups($sig);
 121         };
 122         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 123                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 124         my @paths = qw(out err);
 125         if ($modc eq 'PublicInbox::HTTP') {
 126                 @paths = qw(err);
 127                 $xn{af_default} = 'httpready';
 128                 if (my $p = $opt->{psgi}) {
 129                         die "multiple psgi= options specified\n" if @$p > 1;
 130                         check_absolute('psgi=', $p->[0]) if $daemonize;
 131                         $tlsd->{psgi} = $p->[0];
 132                         warn "# $scheme://$addr psgi=$p->[0]\n";
 133                 }
 134         }
 135         for my $f (@paths) {
 136                 my $p = $opt->{$f} or next;
 137                 die "multiple $f= options specified\n" if @$p > 1;
 138                 check_absolute("$f=", $p->[0]) if $daemonize;
 139                 $p = File::Spec->canonpath($p->[0]);
 140                 open_log_path(my $fh, $p);
 141                 $tlsd->{$f} = $logs{$p} = $fh;
 142                 warn "# $scheme://$addr $f=$p\n";
 143         }
 144         \%xn;
 145 }
 146
 147 sub daemon_prepare ($$) {
 148         my ($default_listen, $xnetd) = @_;
 149         my $listener_names = {}; # sockname => IO::Handle
 150         $oldset = PublicInbox::DS::block_signals();
 151         @CMD = ($0, @ARGV);
 152         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 153         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 154         my $help = <<EOF;
 155 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 156
 157 options:
 158
 159   -l ADDRESS    address to listen on$dh
 160   --cert=FILE   default SSL/TLS certificate
 161   --key=FILE    default SSL/TLS certificate
 162   -W WORKERS    number of worker processes to spawn (default: 1)
 163
 164 See public-inbox-daemon(8) and $prog(1) man pages for more.
 165 EOF
 166         my %opt = (
 167                 'l|listen=s' => \@cfg_listen,
 168                 '1|stdout=s' => \$stdout,
 169                 '2|stderr=s' => \$stderr,
 170                 'W|worker-processes=i' => \$worker_processes,
 171                 'P|pid-file=s' => \$pid_file,
 172                 'u|user=s' => \$user,
 173                 'g|group=s' => \$group,
 174                 'D|daemonize' => \$daemonize,
 175                 'cert=s' => \$default_cert,
 176                 'key=s' => \$default_key,
 177                 'help|h' => \(my $show_help),
 178         );
 179         GetOptions(%opt) or die $help;
 180         if ($show_help) { print $help; exit 0 };
 181
 182         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 183         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 184                 die "--pid-file cannot end with '.oldbin'\n";
 185         }
 186         @listeners = inherit($listener_names);
 187
 188         # allow socket-activation users to set certs once and not
 189         # have to configure each socket:
 190         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 191
 192         # ignore daemonize when inheriting
 193         $daemonize = undef if scalar @listeners;
 194
 195         unless (@listeners || @cfg_listen) {
 196                 $default_listen // die "no listeners specified\n";
 197                 push @cfg_listen, $default_listen
 198         }
 199
 200         foreach my $l (@cfg_listen) {
 201                 my $orig = $l;
 202                 my $scheme = '';
 203                 if ($l =~ s!\A([^:]+)://!!) {
 204                         $scheme = $1;
 205                 } elsif ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9])+/) {
 206                         my $s = $KNOWN_TLS{$1} // $KNOWN_STARTTLS{$1};
 207                         $scheme = $s if defined $s;
 208                 }
 209                 my $opt; # non-TLS options
 210                 if ($l =~ s!/?\?(.+)\z!!) {
 211                         $opt = listener_opt($1);
 212                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 213                 } elsif (defined($default_cert)) {
 214                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 215                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 216                         die "$orig specified w/o cert=\n";
 217                 }
 218                 $scheme =~ /\A(http|imap|nntp|pop3)/ and
 219                         $xnetd->{$l} = load_mod($1, $opt);
 220
 221                 next if $listener_names->{$l}; # already inherited
 222                 my (%o, $sock_pkg);
 223                 if (index($l, '/') == 0) {
 224                         $sock_pkg = 'IO::Socket::UNIX';
 225                         eval "use $sock_pkg";
 226                         die $@ if $@;
 227                         %o = (Type => SOCK_STREAM, Peer => $l);
 228                         if (-S $l) {
 229                                 my $c = $sock_pkg->new(%o);
 230                                 if (!defined($c) && $!{ECONNREFUSED}) {
 231                                         unlink $l or die
 232 "failed to unlink stale socket=$l: $!\n";
 233                                 } # else: let the bind fail
 234                         }
 235                         $o{Local} = delete $o{Peer};
 236                 } else {
 237                         # both work for IPv4, too
 238                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 239                                 $sock_pkg = $_;
 240                                 eval "use $sock_pkg";
 241                                 $@ or last;
 242                         }
 243                         die $@ if $@;
 244                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 245                 }
 246                 $o{Listen} = 1024;
 247                 my $prev = umask 0000;
 248                 my $s = eval { $sock_pkg->new(%o) };
 249                 warn "error binding $l: $! ($@)\n" unless $s;
 250                 umask $prev;
 251                 if ($s) {
 252                         $s->blocking(0);
 253                         my $k = sockname($s);
 254                         warn "# bound $scheme://$k\n";
 255                         $listener_names->{$k} = $s;
 256                         push @listeners, $s;
 257                 }
 258         }
 259
 260         # cert/key options in @cfg_listen takes precedence when inheriting,
 261         # but map well-known inherited ports if --listen isn't specified
 262         # at all
 263         for my $sockname (@inherited_names) {
 264                 $sockname =~ /:([0-9]+)\z/ or next;
 265                 if (my $scheme = $KNOWN_TLS{$1}) {
 266                         $xnetd->{$sockname} = load_mod(substr($scheme, 0, -1));
 267                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 268                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 269                         $xnetd->{$sockname} = load_mod($scheme);
 270                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 271                         $tls_opt{''} ||= accept_tls_opt('');
 272                 }
 273         }
 274         my @d;
 275         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 276         delete @tls_opt{@d};
 277         die "No listeners bound\n" unless @listeners;
 278 }
 279
 280 sub daemonize () {
 281         if ($daemonize) {
 282                 require Cwd;
 283                 foreach my $i (0..$#ARGV) {
 284                         my $arg = $ARGV[$i];
 285                         next unless -e $arg;
 286                         $ARGV[$i] = Cwd::abs_path($arg);
 287                 }
 288                 check_absolute('--stdout', $stdout);
 289                 check_absolute('--stderr', $stderr);
 290                 check_absolute('--pid-file', $pid_file);
 291                 check_absolute('--cert', $default_cert);
 292                 check_absolute('--key', $default_key);
 293
 294                 chdir '/' or die "chdir failed: $!";
 295         }
 296         if (defined($pid_file) || defined($group) || defined($user)) {
 297                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 298 Net::Server required for --pid-file, --group, --user
 299 $@
 300 EOF
 301         }
 302         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 303         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 304         if (defined $group) {
 305                 $gid = Net::Server::Daemonize::get_gid($group);
 306                 $gid = (split /\s+/, $gid)[0];
 307         } elsif (defined $uid) {
 308                 $gid = (getpwuid($uid))[3];
 309         }
 310
 311         # We change users in the worker to ensure upgradability,
 312         # The upgrade will create the ".oldbin" pid file in the
 313         # same directory as the given pid file.
 314         $uid and $set_user = sub {
 315                 $set_user = undef;
 316                 Net::Server::Daemonize::set_user($uid, $gid);
 317         };
 318
 319         if ($daemonize) {
 320                 my $pid = fork // die "fork: $!";
 321                 exit if $pid;
 322
 323                 open(STDIN, '+<', '/dev/null') or
 324                                         die "redirect stdin failed: $!\n";
 325                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 326                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 327                 POSIX::setsid();
 328                 $pid = fork // die "fork: $!";
 329                 exit if $pid;
 330         }
 331         return unless defined $pid_file;
 332
 333         write_pid($pid_file);
 334         # for ->DESTROY:
 335         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 336 }
 337
 338 sub worker_quit { # $_[0] = signal name or number (unused)
 339         # killing again terminates immediately:
 340         exit unless @listeners;
 341
 342         $_->close foreach @listeners; # call PublicInbox::DS::close
 343         @listeners = ();
 344         my $proc_name;
 345         my $warn = 0;
 346         # drop idle connections and try to quit gracefully
 347         PublicInbox::DS->SetPostLoopCallback(sub {
 348                 my ($dmap, undef) = @_;
 349                 my $n = 0;
 350                 my $now = now();
 351                 for my $s (values %$dmap) {
 352                         $s->can('busy') or next;
 353                         if ($s->busy) {
 354                                 ++$n;
 355                         } else { # close as much as possible, early as possible
 356                                 $s->close;
 357                         }
 358                 }
 359                 if ($n) {
 360                         if (($warn + 5) < now()) {
 361                                 warn "$$ quitting, $n client(s) left\n";
 362                                 $warn = now();
 363                         }
 364                         unless (defined $proc_name) {
 365                                 $proc_name = (split(/\s+/, $0))[0];
 366                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 367                         }
 368                         $0 = "$proc_name quitting, $n client(s) left";
 369                 }
 370                 $n; # true: loop continues, false: loop breaks
 371         });
 372 }
 373
 374 sub reopen_logs {
 375         $logs{$stdout} //= \*STDOUT if defined $stdout;
 376         $logs{$stderr} //= \*STDERR if defined $stderr;
 377         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 378 }
 379
 380 sub sockname ($) {
 381         my ($s) = @_;
 382         my $addr = getsockname($s) or return;
 383         my ($host, $port) = host_with_port($addr);
 384         if ($port == 0 && $host eq '127.0.0.1') {
 385                 my ($path) = Socket::sockaddr_un($addr);
 386                 return $path;
 387         }
 388         "$host:$port";
 389 }
 390
 391 sub unpack_ipv6 ($) {
 392         my ($addr) = @_;
 393         my ($port, $host);
 394
 395         # Socket.pm in Perl 5.14+ supports IPv6:
 396         eval {
 397                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 398                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 399         };
 400
 401         if ($@) {
 402                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 403                 # Socket6, so it may be installed on our system, already
 404                 # (otherwise die here):
 405                 require Socket6;
 406
 407                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 408                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 409         }
 410         ($host, $port);
 411 }
 412
 413 sub host_with_port ($) {
 414         my ($addr) = @_;
 415         my ($port, $host);
 416
 417         # this eval will die on Unix sockets:
 418         eval {
 419                 if (length($addr) >= 28) {
 420                         ($host, $port) = unpack_ipv6($addr);
 421                         $host = "[$host]";
 422                 } else {
 423                         ($port, $host) = Socket::sockaddr_in($addr);
 424                         $host = Socket::inet_ntoa($host);
 425                 }
 426         };
 427         $@ ? ('127.0.0.1', 0) : ($host, $port);
 428 }
 429
 430 sub inherit ($) {
 431         my ($listener_names) = @_;
 432         return () if ($ENV{LISTEN_PID} || 0) != $$;
 433         my $fds = $ENV{LISTEN_FDS} or return ();
 434         my $end = $fds + 2; # LISTEN_FDS_START - 1
 435         my @rv = ();
 436         foreach my $fd (3..$end) {
 437                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 438                 if (my $k = sockname($s)) {
 439                         my $prev_was_blocking = $s->blocking(0);
 440                         warn <<"" if $prev_was_blocking;
 441 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 442 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 443 processes when multiple service instances start.
 444
 445                         $listener_names->{$k} = $s;
 446                         warn "# inherited $k fd=$fd\n";
 447                         push @rv, $s;
 448                 } else {
 449                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 450                 }
 451         }
 452         @rv
 453 }
 454
 455 sub upgrade { # $_[0] = signal name or number (unused)
 456         if ($reexec_pid) {
 457                 warn "upgrade in-progress: $reexec_pid\n";
 458                 return;
 459         }
 460         if (defined $pid_file) {
 461                 if ($pid_file =~ /\.oldbin\z/) {
 462                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 463                         return;
 464                 }
 465                 unlink_pid_file_safe_ish($$, $pid_file);
 466                 $pid_file .= '.oldbin';
 467                 write_pid($pid_file);
 468         }
 469         my $pid = fork;
 470         unless (defined $pid) {
 471                 warn "fork failed: $!\n";
 472                 return;
 473         }
 474         if ($pid == 0) {
 475                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 476                 $ENV{LISTEN_FDS} = scalar @listeners;
 477                 $ENV{LISTEN_PID} = $$;
 478                 foreach my $s (@listeners) {
 479                         # @listeners are globs with workers, PI::L w/o workers
 480                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 481
 482                         my $fl = fcntl($s, F_GETFD, 0);
 483                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 484                 }
 485                 exec @CMD;
 486                 die "Failed to exec: $!\n";
 487         }
 488         $reexec_pid = $pid;
 489 }
 490
 491 sub kill_workers ($) {
 492         my ($sig) = @_;
 493         kill $sig, keys(%pids);
 494 }
 495
 496 sub upgrade_aborted ($) {
 497         my ($p) = @_;
 498         warn "reexec PID($p) died with: $?\n";
 499         $reexec_pid = undef;
 500         return unless $pid_file;
 501
 502         my $file = $pid_file;
 503         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 504         unlink_pid_file_safe_ish($$, $pid_file);
 505         $pid_file = $file;
 506         eval { write_pid($pid_file) };
 507         warn $@, "\n" if $@;
 508 }
 509
 510 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 511         while (1) {
 512                 my $p = waitpid(-1, WNOHANG) or return;
 513                 if (defined $reexec_pid && $p == $reexec_pid) {
 514                         upgrade_aborted($p);
 515                 } elsif (defined(my $id = delete $pids{$p})) {
 516                         warn "worker[$id] PID($p) died with: $?\n";
 517                 } elsif ($p > 0) {
 518                         warn "unknown PID($p) reaped: $?\n";
 519                 } else {
 520                         return;
 521                 }
 522         }
 523 }
 524
 525 sub unlink_pid_file_safe_ish ($$) {
 526         my ($unlink_pid, $file) = @_;
 527         return unless defined $unlink_pid && $unlink_pid == $$;
 528
 529         open my $fh, '<', $file or return;
 530         local $/ = "\n";
 531         defined(my $read_pid = <$fh>) or return;
 532         chomp $read_pid;
 533         if ($read_pid == $unlink_pid) {
 534                 Net::Server::Daemonize::unlink_pid_file($file);
 535         }
 536 }
 537
 538 sub master_quit ($) {
 539         exit unless @listeners;
 540         @listeners = ();
 541         kill_workers($_[0]);
 542 }
 543
 544 sub master_loop {
 545         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 546         my $set_workers = $worker_processes;
 547         reopen_logs();
 548         my $ignore_winch;
 549         my $sig = {
 550                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 551                 USR2 => \&upgrade,
 552                 QUIT => \&master_quit,
 553                 INT => \&master_quit,
 554                 TERM => \&master_quit,
 555                 WINCH => sub {
 556                         return if $ignore_winch || !@listeners;
 557                         if (-t STDIN || -t STDOUT || -t STDERR) {
 558                                 $ignore_winch = 1;
 559                                 warn <<EOF;
 560 ignoring SIGWINCH since we are not daemonized
 561 EOF
 562                         } else {
 563                                 $worker_processes = 0;
 564                         }
 565                 },
 566                 HUP => sub {
 567                         return unless @listeners;
 568                         $worker_processes = $set_workers;
 569                         kill_workers($_[0]);
 570                 },
 571                 TTIN => sub {
 572                         return unless @listeners;
 573                         if ($set_workers > $worker_processes) {
 574                                 ++$worker_processes;
 575                         } else {
 576                                 $worker_processes = ++$set_workers;
 577                         }
 578                 },
 579                 TTOU => sub {
 580                         $worker_processes = --$set_workers if $set_workers > 0;
 581                 },
 582                 CHLD => \&reap_children,
 583         };
 584         my $sigfd = PublicInbox::Sigfd->new($sig);
 585         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 586         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 587         while (1) { # main loop
 588                 my $n = scalar keys %pids;
 589                 unless (@listeners) {
 590                         exit if $n == 0;
 591                         $set_workers = $worker_processes = $n = 0;
 592                 }
 593
 594                 if ($n > $worker_processes) {
 595                         while (my ($k, $v) = each %pids) {
 596                                 kill('TERM', $k) if $v >= $worker_processes;
 597                         }
 598                         $n = $worker_processes;
 599                 }
 600                 my $want = $worker_processes - 1;
 601                 if ($n <= $want) {
 602                         PublicInbox::DS::block_signals() if !$sigfd;
 603                         for my $i ($n..$want) {
 604                                 my $seed = rand(0xffffffff);
 605                                 my $pid = fork;
 606                                 if (!defined $pid) {
 607                                         warn "failed to fork worker[$i]: $!\n";
 608                                 } elsif ($pid == 0) {
 609                                         srand($seed);
 610                                         eval { Net::SSLeay::randomize() };
 611                                         $set_user->() if $set_user;
 612                                         return $p0; # run normal work code
 613                                 } else {
 614                                         warn "PID=$pid is worker[$i]\n";
 615                                         $pids{$pid} = $i;
 616                                 }
 617                         }
 618                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 619                 }
 620
 621                 if ($sigfd) { # Linux and IO::KQueue users:
 622                         $sigfd->wait_once;
 623                 } else { # wake up every second
 624                         sleep(1);
 625                 }
 626         }
 627         exit # never gets here, just for documentation
 628 }
 629
 630 sub tls_start_cb ($$) {
 631         my ($opt, $orig_post_accept) = @_;
 632         sub {
 633                 my ($io, $addr, $srv) = @_;
 634                 my $ssl = IO::Socket::SSL->start_SSL($io, %$opt);
 635                 $orig_post_accept->($ssl, $addr, $srv);
 636         }
 637 }
 638
 639 sub defer_accept ($$) {
 640         my ($s, $af_name) = @_;
 641         return unless defined $af_name;
 642         if ($^O eq 'linux') {
 643                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 644                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 645                 return unless defined $x; # may be Unix socket
 646                 my $sec = unpack('i', $x);
 647                 return if $sec > 0; # systemd users may set a higher value
 648                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 649         } elsif ($^O eq 'freebsd') {
 650                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 651                 return if defined $x; # don't change if set
 652                 my $accf_arg = pack('a16a240', $af_name, '');
 653                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 654         }
 655 }
 656
 657 sub daemon_loop ($) {
 658         my ($xnetd) = @_;
 659         my $refresh = sub {
 660                 my ($sig) = @_;
 661                 for my $xn (values %$xnetd) {
 662                         eval { $xn->{refresh}->($sig) };
 663                         warn "refresh $@\n" if $@;
 664                 }
 665         };
 666         my %post_accept;
 667         while (my ($k, $v) = each %tls_opt) {
 668                 my $l = $k;
 669                 $l =~ s!\A([^:]+)://!!;
 670                 my $scheme = $1 // '';
 671                 my $xn = $xnetd->{$l} // $xnetd->{''};
 672                 if ($scheme =~ m!\A(?:https|imaps|nntps|pop3s)!) {
 673                         $post_accept{$l} = tls_start_cb($v, $xn->{post_accept});
 674                 } elsif ($xn->{tlsd}) { # STARTTLS, $k eq '' is OK
 675                         $xn->{tlsd}->{accept_tls} = $v;
 676                 }
 677         }
 678         my $sig = {
 679                 HUP => $refresh,
 680                 INT => \&worker_quit,
 681                 QUIT => \&worker_quit,
 682                 TERM => \&worker_quit,
 683                 TTIN => 'IGNORE',
 684                 TTOU => 'IGNORE',
 685                 USR1 => \&reopen_logs,
 686                 USR2 => 'IGNORE',
 687                 WINCH => 'IGNORE',
 688                 CHLD => \&PublicInbox::DS::enqueue_reap,
 689         };
 690         if ($worker_processes > 0) {
 691                 $refresh->(); # preload by default
 692                 my $fh = master_loop(); # returns if in child process
 693                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 694         } else {
 695                 reopen_logs();
 696                 $set_user->() if $set_user;
 697                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 698                 $refresh->();
 699         }
 700         $uid = $gid = undef;
 701         reopen_logs();
 702         @listeners = map {;
 703                 my $l = sockname($_);
 704                 my $tls_cb = $post_accept{$l};
 705                 my $xn = $xnetd->{$l} // $xnetd->{''};
 706
 707                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 708                 # IMAP, NNTP and POP3 are server-first
 709                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 710
 711                 # this calls epoll_create:
 712                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 713         } @listeners;
 714         PublicInbox::DS::event_loop($sig, $oldset);
 715 }
 716
 717 sub run {
 718         my ($default_listen) = @_;
 719         my $xnetd = {};
 720         if ($default_listen) {
 721                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 722                         die "BUG: $default_listen";
 723                 $xnetd->{''} = load_mod($1);
 724         }
 725         daemon_prepare($default_listen, $xnetd);
 726         my $for_destroy = daemonize();
 727
 728         # localize GCF2C for tests:
 729         local $PublicInbox::GitAsyncCat::GCF2C;
 730         local $PublicInbox::Git::async_warn = 1;
 731         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 732
 733         daemon_loop($xnetd);
 734         PublicInbox::DS->Reset;
 735         # ->DESTROY runs when $for_destroy goes out-of-scope
 736 }
 737
 738 sub write_pid ($) {
 739         my ($path) = @_;
 740         Net::Server::Daemonize::create_pid_file($path);
 741         do_chown($path);
 742 }
 743
 744 sub DESTROY {
 745         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 746 }
 747
 748 1;