lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 # - ipc_do and ipc_worker_* is for a single worker/producer and uses pipes
   6 # - wq_do and wq_worker* is for a single producer and multiple workers,
   7 #   using SOCK_SEQPACKET for work distribution
   8 # use ipc_do when you need work done on a certain process
   9 # use wq_do when your work can be done on any idle worker
  10 package PublicInbox::IPC;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(Exporter);
  14 use Carp qw(confess croak);
  15 use PublicInbox::DS qw(dwaitpid);
  16 use PublicInbox::Spawn;
  17 use PublicInbox::OnDestroy;
  18 use PublicInbox::WQWorker;
  19 use Socket qw(AF_UNIX MSG_EOR SOCK_STREAM);
  20 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  21 use constant PIPE_BUF => $^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF();
  22 our @EXPORT_OK = qw(ipc_freeze ipc_thaw);
  23 my $WQ_MAX_WORKERS = 4096;
  24 my ($enc, $dec);
  25 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  26 # and eliminate method call overhead
  27 BEGIN {
  28         eval {
  29                 require Sereal::Encoder;
  30                 require Sereal::Decoder;
  31                 Sereal::Encoder->import('sereal_encode_with_object');
  32                 Sereal::Decoder->import('sereal_decode_with_object');
  33                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  34         };
  35 };
  36
  37 if ($enc && $dec) { # should be custom ops
  38         *ipc_freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  39         *ipc_thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  40 } else {
  41         eval { # some distros have Storable as a separate package from Perl
  42                 require Storable;
  43                 *ipc_freeze = \&Storable::freeze;
  44                 *ipc_thaw = \&Storable::thaw;
  45                 $enc = 1;
  46         } // warn("Storable (part of Perl) missing: $@\n");
  47 }
  48
  49 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  50 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  51         require PublicInbox::CmdIPC4;
  52         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  53         PublicInbox::CmdIPC4->can('send_cmd4');
  54 };
  55
  56 sub _get_rec ($) {
  57         my ($r) = @_;
  58         defined(my $len = <$r>) or return;
  59         chop($len) eq "\n" or croak "no LF byte in $len";
  60         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  61         $n == $len or croak "short read: $n != $len";
  62         ipc_thaw($buf);
  63 }
  64
  65 sub _pack_rec ($) {
  66         my ($ref) = @_;
  67         my $buf = ipc_freeze($ref);
  68         length($buf) . "\n" . $buf;
  69 }
  70
  71 sub _send_rec ($$) {
  72         my ($w, $ref) = @_;
  73         print $w _pack_rec($ref) or croak "print: $!";
  74 }
  75
  76 sub ipc_return ($$$) {
  77         my ($w, $ret, $exc) = @_;
  78         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  79 }
  80
  81 sub ipc_worker_loop ($$$) {
  82         my ($self, $r_req, $w_res) = @_;
  83         my ($rec, $wantarray, $sub, @args);
  84         local $/ = "\n";
  85         while ($rec = _get_rec($r_req)) {
  86                 ($wantarray, $sub, @args) = @$rec;
  87                 # no waiting if client doesn't care,
  88                 # this is the overwhelmingly likely case
  89                 if (!defined($wantarray)) {
  90                         eval { $self->$sub(@args) };
  91                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  92                 } elsif ($wantarray) {
  93                         my @ret = eval { $self->$sub(@args) };
  94                         ipc_return($w_res, \@ret, $@);
  95                 } else { # '' => wantscalar
  96                         my $ret = eval { $self->$sub(@args) };
  97                         ipc_return($w_res, \$ret, $@);
  98                 }
  99         }
 100 }
 101
 102 # starts a worker if Sereal or Storable is installed
 103 sub ipc_worker_spawn {
 104         my ($self, $ident, $oldset) = @_;
 105         return unless $enc; # no Sereal or Storable
 106         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
 107         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
 108         pipe(my ($r_req, $w_req)) or die "pipe: $!";
 109         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 110         my $sigset = $oldset // PublicInbox::DS::block_signals();
 111         $self->ipc_atfork_prepare;
 112         my $seed = rand(0xffffffff);
 113         my $pid = fork // die "fork: $!";
 114         if ($pid == 0) {
 115                 srand($seed);
 116                 eval { PublicInbox::DS->Reset };
 117                 delete @$self{qw(-wq_s1 -wq_s2 -wq_workers -wq_ppid)};
 118                 $w_req = $r_res = undef;
 119                 $w_res->autoflush(1);
 120                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 121                 local $0 = $ident;
 122                 PublicInbox::DS::sig_setmask($sigset);
 123                 # ensure we properly exit even if warn() dies:
 124                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 125                 eval {
 126                         my $on_destroy = $self->ipc_atfork_child;
 127                         local %SIG = %SIG;
 128                         ipc_worker_loop($self, $r_req, $w_res);
 129                 };
 130                 die "worker $ident PID:$$ died: $@\n" if $@;
 131                 undef $end; # trigger exit
 132         }
 133         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 134         $r_req = $w_res = undef;
 135         $w_req->autoflush(1);
 136         $self->{-ipc_req} = $w_req;
 137         $self->{-ipc_res} = $r_res;
 138         $self->{-ipc_ppid} = $$;
 139         $self->{-ipc_pid} = $pid;
 140 }
 141
 142 sub ipc_worker_reap { # dwaitpid callback
 143         my ($args, $pid) = @_;
 144         return if !$?;
 145         # TERM(15) is our default exit signal, PIPE(13) is likely w/ pager
 146         my $s = $? & 127;
 147         warn "PID:$pid died with \$?=$?\n" if $s != 15 && $s != 13;
 148 }
 149
 150 sub wq_wait_old {
 151         my ($self, $args) = @_;
 152         my $pids = delete $self->{"-wq_old_pids.$$"} or return;
 153         dwaitpid($_, \&ipc_worker_reap, [$self, $args]) for @$pids;
 154 }
 155
 156 # for base class, override in sub classes
 157 sub ipc_atfork_prepare {}
 158
 159 sub wq_atexit_child {}
 160
 161 sub ipc_atfork_child {
 162         my ($self) = @_;
 163         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 164         close($_) for @$io;
 165         undef;
 166 }
 167
 168 # idempotent, can be called regardless of whether worker is active or not
 169 sub ipc_worker_stop {
 170         my ($self, $args) = @_;
 171         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 172         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 173         if (!$w_req && !$r_res) {
 174                 die "unexpected PID:$pid without IPC pipes" if $pid;
 175                 return; # idempotent
 176         }
 177         die 'no PID with IPC pipes' unless $pid;
 178         $w_req = $r_res = undef;
 179
 180         return if $$ != $ppid;
 181         dwaitpid($pid, \&ipc_worker_reap, [$self, $args]);
 182 }
 183
 184 # use this if we have multiple readers reading curl or "pigz -dc"
 185 # and writing to the same store
 186 sub ipc_lock_init {
 187         my ($self, $f) = @_;
 188         require PublicInbox::Lock;
 189         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 190 }
 191
 192 sub ipc_async_wait ($$) {
 193         my ($self, $max) = @_; # max == -1 to wait for all
 194         my $aif = $self->{-async_inflight} or return;
 195         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 196         while (my ($sub, $bytes, $cb, $cb_arg) = splice(@$aif, 0, 4)) {
 197                 my $ret = _get_rec($r_res) //
 198                         die "no response on $sub (req.size=$bytes)";
 199                 $self->{-async_inflight_bytes} -= $bytes;
 200
 201                 eval { $cb->($cb_arg, $ret) };
 202                 warn "E: $sub callback error: $@\n" if $@;
 203                 return if --$max == 0;
 204         }
 205 }
 206
 207 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 208 sub ipc_do {
 209         my ($self, $sub, @args) = @_;
 210         if (my $w_req = $self->{-ipc_req}) { # run in worker
 211                 my $ipc_lock = $self->{-ipc_lock};
 212                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 213                 if (defined(wantarray)) {
 214                         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 215                         ipc_async_wait($self, -1);
 216                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 217                         my $ret = _get_rec($r_res) // die "no response on $sub";
 218                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 219                         wantarray ? @$ret : $$ret;
 220                 } else { # likely, fire-and-forget into pipe
 221                         _send_rec($w_req, [ undef , $sub, @args ]);
 222                 }
 223         } else { # run locally
 224                 $self->$sub(@args);
 225         }
 226 }
 227
 228 sub ipc_async {
 229         my ($self, $sub, $sub_args, $cb, $cb_arg) = @_;
 230         if (my $w_req = $self->{-ipc_req}) { # run in worker
 231                 my $rec = _pack_rec([ 1, $sub, @$sub_args ]);
 232                 my $cur_bytes = \($self->{-async_inflight_bytes} //= 0);
 233                 while (($$cur_bytes + length($rec)) > PIPE_BUF) {
 234                         ipc_async_wait($self, 1);
 235                 }
 236                 my $ipc_lock = $self->{-ipc_lock};
 237                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 238                 print $w_req $rec or croak "print: $!";
 239                 $$cur_bytes += length($rec);
 240                 push @{$self->{-async_inflight}},
 241                                 $sub, length($rec), $cb, $cb_arg;
 242         } else {
 243                 my $ret = [ eval { $self->$sub(@$sub_args) } ];
 244                 if (my $exc = $@) {
 245                         $ret = ( bless(\$exc, 'PublicInbox::IPC::Die') );
 246                 }
 247                 eval { $cb->($cb_arg, $ret) };
 248                 warn "E: $sub callback error: $@\n" if $@;
 249         }
 250 }
 251
 252 # needed when there's multiple IPC workers and the parent forking
 253 # causes newer siblings to inherit older siblings sockets
 254 sub ipc_sibling_atfork_child {
 255         my ($self) = @_;
 256         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 257         delete(@$self{qw(-ipc_req -ipc_res)});
 258         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 259 }
 260
 261 sub recv_and_run {
 262         my ($self, $s2, $len, $full_stream) = @_;
 263         my @fds = $recv_cmd->($s2, my $buf, $len);
 264         return if scalar(@fds) && !defined($fds[0]);
 265         my $n = length($buf) or return 0;
 266         my $nfd = 0;
 267         for my $fd (@fds) {
 268                 if (open(my $cmdfh, '+<&=', $fd)) {
 269                         $self->{$nfd++} = $cmdfh;
 270                         $cmdfh->autoflush(1);
 271                 } else {
 272                         die "$$ open(+<&=$fd) (FD:$nfd): $!";
 273                 }
 274         }
 275         while ($full_stream && $n < $len) {
 276                 my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
 277                 croak "read EOF after $n/$len bytes" if $r == 0;
 278                 $n = length($buf);
 279         }
 280         # Sereal dies on truncated data, Storable returns undef
 281         my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
 282         undef $buf;
 283         my $sub = shift @$args;
 284         eval { $self->$sub(@$args) };
 285         warn "$$ wq_worker: $@" if $@;
 286         delete @$self{0..($nfd-1)};
 287         $n;
 288 }
 289
 290 sub wq_worker_loop ($) {
 291         my ($self) = @_;
 292         my $wqw = PublicInbox::WQWorker->new($self);
 293         PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
 294         PublicInbox::DS->EventLoop;
 295         PublicInbox::DS->Reset;
 296 }
 297
 298 sub do_sock_stream { # via wq_do, for big requests
 299         my ($self, $len) = @_;
 300         recv_and_run($self, delete $self->{0}, $len, 1);
 301 }
 302
 303 sub wq_do { # always async
 304         my ($self, $sub, $ios, @args) = @_;
 305         if (my $s1 = $self->{-wq_s1}) { # run in worker
 306                 my $fds = [ map { fileno($_) } @$ios ];
 307                 my $buf = ipc_freeze([$sub, @args]);
 308                 my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
 309                 return if defined($n); # likely
 310                 croak "sendmsg: $! (check RLIMIT_NOFILE)" if $!{ETOOMANYREFS};
 311                 croak "sendmsg: $!" if !$!{EMSGSIZE};
 312                 socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
 313                         croak "socketpair: $!";
 314                 $n = $send_cmd->($s1, [ fileno($r) ],
 315                                 ipc_freeze(['do_sock_stream', length($buf)]),
 316                                 MSG_EOR) // croak "sendmsg: $!";
 317                 undef $r;
 318                 $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
 319                 while ($n < length($buf)) {
 320                         my $x = syswrite($w, $buf, length($buf) - $n, $n) //
 321                                         croak "syswrite: $!";
 322                         croak "syswrite wrote 0 bytes" if $x == 0;
 323                         $n += $x;
 324                 }
 325         } else {
 326                 @$self{0..$#$ios} = @$ios;
 327                 eval { $self->$sub(@args) };
 328                 warn "wq_do: $@" if $@;
 329                 delete @$self{0..$#$ios}; # don't close
 330         }
 331 }
 332
 333 sub _wq_worker_start ($$$) {
 334         my ($self, $oldset, $fields) = @_;
 335         my $seed = rand(0xffffffff);
 336         my $pid = fork // die "fork: $!";
 337         if ($pid == 0) {
 338                 srand($seed);
 339                 eval { PublicInbox::DS->Reset };
 340                 delete @$self{qw(-wq_s1 -wq_workers -wq_ppid)};
 341                 $SIG{$_} = 'IGNORE' for (qw(PIPE));
 342                 $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
 343                 local $0 = $self->{-wq_ident};
 344                 PublicInbox::DS::sig_setmask($oldset);
 345                 # ensure we properly exit even if warn() dies:
 346                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 347                 eval {
 348                         $fields //= {};
 349                         local @$self{keys %$fields} = values(%$fields);
 350                         my $on_destroy = $self->ipc_atfork_child;
 351                         local %SIG = %SIG;
 352                         wq_worker_loop($self);
 353                 };
 354                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 355                 undef $end; # trigger exit
 356         } else {
 357                 $self->{-wq_workers}->{$pid} = \undef;
 358         }
 359 }
 360
 361 # starts workqueue workers if Sereal or Storable is installed
 362 sub wq_workers_start {
 363         my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
 364         ($enc && $send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 365         return if $self->{-wq_s1}; # idempotent
 366         $self->{-wq_s1} = $self->{-wq_s2} = undef;
 367         socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
 368                 die "socketpair: $!";
 369         $self->ipc_atfork_prepare;
 370         $nr_workers //= 4;
 371         $nr_workers = $WQ_MAX_WORKERS if $nr_workers > $WQ_MAX_WORKERS;
 372         my $sigset = $oldset // PublicInbox::DS::block_signals();
 373         $self->{-wq_workers} = {};
 374         $self->{-wq_ident} = $ident;
 375         _wq_worker_start($self, $sigset, $fields) for (1..$nr_workers);
 376         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 377         $self->{-wq_ppid} = $$;
 378 }
 379
 380 sub wq_worker_incr { # SIGTTIN handler
 381         my ($self, $oldset, $fields) = @_;
 382         $self->{-wq_s2} or return;
 383         return if wq_workers($self) >= $WQ_MAX_WORKERS;
 384         $self->ipc_atfork_prepare;
 385         my $sigset = $oldset // PublicInbox::DS::block_signals();
 386         _wq_worker_start($self, $sigset, $fields);
 387         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 388 }
 389
 390 sub wq_exit { # wakes up wq_worker_decr_wait
 391         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 392         exit;
 393 }
 394
 395 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 396         my ($self) = @_;
 397         return unless wq_workers($self);
 398         my $s2 = $self->{-wq_s2} // die 'BUG: no wq_s2';
 399         $self->wq_do('wq_exit', [ $s2, $s2, $s2 ]);
 400         # caller must call wq_worker_decr_wait in main loop
 401 }
 402
 403 sub wq_worker_decr_wait {
 404         my ($self, $timeout) = @_;
 405         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 406         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 407         vec(my $rin = '', fileno($s1), 1) = 1;
 408         select(my $rout = $rin, undef, undef, $timeout) or
 409                 croak 'timed out waiting for wq_exit';
 410         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 411         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 412         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 413         dwaitpid($pid, \&ipc_worker_reap, $self);
 414 }
 415
 416 # set or retrieve number of workers
 417 sub wq_workers {
 418         my ($self, $nr) = @_;
 419         my $cur = $self->{-wq_workers} or return;
 420         if (defined $nr) {
 421                 while (scalar(keys(%$cur)) > $nr) {
 422                         $self->wq_worker_decr;
 423                         $self->wq_worker_decr_wait;
 424                 }
 425                 $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
 426         }
 427         scalar(keys(%$cur));
 428 }
 429
 430 sub wq_close {
 431         my ($self, $nohang) = @_;
 432         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 433         my $ppid = delete $self->{-wq_ppid} or return;
 434         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 435         return if $ppid != $$; # can't reap siblings or parents
 436         my @pids = map { $_ + 0 } keys %$workers;
 437         if ($nohang) {
 438                 push @{$self->{"-wq_old_pids.$$"}}, @pids;
 439         } else {
 440                 dwaitpid($_, \&ipc_worker_reap, $self) for @pids;
 441         }
 442 }
 443
 444 sub wq_kill_old {
 445         my ($self) = @_;
 446         my $pids = $self->{"-wq_old_pids.$$"} or return;
 447         kill 'TERM', @$pids;
 448 }
 449
 450 sub wq_kill {
 451         my ($self, $sig) = @_;
 452         my $workers = $self->{-wq_workers} or return;
 453         kill($sig // 'TERM', keys %$workers);
 454 }
 455
 456 sub WQ_MAX_WORKERS { $WQ_MAX_WORKERS }
 457
 458 sub DESTROY {
 459         my ($self) = @_;
 460         my $ppid = $self->{-wq_ppid};
 461         wq_kill($self) if $ppid && $ppid == $$;
 462         wq_close($self);
 463         wq_wait_old($self);
 464         ipc_worker_stop($self);
 465 }
 466
 467 # Sereal doesn't have dclone
 468 sub deep_clone { ipc_thaw(ipc_freeze($_[-1])) }
 469
 470 sub detect_nproc () {
 471         # _SC_NPROCESSORS_ONLN = 84 on both Linux glibc and musl
 472         return POSIX::sysconf(84) if $^O eq 'linux';
 473         return POSIX::sysconf(58) if $^O eq 'freebsd';
 474         # TODO: more OSes
 475
 476         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
 477         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
 478                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
 479         }
 480         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
 481                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
 482         }
 483
 484         # should we bother with `sysctl hw.ncpu`?  Those only give
 485         # us total processor count, not online processor count.
 486         undef
 487 }
 488
 489 1;