lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env input_left remote_addr remote_port forward);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 use PublicInbox::DS qw(msg_more);
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use PublicInbox::Tmpfile;
  25 use constant {
  26         CHUNK_START => -1,   # [a-f0-9]+\r\n
  27         CHUNK_END => -2,     # \r\n
  28         CHUNK_ZEND => -3,    # \r\n
  29         CHUNK_MAX_HDR => 256,
  30 };
  31 use Errno qw(EAGAIN);
  32
  33 my $pipelineq = [];
  34 sub process_pipelineq () {
  35         my $q = $pipelineq;
  36         $pipelineq = [];
  37         foreach (@$q) {
  38                 next unless $_->{sock};
  39                 rbuf_process($_);
  40         }
  41 }
  42
  43 # Use the same configuration parameter as git since this is primarily
  44 # a slow-client sponge for git-http-backend
  45 # TODO: support per-respository http.maxRequestBuffer somehow...
  46 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  47                         (10 * 1024 * 1024);
  48
  49 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  50 my $http_date;
  51 my $prev = 0;
  52 sub http_date () {
  53         my $now = time;
  54         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  55 }
  56
  57 sub new ($$$) {
  58         my ($class, $sock, $addr, $httpd) = @_;
  59         my $self = fields::new($class);
  60         my $ev = EPOLLIN;
  61         my $wbuf;
  62         if (ref($sock) eq 'IO::Socket::SSL' && !$sock->accept_SSL) {
  63                 return CORE::close($sock) if $! != EAGAIN;
  64                 $ev = PublicInbox::TLS::epollbit();
  65                 $wbuf = [ \&PublicInbox::DS::accept_tls_step ];
  66         }
  67         $self->SUPER::new($sock, $ev | EPOLLONESHOT);
  68         $self->{httpd} = $httpd;
  69         $self->{wbuf} = $wbuf if $wbuf;
  70         ($self->{remote_addr}, $self->{remote_port}) =
  71                 PublicInbox::Daemon::host_with_port($addr);
  72         $self;
  73 }
  74
  75 sub event_step { # called by PublicInbox::DS
  76         my ($self) = @_;
  77
  78         return unless $self->flush_write && $self->{sock};
  79
  80         # only read more requests if we've drained the write buffer,
  81         # otherwise we can be buffering infinitely w/o backpressure
  82
  83         return read_input($self) if defined $self->{env};
  84         my $rbuf = $self->{rbuf} // (\(my $x = ''));
  85         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or return;
  86         rbuf_process($self, $rbuf);
  87 }
  88
  89 sub rbuf_process {
  90         my ($self, $rbuf) = @_;
  91         $rbuf //= $self->{rbuf} // (\(my $x = ''));
  92
  93         my %env = %{$self->{httpd}->{env}}; # full hash copy
  94         my $r = parse_http_request($$rbuf, \%env);
  95
  96         # We do not support Trailers in chunked requests, for now
  97         # (they are rarely-used and git (as of 2.7.2) does not use them)
  98         if ($r == -1 || $env{HTTP_TRAILER} ||
  99                         # this length-check is necessary for PURE_PERL=1:
 100                         ($r == -2 && bytes::length($$rbuf) > 0x4000)) {
 101                 return quit($self, 400);
 102         }
 103         if ($r < 0) { # incomplete
 104                 $self->rbuf_idle($rbuf);
 105                 return $self->requeue;
 106         }
 107         $$rbuf = substr($$rbuf, $r);
 108         my $len = input_prepare($self, \%env);
 109         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 110
 111         $len ? read_input($self, $rbuf) : app_dispatch($self, undef, $rbuf);
 112 }
 113
 114 # IO::Handle::write returns boolean, this returns bytes written:
 115 sub xwrite ($$$) {
 116         my ($fh, $rbuf, $max) = @_;
 117         my $w = bytes::length($$rbuf);
 118         $w = $max if $w > $max;
 119         $fh->write($$rbuf, $w) or return;
 120         $w;
 121 }
 122
 123 sub read_input ($;$) {
 124         my ($self, $rbuf) = @_;
 125         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 126         my $env = $self->{env};
 127         return if $env->{REMOTE_ADDR}; # in app dispatch
 128         return read_input_chunked($self, $rbuf) if env_chunked($env);
 129
 130         # env->{CONTENT_LENGTH} (identity)
 131         my $len = delete $self->{input_left};
 132         my $input = $env->{'psgi.input'};
 133
 134         while ($len > 0) {
 135                 if ($$rbuf ne '') {
 136                         my $w = xwrite($input, $rbuf, $len);
 137                         return write_err($self, $len) unless $w;
 138                         $len -= $w;
 139                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 140                         if ($len == 0) { # next request may be pipelined
 141                                 $$rbuf = substr($$rbuf, $w);
 142                                 last;
 143                         }
 144                         $$rbuf = '';
 145                 }
 146                 $self->do_read($rbuf, 8192) or return recv_err($self, $len);
 147                 # continue looping if $r > 0;
 148         }
 149         app_dispatch($self, $input, $rbuf);
 150 }
 151
 152 sub app_dispatch {
 153         my ($self, $input, $rbuf) = @_;
 154         $self->rbuf_idle($rbuf);
 155         my $env = $self->{env};
 156         $env->{REMOTE_ADDR} = $self->{remote_addr};
 157         $env->{REMOTE_PORT} = $self->{remote_port};
 158         if (my $host = $env->{HTTP_HOST}) {
 159                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 160                 $env->{SERVER_NAME} = $host;
 161         }
 162         if (defined $input) {
 163                 sysseek($input, 0, SEEK_SET) or
 164                         die "BUG: psgi.input seek failed: $!";
 165         }
 166         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 167         # to do proper cleanup:
 168         $env->{'psgix.io'} = $self; # only for ->close
 169         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 170         eval {
 171                 if (ref($res) eq 'CODE') {
 172                         $res->(sub { response_write($self, $env, $_[0]) });
 173                 } else {
 174                         response_write($self, $env, $res);
 175                 }
 176         };
 177         $self->close if $@;
 178 }
 179
 180 sub response_header_write {
 181         my ($self, $env, $res) = @_;
 182         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 183         my $status = $res->[0];
 184         my $h = "$proto $status " . status_message($status) . "\r\n";
 185         my ($len, $chunked);
 186         my $headers = $res->[1];
 187
 188         for (my $i = 0; $i < @$headers; $i += 2) {
 189                 my $k = $headers->[$i];
 190                 my $v = $headers->[$i + 1];
 191                 next if $k =~ /\A(?:Connection|Date)\z/i;
 192
 193                 $len = $v if $k =~ /\AContent-Length\z/i;
 194                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 195                         $chunked = 1;
 196                 }
 197                 $h .= "$k: $v\r\n";
 198         }
 199
 200         my $conn = $env->{HTTP_CONNECTION} || '';
 201         my $term = defined($len) || $chunked;
 202         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 203         my $alive;
 204         if (!$term && $prot_persist) { # auto-chunk
 205                 $chunked = $alive = 2;
 206                 $h .= "Transfer-Encoding: chunked\r\n";
 207                 # no need for "Connection: keep-alive" with HTTP/1.1
 208         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 209                 $alive = 1;
 210                 $h .= "Connection: keep-alive\r\n";
 211         } else {
 212                 $alive = 0;
 213                 $h .= "Connection: close\r\n";
 214         }
 215         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 216
 217         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 218                 msg_more($self, $h);
 219         } else {
 220                 $self->write(\$h);
 221         }
 222         $alive;
 223 }
 224
 225 # middlewares such as Deflater may write empty strings
 226 sub chunked_wcb ($) {
 227         my ($self) = @_;
 228         sub {
 229                 return if $_[0] eq '';
 230                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 231                 msg_more($self, $_[0]);
 232
 233                 # use $self->write(\"\n\n") if you care about real-time
 234                 # streaming responses, public-inbox WWW does not.
 235                 msg_more($self, "\r\n");
 236         }
 237 }
 238
 239 sub identity_wcb ($) {
 240         my ($self) = @_;
 241         sub { $self->write(\($_[0])) if $_[0] ne '' }
 242 }
 243
 244 sub next_request ($) {
 245         my ($self) = @_;
 246         if ($self->{rbuf}) {
 247                 # avoid recursion for pipelined requests
 248                 PublicInbox::DS::requeue(\&process_pipelineq) if !@$pipelineq;
 249                 push @$pipelineq, $self;
 250         } else { # wait for next request
 251                 $self->requeue;
 252         }
 253 }
 254
 255 sub response_done_cb ($$) {
 256         my ($self, $alive) = @_;
 257         sub {
 258                 delete $self->{env}; # we're no longer busy
 259                 $self->write(\"0\r\n\r\n") if $alive == 2;
 260                 $self->write($alive ? \&next_request : \&close);
 261         }
 262 }
 263
 264 sub getline_response ($$$) {
 265         my ($self, $write, $close) = @_;
 266         my $pull; # DANGER: self-referential
 267         $pull = sub {
 268                 my $forward = $self->{forward};
 269                 # limit our own running time for fairness with other
 270                 # clients and to avoid buffering too much:
 271                 my $buf = eval {
 272                         local $/ = \8192;
 273                         $forward->getline;
 274                 } if $forward;
 275
 276                 if (defined $buf) {
 277                         $write->($buf); # may close in PublicInbox::DS::write
 278
 279                         if ($self->{sock}) {
 280                                 my $wbuf = $self->{wbuf} ||= [];
 281                                 push @$wbuf, $pull;
 282
 283                                 # wbuf may be populated by $write->($buf),
 284                                 # no need to rearm if so:
 285                                 $self->requeue if scalar(@$wbuf) == 1;
 286                                 return; # likely
 287                         }
 288                 } elsif ($@) {
 289                         err($self, "response ->getline error: $@");
 290                         $self->close;
 291                 }
 292
 293                 $pull = undef; # all done!
 294                 # avoid recursion
 295                 if (delete $self->{forward}) {
 296                         eval { $forward->close };
 297                         if ($@) {
 298                                 err($self, "response ->close error: $@");
 299                                 $self->close; # idempotent
 300                         }
 301                 }
 302                 $forward = undef;
 303                 $close->(); # call response_done_cb
 304         };
 305
 306         $pull->(); # kick-off!
 307 }
 308
 309 sub response_write {
 310         my ($self, $env, $res) = @_;
 311         my $alive = response_header_write($self, $env, $res);
 312         my $close = response_done_cb($self, $alive);
 313         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 314         if (defined(my $body = $res->[2])) {
 315                 if (ref $body eq 'ARRAY') {
 316                         $write->($_) foreach @$body;
 317                         $close->();
 318                 } else {
 319                         $self->{forward} = $body;
 320                         getline_response($self, $write, $close);
 321                 }
 322         } else {
 323                 # this is returned to the calling application:
 324                 Plack::Util::inline_object(write => $write, close => $close);
 325         }
 326 }
 327
 328 sub input_tmpfile ($) {
 329         my $input = tmpfile('http.input', $_[0]->{sock}) or return;
 330         $input->autoflush(1);
 331         $input;
 332 }
 333
 334 sub input_prepare {
 335         my ($self, $env) = @_;
 336         my $input;
 337         my $len = $env->{CONTENT_LENGTH};
 338         if ($len) {
 339                 if ($len > $MAX_REQUEST_BUFFER) {
 340                         quit($self, 413);
 341                         return;
 342                 }
 343                 $input = input_tmpfile($self);
 344         } elsif (env_chunked($env)) {
 345                 $len = CHUNK_START;
 346                 $input = input_tmpfile($self);
 347         } else {
 348                 $input = $null_io;
 349         }
 350
 351         # TODO: expire idle clients on ENFILE / EMFILE
 352         return unless $input;
 353
 354         $env->{'psgi.input'} = $input;
 355         $self->{env} = $env;
 356         $self->{input_left} = $len || 0;
 357 }
 358
 359 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 360
 361 sub err ($$) {
 362         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 363 }
 364
 365 sub write_err {
 366         my ($self, $len) = @_;
 367         my $msg = $! || '(zero write)';
 368         $msg .= " ($len bytes remaining)" if defined $len;
 369         err($self, "error buffering to input: $msg");
 370         quit($self, 500);
 371 }
 372
 373 sub recv_err {
 374         my ($self, $len) = @_;
 375         if ($! == EAGAIN) { # epoll/kevent watch already set by do_read
 376                 $self->{input_left} = $len;
 377         } else {
 378                 err($self, "error reading input: $! ($len bytes remaining)");
 379         }
 380 }
 381
 382 sub read_input_chunked { # unlikely...
 383         my ($self, $rbuf) = @_;
 384         $rbuf //= $self->{rbuf} // (\(my $x = ''));
 385         my $input = $self->{env}->{'psgi.input'};
 386         my $len = delete $self->{input_left};
 387
 388         while (1) { # chunk start
 389                 if ($len == CHUNK_ZEND) {
 390                         $$rbuf =~ s/\A\r\n//s and
 391                                 return app_dispatch($self, $input, $rbuf);
 392
 393                         return quit($self, 400) if bytes::length($$rbuf) > 2;
 394                 }
 395                 if ($len == CHUNK_END) {
 396                         if ($$rbuf =~ s/\A\r\n//s) {
 397                                 $len = CHUNK_START;
 398                         } elsif (bytes::length($$rbuf) > 2) {
 399                                 return quit($self, 400);
 400                         }
 401                 }
 402                 if ($len == CHUNK_START) {
 403                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 404                                 $len = hex $1;
 405                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 406                                         return quit($self, 413);
 407                                 }
 408                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
 409                                 return quit($self, 400);
 410                         }
 411                         # will break from loop since $len >= 0
 412                 }
 413
 414                 if ($len < 0) { # chunk header is trickled, read more
 415                         $self->do_read($rbuf, 8192, bytes::length($$rbuf)) or
 416                                 return recv_err($self, $len);
 417                         # (implicit) goto chunk_start if $r > 0;
 418                 }
 419                 $len = CHUNK_ZEND if $len == 0;
 420
 421                 # drain the current chunk
 422                 until ($len <= 0) {
 423                         if ($$rbuf ne '') {
 424                                 my $w = xwrite($input, $rbuf, $len);
 425                                 return write_err($self, "$len chunk") if !$w;
 426                                 $len -= $w;
 427                                 if ($len == 0) {
 428                                         # we may have leftover data to parse
 429                                         # in chunk
 430                                         $$rbuf = substr($$rbuf, $w);
 431                                         $len = CHUNK_END;
 432                                 } elsif ($len < 0) {
 433                                         die "BUG: len < 0: $len";
 434                                 } else {
 435                                         $$rbuf = '';
 436                                 }
 437                         }
 438                         if ($$rbuf eq '') {
 439                                 # read more of current chunk
 440                                 $self->do_read($rbuf, 8192) or
 441                                         return recv_err($self, $len);
 442                         }
 443                 }
 444         }
 445 }
 446
 447 sub quit {
 448         my ($self, $status) = @_;
 449         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 450         $self->write(\$h);
 451         $self->close;
 452 }
 453
 454 sub close {
 455         my $self = $_[0];
 456         delete $self->{env}; # prevent circular references
 457         if (my $forward = delete $self->{forward}) {
 458                 eval { $forward->close };
 459                 err($self, "forward ->close error: $@") if $@;
 460         }
 461         $self->SUPER::close; # PublicInbox::DS::close
 462 }
 463
 464 # for graceful shutdown in PublicInbox::Daemon:
 465 sub busy () {
 466         my ($self) = @_;
 467         ($self->{rbuf} || $self->{env} || $self->{wbuf});
 468 }
 469
 470 1;