lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 # - ipc_do and ipc_worker_* is for a single worker/producer and uses pipes
   6 # - wq_do and wq_worker* is for a single producer and multiple workers,
   7 #   using SOCK_SEQPACKET for work distribution
   8 # use ipc_do when you need work done on a certain process
   9 # use wq_do when your work can be done on any idle worker
  10 package PublicInbox::IPC;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(Exporter);
  14 use Carp qw(croak);
  15 use PublicInbox::DS qw(dwaitpid);
  16 use PublicInbox::Spawn;
  17 use PublicInbox::OnDestroy;
  18 use PublicInbox::WQWorker;
  19 use Socket qw(AF_UNIX MSG_EOR SOCK_STREAM);
  20 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  21 use constant PIPE_BUF => $^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF();
  22 our @EXPORT_OK = qw(ipc_freeze ipc_thaw);
  23 my $WQ_MAX_WORKERS = 4096;
  24 my ($enc, $dec);
  25 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  26 # and eliminate method call overhead
  27 BEGIN {
  28         eval {
  29                 require Sereal::Encoder;
  30                 require Sereal::Decoder;
  31                 Sereal::Encoder->import('sereal_encode_with_object');
  32                 Sereal::Decoder->import('sereal_decode_with_object');
  33                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  34         };
  35 };
  36
  37 if ($enc && $dec) { # should be custom ops
  38         *ipc_freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  39         *ipc_thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  40 } else {
  41         require Storable;
  42         *ipc_freeze = \&Storable::freeze;
  43         *ipc_thaw = \&Storable::thaw;
  44 }
  45
  46 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  47 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  48         require PublicInbox::CmdIPC4;
  49         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  50         PublicInbox::CmdIPC4->can('send_cmd4');
  51 };
  52
  53 sub _get_rec ($) {
  54         my ($r) = @_;
  55         defined(my $len = <$r>) or return;
  56         chop($len) eq "\n" or croak "no LF byte in $len";
  57         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  58         $n == $len or croak "short read: $n != $len";
  59         ipc_thaw($buf);
  60 }
  61
  62 sub _pack_rec ($) {
  63         my ($ref) = @_;
  64         my $buf = ipc_freeze($ref);
  65         length($buf) . "\n" . $buf;
  66 }
  67
  68 sub _send_rec ($$) {
  69         my ($w, $ref) = @_;
  70         print $w _pack_rec($ref) or croak "print: $!";
  71 }
  72
  73 sub ipc_return ($$$) {
  74         my ($w, $ret, $exc) = @_;
  75         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  76 }
  77
  78 sub ipc_worker_loop ($$$) {
  79         my ($self, $r_req, $w_res) = @_;
  80         my ($rec, $wantarray, $sub, @args);
  81         local $/ = "\n";
  82         while ($rec = _get_rec($r_req)) {
  83                 ($wantarray, $sub, @args) = @$rec;
  84                 # no waiting if client doesn't care,
  85                 # this is the overwhelmingly likely case
  86                 if (!defined($wantarray)) {
  87                         eval { $self->$sub(@args) };
  88                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  89                 } elsif ($wantarray) {
  90                         my @ret = eval { $self->$sub(@args) };
  91                         ipc_return($w_res, \@ret, $@);
  92                 } else { # '' => wantscalar
  93                         my $ret = eval { $self->$sub(@args) };
  94                         ipc_return($w_res, \$ret, $@);
  95                 }
  96         }
  97 }
  98
  99 # starts a worker if Sereal or Storable is installed
 100 sub ipc_worker_spawn {
 101         my ($self, $ident, $oldset, $fields) = @_;
 102         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
 103         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
 104         pipe(my ($r_req, $w_req)) or die "pipe: $!";
 105         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 106         my $sigset = $oldset // PublicInbox::DS::block_signals();
 107         $self->ipc_atfork_prepare;
 108         my $seed = rand(0xffffffff);
 109         my $pid = fork // die "fork: $!";
 110         if ($pid == 0) {
 111                 srand($seed);
 112                 eval { PublicInbox::DS->Reset };
 113                 delete @$self{qw(-wq_s1 -wq_s2 -wq_workers -wq_ppid)};
 114                 $w_req = $r_res = undef;
 115                 $w_res->autoflush(1);
 116                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 117                 local $0 = $ident;
 118                 PublicInbox::DS::sig_setmask($sigset);
 119                 # ensure we properly exit even if warn() dies:
 120                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 121                 eval {
 122                         $fields //= {};
 123                         local @$self{keys %$fields} = values(%$fields);
 124                         my $on_destroy = $self->ipc_atfork_child;
 125                         local %SIG = %SIG;
 126                         ipc_worker_loop($self, $r_req, $w_res);
 127                 };
 128                 warn "worker $ident PID:$$ died: $@\n" if $@;
 129                 undef $end; # trigger exit
 130         }
 131         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 132         $r_req = $w_res = undef;
 133         $w_req->autoflush(1);
 134         $self->{-ipc_req} = $w_req;
 135         $self->{-ipc_res} = $r_res;
 136         $self->{-ipc_ppid} = $$;
 137         $self->{-ipc_pid} = $pid;
 138 }
 139
 140 sub ipc_worker_reap { # dwaitpid callback
 141         my ($args, $pid) = @_;
 142         return if !$?;
 143         # TERM(15) is our default exit signal, PIPE(13) is likely w/ pager
 144         my $s = $? & 127;
 145         warn "PID:$pid died with \$?=$?\n" if $s != 15 && $s != 13;
 146 }
 147
 148 sub wq_wait_old {
 149         my ($self, @args) = @_;
 150         my $cb = ref($args[0]) eq 'CODE' ? shift(@args) : \&ipc_worker_reap;
 151         my $pids = delete $self->{"-wq_old_pids.$$"} or return;
 152         dwaitpid($_, $cb, [$self, @args]) for @$pids;
 153 }
 154
 155 # for base class, override in sub classes
 156 sub ipc_atfork_prepare {}
 157
 158 sub wq_atexit_child {}
 159
 160 sub ipc_atfork_child {
 161         my ($self) = @_;
 162         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 163         close($_) for @$io;
 164         undef;
 165 }
 166
 167 # idempotent, can be called regardless of whether worker is active or not
 168 sub ipc_worker_stop {
 169         my ($self, $args) = @_;
 170         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 171         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 172         if (!$w_req && !$r_res) {
 173                 die "unexpected PID:$pid without IPC pipes" if $pid;
 174                 return; # idempotent
 175         }
 176         die 'no PID with IPC pipes' unless $pid;
 177         $w_req = $r_res = undef;
 178
 179         return if $$ != $ppid;
 180         dwaitpid($pid, \&ipc_worker_reap, [$self, $args]);
 181 }
 182
 183 # use this if we have multiple readers reading curl or "pigz -dc"
 184 # and writing to the same store
 185 sub ipc_lock_init {
 186         my ($self, $f) = @_;
 187         require PublicInbox::Lock;
 188         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 189 }
 190
 191 sub ipc_async_wait ($$) {
 192         my ($self, $max) = @_; # max == -1 to wait for all
 193         my $aif = $self->{-async_inflight} or return;
 194         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 195         while (my ($sub, $bytes, $cb, $cb_arg) = splice(@$aif, 0, 4)) {
 196                 my $ret = _get_rec($r_res) //
 197                         die "no response on $sub (req.size=$bytes)";
 198                 $self->{-async_inflight_bytes} -= $bytes;
 199
 200                 eval { $cb->($cb_arg, $ret) };
 201                 warn "E: $sub callback error: $@\n" if $@;
 202                 return if --$max == 0;
 203         }
 204 }
 205
 206 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 207 sub ipc_do {
 208         my ($self, $sub, @args) = @_;
 209         if (my $w_req = $self->{-ipc_req}) { # run in worker
 210                 my $ipc_lock = $self->{-ipc_lock};
 211                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 212                 if (defined(wantarray)) {
 213                         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 214                         ipc_async_wait($self, -1);
 215                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 216                         my $ret = _get_rec($r_res) // die "no response on $sub";
 217                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 218                         wantarray ? @$ret : $$ret;
 219                 } else { # likely, fire-and-forget into pipe
 220                         _send_rec($w_req, [ undef , $sub, @args ]);
 221                 }
 222         } else { # run locally
 223                 $self->$sub(@args);
 224         }
 225 }
 226
 227 sub ipc_async {
 228         my ($self, $sub, $sub_args, $cb, $cb_arg) = @_;
 229         if (my $w_req = $self->{-ipc_req}) { # run in worker
 230                 my $rec = _pack_rec([ 1, $sub, @$sub_args ]);
 231                 my $cur_bytes = \($self->{-async_inflight_bytes} //= 0);
 232                 while (($$cur_bytes + length($rec)) > PIPE_BUF) {
 233                         ipc_async_wait($self, 1);
 234                 }
 235                 my $ipc_lock = $self->{-ipc_lock};
 236                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 237                 print $w_req $rec or croak "print: $!";
 238                 $$cur_bytes += length($rec);
 239                 push @{$self->{-async_inflight}},
 240                                 $sub, length($rec), $cb, $cb_arg;
 241         } else {
 242                 my $ret = [ eval { $self->$sub(@$sub_args) } ];
 243                 if (my $exc = $@) {
 244                         $ret = ( bless(\$exc, 'PublicInbox::IPC::Die') );
 245                 }
 246                 eval { $cb->($cb_arg, $ret) };
 247                 warn "E: $sub callback error: $@\n" if $@;
 248         }
 249 }
 250
 251 # needed when there's multiple IPC workers and the parent forking
 252 # causes newer siblings to inherit older siblings sockets
 253 sub ipc_sibling_atfork_child {
 254         my ($self) = @_;
 255         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 256         delete(@$self{qw(-ipc_req -ipc_res)});
 257         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 258 }
 259
 260 sub recv_and_run {
 261         my ($self, $s2, $len, $full_stream) = @_;
 262         my @fds = $recv_cmd->($s2, my $buf, $len);
 263         return if scalar(@fds) && !defined($fds[0]);
 264         my $n = length($buf) or return 0;
 265         my $nfd = 0;
 266         for my $fd (@fds) {
 267                 if (open(my $cmdfh, '+<&=', $fd)) {
 268                         $self->{$nfd++} = $cmdfh;
 269                         $cmdfh->autoflush(1);
 270                 } else {
 271                         die "$$ open(+<&=$fd) (FD:$nfd): $!";
 272                 }
 273         }
 274         while ($full_stream && $n < $len) {
 275                 my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
 276                 croak "read EOF after $n/$len bytes" if $r == 0;
 277                 $n = length($buf);
 278         }
 279         # Sereal dies on truncated data, Storable returns undef
 280         my $args = ipc_thaw($buf) // die "thaw error on buffer of size: $n";
 281         undef $buf;
 282         my $sub = shift @$args;
 283         eval { $self->$sub(@$args) };
 284         warn "$$ wq_worker: $@" if $@;
 285         delete @$self{0..($nfd-1)};
 286         $n;
 287 }
 288
 289 sub wq_worker_loop ($) {
 290         my ($self) = @_;
 291         my $wqw = PublicInbox::WQWorker->new($self);
 292         PublicInbox::DS->SetPostLoopCallback(sub { $wqw->{sock} });
 293         PublicInbox::DS->EventLoop;
 294         PublicInbox::DS->Reset;
 295 }
 296
 297 sub do_sock_stream { # via wq_do, for big requests
 298         my ($self, $len) = @_;
 299         recv_and_run($self, delete $self->{0}, $len, 1);
 300 }
 301
 302 sub wq_do { # always async
 303         my ($self, $sub, $ios, @args) = @_;
 304         if (my $s1 = $self->{-wq_s1}) { # run in worker
 305                 my $fds = [ map { fileno($_) } @$ios ];
 306                 my $buf = ipc_freeze([$sub, @args]);
 307                 my $n = $send_cmd->($s1, $fds, $buf, MSG_EOR);
 308                 return if defined($n); # likely
 309                 croak "sendmsg: $! (check RLIMIT_NOFILE)" if $!{ETOOMANYREFS};
 310                 croak "sendmsg: $!" if !$!{EMSGSIZE};
 311                 socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
 312                         croak "socketpair: $!";
 313                 $n = $send_cmd->($s1, [ fileno($r) ],
 314                                 ipc_freeze(['do_sock_stream', length($buf)]),
 315                                 MSG_EOR) // croak "sendmsg: $!";
 316                 undef $r;
 317                 $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
 318                 while ($n < length($buf)) {
 319                         my $x = syswrite($w, $buf, length($buf) - $n, $n) //
 320                                         croak "syswrite: $!";
 321                         croak "syswrite wrote 0 bytes" if $x == 0;
 322                         $n += $x;
 323                 }
 324         } else {
 325                 @$self{0..$#$ios} = @$ios;
 326                 eval { $self->$sub(@args) };
 327                 warn "wq_do: $@" if $@;
 328                 delete @$self{0..$#$ios}; # don't close
 329         }
 330 }
 331
 332 sub _wq_worker_start ($$$) {
 333         my ($self, $oldset, $fields) = @_;
 334         my $seed = rand(0xffffffff);
 335         my $pid = fork // die "fork: $!";
 336         if ($pid == 0) {
 337                 srand($seed);
 338                 eval { PublicInbox::DS->Reset };
 339                 delete @$self{qw(-wq_s1 -wq_workers -wq_ppid)};
 340                 $SIG{$_} = 'IGNORE' for (qw(PIPE));
 341                 $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
 342                 local $0 = $self->{-wq_ident};
 343                 PublicInbox::DS::sig_setmask($oldset);
 344                 # ensure we properly exit even if warn() dies:
 345                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 346                 eval {
 347                         $fields //= {};
 348                         local @$self{keys %$fields} = values(%$fields);
 349                         my $on_destroy = $self->ipc_atfork_child;
 350                         local %SIG = %SIG;
 351                         wq_worker_loop($self);
 352                 };
 353                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 354                 undef $end; # trigger exit
 355         } else {
 356                 $self->{-wq_workers}->{$pid} = \undef;
 357         }
 358 }
 359
 360 # starts workqueue workers if Sereal or Storable is installed
 361 sub wq_workers_start {
 362         my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
 363         ($send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 364         return if $self->{-wq_s1}; # idempotent
 365         $self->{-wq_s1} = $self->{-wq_s2} = undef;
 366         socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
 367                 die "socketpair: $!";
 368         $self->ipc_atfork_prepare;
 369         $nr_workers //= 4;
 370         $nr_workers = $WQ_MAX_WORKERS if $nr_workers > $WQ_MAX_WORKERS;
 371         my $sigset = $oldset // PublicInbox::DS::block_signals();
 372         $self->{-wq_workers} = {};
 373         $self->{-wq_ident} = $ident;
 374         _wq_worker_start($self, $sigset, $fields) for (1..$nr_workers);
 375         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 376         $self->{-wq_ppid} = $$;
 377 }
 378
 379 sub wq_worker_incr { # SIGTTIN handler
 380         my ($self, $oldset, $fields) = @_;
 381         $self->{-wq_s2} or return;
 382         return if wq_workers($self) >= $WQ_MAX_WORKERS;
 383         $self->ipc_atfork_prepare;
 384         my $sigset = $oldset // PublicInbox::DS::block_signals();
 385         _wq_worker_start($self, $sigset, $fields);
 386         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 387 }
 388
 389 sub wq_exit { # wakes up wq_worker_decr_wait
 390         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 391         exit;
 392 }
 393
 394 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 395         my ($self) = @_;
 396         return unless wq_workers($self);
 397         my $s2 = $self->{-wq_s2} // die 'BUG: no wq_s2';
 398         $self->wq_do('wq_exit', [ $s2, $s2, $s2 ]);
 399         # caller must call wq_worker_decr_wait in main loop
 400 }
 401
 402 sub wq_worker_decr_wait {
 403         my ($self, $timeout) = @_;
 404         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 405         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 406         vec(my $rin = '', fileno($s1), 1) = 1;
 407         select(my $rout = $rin, undef, undef, $timeout) or
 408                 croak 'timed out waiting for wq_exit';
 409         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 410         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 411         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 412         dwaitpid($pid, \&ipc_worker_reap, $self);
 413 }
 414
 415 # set or retrieve number of workers
 416 sub wq_workers {
 417         my ($self, $nr) = @_;
 418         my $cur = $self->{-wq_workers} or return;
 419         if (defined $nr) {
 420                 while (scalar(keys(%$cur)) > $nr) {
 421                         $self->wq_worker_decr;
 422                         $self->wq_worker_decr_wait;
 423                 }
 424                 $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
 425         }
 426         scalar(keys(%$cur));
 427 }
 428
 429 sub wq_close {
 430         my ($self, $nohang) = @_;
 431         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 432         my $ppid = delete $self->{-wq_ppid} or return;
 433         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 434         return if $ppid != $$; # can't reap siblings or parents
 435         my @pids = map { $_ + 0 } keys %$workers;
 436         if ($nohang) {
 437                 push @{$self->{"-wq_old_pids.$$"}}, @pids;
 438         } else {
 439                 dwaitpid($_, \&ipc_worker_reap, $self) for @pids;
 440         }
 441 }
 442
 443 sub wq_kill_old {
 444         my ($self) = @_;
 445         my $pids = $self->{"-wq_old_pids.$$"} or return;
 446         kill 'TERM', @$pids;
 447 }
 448
 449 sub wq_kill {
 450         my ($self, $sig) = @_;
 451         my $workers = $self->{-wq_workers} or return;
 452         kill($sig // 'TERM', keys %$workers);
 453 }
 454
 455 sub WQ_MAX_WORKERS { $WQ_MAX_WORKERS }
 456
 457 sub DESTROY {
 458         my ($self) = @_;
 459         my $ppid = $self->{-wq_ppid};
 460         wq_kill($self) if $ppid && $ppid == $$;
 461         wq_close($self);
 462         wq_wait_old($self);
 463         ipc_worker_stop($self);
 464 }
 465
 466 sub detect_nproc () {
 467         # _SC_NPROCESSORS_ONLN = 84 on both Linux glibc and musl
 468         return POSIX::sysconf(84) if $^O eq 'linux';
 469         return POSIX::sysconf(58) if $^O eq 'freebsd';
 470         # TODO: more OSes
 471
 472         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
 473         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
 474                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
 475         }
 476         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
 477                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
 478         }
 479
 480         # should we bother with `sysctl hw.ncpu`?  Those only give
 481         # us total processor count, not online processor count.
 482         undef
 483 }
 484
 485 1;