lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/encode decode/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime);
  15 use constant DATEFMT => '%Y-%m-%dT%H:%M:%SZ';
  16 use PublicInbox::View;
  17
  18 # main function
  19 sub generate {
  20         my ($class, $args) = @_;
  21         my $max = $args->{max} || 25;
  22         my $top = $args->{top}; # bool
  23
  24         local $ENV{GIT_DIR} = $args->{git_dir};
  25         my $feed_opts = get_feedopts($args);
  26
  27         my $feed = XML::Atom::SimpleFeed->new(
  28                 title => $feed_opts->{description} || "unnamed feed",
  29                 link => $feed_opts->{url} || "http://example.com/",
  30                 link => {
  31                         rel => 'self',
  32                         href => $feed_opts->{atomurl} ||
  33                                 "http://example.com/atom",
  34                 },
  35                 id => $feed_opts->{address} || 'public-inbox@example.com',
  36                 updated => strftime(DATEFMT, gmtime),
  37         );
  38
  39         my @entries;
  40
  41         # get recent messages
  42         # we could use git log -z, but, we already know ssoma will not
  43         # leave us with filenames with spaces in them..
  44         my $cmd = "git log --no-color --raw -r --no-abbrev HEAD |";
  45         my $pid = open my $log, $cmd or die "open `$cmd' pipe failed: $!\n";
  46         my %deleted;
  47         my $nr = 0;
  48         foreach my $line (<$log>) {
  49                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
  50                         my $add = $1;
  51                         next if $deleted{$add};
  52                         $nr += add_to_feed($feed_opts, $feed, $add, $top);
  53                         last if $nr >= $max;
  54                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
  55                         $deleted{$1} = 1;
  56                 }
  57         }
  58
  59         close $log;
  60
  61         $feed->as_string;
  62 }
  63
  64 # private functions below
  65 sub get_feedopts {
  66         my ($args) = @_;
  67         my $pi_config = $args->{pi_config};
  68         my $listname = $args->{listname};
  69         my $cgi = $args->{cgi};
  70         my %rv;
  71
  72         if ($pi_config && defined $listname && length $listname) {
  73                 foreach my $key (qw(description address)) {
  74                         $rv{$key} = $pi_config->get($listname, $key);
  75                 }
  76         }
  77         if ($cgi) {
  78                 my $cgi_url = $cgi->self_url;
  79                 my $url_base = $cgi_url;
  80                 $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
  81                 $rv{url} ||= "$url_base/";
  82                 $rv{midurl} = "$url_base/mid/";
  83                 $rv{fullurl} = "$url_base/full/";
  84                 $rv{atomurl} = $cgi_url;
  85         }
  86
  87         \%rv;
  88 }
  89
  90 sub utf8_header {
  91         my ($mime, $name) = @_;
  92         encode('utf8', decode('MIME-Header', $mime->header($name)));
  93 }
  94
  95 sub feed_date {
  96         my ($date) = @_;
  97         my @t = eval { strptime($date) };
  98
  99         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 100 }
 101
 102 # returns 0 (skipped) or 1 (added)
 103 sub add_to_feed {
 104         my ($feed_opts, $feed, $add, $top) = @_;
 105
 106         # we can use git cat-file --batch if performance becomes a
 107         # problem, but I doubt it...
 108         my $str = `git cat-file blob $add`;
 109         return 0 if $? != 0;
 110         my $mime = Email::MIME->new($str);
 111
 112         if ($top && $mime->header("In-Reply-To")) {
 113                 return 0;
 114         }
 115
 116         my $midurl = $feed_opts->{midurl} || 'http://example.com/mid/';
 117         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/full/';
 118
 119         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 120         defined($content) or return 0;
 121
 122         my $mid = utf8_header($mime, "Message-ID") or return 0;
 123         $mid =~ s/\A<//;
 124         $mid =~ s/>\z//;
 125
 126         my $subject = utf8_header($mime, "Subject") || "";
 127         defined($subject) && length($subject) or return 0;
 128
 129         my $from = utf8_header($mime, "From") or return 0;
 130
 131         my @from = Email::Address->parse($from);
 132         my $name = $from[0]->name;
 133         defined $name or $name = "";
 134         my $email = $from[0]->address;
 135         defined $email or $email = "";
 136
 137         my $url = $midurl . uri_escape($mid);
 138         my $date = utf8_header($mime, "Date");
 139         $date or return 0;
 140         $date = feed_date($date) or return 0;
 141         $feed->add_entry(
 142                 author => { name => $name, email => $email },
 143                 title => $subject,
 144                 updated => $date,
 145                 content => { type => "html", content => $content },
 146                 link => $url,
 147                 id => $add,
 148         );
 149         1;
 150 }
 151
 152 1;