lib/PublicInbox/DirIdle.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Used by public-inbox-watch for Maildir (and possibly MH in the future)
   5 package PublicInbox::DirIdle;
   6 use strict;
   7 use parent 'PublicInbox::DS';
   8 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
   9 use PublicInbox::In2Tie;
  10
  11 my ($MAIL_IN, $ino_cls);
  12 if ($^O eq 'linux' && eval { require Linux::Inotify2; 1 }) {
  13         $MAIL_IN = Linux::Inotify2::IN_MOVED_TO() |
  14                 Linux::Inotify2::IN_CREATE();
  15         $ino_cls = 'Linux::Inotify2';
  16 # Perl 5.22+ is needed for fileno(DIRHANDLE) support:
  17 } elsif ($^V ge v5.22 && eval { require PublicInbox::KQNotify }) {
  18         $MAIL_IN = PublicInbox::KQNotify::MOVED_TO_OR_CREATE();
  19         $ino_cls = 'PublicInbox::KQNotify';
  20 } else {
  21         require PublicInbox::FakeInotify;
  22         $MAIL_IN = PublicInbox::FakeInotify::MOVED_TO_OR_CREATE();
  23 }
  24
  25 sub new {
  26         my ($class, $dirs, $cb) = @_;
  27         my $self = bless { cb => $cb }, $class;
  28         my $inot;
  29         if ($ino_cls) {
  30                 $inot = $ino_cls->new or die "E: $ino_cls->new: $!";
  31                 my $io = PublicInbox::In2Tie::io($inot);
  32                 $self->SUPER::new($io, EPOLLIN | EPOLLET);
  33         } else {
  34                 require PublicInbox::FakeInotify;
  35                 $inot = PublicInbox::FakeInotify->new; # starts timer
  36         }
  37
  38         # Linux::Inotify2->watch or similar
  39         $inot->watch($_, $MAIL_IN) for @$dirs;
  40         $self->{inot} = $inot;
  41         PublicInbox::FakeInotify::poll_once($self) if !$ino_cls;
  42         $self;
  43 }
  44
  45 sub event_step {
  46         my ($self) = @_;
  47         my $cb = $self->{cb};
  48         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
  49         eval {
  50                 my @events = $self->{inot}->read; # Linux::Inotify2->read
  51                 $cb->($_) for @events;
  52         };
  53         warn "$self->{inot}->read err: $@\n" if $@;
  54 }
  55
  56 1;