lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/encode decode/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime);
  15 use constant DATEFMT => '%Y-%m-%dT%H:%M:%SZ';
  16 use PublicInbox::View;
  17 use Mail::Thread;
  18
  19 # FIXME: workaround https://rt.cpan.org/Public/Bug/Display.html?id=22817
  20
  21 # main function
  22 sub generate {
  23         my ($class, $args) = @_;
  24         my $max = $args->{max} || 25;
  25         my $top = $args->{top}; # bool
  26
  27         local $ENV{GIT_DIR} = $args->{git_dir};
  28         my $feed_opts = get_feedopts($args);
  29
  30         my $feed = XML::Atom::SimpleFeed->new(
  31                 title => $feed_opts->{description} || "unnamed feed",
  32                 link => $feed_opts->{url} || "http://example.com/",
  33                 link => {
  34                         rel => 'self',
  35                         href => $feed_opts->{atomurl} ||
  36                                 "http://example.com/atom",
  37                 },
  38                 id => $feed_opts->{address} || 'public-inbox@example.com',
  39                 updated => strftime(DATEFMT, gmtime),
  40         );
  41
  42         each_recent_blob($max, sub {
  43                 my ($add) = @_;
  44                 add_to_feed($feed_opts, $feed, $add, $top);
  45         });
  46         $feed->as_string;
  47 }
  48
  49 sub generate_html_index {
  50         my ($class, $args) = @_;
  51         my $max = $args->{max} || 50;
  52         my $top = $args->{top}; # bool
  53         local $ENV{GIT_DIR} = $args->{git_dir};
  54         my $feed_opts = get_feedopts($args);
  55         my $title = escapeHTML($feed_opts->{description} || "");
  56         my @messages;
  57         each_recent_blob($max, sub {
  58                 my $str = `git cat-file blob $_[0]`;
  59                 return 0 if $? != 0;
  60                 my $simple = Email::Simple->new($str);
  61                 if ($top && ($simple->header("In-Reply-To") ||
  62                              $simple->header("References"))) {
  63                         return 0;
  64                 }
  65                 $simple->body_set(""); # save some memory
  66                 push @messages, $simple;
  67                 1;
  68         });
  69
  70         my $th = Mail::Thread->new(@messages);
  71         $th->thread;
  72         my @args = (
  73                 "<html><head><title>$title</title>" .
  74                 '<link rel=alternate title=Atom.feed href="' .
  75                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  76                 '</head><body><pre>');
  77         push @args, $feed_opts->{midurl};
  78         dump_html_line($_, 0, \@args) for $th->rootset;
  79         $args[0] . '</pre></html>';
  80 }
  81
  82 # private subs
  83
  84 sub each_recent_blob {
  85         my ($max, $cb) = @_;
  86
  87         # get recent messages
  88         # we could use git log -z, but, we already know ssoma will not
  89         # leave us with filenames with spaces in them..
  90         my $cmd = "git log --no-notes --no-color --raw -r --no-abbrev HEAD |";
  91         my $pid = open my $log, $cmd or die "open `$cmd' pipe failed: $!\n";
  92         my %deleted;
  93         my $nr = 0;
  94         foreach my $line (<$log>) {
  95                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
  96                         my $add = $1;
  97                         next if $deleted{$add};
  98                         $nr += $cb->($add);
  99                         last if $nr >= $max;
 100                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
 101                         $deleted{$1} = 1;
 102                 }
 103         }
 104
 105         close $log;
 106 }
 107
 108 # private functions below
 109 sub get_feedopts {
 110         my ($args) = @_;
 111         my $pi_config = $args->{pi_config};
 112         my $listname = $args->{listname};
 113         my $cgi = $args->{cgi};
 114         my %rv;
 115
 116         if ($pi_config && defined $listname && length $listname) {
 117                 foreach my $key (qw(description address)) {
 118                         $rv{$key} = $pi_config->get($listname, $key) || "";
 119                 }
 120         }
 121         my $url_base;
 122         if ($cgi) {
 123                 my $cgi_url = $cgi->url(-path=>1, -query=>1, -relative=>1);
 124                 my $base = $cgi->url(-base);
 125                 $url_base = $cgi_url;
 126                 if ($url_base =~ s!/(?:|(index|all)\.html)?\z!!) {
 127                         my $ia = $1 || 'index';
 128                         $rv{atomurl} = "$base$url_base/$ia.atom.xml";
 129                 } else {
 130                         $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
 131                         $rv{atomurl} = $base . $cgi_url;
 132                         $url_base = $base . $url_base; # XXX is this needed?
 133                 }
 134         } else {
 135                 $url_base = "http://example.com";
 136                 $rv{atomurl} = "$url_base/index.atom.xml";
 137         }
 138         $rv{url} ||= "$url_base/";
 139         $rv{midurl} = "$url_base/m/";
 140         $rv{fullurl} = "$url_base/f/";
 141
 142         \%rv;
 143 }
 144
 145 sub utf8_header {
 146         my ($simple, $name) = @_;
 147         my $val = $simple->header($name);
 148         return "" unless defined $val;
 149         $val =~ tr/\t\r\n / /s;
 150         encode('utf8', decode('MIME-Header', $val));
 151 }
 152
 153 sub feed_date {
 154         my ($date) = @_;
 155         my @t = eval { strptime($date) };
 156
 157         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 158 }
 159
 160 # returns 0 (skipped) or 1 (added)
 161 sub add_to_feed {
 162         my ($feed_opts, $feed, $add, $top) = @_;
 163
 164         # we can use git cat-file --batch if performance becomes a
 165         # problem, but I doubt it...
 166         my $str = `git cat-file blob $add`;
 167         return 0 if $? != 0;
 168         my $mime = Email::MIME->new($str);
 169
 170         if ($top && $mime->header("In-Reply-To")) {
 171                 return 0;
 172         }
 173
 174         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 175         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 176
 177         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 178         defined($content) or return 0;
 179
 180         my $mid = utf8_header($mime, "Message-ID") or return 0;
 181         $mid =~ s/\A<//; $mid =~ s/>\z//;
 182
 183         my $subject = utf8_header($mime, "Subject") || "";
 184         length($subject) or return 0;
 185
 186         my $from = utf8_header($mime, "From") or return 0;
 187
 188         my @from = Email::Address->parse($from);
 189         my $name = $from[0]->name;
 190         defined $name or $name = "";
 191         my $email = $from[0]->address;
 192         defined $email or $email = "";
 193
 194         my $url = $midurl . uri_escape($mid);
 195         my $date = utf8_header($mime, "Date");
 196         $date or return 0;
 197         $date = feed_date($date) or return 0;
 198         $feed->add_entry(
 199                 author => { name => $name, email => $email },
 200                 title => $subject,
 201                 updated => $date,
 202                 content => { type => "html", content => $content },
 203                 link => $url,
 204                 id => $add,
 205         );
 206         1;
 207 }
 208
 209 sub dump_html_line {
 210         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 211         $args->[0] .= (' ' x $level);
 212         if ($self->message) {
 213                 my $simple = $self->message;
 214                 my $subj = utf8_header($simple, "Subject");
 215                 my $mid = utf8_header($simple, "Message-ID");
 216                 $mid =~ s/\A<//;
 217                 $mid =~ s/>\z//;
 218                 my $url = $args->[1] . uri_escape($mid);
 219                 my $from = utf8_header($simple, "From");
 220                 my @from = Email::Address->parse($from);
 221                 $from = $from[0]->name;
 222                 (defined($from) && length($from)) or $from = $from[0]->address;
 223                 $from = escapeHTML($from);
 224                 $subj = escapeHTML($subj);
 225                 $args->[0] .= "<a href=\"$url.html\">`-&gt; $subj</a> $from\n";
 226         } else {
 227                 $args->[0] .= "[ Message not available ]\n";
 228         }
 229         dump_html_line($self->child, $level+1, $args) if $self->child;
 230         dump_html_line($self->next, $level, $args) if $self->next;
 231 }
 232
 233 1;