lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing which depends on public-inbox, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  20 use Scalar::Util qw(weaken);
  21 use IO::File;
  22 use constant {
  23         CHUNK_START => -1,   # [a-f0-9]+\r\n
  24         CHUNK_END => -2,     # \r\n
  25         CHUNK_ZEND => -3,    # \r\n
  26         CHUNK_MAX_HDR => 256,
  27 };
  28
  29 sub now () { clock_gettime(CLOCK_MONOTONIC) }
  30
  31 # FIXME: duplicated code with NNTP.pm, layering violation
  32 my $WEAKEN = {}; # string(inbox) -> inbox
  33 my $weakt;
  34 sub weaken_task () {
  35         $weakt = undef;
  36         $_->weaken_all for values %$WEAKEN;
  37         $WEAKEN = {};
  38 }
  39
  40 my $pipelineq = [];
  41 my $pipet;
  42 sub process_pipelineq () {
  43         my $q = $pipelineq;
  44         $pipet = undef;
  45         $pipelineq = [];
  46         foreach (@$q) {
  47                 next if $_->{closed};
  48                 rbuf_process($_);
  49         }
  50 }
  51
  52 # Use the same configuration parameter as git since this is primarily
  53 # a slow-client sponge for git-http-backend
  54 # TODO: support per-respository http.maxRequestBuffer somehow...
  55 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  56                         (10 * 1024 * 1024);
  57
  58 my $null_io = IO::File->new('/dev/null', '<');
  59 my $http_date;
  60 my $prev = 0;
  61 sub http_date () {
  62         my $now = time;
  63         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  64 }
  65
  66 sub new ($$$) {
  67         my ($class, $sock, $addr, $httpd) = @_;
  68         my $self = fields::new($class);
  69         $self->SUPER::new($sock);
  70         $self->{httpd} = $httpd;
  71         $self->{rbuf} = '';
  72         ($self->{remote_addr}, $self->{remote_port}) =
  73                 PublicInbox::Daemon::host_with_port($addr);
  74         $self->watch_read(1);
  75         $self;
  76 }
  77
  78 sub event_read { # called by Danga::Socket
  79         my ($self) = @_;
  80
  81         return event_read_input($self) if defined $self->{env};
  82
  83         my $off = length($self->{rbuf});
  84         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  85         if (defined $r) {
  86                 return $self->close if $r == 0;
  87                 return rbuf_process($self);
  88         }
  89         return if $!{EAGAIN}; # no need to call watch_read(1) again
  90
  91         # common for clients to break connections without warning,
  92         # would be too noisy to log here:
  93         return $self->close;
  94 }
  95
  96 sub rbuf_process {
  97         my ($self) = @_;
  98
  99         my %env = %{$self->{httpd}->{env}}; # full hash copy
 100         my $r = parse_http_request($self->{rbuf}, \%env);
 101
 102         # We do not support Trailers in chunked requests, for now
 103         # (they are rarely-used and git (as of 2.7.2) does not use them)
 104         if ($r == -1 || $env{HTTP_TRAILER} ||
 105                         # this length-check is necessary for PURE_PERL=1:
 106                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
 107                 return quit($self, 400);
 108         }
 109         return $self->watch_read(1) if $r < 0; # incomplete
 110         $self->{rbuf} = substr($self->{rbuf}, $r);
 111
 112         my $len = input_prepare($self, \%env);
 113         defined $len or return write_err($self); # EMFILE/ENFILE
 114
 115         $len ? event_read_input($self) : app_dispatch($self);
 116 }
 117
 118 sub event_read_input ($) {
 119         my ($self) = @_;
 120         my $env = $self->{env};
 121         return event_read_input_chunked($self) if env_chunked($env);
 122
 123         # env->{CONTENT_LENGTH} (identity)
 124         my $sock = $self->{sock};
 125         my $len = $self->{input_left};
 126         $self->{input_left} = undef;
 127         my $rbuf = \($self->{rbuf});
 128         my $input = $env->{'psgi.input'};
 129
 130         while ($len > 0) {
 131                 if ($$rbuf ne '') {
 132                         my $w = write_in_full($input, $rbuf, $len);
 133                         return write_err($self) unless $w;
 134                         $len -= $w;
 135                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 136                         if ($len == 0) { # next request may be pipelined
 137                                 $$rbuf = substr($$rbuf, $w);
 138                                 last;
 139                         }
 140                         $$rbuf = '';
 141                 }
 142                 my $r = sysread($sock, $$rbuf, 8192);
 143                 return recv_err($self, $r, $len) unless $r;
 144                 # continue looping if $r > 0;
 145         }
 146         app_dispatch($self, $input);
 147 }
 148
 149 sub app_dispatch {
 150         my ($self, $input) = @_;
 151         $self->watch_read(0);
 152         my $env = $self->{env};
 153         $env->{REMOTE_ADDR} = $self->{remote_addr};
 154         $env->{REMOTE_PORT} = $self->{remote_port};
 155         if (my $host = $env->{HTTP_HOST}) {
 156                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 157                 $env->{SERVER_NAME} = $host;
 158         }
 159         if (defined $input) {
 160                 sysseek($input, 0, SEEK_SET) or
 161                         die "BUG: psgi.input seek failed: $!";
 162         }
 163         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 164         # to do proper cleanup:
 165         $env->{'psgix.io'} = $self; # only for ->close
 166         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 167         eval {
 168                 if (ref($res) eq 'CODE') {
 169                         $res->(sub { response_write($self, $env, $_[0]) });
 170                 } else {
 171                         response_write($self, $env, $res);
 172                 }
 173         };
 174         $self->close if $@;
 175 }
 176
 177 sub response_header_write {
 178         my ($self, $env, $res) = @_;
 179         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 180         my $status = $res->[0];
 181         my $h = "$proto $status " . status_message($status) . "\r\n";
 182         my ($len, $chunked);
 183         my $headers = $res->[1];
 184
 185         for (my $i = 0; $i < @$headers; $i += 2) {
 186                 my $k = $headers->[$i];
 187                 my $v = $headers->[$i + 1];
 188                 next if $k =~ /\A(?:Connection|Date)\z/i;
 189
 190                 $len = $v if $k =~ /\AContent-Length\z/i;
 191                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 192                         $chunked = 1;
 193                 }
 194                 $h .= "$k: $v\r\n";
 195         }
 196
 197         my $conn = $env->{HTTP_CONNECTION} || '';
 198         my $term = defined($len) || $chunked;
 199         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 200         my $alive;
 201         if (!$term && $prot_persist) { # auto-chunk
 202                 $chunked = $alive = 2;
 203                 $h .= "Transfer-Encoding: chunked\r\n";
 204                 # no need for "Connection: keep-alive" with HTTP/1.1
 205         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 206                 $alive = 1;
 207                 $h .= "Connection: keep-alive\r\n";
 208         } else {
 209                 $alive = 0;
 210                 $h .= "Connection: close\r\n";
 211         }
 212         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 213
 214         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 215                 more($self, $h);
 216         } else {
 217                 $self->write($h);
 218         }
 219         $alive;
 220 }
 221
 222 # middlewares such as Deflater may write empty strings
 223 sub chunked_wcb ($) {
 224         my ($self) = @_;
 225         sub {
 226                 return if $_[0] eq '';
 227                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 228                 more($self, $_[0]);
 229                 $self->write("\r\n");
 230         }
 231 }
 232
 233 sub identity_wcb ($) {
 234         my ($self) = @_;
 235         sub { $self->write(\($_[0])) if $_[0] ne '' }
 236 }
 237
 238 sub next_request ($) {
 239         my ($self) = @_;
 240         $self->watch_write(0);
 241         if ($self->{rbuf} eq '') { # wait for next request
 242                 $self->watch_read(1);
 243         } else { # avoid recursion for pipelined requests
 244                 push @$pipelineq, $self;
 245                 $pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
 246         }
 247 }
 248
 249 sub response_done ($$) {
 250         my ($self, $alive) = @_;
 251         my $env = $self->{env};
 252         $self->{env} = undef;
 253         $self->write("0\r\n\r\n") if $alive == 2;
 254         $self->write(sub { $alive ? next_request($self) : $self->close });
 255
 256         # FIXME: layering violation
 257         if (my $obj = $env->{'pi-httpd.inbox'}) {
 258                 # grace period for reaping resources
 259                 $WEAKEN->{"$obj"} = $obj;
 260                 PublicInbox::EvCleanup::later(*weaken_task);
 261         }
 262 }
 263
 264 sub getline_response {
 265         my ($self, $body, $write, $close) = @_;
 266         $self->{forward} = $body;
 267         weaken($self);
 268         my $pull = $self->{pull} = sub {
 269                 local $/ = \8192;
 270                 my $forward = $self->{forward};
 271                 # limit our own running time for fairness with other
 272                 # clients and to avoid buffering too much:
 273                 my $end = now() + 0.1;
 274                 while ($forward && defined(my $buf = $forward->getline)) {
 275                         $write->($buf);
 276                         last if $self->{closed};
 277                         if ($self->{write_buf_size}) {
 278                                 $self->write($self->{pull});
 279                                 return;
 280                         } elsif (now() > $end) {
 281                                 PublicInbox::EvCleanup::asap($self->{pull});
 282                                 return;
 283                         }
 284                 }
 285                 $self->{forward} = $self->{pull} = undef;
 286                 $forward->close if $forward; # avoid recursion
 287                 $close->();
 288         };
 289         $pull->();
 290 }
 291
 292 sub response_write {
 293         my ($self, $env, $res) = @_;
 294         my $alive = response_header_write($self, $env, $res);
 295
 296         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 297         my $close = sub { response_done($self, $alive) };
 298         if (defined(my $body = $res->[2])) {
 299                 if (ref $body eq 'ARRAY') {
 300                         $write->($_) foreach @$body;
 301                         $close->();
 302                 } else {
 303                         getline_response($self, $body, $write, $close);
 304                 }
 305         } else {
 306                 # this is returned to the calling application:
 307                 Plack::Util::inline_object(write => $write, close => $close);
 308         }
 309 }
 310
 311 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 312 sub more ($$) {
 313         my $self = $_[0];
 314         return if $self->{closed};
 315         if (MSG_MORE && !$self->{write_buf_size}) {
 316                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 317                 if (defined $n) {
 318                         my $dlen = length($_[1]);
 319                         return 1 if $n == $dlen; # all done!
 320                         $_[1] = substr($_[1], $n, $dlen - $n);
 321                         # fall through to normal write:
 322                 }
 323         }
 324         $self->write($_[1]);
 325 }
 326
 327 sub input_prepare {
 328         my ($self, $env) = @_;
 329         my $input = $null_io;
 330         my $len = $env->{CONTENT_LENGTH};
 331         if ($len) {
 332                 if ($len > $MAX_REQUEST_BUFFER) {
 333                         quit($self, 413);
 334                         return;
 335                 }
 336                 $input = IO::File->new_tmpfile;
 337         } elsif (env_chunked($env)) {
 338                 $len = CHUNK_START;
 339                 $input = IO::File->new_tmpfile;
 340         }
 341
 342         # TODO: expire idle clients on ENFILE / EMFILE
 343         return unless $input;
 344
 345         $env->{'psgi.input'} = $input;
 346         $self->{env} = $env;
 347         $self->{input_left} = $len || 0;
 348 }
 349
 350 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 351
 352 sub write_err {
 353         my ($self) = @_;
 354         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 355         my $msg = $! || '(zero write)';
 356         $err->print("error buffering to input: $msg\n");
 357         quit($self, 500);
 358 }
 359
 360 sub recv_err {
 361         my ($self, $r, $len) = @_;
 362         return $self->close if (defined $r && $r == 0);
 363         if ($!{EAGAIN}) {
 364                 $self->{input_left} = $len;
 365                 return;
 366         }
 367         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 368         $err->print("error reading for input: $! ($len bytes remaining)\n");
 369         quit($self, 500);
 370 }
 371
 372 sub write_in_full {
 373         my ($fh, $rbuf, $len) = @_;
 374         my $rv = 0;
 375         my $off = 0;
 376         while ($len > 0) {
 377                 my $w = syswrite($fh, $$rbuf, $len, $off);
 378                 return ($rv ? $rv : $w) unless $w; # undef or 0
 379                 $rv += $w;
 380                 $off += $w;
 381                 $len -= $w;
 382         }
 383         $rv
 384 }
 385
 386 sub event_read_input_chunked { # unlikely...
 387         my ($self) = @_;
 388         my $input = $self->{env}->{'psgi.input'};
 389         my $sock = $self->{sock};
 390         my $len = $self->{input_left};
 391         $self->{input_left} = undef;
 392         my $rbuf = \($self->{rbuf});
 393
 394         while (1) { # chunk start
 395                 if ($len == CHUNK_ZEND) {
 396                         $$rbuf =~ s/\A\r\n//s and
 397                                 return app_dispatch($self, $input);
 398                         return quit($self, 400) if length($$rbuf) > 2;
 399                 }
 400                 if ($len == CHUNK_END) {
 401                         if ($$rbuf =~ s/\A\r\n//s) {
 402                                 $len = CHUNK_START;
 403                         } elsif (length($$rbuf) > 2) {
 404                                 return quit($self, 400);
 405                         }
 406                 }
 407                 if ($len == CHUNK_START) {
 408                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 409                                 $len = hex $1;
 410                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 411                                         return quit($self, 413);
 412                                 }
 413                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 414                                 return quit($self, 400);
 415                         }
 416                         # will break from loop since $len >= 0
 417                 }
 418
 419                 if ($len < 0) { # chunk header is trickled, read more
 420                         my $off = length($$rbuf);
 421                         my $r = sysread($sock, $$rbuf, 8192, $off);
 422                         return recv_err($self, $r, $len) unless $r;
 423                         # (implicit) goto chunk_start if $r > 0;
 424                 }
 425                 $len = CHUNK_ZEND if $len == 0;
 426
 427                 # drain the current chunk
 428                 until ($len <= 0) {
 429                         if ($$rbuf ne '') {
 430                                 my $w = write_in_full($input, $rbuf, $len);
 431                                 return write_err($self) unless $w;
 432                                 $len -= $w;
 433                                 if ($len == 0) {
 434                                         # we may have leftover data to parse
 435                                         # in chunk
 436                                         $$rbuf = substr($$rbuf, $w);
 437                                         $len = CHUNK_END;
 438                                 } elsif ($len < 0) {
 439                                         die "BUG: len < 0: $len";
 440                                 } else {
 441                                         $$rbuf = '';
 442                                 }
 443                         }
 444                         if ($$rbuf eq '') {
 445                                 # read more of current chunk
 446                                 my $r = sysread($sock, $$rbuf, 8192);
 447                                 return recv_err($self, $r, $len) unless $r;
 448                         }
 449                 }
 450         }
 451 }
 452
 453 sub quit {
 454         my ($self, $status) = @_;
 455         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 456         $self->write($h);
 457         $self->close;
 458 }
 459
 460 # callbacks for Danga::Socket
 461
 462 sub event_hup { $_[0]->close }
 463 sub event_err { $_[0]->close }
 464
 465 sub close {
 466         my $self = shift;
 467         my $forward = $self->{forward};
 468         my $env = $self->{env};
 469         delete $env->{'psgix.io'} if $env; # prevent circular referernces
 470         $self->{pull} = $self->{forward} = $self->{env} = undef;
 471         $forward->close if $forward;
 472         $self->SUPER::close(@_);
 473 }
 474
 475 # for graceful shutdown in PublicInbox::Daemon:
 476 sub busy () {
 477         my ($self) = @_;
 478         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 479 }
 480
 481 1;