lib/PublicInbox/Feed.pm

   1 # Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::Feed;
   4 use strict;
   5 use warnings;
   6 use XML::Atom::SimpleFeed;
   7 use Email::MIME;
   8 use Email::Address;
   9 use URI::Escape qw/uri_escape/;
  10 use Encode qw/encode decode/;
  11 use Encode::MIME::Header;
  12 use CGI qw(escapeHTML);
  13 use POSIX qw(strftime);
  14 use Date::Parse qw(strptime);
  15 use constant DATEFMT => '%Y-%m-%dT%H:%M:%SZ';
  16 use PublicInbox::View;
  17 use Mail::Thread;
  18
  19 # main function
  20 sub generate {
  21         my ($class, $args) = @_;
  22         my $max = $args->{max} || 25;
  23         my $top = $args->{top}; # bool
  24
  25         local $ENV{GIT_DIR} = $args->{git_dir};
  26         my $feed_opts = get_feedopts($args);
  27
  28         my $feed = XML::Atom::SimpleFeed->new(
  29                 title => $feed_opts->{description} || "unnamed feed",
  30                 link => $feed_opts->{url} || "http://example.com/",
  31                 link => {
  32                         rel => 'self',
  33                         href => $feed_opts->{atomurl} ||
  34                                 "http://example.com/atom",
  35                 },
  36                 id => $feed_opts->{address} || 'public-inbox@example.com',
  37                 updated => strftime(DATEFMT, gmtime),
  38         );
  39
  40         each_recent_blob($max, sub {
  41                 my ($add) = @_;
  42                 add_to_feed($feed_opts, $feed, $add, $top);
  43         });
  44         $feed->as_string;
  45 }
  46
  47 sub generate_html_index {
  48         my ($class, $args) = @_;
  49         my $max = $args->{max} || 50;
  50         my $top = $args->{top}; # bool
  51         local $ENV{GIT_DIR} = $args->{git_dir};
  52         my $feed_opts = get_feedopts($args);
  53         my $title = escapeHTML($feed_opts->{description} || "");
  54         my @messages;
  55         each_recent_blob($max, sub {
  56                 my $str = `git cat-file blob $_[0]`;
  57                 return 0 if $? != 0;
  58                 my $simple = Email::Simple->new($str);
  59                 if ($top && ($simple->header("In-Reply-To") ||
  60                              $simple->header("References"))) {
  61                         return 0;
  62                 }
  63                 $simple->body_set(""); # save some memory
  64                 push @messages, $simple;
  65                 1;
  66         });
  67
  68         my $th = Mail::Thread->new(@messages);
  69         $th->thread;
  70         my @args = (
  71                 "<html><head><title>$title</title>" .
  72                 '<link rel=alternate title=Atom.feed href="' .
  73                 $feed_opts->{atomurl} . '" type="application/atom+xml"/>' .
  74                 '</head><body><pre>');
  75         push @args, $feed_opts->{midurl};
  76         dump_html_line($_, 0, \@args) for $th->rootset;
  77         $args[0] . '</pre></html>';
  78 }
  79
  80 # private subs
  81
  82 sub each_recent_blob {
  83         my ($max, $cb) = @_;
  84
  85         # get recent messages
  86         # we could use git log -z, but, we already know ssoma will not
  87         # leave us with filenames with spaces in them..
  88         my $cmd = "git log --no-notes --no-color --raw -r --no-abbrev HEAD |";
  89         my $pid = open my $log, $cmd or die "open `$cmd' pipe failed: $!\n";
  90         my %deleted;
  91         my $nr = 0;
  92         foreach my $line (<$log>) {
  93                 if ($line =~ /^:000000 100644 0{40} ([a-f0-9]{40})/) {
  94                         my $add = $1;
  95                         next if $deleted{$add};
  96                         $nr += $cb->($add);
  97                         last if $nr >= $max;
  98                 } elsif ($line =~ /^:100644 000000 ([a-f0-9]{40}) 0{40}/) {
  99                         $deleted{$1} = 1;
 100                 }
 101         }
 102
 103         close $log;
 104 }
 105
 106 # private functions below
 107 sub get_feedopts {
 108         my ($args) = @_;
 109         my $pi_config = $args->{pi_config};
 110         my $listname = $args->{listname};
 111         my $cgi = $args->{cgi};
 112         my %rv;
 113
 114         if ($pi_config && defined $listname && length $listname) {
 115                 foreach my $key (qw(description address)) {
 116                         $rv{$key} = $pi_config->get($listname, $key) || "";
 117                 }
 118         }
 119         my $url_base;
 120         if ($cgi) {
 121                 my $cgi_url = $cgi->url(-path=>1, -query=>1, -relative=>1);
 122                 my $base = $cgi->url(-base);
 123                 $url_base = $cgi_url;
 124                 if ($url_base =~ s!/(?:|(index|all)\.html)?\z!!) {
 125                         my $ia = $1 || 'index';
 126                         $rv{atomurl} = "$base$url_base/$ia.atom.xml";
 127                 } else {
 128                         $url_base =~ s!/?(?:index|all)\.atom\.xml\z!!;
 129                         $rv{atomurl} = $base . $cgi_url;
 130                         $url_base = $base . $url_base; # XXX is this needed?
 131                 }
 132         } else {
 133                 $url_base = "http://example.com";
 134                 $rv{atomurl} = "$url_base/index.atom.xml";
 135         }
 136         $rv{url} ||= "$url_base/";
 137         $rv{midurl} = "$url_base/m/";
 138         $rv{fullurl} = "$url_base/f/";
 139
 140         \%rv;
 141 }
 142
 143 sub utf8_header {
 144         my ($simple, $name) = @_;
 145         my $val = $simple->header($name);
 146         return "" unless defined $val;
 147         $val =~ tr/\t\r\n / /s;
 148         encode('utf8', decode('MIME-Header', $val));
 149 }
 150
 151 sub feed_date {
 152         my ($date) = @_;
 153         my @t = eval { strptime($date) };
 154
 155         scalar(@t) ? strftime(DATEFMT, @t) : 0;
 156 }
 157
 158 # returns 0 (skipped) or 1 (added)
 159 sub add_to_feed {
 160         my ($feed_opts, $feed, $add, $top) = @_;
 161
 162         # we can use git cat-file --batch if performance becomes a
 163         # problem, but I doubt it...
 164         my $str = `git cat-file blob $add`;
 165         return 0 if $? != 0;
 166         my $mime = Email::MIME->new($str);
 167
 168         if ($top && $mime->header("In-Reply-To")) {
 169                 return 0;
 170         }
 171
 172         my $midurl = $feed_opts->{midurl} || 'http://example.com/m/';
 173         my $fullurl = $feed_opts->{fullurl} || 'http://example.com/f/';
 174
 175         my $content = PublicInbox::View->as_feed_entry($mime, $fullurl);
 176         defined($content) or return 0;
 177
 178         my $mid = utf8_header($mime, "Message-ID") or return 0;
 179         $mid =~ s/\A<//; $mid =~ s/>\z//;
 180
 181         my $subject = utf8_header($mime, "Subject") || "";
 182         length($subject) or return 0;
 183
 184         my $from = utf8_header($mime, "From") or return 0;
 185
 186         my @from = Email::Address->parse($from);
 187         my $name = $from[0]->name;
 188         defined $name or $name = "";
 189         my $email = $from[0]->address;
 190         defined $email or $email = "";
 191
 192         my $url = $midurl . uri_escape($mid);
 193         my $date = utf8_header($mime, "Date");
 194         $date or return 0;
 195         $date = feed_date($date) or return 0;
 196         $feed->add_entry(
 197                 author => { name => $name, email => $email },
 198                 title => $subject,
 199                 updated => $date,
 200                 content => { type => "html", content => $content },
 201                 link => $url,
 202                 id => $add,
 203         );
 204         1;
 205 }
 206
 207 sub dump_html_line {
 208         my ($self, $level, $args) = @_; # args => [ $html, $midurl ]
 209         $args->[0] .= (' ' x $level);
 210         if ($self->message) {
 211                 my $simple = $self->message;
 212                 my $subj = utf8_header($simple, "Subject");
 213                 my $mid = utf8_header($simple, "Message-ID");
 214                 $mid =~ s/\A<//;
 215                 $mid =~ s/>\z//;
 216                 my $url = $args->[1] . uri_escape($mid);
 217                 my $from = utf8_header($simple, "From");
 218                 my @from = Email::Address->parse($from);
 219                 $from = $from[0]->name;
 220                 (defined($from) && length($from)) or $from = $from[0]->address;
 221                 $from = escapeHTML($from);
 222                 $subj = escapeHTML($subj);
 223                 $args->[0] .= "<a href=\"$url.html\">`-&gt; $subj</a> $from\n";
 224         } else {
 225                 $args->[0] .= "[ Message not available ]\n";
 226         }
 227         dump_html_line($self->child, $level+1, $args) if $self->child;
 228         dump_html_line($self->next, $level, $args) if $self->next;
 229 }
 230
 231 1;