lib/PublicInbox/Daemon.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Contains common daemon code for the httpd, imapd, and nntpd servers
   5 # and designed for handling thousands of untrusted clients over slow
   6 # and/or lossy connections.
   7 package PublicInbox::Daemon;
   8 use strict;
   9 use v5.10.1;
  10 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  11 use IO::Handle; # ->autoflush
  12 use IO::Socket;
  13 use File::Spec;
  14 use POSIX qw(WNOHANG :signal_h);
  15 use Socket qw(IPPROTO_TCP SOL_SOCKET);
  16 STDOUT->autoflush(1);
  17 STDERR->autoflush(1);
  18 use PublicInbox::DS qw(now);
  19 use PublicInbox::Listener;
  20 use PublicInbox::EOFpipe;
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::Git;
  23 use PublicInbox::GitAsyncCat;
  24 use PublicInbox::Eml;
  25 use PublicInbox::Config;
  26 our $SO_ACCEPTFILTER = 0x1000;
  27 my @CMD;
  28 my ($set_user, $oldset);
  29 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  30 my $worker_processes = 1;
  31 my @listeners;
  32 my (%pids, %logs);
  33 my %tls_opt; # scheme://sockname => args for IO::Socket::SSL::SSL_Context->new
  34 my $reexec_pid;
  35 my ($uid, $gid);
  36 my ($default_cert, $default_key);
  37 my %KNOWN_TLS = (443 => 'https', 563 => 'nntps', 993 => 'imaps', 995 =>'pop3s');
  38 my %KNOWN_STARTTLS = (110 => 'pop3', 119 => 'nntp', 143 => 'imap');
  39 my %SCHEME2PORT = map { $KNOWN_TLS{$_} => $_ + 0 } keys %KNOWN_TLS;
  40 for (keys %KNOWN_STARTTLS) { $SCHEME2PORT{$KNOWN_STARTTLS{$_}} = $_ + 0 }
  41 $SCHEME2PORT{http} = 80;
  42
  43 sub listener_opt ($) {
  44         my ($str) = @_; # opt1=val1,opt2=val2 (opt may repeat for multi-value)
  45         my $o = {};
  46         # allow ',' as delimiter since '&' is shell-unfriendly
  47         for (split(/[,&]/, $str)) {
  48                 my ($k, $v) = split(/=/, $_, 2);
  49                 push @{$o->{$k}}, $v;
  50         }
  51
  52         # key may be a part of cert.  At least
  53         # p5-io-socket-ssl/example/ssl_server.pl has this fallback:
  54         $o->{cert} //= [ $default_cert ] if defined($default_cert);
  55         $o->{key} //= defined($default_key) ? [ $default_key ] : $o->{cert};
  56         $o;
  57 }
  58
  59 sub check_absolute ($$) {
  60         my ($var, $val) = @_;
  61         die <<EOM if index($val // '/', '/') != 0;
  62 $var must be an absolute path when using --daemonize: $val
  63 EOM
  64 }
  65
  66 sub accept_tls_opt ($) {
  67         my ($opt) = @_;
  68         my $o = ref($opt) eq 'HASH' ? $opt : listener_opt($opt);
  69         return if !defined($o->{cert});
  70         require PublicInbox::TLS;
  71         my @ctx_opt;
  72         # parse out hostname:/path/to/ mappings:
  73         for my $k (qw(cert key)) {
  74                 $o->{$k} // next;
  75                 push(@ctx_opt, "SSL_${k}_file", {});
  76                 foreach my $path (@{$o->{$k}}) {
  77                         my $host = '';
  78                         $path =~ s/\A([^:]+):// and $host = $1;
  79                         $ctx_opt[-1]->{$host} = $path;
  80                         check_absolute($k, $path) if $daemonize;
  81                 }
  82         }
  83         \@ctx_opt;
  84 }
  85
  86 sub do_chown ($) {
  87         $uid // return;
  88         my ($path) = @_;
  89         chown($uid, $gid, $path) or warn "chown $path: $!\n";
  90 }
  91
  92 sub open_log_path ($$) { # my ($fh, $path) = @_; # $_[0] is modified
  93         open $_[0], '>>', $_[1] or die "open(>> $_[1]): $!";
  94         $_[0]->autoflush(1);
  95         do_chown($_[1]);
  96         $_[0];
  97 }
  98
  99 sub load_mod ($;$$) {
 100         my ($scheme, $opt, $addr) = @_;
 101         my $modc = "PublicInbox::\U$scheme";
 102         $modc =~ s/S\z//;
 103         my $mod = $modc.'D';
 104         eval "require $mod"; # IMAPD|HTTPD|NNTPD|POP3D
 105         die $@ if $@;
 106         my %xn;
 107         my $tlsd = $xn{tlsd} = $mod->new;
 108         my %env = map {
 109                 substr($_, length('env.')) => $opt->{$_}->[-1];
 110         } grep(/\Aenv\./, keys %$opt);
 111         $xn{refresh} = sub {
 112                 my ($sig) = @_;
 113                 local @ENV{keys %env} = values %env;
 114                 $tlsd->refresh_groups($sig);
 115         };
 116         $xn{post_accept} = $tlsd->can('post_accept_cb') ?
 117                         $tlsd->post_accept_cb : sub { $modc->new($_[0], $tlsd) };
 118         my @paths = qw(out err);
 119         if ($modc eq 'PublicInbox::HTTP') {
 120                 @paths = qw(err);
 121                 $xn{af_default} = 'httpready';
 122                 if (my $p = $opt->{psgi}) {
 123                         die "multiple psgi= options specified\n" if @$p > 1;
 124                         check_absolute('psgi=', $p->[0]) if $daemonize;
 125                         $tlsd->{psgi} = $p->[0];
 126                         warn "# $scheme://$addr psgi=$p->[0]\n";
 127                 }
 128         }
 129         for my $f (@paths) {
 130                 my $p = $opt->{$f} or next;
 131                 die "multiple $f= options specified\n" if @$p > 1;
 132                 check_absolute("$f=", $p->[0]) if $daemonize;
 133                 $p = File::Spec->canonpath($p->[0]);
 134                 $tlsd->{$f} = $logs{$p} //= open_log_path(my $fh, $p);
 135                 warn "# $scheme://$addr $f=$p\n";
 136         }
 137         my $err = $tlsd->{err};
 138         $tlsd->{warn_cb} = sub { print $err @_ }; # for local $SIG{__WARN__}
 139         \%xn;
 140 }
 141
 142 sub daemon_prepare ($$) {
 143         my ($default_listen, $xnetd) = @_;
 144         my $listener_names = {}; # sockname => IO::Handle
 145         $oldset = PublicInbox::DS::block_signals();
 146         @CMD = ($0, @ARGV);
 147         my ($prog) = ($CMD[0] =~ m!([^/]+)\z!g);
 148         my $dh = defined($default_listen) ? " (default: $default_listen)" : '';
 149         my $help = <<EOF;
 150 usage: $prog [-l ADDRESS] [--cert=FILE] [--key=FILE]
 151
 152 options:
 153
 154   -l ADDRESS    address to listen on$dh
 155   --cert=FILE   default SSL/TLS certificate
 156   --key=FILE    default SSL/TLS certificate
 157   -W WORKERS    number of worker processes to spawn (default: 1)
 158
 159 See public-inbox-daemon(8) and $prog(1) man pages for more.
 160 EOF
 161         my %opt = (
 162                 'l|listen=s' => \@cfg_listen,
 163                 '1|stdout=s' => \$stdout,
 164                 '2|stderr=s' => \$stderr,
 165                 'W|worker-processes=i' => \$worker_processes,
 166                 'P|pid-file=s' => \$pid_file,
 167                 'u|user=s' => \$user,
 168                 'g|group=s' => \$group,
 169                 'D|daemonize' => \$daemonize,
 170                 'cert=s' => \$default_cert,
 171                 'key=s' => \$default_key,
 172                 'help|h' => \(my $show_help),
 173         );
 174         GetOptions(%opt) or die $help;
 175         if ($show_help) { print $help; exit 0 };
 176
 177         $_ = File::Spec->canonpath($_ // next) for ($stdout, $stderr);
 178         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
 179                 die "--pid-file cannot end with '.oldbin'\n";
 180         }
 181         @listeners = inherit($listener_names);
 182
 183         # allow socket-activation users to set certs once and not
 184         # have to configure each socket:
 185         my @inherited_names = keys(%$listener_names) if defined($default_cert);
 186
 187         # ignore daemonize when inheriting
 188         $daemonize = undef if scalar @listeners;
 189
 190         unless (@listeners || @cfg_listen) {
 191                 $default_listen // die "no listeners specified\n";
 192                 push @cfg_listen, $default_listen
 193         }
 194
 195         foreach my $l (@cfg_listen) {
 196                 my $orig = $l;
 197                 my ($scheme, $port, $opt);
 198
 199                 $l =~ s!\A([a-z0-9]+)://!! and $scheme = $1;
 200                 (!$scheme && ($default_listen // '') =~ m!\A([^:]+)://!) and
 201                         $scheme = $1;
 202                 if ($l =~ /\A(?:\[[^\]]+\]|[^:]+):([0-9]+)/) {
 203                         $port = $1 + 0;
 204                         $scheme //= $KNOWN_TLS{$port} // $KNOWN_STARTTLS{$port};
 205                 }
 206                 $scheme or die "unable to determine URL scheme of $orig\n";
 207                 if (!defined($port) && index($l, '/') != 0) { # unix socket
 208                         $port = $SCHEME2PORT{$scheme} //
 209                                 die "no port in listen=$orig\n";
 210                         $l =~ s!\A([^/]+)!$1:$port! or
 211                                 die "unable to add port=$port to $l\n";
 212                 }
 213                 $l =~ s!/\z!!; # chop one trailing slash
 214                 if ($l =~ s!/?\?(.+)\z!!) {
 215                         $opt = listener_opt($1);
 216                         $tls_opt{"$scheme://$l"} = accept_tls_opt($opt);
 217                 } elsif (defined($default_cert)) {
 218                         $tls_opt{"$scheme://$l"} = accept_tls_opt('');
 219                 } elsif ($scheme =~ /\A(?:https|imaps|nntps|pop3s)\z/) {
 220                         die "$orig specified w/o cert=\n";
 221                 }
 222                 if ($listener_names->{$l}) { # already inherited
 223                         $xnetd->{$l} = load_mod($scheme, $opt, $l);
 224                         next;
 225                 }
 226                 my (%o, $sock_pkg);
 227                 if (index($l, '/') == 0) {
 228                         $sock_pkg = 'IO::Socket::UNIX';
 229                         eval "use $sock_pkg";
 230                         die $@ if $@;
 231                         %o = (Type => SOCK_STREAM, Peer => $l);
 232                         if (-S $l) {
 233                                 my $c = $sock_pkg->new(%o);
 234                                 if (!defined($c) && $!{ECONNREFUSED}) {
 235                                         unlink $l or die
 236 "failed to unlink stale socket=$l: $!\n";
 237                                 } # else: let the bind fail
 238                         }
 239                         $o{Local} = delete $o{Peer};
 240                 } else {
 241                         # both work for IPv4, too
 242                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
 243                                 $sock_pkg = $_;
 244                                 eval "use $sock_pkg";
 245                                 $@ or last;
 246                         }
 247                         die $@ if $@;
 248                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
 249                 }
 250                 $o{Listen} = 1024;
 251                 my $prev = umask 0000;
 252                 my $s = eval { $sock_pkg->new(%o) } or
 253                         warn "error binding $l: $! ($@)\n";
 254                 umask $prev;
 255                 $s // next;
 256                 $s->blocking(0);
 257                 my $sockname = sockname($s);
 258                 warn "# bound $scheme://$sockname\n";
 259                 $xnetd->{$sockname} //= load_mod($scheme);
 260                 $listener_names->{$sockname} = $s;
 261                 push @listeners, $s;
 262         }
 263
 264         # cert/key options in @cfg_listen takes precedence when inheriting,
 265         # but map well-known inherited ports if --listen isn't specified
 266         # at all
 267         for my $sockname (@inherited_names) {
 268                 $sockname =~ /:([0-9]+)\z/ or next;
 269                 if (my $scheme = $KNOWN_TLS{$1}) {
 270                         $xnetd->{$sockname} //= load_mod($scheme);
 271                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 272                 } elsif (($scheme = $KNOWN_STARTTLS{$1})) {
 273                         $xnetd->{$sockname} //= load_mod($scheme);
 274                         $tls_opt{"$scheme://$sockname"} ||= accept_tls_opt('');
 275                         $tls_opt{''} ||= accept_tls_opt('');
 276                 }
 277         }
 278         my @d;
 279         while (my ($k, $v) = each %tls_opt) { push(@d, $k) if !defined($v) }
 280         delete @tls_opt{@d};
 281         die "No listeners bound\n" unless @listeners;
 282 }
 283
 284 sub daemonize () {
 285         if ($daemonize) {
 286                 require Cwd;
 287                 foreach my $i (0..$#ARGV) {
 288                         my $arg = $ARGV[$i];
 289                         next unless -e $arg;
 290                         $ARGV[$i] = Cwd::abs_path($arg);
 291                 }
 292                 check_absolute('--stdout', $stdout);
 293                 check_absolute('--stderr', $stderr);
 294                 check_absolute('--pid-file', $pid_file);
 295                 check_absolute('--cert', $default_cert);
 296                 check_absolute('--key', $default_key);
 297
 298                 chdir '/' or die "chdir failed: $!";
 299         }
 300         if (defined($pid_file) || defined($group) || defined($user)) {
 301                 eval { require Net::Server::Daemonize; 1 } // die <<EOF;
 302 Net::Server required for --pid-file, --group, --user
 303 $@
 304 EOF
 305         }
 306         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 307         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 308         if (defined $group) {
 309                 $gid = Net::Server::Daemonize::get_gid($group);
 310                 $gid = (split /\s+/, $gid)[0];
 311         } elsif (defined $uid) {
 312                 $gid = (getpwuid($uid))[3];
 313         }
 314
 315         # We change users in the worker to ensure upgradability,
 316         # The upgrade will create the ".oldbin" pid file in the
 317         # same directory as the given pid file.
 318         $uid and $set_user = sub {
 319                 $set_user = undef;
 320                 Net::Server::Daemonize::set_user($uid, $gid);
 321         };
 322
 323         if ($daemonize) {
 324                 my $pid = fork // die "fork: $!";
 325                 exit if $pid;
 326
 327                 open(STDIN, '+<', '/dev/null') or
 328                                         die "redirect stdin failed: $!\n";
 329                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 330                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 331                 POSIX::setsid();
 332                 $pid = fork // die "fork: $!";
 333                 exit if $pid;
 334         }
 335         return unless defined $pid_file;
 336
 337         write_pid($pid_file);
 338         # for ->DESTROY:
 339         bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 340 }
 341
 342 sub worker_quit { # $_[0] = signal name or number (unused)
 343         # killing again terminates immediately:
 344         exit unless @listeners;
 345
 346         $_->close foreach @listeners; # call PublicInbox::DS::close
 347         @listeners = ();
 348         my $proc_name;
 349         my $warn = 0;
 350         # drop idle connections and try to quit gracefully
 351         PublicInbox::DS->SetPostLoopCallback(sub {
 352                 my ($dmap, undef) = @_;
 353                 my $n = 0;
 354                 my $now = now();
 355                 for my $s (values %$dmap) {
 356                         $s->can('busy') or next;
 357                         if ($s->busy) {
 358                                 ++$n;
 359                         } else { # close as much as possible, early as possible
 360                                 $s->close;
 361                         }
 362                 }
 363                 if ($n) {
 364                         if (($warn + 5) < now()) {
 365                                 warn "$$ quitting, $n client(s) left\n";
 366                                 $warn = now();
 367                         }
 368                         unless (defined $proc_name) {
 369                                 $proc_name = (split(/\s+/, $0))[0];
 370                                 $proc_name =~ s!\A.*?([^/]+)\z!$1!;
 371                         }
 372                         $0 = "$proc_name quitting, $n client(s) left";
 373                 }
 374                 $n; # true: loop continues, false: loop breaks
 375         });
 376 }
 377
 378 sub reopen_logs {
 379         $logs{$stdout} //= \*STDOUT if defined $stdout;
 380         $logs{$stderr} //= \*STDERR if defined $stderr;
 381         while (my ($p, $fh) = each %logs) { open_log_path($fh, $p) }
 382 }
 383
 384 sub sockname ($) {
 385         my ($s) = @_;
 386         my $addr = getsockname($s) or return;
 387         my ($host, $port) = host_with_port($addr);
 388         if ($port == 0 && $host eq '127.0.0.1') {
 389                 my ($path) = Socket::sockaddr_un($addr);
 390                 return $path;
 391         }
 392         "$host:$port";
 393 }
 394
 395 sub unpack_ipv6 ($) {
 396         my ($addr) = @_;
 397         my ($port, $host);
 398
 399         # Socket.pm in Perl 5.14+ supports IPv6:
 400         eval {
 401                 ($port, $host) = Socket::unpack_sockaddr_in6($addr);
 402                 $host = Socket::inet_ntop(Socket::AF_INET6(), $host);
 403         };
 404
 405         if ($@) {
 406                 # Perl 5.12 or earlier?  SpamAssassin and Net::Server use
 407                 # Socket6, so it may be installed on our system, already
 408                 # (otherwise die here):
 409                 require Socket6;
 410
 411                 ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 412                 $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 413         }
 414         ($host, $port);
 415 }
 416
 417 sub host_with_port ($) {
 418         my ($addr) = @_;
 419         my ($port, $host);
 420
 421         # this eval will die on Unix sockets:
 422         eval {
 423                 if (length($addr) >= 28) {
 424                         ($host, $port) = unpack_ipv6($addr);
 425                         $host = "[$host]";
 426                 } else {
 427                         ($port, $host) = Socket::sockaddr_in($addr);
 428                         $host = Socket::inet_ntoa($host);
 429                 }
 430         };
 431         $@ ? ('127.0.0.1', 0) : ($host, $port);
 432 }
 433
 434 sub inherit ($) {
 435         my ($listener_names) = @_;
 436         return () if ($ENV{LISTEN_PID} || 0) != $$;
 437         my $fds = $ENV{LISTEN_FDS} or return ();
 438         my $end = $fds + 2; # LISTEN_FDS_START - 1
 439         my @rv = ();
 440         foreach my $fd (3..$end) {
 441                 open(my $s, '<&=', $fd) or warn "fdopen fd=$fd: $!";
 442                 if (my $k = sockname($s)) {
 443                         my $prev_was_blocking = $s->blocking(0);
 444                         warn <<"" if $prev_was_blocking;
 445 Inherited socket ($k fd=$fd) is blocking, making it non-blocking.
 446 Set 'NonBlocking = true' in the systemd.service unit to avoid stalled
 447 processes when multiple service instances start.
 448
 449                         $listener_names->{$k} = $s;
 450                         warn "# inherited $k fd=$fd\n";
 451                         push @rv, $s;
 452                 } else {
 453                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 454                 }
 455         }
 456         @rv
 457 }
 458
 459 sub upgrade { # $_[0] = signal name or number (unused)
 460         if ($reexec_pid) {
 461                 warn "upgrade in-progress: $reexec_pid\n";
 462                 return;
 463         }
 464         if (defined $pid_file) {
 465                 if ($pid_file =~ /\.oldbin\z/) {
 466                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 467                         return;
 468                 }
 469                 unlink_pid_file_safe_ish($$, $pid_file);
 470                 $pid_file .= '.oldbin';
 471                 write_pid($pid_file);
 472         }
 473         my $pid = fork;
 474         unless (defined $pid) {
 475                 warn "fork failed: $!\n";
 476                 return;
 477         }
 478         if ($pid == 0) {
 479                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 480                 $ENV{LISTEN_FDS} = scalar @listeners;
 481                 $ENV{LISTEN_PID} = $$;
 482                 foreach my $s (@listeners) {
 483                         # @listeners are globs with workers, PI::L w/o workers
 484                         $s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
 485
 486                         my $fl = fcntl($s, F_GETFD, 0);
 487                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 488                 }
 489                 exec @CMD;
 490                 die "Failed to exec: $!\n";
 491         }
 492         $reexec_pid = $pid;
 493 }
 494
 495 sub kill_workers ($) {
 496         my ($sig) = @_;
 497         kill $sig, keys(%pids);
 498 }
 499
 500 sub upgrade_aborted ($) {
 501         my ($p) = @_;
 502         warn "reexec PID($p) died with: $?\n";
 503         $reexec_pid = undef;
 504         return unless $pid_file;
 505
 506         my $file = $pid_file;
 507         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 508         unlink_pid_file_safe_ish($$, $pid_file);
 509         $pid_file = $file;
 510         eval { write_pid($pid_file) };
 511         warn $@, "\n" if $@;
 512 }
 513
 514 sub reap_children { # $_[0] = 'CHLD' or POSIX::SIGCHLD()
 515         while (1) {
 516                 my $p = waitpid(-1, WNOHANG) or return;
 517                 if (defined $reexec_pid && $p == $reexec_pid) {
 518                         upgrade_aborted($p);
 519                 } elsif (defined(my $id = delete $pids{$p})) {
 520                         warn "worker[$id] PID($p) died with: $?\n";
 521                 } elsif ($p > 0) {
 522                         warn "unknown PID($p) reaped: $?\n";
 523                 } else {
 524                         return;
 525                 }
 526         }
 527 }
 528
 529 sub unlink_pid_file_safe_ish ($$) {
 530         my ($unlink_pid, $file) = @_;
 531         return unless defined $unlink_pid && $unlink_pid == $$;
 532
 533         open my $fh, '<', $file or return;
 534         local $/ = "\n";
 535         defined(my $read_pid = <$fh>) or return;
 536         chomp $read_pid;
 537         if ($read_pid == $unlink_pid) {
 538                 Net::Server::Daemonize::unlink_pid_file($file);
 539         }
 540 }
 541
 542 sub master_quit ($) {
 543         exit unless @listeners;
 544         @listeners = ();
 545         kill_workers($_[0]);
 546 }
 547
 548 sub master_loop {
 549         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 550         my $set_workers = $worker_processes;
 551         reopen_logs();
 552         my $ignore_winch;
 553         my $sig = {
 554                 USR1 => sub { reopen_logs(); kill_workers($_[0]); },
 555                 USR2 => \&upgrade,
 556                 QUIT => \&master_quit,
 557                 INT => \&master_quit,
 558                 TERM => \&master_quit,
 559                 WINCH => sub {
 560                         return if $ignore_winch || !@listeners;
 561                         if (-t STDIN || -t STDOUT || -t STDERR) {
 562                                 $ignore_winch = 1;
 563                                 warn <<EOF;
 564 ignoring SIGWINCH since we are not daemonized
 565 EOF
 566                         } else {
 567                                 $worker_processes = 0;
 568                         }
 569                 },
 570                 HUP => sub {
 571                         return unless @listeners;
 572                         $worker_processes = $set_workers;
 573                         kill_workers($_[0]);
 574                 },
 575                 TTIN => sub {
 576                         return unless @listeners;
 577                         if ($set_workers > $worker_processes) {
 578                                 ++$worker_processes;
 579                         } else {
 580                                 $worker_processes = ++$set_workers;
 581                         }
 582                 },
 583                 TTOU => sub {
 584                         $worker_processes = --$set_workers if $set_workers > 0;
 585                 },
 586                 CHLD => \&reap_children,
 587         };
 588         my $sigfd = PublicInbox::Sigfd->new($sig);
 589         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 590         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 591         while (1) { # main loop
 592                 my $n = scalar keys %pids;
 593                 unless (@listeners) {
 594                         exit if $n == 0;
 595                         $set_workers = $worker_processes = $n = 0;
 596                 }
 597
 598                 if ($n > $worker_processes) {
 599                         while (my ($k, $v) = each %pids) {
 600                                 kill('TERM', $k) if $v >= $worker_processes;
 601                         }
 602                         $n = $worker_processes;
 603                 }
 604                 my $want = $worker_processes - 1;
 605                 if ($n <= $want) {
 606                         PublicInbox::DS::block_signals() if !$sigfd;
 607                         for my $i ($n..$want) {
 608                                 my $seed = rand(0xffffffff);
 609                                 my $pid = fork;
 610                                 if (!defined $pid) {
 611                                         warn "failed to fork worker[$i]: $!\n";
 612                                 } elsif ($pid == 0) {
 613                                         srand($seed);
 614                                         eval { Net::SSLeay::randomize() };
 615                                         $set_user->() if $set_user;
 616                                         return $p0; # run normal work code
 617                                 } else {
 618                                         warn "PID=$pid is worker[$i]\n";
 619                                         $pids{$pid} = $i;
 620                                 }
 621                         }
 622                         PublicInbox::DS::sig_setmask($oldset) if !$sigfd;
 623                 }
 624
 625                 if ($sigfd) { # Linux and IO::KQueue users:
 626                         $sigfd->wait_once;
 627                 } else { # wake up every second
 628                         sleep(1);
 629                 }
 630         }
 631         exit # never gets here, just for documentation
 632 }
 633
 634 sub tls_cb {
 635         my ($post_accept, $tlsd) = @_;
 636         sub {
 637                 my ($io, $addr, $srv) = @_;
 638                 $post_accept->(PublicInbox::TLS::start($io, $tlsd), $addr, $srv)
 639         }
 640 }
 641
 642 sub defer_accept ($$) {
 643         my ($s, $af_name) = @_;
 644         return unless defined $af_name;
 645         if ($^O eq 'linux') {
 646                 my $TCP_DEFER_ACCEPT = 9; # Socket::TCP_DEFER_ACCEPT is in 5.14+
 647                 my $x = getsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT);
 648                 return unless defined $x; # may be Unix socket
 649                 my $sec = unpack('i', $x);
 650                 return if $sec > 0; # systemd users may set a higher value
 651                 setsockopt($s, IPPROTO_TCP, $TCP_DEFER_ACCEPT, 1);
 652         } elsif ($^O eq 'freebsd') {
 653                 my $x = getsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER);
 654                 return if defined $x; # don't change if set
 655                 my $accf_arg = pack('a16a240', $af_name, '');
 656                 setsockopt($s, SOL_SOCKET, $SO_ACCEPTFILTER, $accf_arg);
 657         }
 658 }
 659
 660 sub daemon_loop ($) {
 661         my ($xnetd) = @_;
 662         local $PublicInbox::Config::DEDUPE = {}; # enable dedupe cache
 663         my $refresh = sub {
 664                 my ($sig) = @_;
 665                 %$PublicInbox::Config::DEDUPE = (); # clear cache
 666                 for my $xn (values %$xnetd) {
 667                         delete $xn->{tlsd}->{ssl_ctx}; # PublicInbox::TLS::start
 668                         eval { $xn->{refresh}->($sig) };
 669                         warn "refresh $@\n" if $@;
 670                 }
 671         };
 672         my %post_accept;
 673         while (my ($k, $ctx_opt) = each %tls_opt) {
 674                 my $l = $k;
 675                 $l =~ s!\A([^:]+)://!!;
 676                 my $scheme = $1 // '';
 677                 my $xn = $xnetd->{$l} // $xnetd->{''};
 678                 $xn->{tlsd}->{ssl_ctx_opt} //= $ctx_opt;
 679                 $scheme =~ m!\A(?:https|imaps|nntps|pop3s)! and
 680                         $post_accept{$l} = tls_cb(@$xn{qw(post_accept tlsd)});
 681         }
 682         my $sig = {
 683                 HUP => $refresh,
 684                 INT => \&worker_quit,
 685                 QUIT => \&worker_quit,
 686                 TERM => \&worker_quit,
 687                 TTIN => 'IGNORE',
 688                 TTOU => 'IGNORE',
 689                 USR1 => \&reopen_logs,
 690                 USR2 => 'IGNORE',
 691                 WINCH => 'IGNORE',
 692                 CHLD => \&PublicInbox::DS::enqueue_reap,
 693         };
 694         if ($worker_processes > 0) {
 695                 $refresh->(); # preload by default
 696                 my $fh = master_loop(); # returns if in child process
 697                 PublicInbox::EOFpipe->new($fh, \&worker_quit, undef);
 698         } else {
 699                 reopen_logs();
 700                 $set_user->() if $set_user;
 701                 $sig->{USR2} = sub { worker_quit() if upgrade() };
 702                 $refresh->();
 703         }
 704         $uid = $gid = undef;
 705         reopen_logs();
 706         @listeners = map {;
 707                 my $l = sockname($_);
 708                 my $tls_cb = $post_accept{$l};
 709                 my $xn = $xnetd->{$l} // $xnetd->{''};
 710
 711                 # NNTPS, HTTPS, HTTP, IMAPS and POP3S are client-first traffic
 712                 # IMAP, NNTP and POP3 are server-first
 713                 defer_accept($_, $tls_cb ? 'dataready' : $xn->{af_default});
 714
 715                 # this calls epoll_create:
 716                 PublicInbox::Listener->new($_, $tls_cb || $xn->{post_accept})
 717         } @listeners;
 718         PublicInbox::DS::event_loop($sig, $oldset);
 719 }
 720
 721 sub run {
 722         my ($default_listen) = @_;
 723         my $xnetd = {};
 724         if ($default_listen) {
 725                 $default_listen =~ /\A(http|imap|nntp|pop3)/ or
 726                         die "BUG: $default_listen";
 727                 $xnetd->{''} = load_mod($1);
 728         }
 729         daemon_prepare($default_listen, $xnetd);
 730         my $for_destroy = daemonize();
 731
 732         # localize GCF2C for tests:
 733         local $PublicInbox::GitAsyncCat::GCF2C;
 734         local $PublicInbox::Git::async_warn = 1;
 735         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 736
 737         daemon_loop($xnetd);
 738         PublicInbox::DS->Reset;
 739         # ->DESTROY runs when $for_destroy goes out-of-scope
 740 }
 741
 742 sub write_pid ($) {
 743         my ($path) = @_;
 744         Net::Server::Daemonize::create_pid_file($path);
 745         do_chown($path);
 746 }
 747
 748 sub DESTROY {
 749         unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 750 }
 751
 752 1;