lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 use PublicInbox::Config;
  26 our $SO_ACCEPTFILTER = 0x1000;
  27 my @CMD;
  28 my ($set_user, $oldset);
  29 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  30 my $worker_processes = 1;
  31 my @listeners;
  32 my (%pids, %logs);
  33 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL::SSL_Context->new
  34 my $reexec_pid;
  35 my ($uid, $gid);
  36 my ($default_cert, $default_key);
  37 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  38 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  39 my %SCHEME2PORT = map { $KNOWN_TLS{$_} => $_ + 0 } keys %KNOWN_TLS;
  40 for (keys %KNOWN_STARTTLS) { $SCHEME2PORT{$KNOWN_STARTTLS{$_}} = $_ + 0 }
  41 $SCHEME2PORT{http} = 80;
  42
  43 sub listener_opt ($) {
  44         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  45         my $o = {};
  46         # allow ',' as delimiter since '&' is shell-unfriendly
  47         for (split(/[,&]/, $str)) {
  48                 my ($k, $v) = split(/=/, $_, 2);
  49                 push @{$o->{$k}}, $v;
  50         }
  51
  52         # key may be a part of cert.  At least
  53         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  54         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  55         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  56         $o;
  57 }
  58
  59 sub check_absolute ($$) {
  60         my ($var, $val) = @_;
  61         die <<EOM if index($val // '/', '/') != 0;
  62 $var must be an absolute path when using --daemonize: $val
  63 EOM
  64 }
  65
  66 sub accept_tls_opt ($) {
  67         my ($opt) = @_;
  68         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  69         return if !defined($o->{cert});
  70         require PublicInbox::TLS;
  71         my @ctx_opt;
  72         # parse out hostname:/path/to/ mappings:
  73         for my $k (qw(cert key)) {
  74                 $o->{$k} // next;
  75                 push(@ctx_opt, "SSL_${k}_file", {});
  76                 foreach my $path (@{$o->{$k}}) {
  77                         my $host = '';
  78                         $path =~ s/\A([^:]+):// and $host = $1;
  79                         $ctx_opt[-1]->{$host} = $path;
  80                         check_absolute($k, $path) if $daemonize;
  81                 }
  82         }
  83         \@ctx_opt;
  84 }
  85
  86 sub do_chown ($) {
  87         $uid // return;
  88         my ($path) = @_;
  89         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  90 }
  91
  92 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
  93         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
  94         $_[0]->autoflush(1);
  95         do_chown($_[1]);
  96         $_[0];
  97 }
  98
  99 sub load_mod ($;$$) {
 100         my ($scheme, $opt, $addr) = @_;
 101         my $modc = "PublicInbox::\U$scheme";
 102         $modc =~ s/S\z//;
 103         my $mod = $modc.'D';
 104         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 105         die $@ if $@;
 106         my %xn;
 107         my $tlsd = $xn{tlsd} = $mod->new;
 108         my %env = map {
 109                 substr($_, length('env.')) => $opt->{$_}->[-1];
 110         } grep(/\Aenv\./, keys %$opt);
 111         $xn{refresh} = sub {
 112                 my ($sig) = @_;
 113                 local @ENV{keys %env} = values %env;
 114                 $tlsd->refresh_groups($sig);
 115         };
 116         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 117                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 118         my @paths = qw(out err);
 119         if ($modc eq 'PublicInbox::HTTP') {
 120                 @paths = qw(err);
 121                 $xn{af_default} = 'httpready';
 122                 if (my $p = $opt->{psgi}) {
 123                         die "multiple psgi= options specified\n" if @$p > 1;
 124                         check_absolute('psgi=', $p->[0]) if $daemonize;
 125                         $tlsd->{psgi} = $p->[0];
 126                         warn "# $scheme://$addr psgi=$p->[0]\n";
 127                 }
 128         }
 129         for my $f (@paths) {
 130                 my $p = $opt->{$f} or next;
 131                 die "multiple $f= options specified\n" if @$p > 1;
 132                 check_absolute("$f=", $p->[0]) if $daemonize;
 133                 $p = File::Spec->canonpath($p->[0]);
 134                 $tlsd->{$f} = $logs{$p} //= open_log_path(my $fh, $p);
 135                 warn "# $scheme://$addr $f=$p\n";
 136         }
 137         \%xn;
 138 }
 139
 140 sub daemon_prepare ($$) {
 141         my ($default_listen, $xnetd) = @_;
 142         my $listener_names = {}; # sockname => IO::Handle
 143         $oldset = PublicInbox::DS::block_signals();
 144         @CMD = ($0, @ARGV);
 145         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 146         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 147         my $help = <<EOF;
 148 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 149
 150 options:
 151
 152   -l ADDRESS    address to listen on$dh
 153   --cert=FILE   default SSL/TLS certificate
 154   --key=FILE    default SSL/TLS certificate
 155   -W WORKERS    number of worker processes to spawn (default: 1)
 156
 157 See public-inbox-daemon(8) and $prog(1) man pages for more.
 158 EOF
 159         my %opt = (
 160                 'l|listen=s' => \@cfg_listen,
 161                 '1|stdout=s' => \$stdout,
 162                 '2|stderr=s' => \$stderr,
 163                 'W|worker-processes=i' => \$worker_processes,
 164                 'P|pid-file=s' => \$pid_file,
 165                 'u|user=s' => \$user,
 166                 'g|group=s' => \$group,
 167                 'D|daemonize' => \$daemonize,
 168                 'cert=s' => \$default_cert,
 169                 'key=s' => \$default_key,
 170                 'help|h' => \(my $show_help),
 171         );
 172         GetOptions(%opt) or die $help;
 173         if ($show_help) { print $help; exit 0 };
 174
 175         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 176         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 177                 die "--pid-file cannot end with '.oldbin'\n";
 178         }
 179         @listeners = inherit($listener_names);
 180
 181         # allow socket-activation users to set certs once and not
 182         # have to configure each socket:
 183         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 184
 185         # ignore daemonize when inheriting
 186         $daemonize = undef if scalar @listeners;
 187
 188         unless (@listeners || @cfg_listen) {
 189                 $default_listen // die "no listeners specified\n";
 190                 push @cfg_listen, $default_listen
 191         }
 192
 193         foreach my $l (@cfg_listen) {
 194                 my $orig = $l;
 195                 my $scheme = '';
 196                 my $port;
 197                 if ($l =~ s!\A([^:]+)://!!) { $scheme = $1 }
 198                 if ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9]+)/) {
 199                         $port = $1 + 0;
 200                         my $s = $KNOWN_TLS{$port} // $KNOWN_STARTTLS{$port};
 201                         $scheme //= $s if defined $s;
 202                 } elsif (index($l, '/') != 0) { # unix socket
 203                         $port //= $SCHEME2PORT{$scheme} if $scheme;
 204                         $port // die "no port in listen=$l\n";
 205                         $l =~ s!\A([^/]+)!$1:$port! or
 206                                 die "unable to add port=$port to $l\n";
 207                 }
 208                 my $opt; # non-TLS options
 209                 if ($l =~ s!/?\?(.+)\z!!) {
 210                         $opt = listener_opt($1);
 211                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 212                 } elsif (defined($default_cert)) {
 213                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 214                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 215                         die "$orig specified w/o cert=\n";
 216                 }
 217                 $scheme =~ /\A(?:http|imap|nntp|pop3)/ and
 218                         $xnetd->{$l} = load_mod($scheme, $opt, $l);
 219
 220                 next if $listener_names->{$l}; # already inherited
 221                 my (%o, $sock_pkg);
 222                 if (index($l, '/') == 0) {
 223                         $sock_pkg = 'IO::Socket::UNIX';
 224                         eval "use $sock_pkg";
 225                         die $@ if $@;
 226                         %o = (Type => SOCK_STREAM, Peer => $l);
 227                         if (-S $l) {
 228                                 my $c = $sock_pkg->new(%o);
 229                                 if (!defined($c) && $!{ECONNREFUSED}) {
 230                                         unlink $l or die
 231 "failed to unlink stale socket=$l: $!\n";
 232                                 } # else: let the bind fail
 233                         }
 234                         $o{Local} = delete $o{Peer};
 235                 } else {
 236                         # both work for IPv4, too
 237                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 238                                 $sock_pkg = $_;
 239                                 eval "use $sock_pkg";
 240                                 $@ or last;
 241                         }
 242                         die $@ if $@;
 243                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 244                 }
 245                 $o{Listen} = 1024;
 246                 my $prev = umask 0000;
 247                 my $s = eval { $sock_pkg->new(%o) };
 248                 warn "error binding $l: $! ($@)\n" unless $s;
 249                 umask $prev;
 250                 if ($s) {
 251                         $s->blocking(0);
 252                         my $k = sockname($s);
 253                         warn "# bound $scheme://$k\n";
 254                         $listener_names->{$k} = $s;
 255                         push @listeners, $s;
 256                 }
 257         }
 258
 259         # cert/key options in @cfg_listen takes precedence when inheriting,
 260         # but map well-known inherited ports if --listen isn't specified
 261         # at all
 262         for my $sockname (@inherited_names) {
 263                 $sockname =~ /:([0-9]+)\z/ or next;
 264                 if (my $scheme = $KNOWN_TLS{$1}) {
 265                         $xnetd->{$sockname} //= load_mod($scheme);
 266                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 267                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 268                         $xnetd->{$sockname} //= load_mod($scheme);
 269                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 270                         $tls_opt{''} ||= accept_tls_opt('');
 271                 }
 272         }
 273         my @d;
 274         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 275         delete @tls_opt{@d};
 276         die "No listeners bound\n" unless @listeners;
 277 }
 278
 279 sub daemonize () {
 280         if ($daemonize) {
 281                 require Cwd;
 282                 foreach my $i (0..$#ARGV) {
 283                         my $arg = $ARGV[$i];
 284                         next unless -e $arg;
 285                         $ARGV[$i] = Cwd::abs_path($arg);
 286                 }
 287                 check_absolute('--stdout', $stdout);
 288                 check_absolute('--stderr', $stderr);
 289                 check_absolute('--pid-file', $pid_file);
 290                 check_absolute('--cert', $default_cert);
 291                 check_absolute('--key', $default_key);
 292
 293                 chdir '/' or die "chdir failed: $!";
 294         }
 295         if (defined($pid_file) || defined($group) || defined($user)) {
 296                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 297 Net::Server required for --pid-file, --group, --user
 298 $@
 299 EOF
 300         }
 301         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 302         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 303         if (defined $group) {
 304                 $gid = Net::Server::Daemonize::get_gid($group);
 305                 $gid = (split /\s+/, $gid)[0];
 306         } elsif (defined $uid) {
 307                 $gid = (getpwuid($uid))[3];
 308         }
 309
 310         # We change users in the worker to ensure upgradability,
 311         # The upgrade will create the ".oldbin" pid file in the
 312         # same directory as the given pid file.
 313         $uid and $set_user = sub {
 314                 $set_user = undef;
 315                 Net::Server::Daemonize::set_user($uid, $gid);
 316         };
 317
 318         if ($daemonize) {
 319                 my $pid = fork // die "fork: $!";
 320                 exit if $pid;
 321
 322                 open(STDIN, '+<', '/dev/null') or
 323                                         die "redirect stdin failed: $!\n";
 324                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 325                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 326                 POSIX::setsid();
 327                 $pid = fork // die "fork: $!";
 328                 exit if $pid;
 329         }
 330         return unless defined $pid_file;
 331
 332         write_pid($pid_file);
 333         # for ->DESTROY:
 334         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 335 }
 336
 337 sub worker_quit { # $_[0] = signal name or number (unused)
 338         # killing again terminates immediately:
 339         exit unless @listeners;
 340
 341         $_->close foreach @listeners; # call PublicInbox::DS::close
 342         @listeners = ();
 343         my $proc_name;
 344         my $warn = 0;
 345         # drop idle connections and try to quit gracefully
 346         PublicInbox::DS->SetPostLoopCallback(sub {
 347                 my ($dmap, undef) = @_;
 348                 my $n = 0;
 349                 my $now = now();
 350                 for my $s (values %$dmap) {
 351                         $s->can('busy') or next;
 352                         if ($s->busy) {
 353                                 ++$n;
 354                         } else { # close as much as possible, early as possible
 355                                 $s->close;
 356                         }
 357                 }
 358                 if ($n) {
 359                         if (($warn + 5) < now()) {
 360                                 warn "$$ quitting, $n client(s) left\n";
 361                                 $warn = now();
 362                         }
 363                         unless (defined $proc_name) {
 364                                 $proc_name = (split(/\s+/, $0))[0];
 365                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 366                         }
 367                         $0 = "$proc_name quitting, $n client(s) left";
 368                 }
 369                 $n; # true: loop continues, false: loop breaks
 370         });
 371 }
 372
 373 sub reopen_logs {
 374         $logs{$stdout} //= \*STDOUT if defined $stdout;
 375         $logs{$stderr} //= \*STDERR if defined $stderr;
 376         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 377 }
 378
 379 sub sockname ($) {
 380         my ($s) = @_;
 381         my $addr = getsockname($s) or return;
 382         my ($host, $port) = host_with_port($addr);
 383         if ($port == 0 && $host eq '127.0.0.1') {
 384                 my ($path) = Socket::sockaddr_un($addr);
 385                 return $path;
 386         }
 387         "$host:$port";
 388 }
 389
 390 sub unpack_ipv6 ($) {
 391         my ($addr) = @_;
 392         my ($port, $host);
 393
 394         # Socket.pm in Perl 5.14+ supports IPv6:
 395         eval {
 396                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 397                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 398         };
 399
 400         if ($@) {
 401                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 402                 # Socket6, so it may be installed on our system, already
 403                 # (otherwise die here):
 404                 require Socket6;
 405
 406                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 407                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 408         }
 409         ($host, $port);
 410 }
 411
 412 sub host_with_port ($) {
 413         my ($addr) = @_;
 414         my ($port, $host);
 415
 416         # this eval will die on Unix sockets:
 417         eval {
 418                 if (length($addr) >= 28) {
 419                         ($host, $port) = unpack_ipv6($addr);
 420                         $host = "[$host]";
 421                 } else {
 422                         ($port, $host) = Socket::sockaddr_in($addr);
 423                         $host = Socket::inet_ntoa($host);
 424                 }
 425         };
 426         $@ ? ('127.0.0.1', 0) : ($host, $port);
 427 }
 428
 429 sub inherit ($) {
 430         my ($listener_names) = @_;
 431         return () if ($ENV{LISTEN_PID} || 0) != $$;
 432         my $fds = $ENV{LISTEN_FDS} or return ();
 433         my $end = $fds + 2; # LISTEN_FDS_START - 1
 434         my @rv = ();
 435         foreach my $fd (3..$end) {
 436                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 437                 if (my $k = sockname($s)) {
 438                         my $prev_was_blocking = $s->blocking(0);
 439                         warn <<"" if $prev_was_blocking;
 440 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 441 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 442 processes when multiple service instances start.
 443
 444                         $listener_names->{$k} = $s;
 445                         warn "# inherited $k fd=$fd\n";
 446                         push @rv, $s;
 447                 } else {
 448                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 449                 }
 450         }
 451         @rv
 452 }
 453
 454 sub upgrade { # $_[0] = signal name or number (unused)
 455         if ($reexec_pid) {
 456                 warn "upgrade in-progress: $reexec_pid\n";
 457                 return;
 458         }
 459         if (defined $pid_file) {
 460                 if ($pid_file =~ /\.oldbin\z/) {
 461                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 462                         return;
 463                 }
 464                 unlink_pid_file_safe_ish($$, $pid_file);
 465                 $pid_file .= '.oldbin';
 466                 write_pid($pid_file);
 467         }
 468         my $pid = fork;
 469         unless (defined $pid) {
 470                 warn "fork failed: $!\n";
 471                 return;
 472         }
 473         if ($pid == 0) {
 474                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 475                 $ENV{LISTEN_FDS} = scalar @listeners;
 476                 $ENV{LISTEN_PID} = $$;
 477                 foreach my $s (@listeners) {
 478                         # @listeners are globs with workers, PI::L w/o workers
 479                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 480
 481                         my $fl = fcntl($s, F_GETFD, 0);
 482                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 483                 }
 484                 exec @CMD;
 485                 die "Failed to exec: $!\n";
 486         }
 487         $reexec_pid = $pid;
 488 }
 489
 490 sub kill_workers ($) {
 491         my ($sig) = @_;
 492         kill $sig, keys(%pids);
 493 }
 494
 495 sub upgrade_aborted ($) {
 496         my ($p) = @_;
 497         warn "reexec PID($p) died with: $?\n";
 498         $reexec_pid = undef;
 499         return unless $pid_file;
 500
 501         my $file = $pid_file;
 502         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 503         unlink_pid_file_safe_ish($$, $pid_file);
 504         $pid_file = $file;
 505         eval { write_pid($pid_file) };
 506         warn $@, "\n" if $@;
 507 }
 508
 509 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 510         while (1) {
 511                 my $p = waitpid(-1, WNOHANG) or return;
 512                 if (defined $reexec_pid && $p == $reexec_pid) {
 513                         upgrade_aborted($p);
 514                 } elsif (defined(my $id = delete $pids{$p})) {
 515                         warn "worker[$id] PID($p) died with: $?\n";
 516                 } elsif ($p > 0) {
 517                         warn "unknown PID($p) reaped: $?\n";
 518                 } else {
 519                         return;
 520                 }
 521         }
 522 }
 523
 524 sub unlink_pid_file_safe_ish ($$) {
 525         my ($unlink_pid, $file) = @_;
 526         return unless defined $unlink_pid && $unlink_pid == $$;
 527
 528         open my $fh, '<', $file or return;
 529         local $/ = "\n";
 530         defined(my $read_pid = <$fh>) or return;
 531         chomp $read_pid;
 532         if ($read_pid == $unlink_pid) {
 533                 Net::Server::Daemonize::unlink_pid_file($file);
 534         }
 535 }
 536
 537 sub master_quit ($) {
 538         exit unless @listeners;
 539         @listeners = ();
 540         kill_workers($_[0]);
 541 }
 542
 543 sub master_loop {
 544         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 545         my $set_workers = $worker_processes;
 546         reopen_logs();
 547         my $ignore_winch;
 548         my $sig = {
 549                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 550                 USR2 => \&upgrade,
 551                 QUIT => \&master_quit,
 552                 INT => \&master_quit,
 553                 TERM => \&master_quit,
 554                 WINCH => sub {
 555                         return if $ignore_winch || !@listeners;
 556                         if (-t STDIN || -t STDOUT || -t STDERR) {
 557                                 $ignore_winch = 1;
 558                                 warn <<EOF;
 559 ignoring SIGWINCH since we are not daemonized
 560 EOF
 561                         } else {
 562                                 $worker_processes = 0;
 563                         }
 564                 },
 565                 HUP => sub {
 566                         return unless @listeners;
 567                         $worker_processes = $set_workers;
 568                         kill_workers($_[0]);
 569                 },
 570                 TTIN => sub {
 571                         return unless @listeners;
 572                         if ($set_workers > $worker_processes) {
 573                                 ++$worker_processes;
 574                         } else {
 575                                 $worker_processes = ++$set_workers;
 576                         }
 577                 },
 578                 TTOU => sub {
 579                         $worker_processes = --$set_workers if $set_workers > 0;
 580                 },
 581                 CHLD => \&reap_children,
 582         };
 583         my $sigfd = PublicInbox::Sigfd->new($sig);
 584         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 585         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 586         while (1) { # main loop
 587                 my $n = scalar keys %pids;
 588                 unless (@listeners) {
 589                         exit if $n == 0;
 590                         $set_workers = $worker_processes = $n = 0;
 591                 }
 592
 593                 if ($n > $worker_processes) {
 594                         while (my ($k, $v) = each %pids) {
 595                                 kill('TERM', $k) if $v >= $worker_processes;
 596                         }
 597                         $n = $worker_processes;
 598                 }
 599                 my $want = $worker_processes - 1;
 600                 if ($n <= $want) {
 601                         PublicInbox::DS::block_signals() if !$sigfd;
 602                         for my $i ($n..$want) {
 603                                 my $seed = rand(0xffffffff);
 604                                 my $pid = fork;
 605                                 if (!defined $pid) {
 606                                         warn "failed to fork worker[$i]: $!\n";
 607                                 } elsif ($pid == 0) {
 608                                         srand($seed);
 609                                         eval { Net::SSLeay::randomize() };
 610                                         $set_user->() if $set_user;
 611                                         return $p0; # run normal work code
 612                                 } else {
 613                                         warn "PID=$pid is worker[$i]\n";
 614                                         $pids{$pid} = $i;
 615                                 }
 616                         }
 617                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 618                 }
 619
 620                 if ($sigfd) { # Linux and IO::KQueue users:
 621                         $sigfd->wait_once;
 622                 } else { # wake up every second
 623                         sleep(1);
 624                 }
 625         }
 626         exit # never gets here, just for documentation
 627 }
 628
 629 sub tls_cb {
 630         my ($post_accept, $tlsd) = @_;
 631         sub {
 632                 my ($io, $addr, $srv) = @_;
 633                 $post_accept->(PublicInbox::TLS::start($io, $tlsd), $addr, $srv)
 634         }
 635 }
 636
 637 sub defer_accept ($$) {
 638         my ($s, $af_name) = @_;
 639         return unless defined $af_name;
 640         if ($^O eq 'linux') {
 641                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 642                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 643                 return unless defined $x; # may be Unix socket
 644                 my $sec = unpack('i', $x);
 645                 return if $sec > 0; # systemd users may set a higher value
 646                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 647         } elsif ($^O eq 'freebsd') {
 648                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 649                 return if defined $x; # don't change if set
 650                 my $accf_arg = pack('a16a240', $af_name, '');
 651                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 652         }
 653 }
 654
 655 sub daemon_loop ($) {
 656         my ($xnetd) = @_;
 657         local $PublicInbox::Config::DEDUPE = {}; # enable dedupe cache
 658         my $refresh = sub {
 659                 my ($sig) = @_;
 660                 %$PublicInbox::Config::DEDUPE = (); # clear cache
 661                 for my $xn (values %$xnetd) {
 662                         delete $xn->{tlsd}->{ssl_ctx}; # PublicInbox::TLS::start
 663                         eval { $xn->{refresh}->($sig) };
 664                         warn "refresh $@\n" if $@;
 665                 }
 666         };
 667         my %post_accept;
 668         while (my ($k, $ctx_opt) = each %tls_opt) {
 669                 my $l = $k;
 670                 $l =~ s!\A([^:]+)://!!;
 671                 my $scheme = $1 // '';
 672                 my $xn = $xnetd->{$l} // $xnetd->{''};
 673                 $xn->{tlsd}->{ssl_ctx_opt} //= $ctx_opt;
 674                 $scheme =~ m!\A(?:https|imaps|nntps|pop3s)! and
 675                         $post_accept{$l} = tls_cb(@$xn{qw(post_accept tlsd)});
 676         }
 677         my $sig = {
 678                 HUP => $refresh,
 679                 INT => \&worker_quit,
 680                 QUIT => \&worker_quit,
 681                 TERM => \&worker_quit,
 682                 TTIN => 'IGNORE',
 683                 TTOU => 'IGNORE',
 684                 USR1 => \&reopen_logs,
 685                 USR2 => 'IGNORE',
 686                 WINCH => 'IGNORE',
 687                 CHLD => \&PublicInbox::DS::enqueue_reap,
 688         };
 689         if ($worker_processes > 0) {
 690                 $refresh->(); # preload by default
 691                 my $fh = master_loop(); # returns if in child process
 692                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 693         } else {
 694                 reopen_logs();
 695                 $set_user->() if $set_user;
 696                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 697                 $refresh->();
 698         }
 699         $uid = $gid = undef;
 700         reopen_logs();
 701         @listeners = map {;
 702                 my $l = sockname($_);
 703                 my $tls_cb = $post_accept{$l};
 704                 my $xn = $xnetd->{$l} // $xnetd->{''};
 705
 706                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 707                 # IMAP, NNTP and POP3 are server-first
 708                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 709
 710                 # this calls epoll_create:
 711                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 712         } @listeners;
 713         PublicInbox::DS::event_loop($sig, $oldset);
 714 }
 715
 716 sub run {
 717         my ($default_listen) = @_;
 718         my $xnetd = {};
 719         if ($default_listen) {
 720                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 721                         die "BUG: $default_listen";
 722                 $xnetd->{''} = load_mod($1);
 723         }
 724         daemon_prepare($default_listen, $xnetd);
 725         my $for_destroy = daemonize();
 726
 727         # localize GCF2C for tests:
 728         local $PublicInbox::GitAsyncCat::GCF2C;
 729         local $PublicInbox::Git::async_warn = 1;
 730         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 731
 732         daemon_loop($xnetd);
 733         PublicInbox::DS->Reset;
 734         # ->DESTROY runs when $for_destroy goes out-of-scope
 735 }
 736
 737 sub write_pid ($) {
 738         my ($path) = @_;
 739         Net::Server::Daemonize::create_pid_file($path);
 740         do_chown($path);
 741 }
 742
 743 sub DESTROY {
 744         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 745 }
 746
 747 1;