lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 use Cwd qw/abs_path/;
  12 STDOUT->autoflush(1);
  13 STDERR->autoflush(1);
  14 require Danga::Socket;
  15 require POSIX;
  16 require PublicInbox::Listener;
  17 my @CMD;
  18 my $set_user;
  19 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  20 my $worker_processes = 1;
  21 my @listeners;
  22 my %pids;
  23 my %listener_names;
  24 my $reexec_pid;
  25 my $cleanup;
  26 my ($uid, $gid);
  27 END { $cleanup->() if $cleanup };
  28
  29 sub daemon_prepare ($) {
  30         my ($default_listen) = @_;
  31         @CMD = ($0, @ARGV);
  32         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  33                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  34         my %opts = (
  35                 'l|listen=s' => \@cfg_listen,
  36                 '1|stdout=s' => \$stdout,
  37                 '2|stderr=s' => \$stderr,
  38                 'W|worker-processes=i' => \$worker_processes,
  39                 'P|pid-file=s' => \$pid_file,
  40                 'u|user=s' => \$user,
  41                 'g|group=s' => \$group,
  42                 'D|daemonize' => \$daemonize,
  43         );
  44         GetOptions(%opts) or die "bad command-line args\n";
  45
  46         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  47                 die "--pid-file cannot end with '.oldbin'\n";
  48         }
  49         @listeners = inherit();
  50         # ignore daemonize when inheriting
  51         $daemonize = undef if scalar @listeners;
  52
  53         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  54
  55         foreach my $l (@cfg_listen) {
  56                 next if $listener_names{$l}; # already inherited
  57                 my (%o, $sock_pkg);
  58                 if (index($l, '/') == 0) {
  59                         $sock_pkg = 'IO::Socket::UNIX';
  60                         eval "use $sock_pkg";
  61                         die $@ if $@;
  62                         %o = (Type => SOCK_STREAM, Peer => $l);
  63                         if (-S $l) {
  64                                 my $c = $sock_pkg->new(%o);
  65                                 if (!defined($c) && $!{ECONNREFUSED}) {
  66                                         unlink $l or die
  67 "failed to unlink stale socket=$l: $!\n";
  68                                 } # else: let the bind fail
  69                         }
  70                         $o{Local} = delete $o{Peer};
  71                 } else {
  72                         # both work for IPv4, too
  73                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
  74                                 $sock_pkg = $_;
  75                                 eval "use $sock_pkg";
  76                                 $@ or last;
  77                         }
  78                         die $@ if $@;
  79                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  80                 }
  81                 $o{Listen} = 1024;
  82                 my $prev = umask 0000;
  83                 my $s = eval { $sock_pkg->new(%o) };
  84                 warn "error binding $l: $! ($@)\n" unless $s;
  85                 umask $prev;
  86
  87                 if ($s) {
  88                         $listener_names{sockname($s)} = $s;
  89                         push @listeners, $s;
  90                 }
  91         }
  92         die "No listeners bound\n" unless @listeners;
  93 }
  94
  95 sub check_absolute ($$) {
  96         my ($var, $val) = @_;
  97         if (defined $val && index($val, '/') != 0) {
  98                 die
  99 "--$var must be an absolute path when using --daemonize: $val\n";
 100         }
 101 }
 102
 103 sub daemonize () {
 104         foreach my $i (0..$#ARGV) {
 105                 my $arg = $ARGV[$i];
 106                 next unless -e $arg;
 107                 $ARGV[$i] = abs_path($arg);
 108         }
 109         check_absolute('stdout', $stdout);
 110         check_absolute('stderr', $stderr);
 111         check_absolute('pid-file', $pid_file);
 112
 113         chdir '/' or die "chdir failed: $!";
 114         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 115
 116         return unless (defined $pid_file || defined $group || defined $user
 117                         || $daemonize);
 118
 119         eval { require Net::Server::Daemonize };
 120         if ($@) {
 121                 die
 122 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 123         }
 124
 125         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 126         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 127         if (defined $group) {
 128                 $gid = Net::Server::Daemonize::get_gid($group);
 129                 $gid = (split /\s+/, $gid)[0];
 130         } elsif (defined $uid) {
 131                 $gid = (getpwuid($uid))[3];
 132         }
 133
 134         # We change users in the worker to ensure upgradability,
 135         # The upgrade will create the ".oldbin" pid file in the
 136         # same directory as the given pid file.
 137         $uid and $set_user = sub {
 138                 $set_user = undef;
 139                 Net::Server::Daemonize::set_user($uid, $gid);
 140         };
 141
 142         if ($daemonize) {
 143                 my ($pid, $err) = do_fork();
 144                 die "could not fork: $err\n" unless defined $pid;
 145                 exit if $pid;
 146
 147                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 148                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 149                 POSIX::setsid();
 150                 ($pid, $err) = do_fork();
 151                 die "could not fork: $err\n" unless defined $pid;
 152                 exit if $pid;
 153         }
 154         if (defined $pid_file) {
 155                 write_pid($pid_file);
 156                 my $unlink_pid = $$;
 157                 $cleanup = sub {
 158                         $cleanup = undef; # avoid cyclic reference
 159                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 160                 };
 161         }
 162 }
 163
 164 sub worker_quit () {
 165         # killing again terminates immediately:
 166         exit unless @listeners;
 167
 168         $_->close foreach @listeners; # call Danga::Socket::close
 169         @listeners = ();
 170
 171         # give slow clients 30s to finish reading/writing whatever
 172         Danga::Socket->AddTimer(30, sub { exit });
 173
 174         # drop idle connections and try to quit gracefully
 175         Danga::Socket->SetPostLoopCallback(sub {
 176                 my ($dmap, undef) = @_;
 177                 my $n = 0;
 178
 179                 foreach my $s (values %$dmap) {
 180                         if ($s->can('busy') && $s->busy) {
 181                                 $n = 1;
 182                         } else {
 183                                 # close as much as possible, early as possible
 184                                 $s->close;
 185                         }
 186                 }
 187                 $n; # true: loop continues, false: loop breaks
 188         });
 189 }
 190
 191 sub reopen_logs {
 192         if ($stdout) {
 193                 open STDOUT, '>>', $stdout or
 194                         warn "failed to redirect stdout to $stdout: $!\n";
 195                 STDOUT->autoflush(1);
 196                 do_chown($stdout);
 197         }
 198         if ($stderr) {
 199                 open STDERR, '>>', $stderr or
 200                         warn "failed to redirect stderr to $stderr: $!\n";
 201                 STDERR->autoflush(1);
 202                 do_chown($stderr);
 203         }
 204 }
 205
 206 sub sockname ($) {
 207         my ($s) = @_;
 208         my $addr = getsockname($s) or return;
 209         my ($host, $port) = host_with_port($addr);
 210         if ($port == 0 && $host eq '127.0.0.1') {
 211                 my ($path) = Socket::sockaddr_un($addr);
 212                 return $path;
 213         }
 214         "$host:$port";
 215 }
 216
 217 sub host_with_port ($) {
 218         my ($addr) = @_;
 219         my ($port, $host);
 220
 221         # this eval will die on Unix sockets:
 222         eval {
 223                 if (length($addr) >= 28) {
 224                         require Socket6;
 225                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 226                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 227                         $host = "[$host]";
 228                 } else {
 229                         ($port, $host) = Socket::sockaddr_in($addr);
 230                         $host = Socket::inet_ntoa($host);
 231                 }
 232         };
 233         $@ ? ('127.0.0.1', 0) : ($host, $port);
 234 }
 235
 236 sub inherit () {
 237         return () if ($ENV{LISTEN_PID} || 0) != $$;
 238         my $fds = $ENV{LISTEN_FDS} or return ();
 239         my $end = $fds + 2; # LISTEN_FDS_START - 1
 240         my @rv = ();
 241         foreach my $fd (3..$end) {
 242                 my $s = IO::Handle->new_from_fd($fd, 'r');
 243                 if (my $k = sockname($s)) {
 244                         $listener_names{$k} = $s;
 245                         push @rv, $s;
 246                 } else {
 247                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 248                 }
 249         }
 250         @rv
 251 }
 252
 253 sub upgrade () {
 254         if ($reexec_pid) {
 255                 warn "upgrade in-progress: $reexec_pid\n";
 256                 return;
 257         }
 258         if (defined $pid_file) {
 259                 if ($pid_file =~ /\.oldbin\z/) {
 260                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 261                         return;
 262                 }
 263                 unlink_pid_file_safe_ish($$, $pid_file);
 264                 $pid_file .= '.oldbin';
 265                 write_pid($pid_file);
 266         }
 267         my ($pid, $err) = do_fork();
 268         unless (defined $pid) {
 269                 warn "fork failed: $err\n";
 270                 return;
 271         }
 272         if ($pid == 0) {
 273                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 274                 $ENV{LISTEN_FDS} = scalar @listeners;
 275                 $ENV{LISTEN_PID} = $$;
 276                 foreach my $s (@listeners) {
 277                         my $fl = fcntl($s, F_GETFD, 0);
 278                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 279                 }
 280                 exec @CMD;
 281                 die "Failed to exec: $!\n";
 282         }
 283         $reexec_pid = $pid;
 284 }
 285
 286 sub kill_workers ($) {
 287         my ($s) = @_;
 288
 289         while (my ($pid, $id) = each %pids) {
 290                 kill $s, $pid;
 291         }
 292 }
 293
 294 sub do_fork () {
 295         my $new = POSIX::SigSet->new;
 296         $new->fillset;
 297         my $old = POSIX::SigSet->new;
 298         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 299         my $pid = fork;
 300         my $err = $!;
 301         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 302         ($pid, $err);
 303 }
 304
 305 sub upgrade_aborted ($) {
 306         my ($p) = @_;
 307         warn "reexec PID($p) died with: $?\n";
 308         $reexec_pid = undef;
 309         return unless $pid_file;
 310
 311         my $file = $pid_file;
 312         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 313         unlink_pid_file_safe_ish($$, $pid_file);
 314         $pid_file = $file;
 315         eval { write_pid($pid_file) };
 316         warn $@, "\n" if $@;
 317 }
 318
 319 sub reap_children () {
 320         while (1) {
 321                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 322                 if (defined $reexec_pid && $p == $reexec_pid) {
 323                         upgrade_aborted($p);
 324                 } elsif (defined(my $id = delete $pids{$p})) {
 325                         warn "worker[$id] PID($p) died with: $?\n";
 326                 } elsif ($p > 0) {
 327                         warn "unknown PID($p) reaped: $?\n";
 328                 } else {
 329                         return;
 330                 }
 331         }
 332 }
 333
 334 sub unlink_pid_file_safe_ish ($$) {
 335         my ($unlink_pid, $file) = @_;
 336         return unless defined $unlink_pid && $unlink_pid == $$;
 337
 338         open my $fh, '<', $file or return;
 339         defined(my $read_pid = <$fh>) or return;
 340         chomp $read_pid;
 341         if ($read_pid == $unlink_pid) {
 342                 Net::Server::Daemonize::unlink_pid_file($file);
 343         }
 344 }
 345
 346 sub master_loop {
 347         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 348         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 349         IO::Handle::blocking($w, 0);
 350         my $set_workers = $worker_processes;
 351         my @caught;
 352         my $master_pid = $$;
 353         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 354                 $SIG{$s} = sub {
 355                         return if $$ != $master_pid;
 356                         push @caught, $s;
 357                         syswrite($w, '.');
 358                 };
 359         }
 360         reopen_logs();
 361         # main loop
 362         while (1) {
 363                 while (my $s = shift @caught) {
 364                         if ($s eq 'USR1') {
 365                                 reopen_logs();
 366                                 kill_workers($s);
 367                         } elsif ($s eq 'USR2') {
 368                                 upgrade();
 369                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 370                                 # drops pipes and causes children to die
 371                                 exit
 372                         } elsif ($s eq 'WINCH') {
 373                                 $worker_processes = 0;
 374                         } elsif ($s eq 'HUP') {
 375                                 $worker_processes = $set_workers;
 376                                 kill_workers($s);
 377                         } elsif ($s eq 'TTIN') {
 378                                 if ($set_workers > $worker_processes) {
 379                                         ++$worker_processes;
 380                                 } else {
 381                                         $worker_processes = ++$set_workers;
 382                                 }
 383                         } elsif ($s eq 'TTOU') {
 384                                 if ($set_workers > 0) {
 385                                         $worker_processes = --$set_workers;
 386                                 }
 387                         } elsif ($s eq 'CHLD') {
 388                                 reap_children();
 389                         }
 390                 }
 391
 392                 my $n = scalar keys %pids;
 393                 if ($n > $worker_processes) {
 394                         while (my ($k, $v) = each %pids) {
 395                                 kill('TERM', $k) if $v >= $worker_processes;
 396                         }
 397                         $n = $worker_processes;
 398                 }
 399                 foreach my $i ($n..($worker_processes - 1)) {
 400                         my ($pid, $err) = do_fork();
 401                         if (!defined $pid) {
 402                                 warn "failed to fork worker[$i]: $err\n";
 403                         } elsif ($pid == 0) {
 404                                 $set_user->() if $set_user;
 405                                 return $p0; # run normal work code
 406                         } else {
 407                                 warn "PID=$pid is worker[$i]\n";
 408                                 $pids{$pid} = $i;
 409                         }
 410                 }
 411                 # just wait on signal events here:
 412                 sysread($r, my $buf, 8);
 413         }
 414         exit # never gets here, just for documentation
 415 }
 416
 417 sub daemon_loop ($$) {
 418         my ($refresh, $post_accept) = @_;
 419         my $parent_pipe;
 420         if ($worker_processes > 0) {
 421                 $refresh->(); # preload by default
 422                 $parent_pipe = master_loop(); # returns if in child process
 423                 my $fd = fileno($parent_pipe);
 424                 Danga::Socket->AddOtherFds($fd => *worker_quit);
 425         } else {
 426                 reopen_logs();
 427                 $set_user->() if $set_user;
 428                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 429                 $refresh->();
 430         }
 431         $uid = $gid = undef;
 432         reopen_logs();
 433         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 434         $SIG{USR1} = *reopen_logs;
 435         $SIG{HUP} = $refresh;
 436         # this calls epoll_create:
 437         @listeners = map {
 438                 PublicInbox::Listener->new($_, $post_accept)
 439         } @listeners;
 440         Danga::Socket->EventLoop;
 441         $parent_pipe = undef;
 442 }
 443
 444
 445 sub run ($$$) {
 446         my ($default, $refresh, $post_accept) = @_;
 447         daemon_prepare($default);
 448         daemonize();
 449         daemon_loop($refresh, $post_accept);
 450 }
 451
 452 sub do_chown ($) {
 453         my ($path) = @_;
 454         if (defined $uid and !chown($uid, $gid, $path)) {
 455                 warn "could not chown $path: $!\n";
 456         }
 457 }
 458
 459 sub write_pid ($) {
 460         my ($path) = @_;
 461         Net::Server::Daemonize::create_pid_file($path);
 462         do_chown($path);
 463 }
 464
 465 1;