lib/PublicInbox/ExtMsg.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Used by the web interface to link to messages outside of the our
   5 # public-inboxes.  Mail threads may cross projects/threads; so
   6 # we should ensure users can find more easily find them on other
   7 # sites.
   8 package PublicInbox::ExtMsg;
   9 use strict;
  10 use warnings;
  11 use URI::Escape qw(uri_escape_utf8);
  12 use PublicInbox::Hval;
  13 use PublicInbox::MID qw/mid2path/;
  14
  15 # TODO: user-configurable
  16 our @EXT_URL = (
  17         'http://mid.gmane.org/%s',
  18         'https://lists.debian.org/msgid-search/%s',
  19         # leading "//" denotes protocol-relative (http:// or https://)
  20         '//mid.mail-archive.com/%s',
  21         '//marc.info/?i=%s',
  22 );
  23
  24 sub ext_msg {
  25         my ($ctx) = @_;
  26         my $pi_config = $ctx->{pi_config};
  27         my $cur = $ctx->{-inbox};
  28         my $mid = $ctx->{mid};
  29         my $env = $ctx->{env};
  30
  31         eval { require PublicInbox::Search };
  32         my $have_xap = $@ ? 0 : 1;
  33         my (@nox, @ibx);
  34
  35         foreach my $k (keys %$pi_config) {
  36                 $k =~ /\Apublicinbox\.([A-Z0-9a-z-]+)\.url\z/ or next;
  37                 my $name = $1;
  38                 next if $name eq $cur->{name};
  39                 my $other = $pi_config->lookup_name($name) or next;
  40                 next unless $other->base_url;
  41
  42                 my $s = $other->search;
  43                 if (!$s) {
  44                         push @nox, $other;
  45                         next;
  46                 }
  47
  48                 # try to find the URL with Xapian to avoid forking
  49                 my $doc_id = eval { $s->find_unique_doc_id('mid', $mid) };
  50                 if ($@) {
  51                         # xapian not configured properly for this repo
  52                         push @nox, $other;
  53                         next;
  54                 }
  55
  56                 # maybe we found it!
  57                 return r302($other, $mid) if defined $doc_id;
  58
  59                 # no point in trying the fork fallback if we
  60                 # know Xapian is up-to-date but missing the
  61                 # message in the current repo
  62                 push @ibx, $other;
  63         }
  64
  65         # Xapian not installed or configured for some repos,
  66         # do a full MID check:
  67         if (@nox) {
  68                 my $path = mid2path($mid);
  69                 foreach my $other (@nox) {
  70                         my (undef, $type, undef) = $other->path_check($path);
  71
  72                         return r302($other, $mid) if $type && $type eq 'blob';
  73                 }
  74         }
  75
  76         # fall back to partial MID matching
  77         my $n_partial = 0;
  78         my @partial;
  79
  80         eval { require PublicInbox::Msgmap };
  81         my $have_mm = $@ ? 0 : 1;
  82         if ($have_mm) {
  83                 my $tmp_mid = $mid;
  84 again:
  85                 unshift @ibx, $cur;
  86                 foreach my $ibx (@ibx) {
  87                         my $mm = $ibx->mm or next;
  88                         if (my $res = $mm->mid_prefixes($tmp_mid)) {
  89                                 $n_partial += scalar(@$res);
  90                                 push @partial, [ $ibx, $res ];
  91                         }
  92                 }
  93                 # fixup common errors:
  94                 if (!$n_partial && $tmp_mid =~ s,/[tTf],,) {
  95                         goto again;
  96                 }
  97         }
  98
  99         my $code = 404;
 100         my $h = PublicInbox::Hval->new_msgid($mid, 1);
 101         my $href = $h->as_href;
 102         my $html = $h->as_html;
 103         my $title = "Message-ID &lt;$html&gt; not found";
 104         my $s = "<html><head><title>$title</title>" .
 105                 "</head><body><pre><b>$title</b>\n";
 106
 107         if ($n_partial) {
 108                 $code = 300;
 109                 my $es = $n_partial == 1 ? '' : 'es';
 110                 $s.= "\n$n_partial partial match$es found:\n\n";
 111                 foreach my $pair (@partial) {
 112                         my ($ibx, $res) = @$pair;
 113                         my $u = $ibx->base_url or next;
 114                         foreach my $m (@$res) {
 115                                 my $p = PublicInbox::Hval->new_msgid($m);
 116                                 my $r = $p->as_href;
 117                                 my $t = $p->as_html;
 118                                 $s .= qq{<a\nhref="$u$r/">$u$t/</a>\n};
 119                         }
 120                 }
 121         }
 122
 123         # Fall back to external repos if configured
 124         if (@EXT_URL && index($mid, '@') >= 0) {
 125                 $code = 300;
 126                 $s .= "\nPerhaps try an external site:\n\n";
 127                 foreach my $url (@EXT_URL) {
 128                         my $u = PublicInbox::Hval::prurl($env, $url);
 129                         my $r = sprintf($u, $href);
 130                         my $t = sprintf($u, $html);
 131                         $s .= qq{<a\nhref="$r">$t</a>\n};
 132                 }
 133         }
 134         $s .= '</pre></body></html>';
 135
 136         [$code, ['Content-Type'=>'text/html; charset=UTF-8'], [$s]];
 137 }
 138
 139 # Redirect to another public-inbox which is mapped by $pi_config
 140 # TODO: prompt for inbox-switching
 141 sub r302 {
 142         my ($inbox, $mid) = @_;
 143         my $url = $inbox->base_url . uri_escape_utf8($mid) . '/';
 144         [ 302,
 145           [ 'Location' => $url, 'Content-Type' => 'text/plain' ],
 146           [ "Redirecting to\n$url\n" ] ]
 147 }
 148
 149 1;