lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(PublicInbox::DS);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use bytes (); # only for bytes::length
  16 use Fcntl qw(:seek);
  17 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  18 use HTTP::Status qw(status_message);
  19 use HTTP::Date qw(time2str);
  20 use IO::Handle;
  21 require PublicInbox::EvCleanup;
  22 PublicInbox::DS->import(qw(msg_more write_in_full));
  23 use PublicInbox::Syscall qw(EPOLLIN EPOLLONESHOT);
  24 use constant {
  25         CHUNK_START => -1,   # [a-f0-9]+\r\n
  26         CHUNK_END => -2,     # \r\n
  27         CHUNK_ZEND => -3,    # \r\n
  28         CHUNK_MAX_HDR => 256,
  29 };
  30 use Errno qw(EAGAIN);
  31
  32 my $pipelineq = [];
  33 my $pipet;
  34 sub process_pipelineq () {
  35         my $q = $pipelineq;
  36         $pipet = undef;
  37         $pipelineq = [];
  38         foreach (@$q) {
  39                 next unless $_->{sock};
  40                 rbuf_process($_);
  41         }
  42 }
  43
  44 # Use the same configuration parameter as git since this is primarily
  45 # a slow-client sponge for git-http-backend
  46 # TODO: support per-respository http.maxRequestBuffer somehow...
  47 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  48                         (10 * 1024 * 1024);
  49
  50 open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
  51 my $http_date;
  52 my $prev = 0;
  53 sub http_date () {
  54         my $now = time;
  55         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  56 }
  57
  58 sub new ($$$) {
  59         my ($class, $sock, $addr, $httpd) = @_;
  60         my $self = fields::new($class);
  61         $self->SUPER::new($sock, EPOLLIN | EPOLLONESHOT);
  62         $self->{httpd} = $httpd;
  63         $self->{rbuf} = '';
  64         ($self->{remote_addr}, $self->{remote_port}) =
  65                 PublicInbox::Daemon::host_with_port($addr);
  66         $self;
  67 }
  68
  69 sub event_step { # called by PublicInbox::DS
  70         my ($self) = @_;
  71
  72         return unless $self->flush_write && $self->{sock};
  73
  74         # only read more requests if we've drained the write buffer,
  75         # otherwise we can be buffering infinitely w/o backpressure
  76
  77         return read_input($self) if defined $self->{env};
  78         my $rbuf = \($self->{rbuf});
  79         my $off = bytes::length($$rbuf);
  80         $self->do_read($rbuf, 8192, $off) and rbuf_process($self);
  81 }
  82
  83 sub rbuf_process {
  84         my ($self) = @_;
  85
  86         my %env = %{$self->{httpd}->{env}}; # full hash copy
  87         my $r = parse_http_request($self->{rbuf}, \%env);
  88
  89         # We do not support Trailers in chunked requests, for now
  90         # (they are rarely-used and git (as of 2.7.2) does not use them)
  91         if ($r == -1 || $env{HTTP_TRAILER} ||
  92                         # this length-check is necessary for PURE_PERL=1:
  93                         ($r == -2 && bytes::length($self->{rbuf}) > 0x4000)) {
  94                 return quit($self, 400);
  95         }
  96         return $self->watch_in1 if $r < 0; # incomplete
  97         $self->{rbuf} = substr($self->{rbuf}, $r);
  98
  99         my $len = input_prepare($self, \%env);
 100         defined $len or return write_err($self, undef); # EMFILE/ENFILE
 101
 102         $len ? read_input($self) : app_dispatch($self);
 103 }
 104
 105 sub read_input ($) {
 106         my ($self) = @_;
 107         my $env = $self->{env};
 108         return if $env->{REMOTE_ADDR}; # in app dispatch
 109         return read_input_chunked($self) if env_chunked($env);
 110
 111         # env->{CONTENT_LENGTH} (identity)
 112         my $sock = $self->{sock};
 113         my $len = delete $self->{input_left};
 114         my $rbuf = \($self->{rbuf});
 115         my $input = $env->{'psgi.input'};
 116
 117         while ($len > 0) {
 118                 if ($$rbuf ne '') {
 119                         my $w = write_in_full($input, $rbuf, $len, 0);
 120                         return write_err($self, $len) unless $w;
 121                         $len -= $w;
 122                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 123                         if ($len == 0) { # next request may be pipelined
 124                                 $$rbuf = substr($$rbuf, $w);
 125                                 last;
 126                         }
 127                         $$rbuf = '';
 128                 }
 129                 my $r = sysread($sock, $$rbuf, 8192);
 130                 return recv_err($self, $r, $len) unless $r;
 131                 # continue looping if $r > 0;
 132         }
 133         app_dispatch($self, $input);
 134 }
 135
 136 sub app_dispatch {
 137         my ($self, $input) = @_;
 138         my $env = $self->{env};
 139         $env->{REMOTE_ADDR} = $self->{remote_addr};
 140         $env->{REMOTE_PORT} = $self->{remote_port};
 141         if (my $host = $env->{HTTP_HOST}) {
 142                 $host =~ s/:([0-9]+)\z// and $env->{SERVER_PORT} = $1;
 143                 $env->{SERVER_NAME} = $host;
 144         }
 145         if (defined $input) {
 146                 sysseek($input, 0, SEEK_SET) or
 147                         die "BUG: psgi.input seek failed: $!";
 148         }
 149         # note: NOT $self->{sock}, we want our close (+ PublicInbox::DS::close),
 150         # to do proper cleanup:
 151         $env->{'psgix.io'} = $self; # only for ->close
 152         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 153         eval {
 154                 if (ref($res) eq 'CODE') {
 155                         $res->(sub { response_write($self, $env, $_[0]) });
 156                 } else {
 157                         response_write($self, $env, $res);
 158                 }
 159         };
 160         $self->close if $@;
 161 }
 162
 163 sub response_header_write {
 164         my ($self, $env, $res) = @_;
 165         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 166         my $status = $res->[0];
 167         my $h = "$proto $status " . status_message($status) . "\r\n";
 168         my ($len, $chunked);
 169         my $headers = $res->[1];
 170
 171         for (my $i = 0; $i < @$headers; $i += 2) {
 172                 my $k = $headers->[$i];
 173                 my $v = $headers->[$i + 1];
 174                 next if $k =~ /\A(?:Connection|Date)\z/i;
 175
 176                 $len = $v if $k =~ /\AContent-Length\z/i;
 177                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 178                         $chunked = 1;
 179                 }
 180                 $h .= "$k: $v\r\n";
 181         }
 182
 183         my $conn = $env->{HTTP_CONNECTION} || '';
 184         my $term = defined($len) || $chunked;
 185         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 186         my $alive;
 187         if (!$term && $prot_persist) { # auto-chunk
 188                 $chunked = $alive = 2;
 189                 $h .= "Transfer-Encoding: chunked\r\n";
 190                 # no need for "Connection: keep-alive" with HTTP/1.1
 191         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 192                 $alive = 1;
 193                 $h .= "Connection: keep-alive\r\n";
 194         } else {
 195                 $alive = 0;
 196                 $h .= "Connection: close\r\n";
 197         }
 198         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 199
 200         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 201                 msg_more($self, $h);
 202         } else {
 203                 $self->write(\$h);
 204         }
 205         $alive;
 206 }
 207
 208 # middlewares such as Deflater may write empty strings
 209 sub chunked_wcb ($) {
 210         my ($self) = @_;
 211         sub {
 212                 return if $_[0] eq '';
 213                 msg_more($self, sprintf("%x\r\n", bytes::length($_[0])));
 214                 msg_more($self, $_[0]);
 215
 216                 # use $self->write(\"\n\n") if you care about real-time
 217                 # streaming responses, public-inbox WWW does not.
 218                 msg_more($self, "\r\n");
 219         }
 220 }
 221
 222 sub identity_wcb ($) {
 223         my ($self) = @_;
 224         sub { $self->write(\($_[0])) if $_[0] ne '' }
 225 }
 226
 227 sub next_request ($) {
 228         my ($self) = @_;
 229         if ($self->{rbuf} eq '') { # wait for next request
 230                 $self->watch_in1;
 231         } else { # avoid recursion for pipelined requests
 232                 push @$pipelineq, $self;
 233                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 234         }
 235 }
 236
 237 sub response_done_cb ($$) {
 238         my ($self, $alive) = @_;
 239         sub {
 240                 my $env = delete $self->{env};
 241                 $self->write(\"0\r\n\r\n") if $alive == 2;
 242                 $self->write($alive ? \&next_request : \&close);
 243         }
 244 }
 245
 246 sub getline_cb ($$$) {
 247         my ($self, $write, $close) = @_;
 248         local $/ = \8192;
 249         my $forward = $self->{forward};
 250         # limit our own running time for fairness with other
 251         # clients and to avoid buffering too much:
 252         if ($forward) {
 253                 my $buf = eval { $forward->getline };
 254                 if (defined $buf) {
 255                         $write->($buf); # may close in PublicInbox::DS::write
 256                         if ($self->{sock}) {
 257                                 my $next = $self->{pull};
 258                                 if ($self->{wbuf}) {
 259                                         $self->write($next);
 260                                 } else {
 261                                         PublicInbox::EvCleanup::asap($next);
 262                                 }
 263                                 return;
 264                         }
 265                 } elsif ($@) {
 266                         err($self, "response ->getline error: $@");
 267                         $forward = undef;
 268                         $self->close;
 269                 }
 270         }
 271
 272         delete @$self{qw(forward pull)};
 273         # avoid recursion
 274         if ($forward) {
 275                 eval { $forward->close };
 276                 if ($@) {
 277                         err($self, "response ->close error: $@");
 278                         $self->close; # idempotent
 279                 }
 280         }
 281         $close->();
 282 }
 283
 284 sub getline_response ($$$) {
 285         my ($self, $write, $close) = @_;
 286         my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
 287         $pull->();
 288 }
 289
 290 sub response_write {
 291         my ($self, $env, $res) = @_;
 292         my $alive = response_header_write($self, $env, $res);
 293         my $close = response_done_cb($self, $alive);
 294         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 295         if (defined(my $body = $res->[2])) {
 296                 if (ref $body eq 'ARRAY') {
 297                         $write->($_) foreach @$body;
 298                         $close->();
 299                 } else {
 300                         $self->{forward} = $body;
 301                         getline_response($self, $write, $close);
 302                 }
 303         } else {
 304                 # this is returned to the calling application:
 305                 Plack::Util::inline_object(write => $write, close => $close);
 306         }
 307 }
 308
 309 sub input_prepare {
 310         my ($self, $env) = @_;
 311         my $input;
 312         my $len = $env->{CONTENT_LENGTH};
 313         if ($len) {
 314                 if ($len > $MAX_REQUEST_BUFFER) {
 315                         quit($self, 413);
 316                         return;
 317                 }
 318                 open($input, '+>', undef);
 319         } elsif (env_chunked($env)) {
 320                 $len = CHUNK_START;
 321                 open($input, '+>', undef);
 322         } else {
 323                 $input = $null_io;
 324         }
 325
 326         # TODO: expire idle clients on ENFILE / EMFILE
 327         return unless $input;
 328
 329         $env->{'psgi.input'} = $input;
 330         $self->{env} = $env;
 331         $self->{input_left} = $len || 0;
 332 }
 333
 334 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 335
 336 sub err ($$) {
 337         eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
 338 }
 339
 340 sub write_err {
 341         my ($self, $len) = @_;
 342         my $msg = $! || '(zero write)';
 343         $msg .= " ($len bytes remaining)" if defined $len;
 344         err($self, "error buffering to input: $msg");
 345         quit($self, 500);
 346 }
 347
 348 sub recv_err {
 349         my ($self, $r, $len) = @_;
 350         return $self->close if (defined $r && $r == 0);
 351         if ($! == EAGAIN) {
 352                 $self->{input_left} = $len;
 353                 return $self->watch_in1;
 354         }
 355         err($self, "error reading for input: $! ($len bytes remaining)");
 356         quit($self, 500);
 357 }
 358
 359 sub read_input_chunked { # unlikely...
 360         my ($self) = @_;
 361         my $input = $self->{env}->{'psgi.input'};
 362         my $sock = $self->{sock};
 363         my $len = delete $self->{input_left};
 364         my $rbuf = \($self->{rbuf});
 365
 366         while (1) { # chunk start
 367                 if ($len == CHUNK_ZEND) {
 368                         $$rbuf =~ s/\A\r\n//s and
 369                                 return app_dispatch($self, $input);
 370                         return quit($self, 400) if bytes::length($$rbuf) > 2;
 371                 }
 372                 if ($len == CHUNK_END) {
 373                         if ($$rbuf =~ s/\A\r\n//s) {
 374                                 $len = CHUNK_START;
 375                         } elsif (bytes::length($$rbuf) > 2) {
 376                                 return quit($self, 400);
 377                         }
 378                 }
 379                 if ($len == CHUNK_START) {
 380                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 381                                 $len = hex $1;
 382                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 383                                         return quit($self, 413);
 384                                 }
 385                         } elsif (bytes::length($$rbuf) > CHUNK_MAX_HDR) {
 386                                 return quit($self, 400);
 387                         }
 388                         # will break from loop since $len >= 0
 389                 }
 390
 391                 if ($len < 0) { # chunk header is trickled, read more
 392                         my $off = bytes::length($$rbuf);
 393                         my $r = sysread($sock, $$rbuf, 8192, $off);
 394                         return recv_err($self, $r, $len) unless $r;
 395                         # (implicit) goto chunk_start if $r > 0;
 396                 }
 397                 $len = CHUNK_ZEND if $len == 0;
 398
 399                 # drain the current chunk
 400                 until ($len <= 0) {
 401                         if ($$rbuf ne '') {
 402                                 my $w = write_in_full($input, $rbuf, $len, 0);
 403                                 return write_err($self, "$len chunk") if !$w;
 404                                 $len -= $w;
 405                                 if ($len == 0) {
 406                                         # we may have leftover data to parse
 407                                         # in chunk
 408                                         $$rbuf = substr($$rbuf, $w);
 409                                         $len = CHUNK_END;
 410                                 } elsif ($len < 0) {
 411                                         die "BUG: len < 0: $len";
 412                                 } else {
 413                                         $$rbuf = '';
 414                                 }
 415                         }
 416                         if ($$rbuf eq '') {
 417                                 # read more of current chunk
 418                                 my $r = sysread($sock, $$rbuf, 8192);
 419                                 return recv_err($self, $r, $len) unless $r;
 420                         }
 421                 }
 422         }
 423 }
 424
 425 sub quit {
 426         my ($self, $status) = @_;
 427         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 428         $self->write(\$h);
 429         $self->close;
 430 }
 431
 432 sub close {
 433         my $self = $_[0];
 434         if (my $env = delete $self->{env}) {
 435                 delete $env->{'psgix.io'}; # prevent circular references
 436         }
 437         delete $self->{pull};
 438         if (my $forward = delete $self->{forward}) {
 439                 eval { $forward->close };
 440                 err($self, "forward ->close error: $@") if $@;
 441         }
 442         $self->SUPER::close; # PublicInbox::DS::close
 443 }
 444
 445 # for graceful shutdown in PublicInbox::Daemon:
 446 sub busy () {
 447         my ($self) = @_;
 448         ($self->{rbuf} ne '' || $self->{env} || $self->{wbuf});
 449 }
 450
 451 # fires after pending writes are complete:
 452 sub restart_pass ($) {
 453         $_[0]->{forward}->restart_read; # see PublicInbox::HTTPD::Async
 454 }
 455
 456 sub enqueue_restart_pass ($) { $_[0]->write(\&restart_pass) }
 457
 458 1;