lib/PublicInbox/Daemon.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # contains common daemon code for the nntpd and httpd servers.
   4 # This may be used for read-only IMAP server if we decide to implement it.
   5 package PublicInbox::Daemon;
   6 use strict;
   7 use warnings;
   8 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
   9 use IO::Handle;
  10 use IO::Socket;
  11 STDOUT->autoflush(1);
  12 STDERR->autoflush(1);
  13 require Danga::Socket;
  14 require POSIX;
  15 require PublicInbox::Listener;
  16 my @CMD;
  17 my $set_user;
  18 my (@cfg_listen, $stdout, $stderr, $group, $user, $pid_file, $daemonize);
  19 my $worker_processes = 1;
  20 my @listeners;
  21 my %pids;
  22 my %listener_names;
  23 my $reexec_pid;
  24 my $cleanup;
  25 my ($uid, $gid);
  26 END { $cleanup->() if $cleanup };
  27
  28 sub daemon_prepare ($) {
  29         my ($default_listen) = @_;
  30         @CMD = ($0, @ARGV);
  31         $SIG{HUP} = $SIG{USR1} = $SIG{USR2} = $SIG{PIPE} =
  32                 $SIG{TTIN} = $SIG{TTOU} = $SIG{WINCH} = 'IGNORE';
  33         my %opts = (
  34                 'l|listen=s' => \@cfg_listen,
  35                 '1|stdout=s' => \$stdout,
  36                 '2|stderr=s' => \$stderr,
  37                 'W|worker-processes=i' => \$worker_processes,
  38                 'P|pid-file=s' => \$pid_file,
  39                 'u|user=s' => \$user,
  40                 'g|group=s' => \$group,
  41                 'D|daemonize' => \$daemonize,
  42         );
  43         GetOptions(%opts) or die "bad command-line args\n";
  44
  45         if (defined $pid_file && $pid_file =~ /\.oldbin\z/) {
  46                 die "--pid-file cannot end with '.oldbin'\n";
  47         }
  48         @listeners = inherit();
  49         # ignore daemonize when inheriting
  50         $daemonize = undef if scalar @listeners;
  51
  52         push @cfg_listen, $default_listen unless (@listeners || @cfg_listen);
  53
  54         foreach my $l (@cfg_listen) {
  55                 next if $listener_names{$l}; # already inherited
  56                 my (%o, $sock_pkg);
  57                 if (index($l, '/') == 0) {
  58                         $sock_pkg = 'IO::Socket::UNIX';
  59                         eval "use $sock_pkg";
  60                         die $@ if $@;
  61                         %o = (Type => SOCK_STREAM, Peer => $l);
  62                         if (-S $l) {
  63                                 my $c = $sock_pkg->new(%o);
  64                                 if (!defined($c) && $!{ECONNREFUSED}) {
  65                                         unlink $l or die
  66 "failed to unlink stale socket=$l: $!\n";
  67                                 } # else: let the bind fail
  68                         }
  69                         $o{Local} = delete $o{Peer};
  70                 } else {
  71                         # both work for IPv4, too
  72                         for (qw(IO::Socket::IP IO::Socket::INET6)) {
  73                                 $sock_pkg = $_;
  74                                 eval "use $sock_pkg";
  75                                 $@ or last;
  76                         }
  77                         die $@ if $@;
  78                         %o = (LocalAddr => $l, ReuseAddr => 1, Proto => 'tcp');
  79                 }
  80                 $o{Listen} = 1024;
  81                 my $prev = umask 0000;
  82                 my $s = eval { $sock_pkg->new(%o) };
  83                 warn "error binding $l: $! ($@)\n" unless $s;
  84                 umask $prev;
  85
  86                 if ($s) {
  87                         $listener_names{sockname($s)} = $s;
  88                         push @listeners, $s;
  89                 }
  90         }
  91         die "No listeners bound\n" unless @listeners;
  92 }
  93
  94 sub daemonize () {
  95         chdir '/' or die "chdir failed: $!";
  96         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
  97
  98         return unless (defined $pid_file || defined $group || defined $user
  99                         || $daemonize);
 100
 101         eval { require Net::Server::Daemonize };
 102         if ($@) {
 103                 die
 104 "Net::Server required for --pid-file, --group, --user, and --daemonize\n$@\n";
 105         }
 106
 107         Net::Server::Daemonize::check_pid_file($pid_file) if defined $pid_file;
 108         $uid = Net::Server::Daemonize::get_uid($user) if defined $user;
 109         if (defined $group) {
 110                 $gid = Net::Server::Daemonize::get_gid($group);
 111                 $gid = (split /\s+/, $gid)[0];
 112         } elsif (defined $uid) {
 113                 $gid = (getpwuid($uid))[3];
 114         }
 115
 116         # We change users in the worker to ensure upgradability,
 117         # The upgrade will create the ".oldbin" pid file in the
 118         # same directory as the given pid file.
 119         $uid and $set_user = sub {
 120                 $set_user = undef;
 121                 Net::Server::Daemonize::set_user($uid, $gid);
 122         };
 123
 124         if ($daemonize) {
 125                 my ($pid, $err) = do_fork();
 126                 die "could not fork: $err\n" unless defined $pid;
 127                 exit if $pid;
 128
 129                 open STDOUT, '>&STDIN' or die "redirect stdout failed: $!\n";
 130                 open STDERR, '>&STDIN' or die "redirect stderr failed: $!\n";
 131                 POSIX::setsid();
 132                 ($pid, $err) = do_fork();
 133                 die "could not fork: $err\n" unless defined $pid;
 134                 exit if $pid;
 135         }
 136         if (defined $pid_file) {
 137                 write_pid($pid_file);
 138                 my $unlink_pid = $$;
 139                 $cleanup = sub {
 140                         $cleanup = undef; # avoid cyclic reference
 141                         unlink_pid_file_safe_ish($unlink_pid, $pid_file);
 142                 };
 143         }
 144 }
 145
 146 sub worker_quit () {
 147         # killing again terminates immediately:
 148         exit unless @listeners;
 149
 150         $_->close foreach @listeners; # call Danga::Socket::close
 151         @listeners = ();
 152
 153         # give slow clients 30s to finish reading/writing whatever
 154         Danga::Socket->AddTimer(30, sub { exit });
 155
 156         # drop idle connections and try to quit gracefully
 157         Danga::Socket->SetPostLoopCallback(sub {
 158                 my ($dmap, undef) = @_;
 159                 my $n = 0;
 160
 161                 foreach my $s (values %$dmap) {
 162                         if ($s->can('busy') && $s->busy) {
 163                                 $n = 1;
 164                         } else {
 165                                 # close as much as possible, early as possible
 166                                 $s->close;
 167                         }
 168                 }
 169                 $n; # true: loop continues, false: loop breaks
 170         });
 171 }
 172
 173 sub reopen_logs {
 174         if ($stdout) {
 175                 open STDOUT, '>>', $stdout or
 176                         warn "failed to redirect stdout to $stdout: $!\n";
 177                 STDOUT->autoflush(1);
 178                 do_chown($stdout);
 179         }
 180         if ($stderr) {
 181                 open STDERR, '>>', $stderr or
 182                         warn "failed to redirect stderr to $stderr: $!\n";
 183                 STDERR->autoflush(1);
 184                 do_chown($stderr);
 185         }
 186 }
 187
 188 sub sockname ($) {
 189         my ($s) = @_;
 190         my $addr = getsockname($s) or return;
 191         my ($host, $port) = host_with_port($addr);
 192         if ($port == 0 && $host eq '127.0.0.1') {
 193                 my ($path) = Socket::sockaddr_un($addr);
 194                 return $path;
 195         }
 196         "$host:$port";
 197 }
 198
 199 sub host_with_port ($) {
 200         my ($addr) = @_;
 201         my ($port, $host);
 202
 203         # this eval will die on Unix sockets:
 204         eval {
 205                 if (length($addr) >= 28) {
 206                         require Socket6;
 207                         ($port, $host) = Socket6::unpack_sockaddr_in6($addr);
 208                         $host = Socket6::inet_ntop(Socket6::AF_INET6(), $host);
 209                         $host = "[$host]";
 210                 } else {
 211                         ($port, $host) = Socket::sockaddr_in($addr);
 212                         $host = Socket::inet_ntoa($host);
 213                 }
 214         };
 215         $@ ? ('127.0.0.1', 0) : ($host, $port);
 216 }
 217
 218 sub inherit () {
 219         return () if ($ENV{LISTEN_PID} || 0) != $$;
 220         my $fds = $ENV{LISTEN_FDS} or return ();
 221         my $end = $fds + 2; # LISTEN_FDS_START - 1
 222         my @rv = ();
 223         foreach my $fd (3..$end) {
 224                 my $s = IO::Handle->new_from_fd($fd, 'r');
 225                 if (my $k = sockname($s)) {
 226                         $listener_names{$k} = $s;
 227                         push @rv, $s;
 228                 } else {
 229                         warn "failed to inherit fd=$fd (LISTEN_FDS=$fds)";
 230                 }
 231         }
 232         @rv
 233 }
 234
 235 sub upgrade () {
 236         if ($reexec_pid) {
 237                 warn "upgrade in-progress: $reexec_pid\n";
 238                 return;
 239         }
 240         if (defined $pid_file) {
 241                 if ($pid_file =~ /\.oldbin\z/) {
 242                         warn "BUG: .oldbin suffix exists: $pid_file\n";
 243                         return;
 244                 }
 245                 unlink_pid_file_safe_ish($$, $pid_file);
 246                 $pid_file .= '.oldbin';
 247                 write_pid($pid_file);
 248         }
 249         my ($pid, $err) = do_fork();
 250         unless (defined $pid) {
 251                 warn "fork failed: $err\n";
 252                 return;
 253         }
 254         if ($pid == 0) {
 255                 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
 256                 $ENV{LISTEN_FDS} = scalar @listeners;
 257                 $ENV{LISTEN_PID} = $$;
 258                 foreach my $s (@listeners) {
 259                         my $fl = fcntl($s, F_GETFD, 0);
 260                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 261                 }
 262                 exec @CMD;
 263                 die "Failed to exec: $!\n";
 264         }
 265         $reexec_pid = $pid;
 266 }
 267
 268 sub kill_workers ($) {
 269         my ($s) = @_;
 270
 271         while (my ($pid, $id) = each %pids) {
 272                 kill $s, $pid;
 273         }
 274 }
 275
 276 sub do_fork () {
 277         my $new = POSIX::SigSet->new;
 278         $new->fillset;
 279         my $old = POSIX::SigSet->new;
 280         POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new, $old) or die "SIG_BLOCK: $!";
 281         my $pid = fork;
 282         my $err = $!;
 283         POSIX::sigprocmask(&POSIX::SIG_SETMASK, $old) or die "SIG_SETMASK: $!";
 284         ($pid, $err);
 285 }
 286
 287 sub upgrade_aborted ($) {
 288         my ($p) = @_;
 289         warn "reexec PID($p) died with: $?\n";
 290         $reexec_pid = undef;
 291         return unless $pid_file;
 292
 293         my $file = $pid_file;
 294         $file =~ s/\.oldbin\z// or die "BUG: no '.oldbin' suffix in $file";
 295         unlink_pid_file_safe_ish($$, $pid_file);
 296         $pid_file = $file;
 297         eval { write_pid($pid_file) };
 298         warn $@, "\n" if $@;
 299 }
 300
 301 sub reap_children () {
 302         while (1) {
 303                 my $p = waitpid(-1, &POSIX::WNOHANG) or return;
 304                 if (defined $reexec_pid && $p == $reexec_pid) {
 305                         upgrade_aborted($p);
 306                 } elsif (defined(my $id = delete $pids{$p})) {
 307                         warn "worker[$id] PID($p) died with: $?\n";
 308                 } elsif ($p > 0) {
 309                         warn "unknown PID($p) reaped: $?\n";
 310                 } else {
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 sub unlink_pid_file_safe_ish ($$) {
 317         my ($unlink_pid, $file) = @_;
 318         return unless defined $unlink_pid && $unlink_pid == $$;
 319
 320         open my $fh, '<', $file or return;
 321         defined(my $read_pid = <$fh>) or return;
 322         chomp $read_pid;
 323         if ($read_pid == $unlink_pid) {
 324                 Net::Server::Daemonize::unlink_pid_file($file);
 325         }
 326 }
 327
 328 sub master_loop {
 329         pipe(my ($p0, $p1)) or die "failed to create parent-pipe: $!";
 330         pipe(my ($r, $w)) or die "failed to create self-pipe: $!";
 331         IO::Handle::blocking($w, 0);
 332         my $set_workers = $worker_processes;
 333         my @caught;
 334         my $master_pid = $$;
 335         foreach my $s (qw(HUP CHLD QUIT INT TERM USR1 USR2 TTIN TTOU WINCH)) {
 336                 $SIG{$s} = sub {
 337                         return if $$ != $master_pid;
 338                         push @caught, $s;
 339                         syswrite($w, '.');
 340                 };
 341         }
 342         reopen_logs();
 343         # main loop
 344         while (1) {
 345                 while (my $s = shift @caught) {
 346                         if ($s eq 'USR1') {
 347                                 reopen_logs();
 348                                 kill_workers($s);
 349                         } elsif ($s eq 'USR2') {
 350                                 upgrade();
 351                         } elsif ($s =~ /\A(?:QUIT|TERM|INT)\z/) {
 352                                 # drops pipes and causes children to die
 353                                 exit
 354                         } elsif ($s eq 'WINCH') {
 355                                 $worker_processes = 0;
 356                         } elsif ($s eq 'HUP') {
 357                                 $worker_processes = $set_workers;
 358                                 kill_workers($s);
 359                         } elsif ($s eq 'TTIN') {
 360                                 if ($set_workers > $worker_processes) {
 361                                         ++$worker_processes;
 362                                 } else {
 363                                         $worker_processes = ++$set_workers;
 364                                 }
 365                         } elsif ($s eq 'TTOU') {
 366                                 if ($set_workers > 0) {
 367                                         $worker_processes = --$set_workers;
 368                                 }
 369                         } elsif ($s eq 'CHLD') {
 370                                 reap_children();
 371                         }
 372                 }
 373
 374                 my $n = scalar keys %pids;
 375                 if ($n > $worker_processes) {
 376                         while (my ($k, $v) = each %pids) {
 377                                 kill('TERM', $k) if $v >= $worker_processes;
 378                         }
 379                         $n = $worker_processes;
 380                 }
 381                 foreach my $i ($n..($worker_processes - 1)) {
 382                         my ($pid, $err) = do_fork();
 383                         if (!defined $pid) {
 384                                 warn "failed to fork worker[$i]: $err\n";
 385                         } elsif ($pid == 0) {
 386                                 $set_user->() if $set_user;
 387                                 return $p0; # run normal work code
 388                         } else {
 389                                 warn "PID=$pid is worker[$i]\n";
 390                                 $pids{$pid} = $i;
 391                         }
 392                 }
 393                 # just wait on signal events here:
 394                 sysread($r, my $buf, 8);
 395         }
 396         exit # never gets here, just for documentation
 397 }
 398
 399 sub daemon_loop ($$) {
 400         my ($refresh, $post_accept) = @_;
 401         my $parent_pipe;
 402         if ($worker_processes > 0) {
 403                 $refresh->(); # preload by default
 404                 $parent_pipe = master_loop(); # returns if in child process
 405                 my $fd = fileno($parent_pipe);
 406                 Danga::Socket->AddOtherFds($fd => *worker_quit);
 407         } else {
 408                 reopen_logs();
 409                 $set_user->() if $set_user;
 410                 $SIG{USR2} = sub { worker_quit() if upgrade() };
 411                 $refresh->();
 412         }
 413         $uid = $gid = undef;
 414         reopen_logs();
 415         $SIG{QUIT} = $SIG{INT} = $SIG{TERM} = *worker_quit;
 416         $SIG{USR1} = *reopen_logs;
 417         $SIG{HUP} = $refresh;
 418         # this calls epoll_create:
 419         @listeners = map {
 420                 PublicInbox::Listener->new($_, $post_accept)
 421         } @listeners;
 422         Danga::Socket->EventLoop;
 423         $parent_pipe = undef;
 424 }
 425
 426
 427 sub run ($$$) {
 428         my ($default, $refresh, $post_accept) = @_;
 429         daemon_prepare($default);
 430         daemonize();
 431         daemon_loop($refresh, $post_accept);
 432 }
 433
 434 sub do_chown ($) {
 435         my ($path) = @_;
 436         if (defined $uid and !chown($uid, $gid, $path)) {
 437                 warn "could not chown $path: $!\n";
 438         }
 439 }
 440
 441 sub write_pid ($) {
 442         my ($path) = @_;
 443         Net::Server::Daemonize::create_pid_file($path);
 444         do_chown($path);
 445 }
 446
 447 1;