lib/PublicInbox/Git.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: GPLv2 or later <https://www.gnu.org/licenses/gpl-2.0.txt>
   3 #
   4 # Used to read files from a git repository without excessive forking.
   5 # Used in our web interfaces as well as our -nntpd server.
   6 # This is based on code in Git.pm which is GPLv2+, but modified to avoid
   7 # dependence on environment variables for compatibility with mod_perl.
   8 # There are also API changes to simplify our usage and data set.
   9 package PublicInbox::Git;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(Exporter);
  13 use POSIX ();
  14 use IO::Handle; # ->autoflush
  15 use Errno qw(EINTR);
  16 use File::Glob qw(bsd_glob GLOB_NOSORT);
  17 use Time::HiRes qw(stat);
  18 use PublicInbox::Spawn qw(popen_rd);
  19 use PublicInbox::Tmpfile;
  20 use Carp qw(croak);
  21 our @EXPORT_OK = qw(git_unquote git_quote);
  22 our $PIPE_BUFSIZ = 65536; # Linux default
  23 our $in_cleanup;
  24
  25 use constant MAX_INFLIGHT =>
  26         (($^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF()) * 3)
  27         /
  28         65; # SHA-256 hex size + "\n" in preparation for git using non-SHA1
  29
  30 my %GIT_ESC = (
  31         a => "\a",
  32         b => "\b",
  33         f => "\f",
  34         n => "\n",
  35         r => "\r",
  36         t => "\t",
  37         v => "\013",
  38         '"' => '"',
  39         '\\' => '\\',
  40 );
  41 my %ESC_GIT = map { $GIT_ESC{$_} => $_ } keys %GIT_ESC;
  42
  43
  44 # unquote pathnames used by git, see quote.c::unquote_c_style.c in git.git
  45 sub git_unquote ($) {
  46         return $_[0] unless ($_[0] =~ /\A"(.*)"\z/);
  47         $_[0] = $1;
  48         $_[0] =~ s/\\([\\"abfnrtv])/$GIT_ESC{$1}/g;
  49         $_[0] =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  50         $_[0];
  51 }
  52
  53 sub git_quote ($) {
  54         if ($_[0] =~ s/([\\"\a\b\f\n\r\t\013]|[^[:print:]])/
  55                       '\\'.($ESC_GIT{$1}||sprintf("%0o",ord($1)))/egs) {
  56                 return qq{"$_[0]"};
  57         }
  58         $_[0];
  59 }
  60
  61 sub new {
  62         my ($class, $git_dir) = @_;
  63         # may contain {-tmp} field for File::Temp::Dir
  64         bless { git_dir => $git_dir, alt_st => '', -git_path => {} }, $class
  65 }
  66
  67 sub git_path ($$) {
  68         my ($self, $path) = @_;
  69         $self->{-git_path}->{$path} ||= do {
  70                 local $/ = "\n";
  71                 chomp(my $str = $self->qx(qw(rev-parse --git-path), $path));
  72
  73                 # git prior to 2.5.0 did not understand --git-path
  74                 if ($str eq "--git-path\n$path") {
  75                         $str = "$self->{git_dir}/$path";
  76                 }
  77                 $str;
  78         };
  79 }
  80
  81 sub alternates_changed {
  82         my ($self) = @_;
  83         my $alt = git_path($self, 'objects/info/alternates');
  84         my @st = stat($alt) or return 0;
  85
  86         # can't rely on 'q' on some 32-bit builds, but `d' works
  87         my $st = pack('dd', $st[10], $st[7]); # 10: ctime, 7: size
  88         return 0 if $self->{alt_st} eq $st;
  89         $self->{alt_st} = $st; # always a true value
  90 }
  91
  92 sub last_check_err {
  93         my ($self) = @_;
  94         my $fh = $self->{err_c} or return;
  95         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
  96         defined(sysread($fh, my $buf, -s $fh)) or
  97                         fail($self, "sysread failed: $!");
  98         $buf;
  99 }
 100
 101 sub _bidi_pipe {
 102         my ($self, $batch, $in, $out, $pid, $err) = @_;
 103         if ($self->{$pid}) {
 104                 if (defined $err) { # "err_c"
 105                         my $fh = $self->{$err};
 106                         sysseek($fh, 0, 0) or fail($self, "sysseek failed: $!");
 107                         truncate($fh, 0) or fail($self, "truncate failed: $!");
 108                 }
 109                 return;
 110         }
 111         my ($out_r, $out_w);
 112         pipe($out_r, $out_w) or fail($self, "pipe failed: $!");
 113         my @cmd = (qw(git), "--git-dir=$self->{git_dir}",
 114                         qw(-c core.abbrev=40 cat-file), $batch);
 115         my $redir = { 0 => $out_r };
 116         if ($err) {
 117                 my $id = "git.$self->{git_dir}$batch.err";
 118                 my $fh = tmpfile($id) or fail($self, "tmpfile($id): $!");
 119                 $self->{$err} = $fh;
 120                 $redir->{2} = $fh;
 121         }
 122         my ($in_r, $p) = popen_rd(\@cmd, undef, $redir);
 123         $self->{$pid} = $p;
 124         $out_w->autoflush(1);
 125         if ($^O eq 'linux') { # 1031: F_SETPIPE_SZ
 126                 fcntl($out_w, 1031, 4096);
 127                 fcntl($in_r, 1031, 4096) if $batch eq '--batch-check';
 128         }
 129         $self->{$out} = $out_w;
 130         $self->{$in} = $in_r;
 131 }
 132
 133 sub my_read ($$$) {
 134         my ($fh, $rbuf, $len) = @_;
 135         my $left = $len - length($$rbuf);
 136         my $r;
 137         while ($left > 0) {
 138                 $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
 139                 if ($r) {
 140                         $left -= $r;
 141                 } else {
 142                         next if (!defined($r) && $! == EINTR);
 143                         return $r;
 144                 }
 145         }
 146         \substr($$rbuf, 0, $len, '');
 147 }
 148
 149 sub my_readline ($$) {
 150         my ($fh, $rbuf) = @_;
 151         while (1) {
 152                 if ((my $n = index($$rbuf, "\n")) >= 0) {
 153                         return substr($$rbuf, 0, $n + 1, '');
 154                 }
 155                 my $r = sysread($fh, $$rbuf, $PIPE_BUFSIZ, length($$rbuf));
 156                 next if $r || (!defined($r) && $! == EINTR);
 157                 return defined($r) ? '' : undef; # EOF or error
 158         }
 159 }
 160
 161 sub cat_async_retry ($$$$$) {
 162         my ($self, $inflight, $req, $cb, $arg) = @_;
 163
 164         # {inflight} may be non-existent, but if it isn't we delete it
 165         # here to prevent cleanup() from waiting:
 166         delete $self->{inflight};
 167         cleanup($self);
 168
 169         $self->{inflight} = $inflight;
 170         batch_prepare($self);
 171         my $buf = "$req\n";
 172         for (my $i = 0; $i < @$inflight; $i += 3) {
 173                 $buf .= "$inflight->[$i]\n";
 174         }
 175         print { $self->{out} } $buf or fail($self, "write error: $!");
 176         unshift(@$inflight, \$req, $cb, $arg); # \$ref to indicate retried
 177
 178         cat_async_step($self, $inflight); # take one step
 179 }
 180
 181 sub cat_async_step ($$) {
 182         my ($self, $inflight) = @_;
 183         die 'BUG: inflight empty or odd' if scalar(@$inflight) < 3;
 184         my ($req, $cb, $arg) = splice(@$inflight, 0, 3);
 185         my $rbuf = delete($self->{cat_rbuf}) // \(my $new = '');
 186         my ($bref, $oid, $type, $size);
 187         my $head = my_readline($self->{in}, $rbuf);
 188         if ($head =~ /^([0-9a-f]{40,}) (\S+) ([0-9]+)$/) {
 189                 ($oid, $type, $size) = ($1, $2, $3 + 0);
 190                 $bref = my_read($self->{in}, $rbuf, $size + 1) or
 191                         fail($self, defined($bref) ? 'read EOF' : "read: $!");
 192                 chop($$bref) eq "\n" or fail($self, 'LF missing after blob');
 193         } elsif ($head =~ / missing$/) {
 194                 # ref($req) indicates it's already been retried
 195                 # -gcf2 retries internally, so it never hits this path:
 196                 if (!ref($req) && !$in_cleanup && $self->alternates_changed) {
 197                         return cat_async_retry($self, $inflight,
 198                                                 $req, $cb, $arg);
 199                 }
 200                 $type = 'missing';
 201                 $oid = ref($req) ? $$req : $req;
 202         } else {
 203                 fail($self, "Unexpected result from async git cat-file: $head");
 204         }
 205         eval { $cb->($bref, $oid, $type, $size, $arg) };
 206         $self->{cat_rbuf} = $rbuf if $$rbuf ne '';
 207         warn "E: $oid: $@\n" if $@;
 208 }
 209
 210 sub cat_async_wait ($) {
 211         my ($self) = @_;
 212         my $inflight = delete $self->{inflight} or return;
 213         while (scalar(@$inflight)) {
 214                 cat_async_step($self, $inflight);
 215         }
 216 }
 217
 218 sub batch_prepare ($) {
 219         _bidi_pipe($_[0], qw(--batch in out pid));
 220 }
 221
 222 sub _cat_file_cb {
 223         my ($bref, undef, undef, $size, $result) = @_;
 224         @$result = ($bref, $size);
 225 }
 226
 227 sub cat_file {
 228         my ($self, $oid, $sizeref) = @_;
 229         my $result = [];
 230         cat_async($self, $oid, \&_cat_file_cb, $result);
 231         cat_async_wait($self);
 232         $$sizeref = $result->[1] if $sizeref;
 233         $result->[0];
 234 }
 235
 236 sub check_async_step ($$) {
 237         my ($self, $inflight_c) = @_;
 238         die 'BUG: inflight empty or odd' if scalar(@$inflight_c) < 3;
 239         my ($req, $cb, $arg) = splice(@$inflight_c, 0, 3);
 240         my $rbuf = delete($self->{rbuf_c}) // \(my $new = '');
 241         chomp(my $line = my_readline($self->{in_c}, $rbuf));
 242         my ($hex, $type, $size) = split(/ /, $line);
 243
 244         # Future versions of git.git may have type=ambiguous, but for now,
 245         # we must handle 'dangling' below (and maybe some other oddball
 246         # stuff):
 247         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 248         if ($hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop') {
 249                 my $ret = my_read($self->{in_c}, $rbuf, $type + 1);
 250                 fail($self, defined($ret) ? 'read EOF' : "read: $!") if !$ret;
 251         }
 252         eval { $cb->($hex, $type, $size, $arg, $self) };
 253         warn "E: check($req) $@\n" if $@;
 254         $self->{rbuf_c} = $rbuf if $$rbuf ne '';
 255 }
 256
 257 sub check_async_wait ($) {
 258         my ($self) = @_;
 259         my $inflight_c = delete $self->{inflight_c} or return;
 260         while (scalar(@$inflight_c)) {
 261                 check_async_step($self, $inflight_c);
 262         }
 263 }
 264
 265 sub check_async_begin ($) {
 266         my ($self) = @_;
 267         cleanup($self) if alternates_changed($self);
 268         _bidi_pipe($self, qw(--batch-check in_c out_c pid_c err_c));
 269         die 'BUG: already in async check' if $self->{inflight_c};
 270         $self->{inflight_c} = [];
 271 }
 272
 273 sub check_async ($$$$) {
 274         my ($self, $oid, $cb, $arg) = @_;
 275         my $inflight_c = $self->{inflight_c} // check_async_begin($self);
 276         if (scalar(@$inflight_c) >= MAX_INFLIGHT) {
 277                 check_async_step($self, $inflight_c);
 278         }
 279         print { $self->{out_c} } $oid, "\n" or fail($self, "write error: $!");
 280         push(@$inflight_c, $oid, $cb, $arg);
 281 }
 282
 283 sub _check_cb { # check_async callback
 284         my ($hex, $type, $size, $result) = @_;
 285         @$result = ($hex, $type, $size);
 286 }
 287
 288 sub check {
 289         my ($self, $oid) = @_;
 290         my $result = [];
 291         check_async($self, $oid, \&_check_cb, $result);
 292         check_async_wait($self);
 293         my ($hex, $type, $size) = @$result;
 294
 295         # Future versions of git.git may show 'ambiguous', but for now,
 296         # we must handle 'dangling' below (and maybe some other oddball
 297         # stuff):
 298         # https://public-inbox.org/git/20190118033845.s2vlrb3wd3m2jfzu@dcvr/T/
 299         return if $type eq 'missing' || $type eq 'ambiguous';
 300         return if $hex eq 'dangling' || $hex eq 'notdir' || $hex eq 'loop';
 301         ($hex, $type, $size);
 302 }
 303
 304 sub _destroy {
 305         my ($self, $rbuf, $in, $out, $pid, $err) = @_;
 306         my $p = delete $self->{$pid} or return;
 307         delete @$self{($rbuf, $in, $out)};
 308         delete $self->{$err} if $err; # `err_c'
 309
 310         # PublicInbox::DS may not be loaded
 311         eval { PublicInbox::DS::dwaitpid($p, undef, undef) };
 312         waitpid($p, 0) if $@; # wait synchronously if not in event loop
 313 }
 314
 315 sub cat_async_abort ($) {
 316         my ($self) = @_;
 317         my $inflight = delete $self->{inflight} or die 'BUG: not in async';
 318         cleanup($self);
 319 }
 320
 321 sub fail {
 322         my ($self, $msg) = @_;
 323         $self->{inflight} ? cat_async_abort($self) : cleanup($self);
 324         croak("git $self->{git_dir}: $msg");
 325 }
 326
 327 sub popen {
 328         my ($self, @cmd) = @_;
 329         @cmd = ('git', "--git-dir=$self->{git_dir}", @cmd);
 330         popen_rd(\@cmd);
 331 }
 332
 333 sub qx {
 334         my ($self, @cmd) = @_;
 335         my $fh = $self->popen(@cmd);
 336         local $/ = "\n";
 337         return <$fh> if wantarray;
 338         local $/;
 339         <$fh>
 340 }
 341
 342 # returns true if there are pending "git cat-file" processes
 343 sub cleanup {
 344         my ($self) = @_;
 345         local $in_cleanup = 1;
 346         delete $self->{async_cat};
 347         check_async_wait($self);
 348         cat_async_wait($self);
 349         _destroy($self, qw(cat_rbuf in out pid));
 350         _destroy($self, qw(chk_rbuf in_c out_c pid_c err_c));
 351         !!($self->{pid} || $self->{pid_c});
 352 }
 353
 354 # assuming a well-maintained repo, this should be a somewhat
 355 # accurate estimation of its size
 356 # TODO: show this in the WWW UI as a hint to potential cloners
 357 sub packed_bytes {
 358         my ($self) = @_;
 359         my $n = 0;
 360         my $pack_dir = git_path($self, 'objects/pack');
 361         foreach my $p (bsd_glob("$pack_dir/*.pack", GLOB_NOSORT)) {
 362                 $n += -s $p;
 363         }
 364         $n
 365 }
 366
 367 sub DESTROY { cleanup(@_) }
 368
 369 sub local_nick ($) {
 370         my ($self) = @_;
 371         my $ret = '???';
 372         # don't show full FS path, basename should be OK:
 373         if ($self->{git_dir} =~ m!/([^/]+)(?:/\.git)?\z!) {
 374                 $ret = "/path/to/$1";
 375         }
 376         wantarray ? ($ret) : $ret;
 377 }
 378
 379 sub host_prefix_url ($$) {
 380         my ($env, $url) = @_;
 381         return $url if index($url, '//') >= 0;
 382         my $scheme = $env->{'psgi.url_scheme'};
 383         my $host_port = $env->{HTTP_HOST} //
 384                 "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
 385         "$scheme://$host_port". ($env->{SCRIPT_NAME} || '/') . $url;
 386 }
 387
 388 sub pub_urls {
 389         my ($self, $env) = @_;
 390         if (my $urls = $self->{cgit_url}) {
 391                 return map { host_prefix_url($env, $_) } @$urls;
 392         }
 393         local_nick($self);
 394 }
 395
 396 sub cat_async_begin {
 397         my ($self) = @_;
 398         cleanup($self) if $self->alternates_changed;
 399         batch_prepare($self);
 400         die 'BUG: already in async' if $self->{inflight};
 401         $self->{inflight} = [];
 402 }
 403
 404 sub cat_async ($$$;$) {
 405         my ($self, $oid, $cb, $arg) = @_;
 406         my $inflight = $self->{inflight} // cat_async_begin($self);
 407         if (scalar(@$inflight) >= MAX_INFLIGHT) {
 408                 cat_async_step($self, $inflight);
 409         }
 410
 411         print { $self->{out} } $oid, "\n" or fail($self, "write error: $!");
 412         push(@$inflight, $oid, $cb, $arg);
 413 }
 414
 415 # this is safe to call inside $cb, but not guaranteed to enqueue
 416 # returns true if successful, undef if not.
 417 sub async_prefetch {
 418         my ($self, $oid, $cb, $arg) = @_;
 419         if (defined($self->{async_cat}) && (my $inflight = $self->{inflight})) {
 420                 # we could use MAX_INFLIGHT here w/o the halving,
 421                 # but lets not allow one client to monopolize a git process
 422                 if (scalar(@$inflight) < int(MAX_INFLIGHT/2)) {
 423                         print { $self->{out} } $oid, "\n" or
 424                                                 fail($self, "write error: $!");
 425                         return push(@$inflight, $oid, $cb, $arg);
 426                 }
 427         }
 428         undef;
 429 }
 430
 431 sub extract_cmt_time {
 432         my ($bref, undef, undef, undef, $modified) = @_;
 433
 434         if ($$bref =~ /^committer .*?> ([0-9]+) [\+\-]?[0-9]+/sm) {
 435                 my $cmt_time = $1 + 0;
 436                 $$modified = $cmt_time if $cmt_time > $$modified;
 437         }
 438 }
 439
 440 # returns the modified time of a git repo, same as the "modified" field
 441 # of a grokmirror manifest
 442 sub modified ($) {
 443         my ($self) = @_;
 444         my $modified = 0;
 445         my $fh = popen($self, qw(rev-parse --branches));
 446         local $/ = "\n";
 447         while (my $oid = <$fh>) {
 448                 chomp $oid;
 449                 cat_async($self, $oid, \&extract_cmt_time, \$modified);
 450         }
 451         cat_async_wait($self);
 452         $modified || time;
 453 }
 454
 455 1;
 456 __END__
 457 =pod
 458
 459 =head1 NAME
 460
 461 PublicInbox::Git - git wrapper
 462
 463 =head1 VERSION
 464
 465 version 1.0
 466
 467 =head1 SYNOPSIS
 468
 469         use PublicInbox::Git;
 470         chomp(my $git_dir = `git rev-parse --git-dir`);
 471         $git_dir or die "GIT_DIR= must be specified\n";
 472         my $git = PublicInbox::Git->new($git_dir);
 473
 474 =head1 DESCRIPTION
 475
 476 Unstable API outside of the L</new> method.
 477 It requires L<git(1)> to be installed.
 478
 479 =head1 METHODS
 480
 481 =cut
 482
 483 =head2 new
 484
 485         my $git = PublicInbox::Git->new($git_dir);
 486
 487 Initialize a new PublicInbox::Git object for use with L<PublicInbox::Import>
 488 This is the only public API method we support.  Everything else
 489 in this module is subject to change.
 490
 491 =head1 SEE ALSO
 492
 493 L<Git>, L<PublicInbox::Import>
 494
 495 =head1 CONTACT
 496
 497 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 498
 499 The mail archives are hosted at L<https://public-inbox.org/meta/>
 500
 501 =head1 COPYRIGHT
 502
 503 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 504
 505 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 506
 507 =cut