lib/PublicInbox/HTTP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Generic PSGI server for convenience.  It aims to provide
   5 # a consistent experience for public-inbox admins so they don't have
   6 # to learn different ways to admin both NNTP and HTTP components.
   7 # There's nothing public-inbox-specific, here.
   8 # Each instance of this class represents a HTTP client socket
   9
  10 package PublicInbox::HTTP;
  11 use strict;
  12 use warnings;
  13 use base qw(Danga::Socket);
  14 use fields qw(httpd env rbuf input_left remote_addr remote_port forward);
  15 use Fcntl qw(:seek);
  16 use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
  17 use HTTP::Status qw(status_message);
  18 use HTTP::Date qw(time2str);
  19 use IO::File;
  20 use constant {
  21         CHUNK_START => -1,   # [a-f0-9]+\r\n
  22         CHUNK_END => -2,     # \r\n
  23         CHUNK_ZEND => -3,    # \r\n
  24         CHUNK_MAX_HDR => 256,
  25 };
  26
  27 # FIXME: duplicated code with NNTP.pm
  28 my $WEAKEN = {}; # string(inbox) -> inbox
  29 my $WEAKTIMER;
  30 sub weaken_task () {
  31         $WEAKTIMER = undef;
  32         $_->weaken_all for values %$WEAKEN;
  33         $WEAKEN = {};
  34 }
  35
  36 # Use the same configuration parameter as git since this is primarily
  37 # a slow-client sponge for git-http-backend
  38 # TODO: support per-respository http.maxRequestBuffer somehow...
  39 our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
  40                         (10 * 1024 * 1024);
  41
  42 my $null_io = IO::File->new('/dev/null', '<');
  43 my $http_date;
  44 my $prev = 0;
  45 sub http_date () {
  46         my $now = time;
  47         $now == $prev ? $http_date : ($http_date = time2str($prev = $now));
  48 }
  49
  50 sub new ($$$) {
  51         my ($class, $sock, $addr, $httpd) = @_;
  52         my $self = fields::new($class);
  53         $self->SUPER::new($sock);
  54         $self->{httpd} = $httpd;
  55         $self->{rbuf} = '';
  56         ($self->{remote_addr}, $self->{remote_port}) =
  57                 PublicInbox::Daemon::host_with_port($addr);
  58         $self->watch_read(1);
  59         $self;
  60 }
  61
  62 sub event_read { # called by Danga::Socket
  63         my ($self) = @_;
  64
  65         return event_read_input($self) if defined $self->{env};
  66
  67         my $off = length($self->{rbuf});
  68         my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
  69         if (defined $r) {
  70                 return $self->close if $r == 0;
  71                 return rbuf_process($self);
  72         }
  73         return if $!{EAGAIN}; # no need to call watch_read(1) again
  74
  75         # common for clients to break connections without warning,
  76         # would be too noisy to log here:
  77         return $self->close;
  78 }
  79
  80 sub rbuf_process {
  81         my ($self) = @_;
  82
  83         my %env = %{$self->{httpd}->{env}}; # full hash copy
  84         my $r = parse_http_request($self->{rbuf}, \%env);
  85
  86         # We do not support Trailers in chunked requests, for now
  87         # (they are rarely-used and git (as of 2.7.2) does not use them)
  88         if ($r == -1 || $env{HTTP_TRAILER} ||
  89                         # this length-check is necessary for PURE_PERL=1:
  90                         ($r == -2 && length($self->{rbuf}) > 0x4000)) {
  91                 return quit($self, 400);
  92         }
  93         return $self->watch_read(1) if $r < 0; # incomplete
  94         $self->{rbuf} = substr($self->{rbuf}, $r);
  95
  96         my $len = input_prepare($self, \%env);
  97         defined $len or return write_err($self); # EMFILE/ENFILE
  98
  99         $len ? event_read_input($self) : app_dispatch($self);
 100 }
 101
 102 sub event_read_input ($) {
 103         my ($self) = @_;
 104         my $env = $self->{env};
 105         return event_read_input_chunked($self) if env_chunked($env);
 106
 107         # env->{CONTENT_LENGTH} (identity)
 108         my $sock = $self->{sock};
 109         my $len = $self->{input_left};
 110         $self->{input_left} = undef;
 111         my $rbuf = \($self->{rbuf});
 112         my $input = $env->{'psgi.input'};
 113
 114         while ($len > 0) {
 115                 if ($$rbuf ne '') {
 116                         my $w = write_in_full($input, $rbuf, $len);
 117                         return write_err($self) unless $w;
 118                         $len -= $w;
 119                         die "BUG: $len < 0 (w=$w)" if $len < 0;
 120                         if ($len == 0) { # next request may be pipelined
 121                                 $$rbuf = substr($$rbuf, $w);
 122                                 last;
 123                         }
 124                         $$rbuf = '';
 125                 }
 126                 my $r = sysread($sock, $$rbuf, 8192);
 127                 return recv_err($self, $r, $len) unless $r;
 128                 # continue looping if $r > 0;
 129         }
 130         app_dispatch($self, $input);
 131 }
 132
 133 sub app_dispatch {
 134         my ($self, $input) = @_;
 135         $self->watch_read(0);
 136         my $env = $self->{env};
 137         $env->{REMOTE_ADDR} = $self->{remote_addr};
 138         $env->{REMOTE_PORT} = $self->{remote_port};
 139         if (my $host = $env->{HTTP_HOST}) {
 140                 $host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
 141                 $env->{SERVER_NAME} = $host;
 142         }
 143         if (defined $input) {
 144                 sysseek($input, 0, SEEK_SET) or
 145                         die "BUG: psgi.input seek failed: $!";
 146         }
 147         # note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
 148         # to do proper cleanup:
 149         $env->{'psgix.io'} = $self; # only for ->close
 150         my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
 151         eval {
 152                 if (ref($res) eq 'CODE') {
 153                         $res->(sub { response_write($self, $env, $_[0]) });
 154                 } else {
 155                         response_write($self, $env, $res);
 156                 }
 157         };
 158         $self->close if $@;
 159 }
 160
 161 sub response_header_write {
 162         my ($self, $env, $res) = @_;
 163         my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
 164         my $status = $res->[0];
 165         my $h = "$proto $status " . status_message($status) . "\r\n";
 166         my ($len, $chunked);
 167         my $headers = $res->[1];
 168
 169         for (my $i = 0; $i < @$headers; $i += 2) {
 170                 my $k = $headers->[$i];
 171                 my $v = $headers->[$i + 1];
 172                 next if $k =~ /\A(?:Connection|Date)\z/i;
 173
 174                 $len = $v if $k =~ /\AContent-Length\z/i;
 175                 if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
 176                         $chunked = 1;
 177                 }
 178                 $h .= "$k: $v\r\n";
 179         }
 180
 181         my $conn = $env->{HTTP_CONNECTION} || '';
 182         my $term = defined($len) || $chunked;
 183         my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
 184         my $alive;
 185         if (!$term && $prot_persist) { # auto-chunk
 186                 $chunked = $alive = 2;
 187                 $h .= "Transfer-Encoding: chunked\r\n";
 188                 # no need for "Connection: keep-alive" with HTTP/1.1
 189         } elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
 190                 $alive = 1;
 191                 $h .= "Connection: keep-alive\r\n";
 192         } else {
 193                 $alive = 0;
 194                 $h .= "Connection: close\r\n";
 195         }
 196         $h .= 'Date: ' . http_date() . "\r\n\r\n";
 197
 198         if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
 199                 more($self, $h);
 200         } else {
 201                 $self->write($h);
 202         }
 203         $alive;
 204 }
 205
 206 # middlewares such as Deflater may write empty strings
 207 sub chunked_wcb ($) {
 208         my ($self) = @_;
 209         sub {
 210                 return if $_[0] eq '';
 211                 more($self, sprintf("%x\r\n", bytes::length($_[0])));
 212                 more($self, $_[0]);
 213                 $self->write("\r\n");
 214         }
 215 }
 216
 217 sub identity_wcb ($) {
 218         my ($self) = @_;
 219         sub { $self->write(\($_[0])) if $_[0] ne '' }
 220 }
 221
 222 sub response_write {
 223         my ($self, $env, $res) = @_;
 224         my $alive = response_header_write($self, $env, $res);
 225
 226         my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
 227         my $close = sub {
 228                 $self->write("0\r\n\r\n") if $alive == 2;
 229                 if ($alive) {
 230                         $self->event_write; # watch for readability if done
 231                 } else {
 232                         Danga::Socket::write($self, sub { $self->close });
 233                 }
 234                 if (my $obj = $env->{'pi-httpd.inbox'}) {
 235                         # grace period for reaping resources
 236                         $WEAKEN->{"$obj"} = $obj;
 237                         $WEAKTIMER ||= Danga::Socket->AddTimer(60, *weaken_task);
 238                 }
 239                 $self->{env} = undef;
 240         };
 241
 242         if (defined(my $body = $res->[2])) {
 243                 if (ref $body eq 'ARRAY') {
 244                         $write->($_) foreach @$body;
 245                         $close->();
 246                 } else {
 247                         my $pull;
 248                         $pull = sub {
 249                                 local $/ = \8192;
 250                                 while (defined(my $buf = $body->getline)) {
 251                                         $write->($buf);
 252                                         if ($self->{write_buf_size}) {
 253                                                 $self->write($pull);
 254                                                 return;
 255                                         }
 256                                 }
 257                                 $pull = undef;
 258                                 $body->close();
 259                                 $close->();
 260                         };
 261                         $pull->();
 262                 }
 263         } else {
 264                 # this is returned to the calling application:
 265                 Plack::Util::inline_object(write => $write, close => $close);
 266         }
 267 }
 268
 269 use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
 270 sub more ($$) {
 271         my $self = $_[0];
 272         if (MSG_MORE && !$self->{write_buf_size}) {
 273                 my $n = send($self->{sock}, $_[1], MSG_MORE);
 274                 if (defined $n) {
 275                         my $dlen = length($_[1]);
 276                         return 1 if $n == $dlen; # all done!
 277                         $_[1] = substr($_[1], $n, $dlen - $n);
 278                         # fall through to normal write:
 279                 }
 280         }
 281         $self->write($_[1]);
 282 }
 283
 284 my $pipelineq = [];
 285 my $next_tick;
 286 sub process_pipelineq () {
 287         $next_tick = undef;
 288         my $q = $pipelineq;
 289         $pipelineq = [];
 290         rbuf_process($_) foreach @$q;
 291 }
 292
 293 # overrides existing Danga::Socket method
 294 sub event_write {
 295         my ($self) = @_;
 296         # only continue watching for readability when we are done writing:
 297         return if $self->write(undef) != 1;
 298
 299         if ($self->{rbuf} eq '') { # wait for next request
 300                 $self->watch_read(1);
 301         } else { # avoid recursion for pipelined requests
 302                 push @$pipelineq, $self;
 303                 $next_tick ||= Danga::Socket->AddTimer(0, *process_pipelineq);
 304         }
 305 }
 306
 307 sub input_prepare {
 308         my ($self, $env) = @_;
 309         my $input = $null_io;
 310         my $len = $env->{CONTENT_LENGTH};
 311         if ($len) {
 312                 if ($len > $MAX_REQUEST_BUFFER) {
 313                         quit($self, 413);
 314                         return;
 315                 }
 316                 $input = IO::File->new_tmpfile;
 317         } elsif (env_chunked($env)) {
 318                 $len = CHUNK_START;
 319                 $input = IO::File->new_tmpfile;
 320         }
 321
 322         # TODO: expire idle clients on ENFILE / EMFILE
 323         return unless $input;
 324
 325         $env->{'psgi.input'} = $input;
 326         $self->{env} = $env;
 327         $self->{input_left} = $len || 0;
 328 }
 329
 330 sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }
 331
 332 sub write_err {
 333         my ($self) = @_;
 334         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 335         my $msg = $! || '(zero write)';
 336         $err->print("error buffering to input: $msg\n");
 337         quit($self, 500);
 338 }
 339
 340 sub recv_err {
 341         my ($self, $r, $len) = @_;
 342         return $self->close if (defined $r && $r == 0);
 343         if ($!{EAGAIN}) {
 344                 $self->{input_left} = $len;
 345                 return;
 346         }
 347         my $err = $self->{httpd}->{env}->{'psgi.errors'};
 348         $err->print("error reading for input: $! ($len bytes remaining)\n");
 349         quit($self, 500);
 350 }
 351
 352 sub write_in_full {
 353         my ($fh, $rbuf, $len) = @_;
 354         my $rv = 0;
 355         my $off = 0;
 356         while ($len > 0) {
 357                 my $w = syswrite($fh, $$rbuf, $len, $off);
 358                 return ($rv ? $rv : $w) unless $w; # undef or 0
 359                 $rv += $w;
 360                 $off += $w;
 361                 $len -= $w;
 362         }
 363         $rv
 364 }
 365
 366 sub event_read_input_chunked { # unlikely...
 367         my ($self) = @_;
 368         my $input = $self->{env}->{'psgi.input'};
 369         my $sock = $self->{sock};
 370         my $len = $self->{input_left};
 371         $self->{input_left} = undef;
 372         my $rbuf = \($self->{rbuf});
 373
 374         while (1) { # chunk start
 375                 if ($len == CHUNK_ZEND) {
 376                         $$rbuf =~ s/\A\r\n//s and
 377                                 return app_dispatch($self, $input);
 378                         return quit($self, 400) if length($$rbuf) > 2;
 379                 }
 380                 if ($len == CHUNK_END) {
 381                         if ($$rbuf =~ s/\A\r\n//s) {
 382                                 $len = CHUNK_START;
 383                         } elsif (length($$rbuf) > 2) {
 384                                 return quit($self, 400);
 385                         }
 386                 }
 387                 if ($len == CHUNK_START) {
 388                         if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
 389                                 $len = hex $1;
 390                                 if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
 391                                         return quit($self, 413);
 392                                 }
 393                         } elsif (length($$rbuf) > CHUNK_MAX_HDR) {
 394                                 return quit($self, 400);
 395                         }
 396                         # will break from loop since $len >= 0
 397                 }
 398
 399                 if ($len < 0) { # chunk header is trickled, read more
 400                         my $off = length($$rbuf);
 401                         my $r = sysread($sock, $$rbuf, 8192, $off);
 402                         return recv_err($self, $r, $len) unless $r;
 403                         # (implicit) goto chunk_start if $r > 0;
 404                 }
 405                 $len = CHUNK_ZEND if $len == 0;
 406
 407                 # drain the current chunk
 408                 until ($len <= 0) {
 409                         if ($$rbuf ne '') {
 410                                 my $w = write_in_full($input, $rbuf, $len);
 411                                 return write_err($self) unless $w;
 412                                 $len -= $w;
 413                                 if ($len == 0) {
 414                                         # we may have leftover data to parse
 415                                         # in chunk
 416                                         $$rbuf = substr($$rbuf, $w);
 417                                         $len = CHUNK_END;
 418                                 } elsif ($len < 0) {
 419                                         die "BUG: len < 0: $len";
 420                                 } else {
 421                                         $$rbuf = '';
 422                                 }
 423                         }
 424                         if ($$rbuf eq '') {
 425                                 # read more of current chunk
 426                                 my $r = sysread($sock, $$rbuf, 8192);
 427                                 return recv_err($self, $r, $len) unless $r;
 428                         }
 429                 }
 430         }
 431 }
 432
 433 sub quit {
 434         my ($self, $status) = @_;
 435         my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
 436         $self->write($h);
 437         $self->close;
 438 }
 439
 440 # callbacks for Danga::Socket
 441
 442 sub event_hup { $_[0]->close }
 443 sub event_err { $_[0]->close }
 444
 445 sub close {
 446         my $self = shift;
 447         my $forward = $self->{forward};
 448         $forward->close if $forward;
 449         $self->{forward} = $self->{env} = undef;
 450         $self->SUPER::close(@_);
 451 }
 452
 453 # for graceful shutdown in PublicInbox::Daemon:
 454 sub busy () {
 455         my ($self) = @_;
 456         ($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
 457 }
 458
 459 1;