lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 # - ipc_do and ipc_worker_* is for a single worker/producer and uses pipes
   6 # - wq_do and wq_worker* is for a single producer and multiple workers,
   7 #   using SOCK_SEQPACKET for work distribution
   8 # use ipc_do when you need work done on a certain process
   9 # use wq_do when your work can be done on any idle worker
  10 package PublicInbox::IPC;
  11 use strict;
  12 use v5.10.1;
  13 use Carp qw(confess croak);
  14 use PublicInbox::DS qw(dwaitpid);
  15 use PublicInbox::Spawn;
  16 use PublicInbox::OnDestroy;
  17 use Socket qw(AF_UNIX MSG_EOR SOCK_STREAM);
  18 use Errno qw(EMSGSIZE);
  19 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  20 use constant PIPE_BUF => $^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF();
  21 my $WQ_MAX_WORKERS = 4096;
  22 my ($enc, $dec);
  23 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  24 # and eliminate method call overhead
  25 BEGIN {
  26         eval {
  27                 require Sereal::Encoder;
  28                 require Sereal::Decoder;
  29                 Sereal::Encoder->import('sereal_encode_with_object');
  30                 Sereal::Decoder->import('sereal_decode_with_object');
  31                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  32         };
  33 };
  34
  35 if ($enc && $dec) { # should be custom ops
  36         *freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  37         *thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  38 } else {
  39         eval { # some distros have Storable as a separate package from Perl
  40                 require Storable;
  41                 Storable->import(qw(freeze thaw));
  42                 $enc = 1;
  43         } // warn("Storable (part of Perl) missing: $@\n");
  44 }
  45
  46 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  47 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  48         require PublicInbox::CmdIPC4;
  49         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  50         PublicInbox::CmdIPC4->can('send_cmd4');
  51 };
  52
  53 sub _get_rec ($) {
  54         my ($r) = @_;
  55         defined(my $len = <$r>) or return;
  56         chop($len) eq "\n" or croak "no LF byte in $len";
  57         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  58         $n == $len or croak "short read: $n != $len";
  59         thaw($buf);
  60 }
  61
  62 sub _pack_rec ($) {
  63         my ($ref) = @_;
  64         my $buf = freeze($ref);
  65         length($buf) . "\n" . $buf;
  66 }
  67
  68 sub _send_rec ($$) {
  69         my ($w, $ref) = @_;
  70         print $w _pack_rec($ref) or croak "print: $!";
  71 }
  72
  73 sub ipc_return ($$$) {
  74         my ($w, $ret, $exc) = @_;
  75         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  76 }
  77
  78 sub ipc_worker_loop ($$$) {
  79         my ($self, $r_req, $w_res) = @_;
  80         my ($rec, $wantarray, $sub, @args);
  81         local $/ = "\n";
  82         while ($rec = _get_rec($r_req)) {
  83                 ($wantarray, $sub, @args) = @$rec;
  84                 # no waiting if client doesn't care,
  85                 # this is the overwhelmingly likely case
  86                 if (!defined($wantarray)) {
  87                         eval { $self->$sub(@args) };
  88                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  89                 } elsif ($wantarray) {
  90                         my @ret = eval { $self->$sub(@args) };
  91                         ipc_return($w_res, \@ret, $@);
  92                 } else { # '' => wantscalar
  93                         my $ret = eval { $self->$sub(@args) };
  94                         ipc_return($w_res, \$ret, $@);
  95                 }
  96         }
  97 }
  98
  99 # starts a worker if Sereal or Storable is installed
 100 sub ipc_worker_spawn {
 101         my ($self, $ident, $oldset) = @_;
 102         return unless $enc; # no Sereal or Storable
 103         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
 104         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
 105         pipe(my ($r_req, $w_req)) or die "pipe: $!";
 106         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 107         my $sigset = $oldset // PublicInbox::DS::block_signals();
 108         $self->ipc_atfork_prepare;
 109         my $seed = rand(0xffffffff);
 110         my $pid = fork // die "fork: $!";
 111         if ($pid == 0) {
 112                 srand($seed);
 113                 eval { PublicInbox::DS->Reset };
 114                 delete @$self{qw(-wq_s1 -wq_s2 -wq_workers -wq_ppid)};
 115                 $w_req = $r_res = undef;
 116                 $w_res->autoflush(1);
 117                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 118                 local $0 = $ident;
 119                 PublicInbox::DS::sig_setmask($sigset);
 120                 # ensure we properly exit even if warn() dies:
 121                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 122                 eval {
 123                         my $on_destroy = $self->ipc_atfork_child;
 124                         local %SIG = %SIG;
 125                         ipc_worker_loop($self, $r_req, $w_res);
 126                 };
 127                 die "worker $ident PID:$$ died: $@\n" if $@;
 128                 undef $end; # trigger exit
 129         }
 130         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 131         $r_req = $w_res = undef;
 132         $w_req->autoflush(1);
 133         $self->{-ipc_req} = $w_req;
 134         $self->{-ipc_res} = $r_res;
 135         $self->{-ipc_ppid} = $$;
 136         $self->{-ipc_pid} = $pid;
 137 }
 138
 139 sub ipc_worker_reap { # dwaitpid callback
 140         my ($self, $pid) = @_;
 141         # SIGTERM (15) is our default exit signal
 142         warn "PID:$pid died with \$?=$?\n" if $? && ($? & 127) != 15;
 143 }
 144
 145 sub wq_wait_old {
 146         my ($self) = @_;
 147         my $pids = delete $self->{"-wq_old_pids.$$"} or return;
 148         dwaitpid($_, \&ipc_worker_reap, $self) for @$pids;
 149 }
 150
 151 # for base class, override in sub classes
 152 sub ipc_atfork_prepare {}
 153
 154 sub ipc_atfork_child {
 155         my ($self) = @_;
 156         my $io = delete($self->{-ipc_atfork_child_close}) or return;
 157         close($_) for @$io;
 158         undef;
 159 }
 160
 161 # idempotent, can be called regardless of whether worker is active or not
 162 sub ipc_worker_stop {
 163         my ($self) = @_;
 164         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 165         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 166         if (!$w_req && !$r_res) {
 167                 die "unexpected PID:$pid without IPC pipes" if $pid;
 168                 return; # idempotent
 169         }
 170         die 'no PID with IPC pipes' unless $pid;
 171         $w_req = $r_res = undef;
 172
 173         return if $$ != $ppid;
 174         dwaitpid($pid, \&ipc_worker_reap, $self);
 175 }
 176
 177 # use this if we have multiple readers reading curl or "pigz -dc"
 178 # and writing to the same store
 179 sub ipc_lock_init {
 180         my ($self, $f) = @_;
 181         require PublicInbox::Lock;
 182         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 183 }
 184
 185 sub ipc_async_wait ($$) {
 186         my ($self, $max) = @_; # max == -1 to wait for all
 187         my $aif = $self->{-async_inflight} or return;
 188         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 189         while (my ($sub, $bytes, $cb, $cb_arg) = splice(@$aif, 0, 4)) {
 190                 my $ret = _get_rec($r_res) //
 191                         die "no response on $sub (req.size=$bytes)";
 192                 $self->{-async_inflight_bytes} -= $bytes;
 193
 194                 eval { $cb->($cb_arg, $ret) };
 195                 warn "E: $sub callback error: $@\n" if $@;
 196                 return if --$max == 0;
 197         }
 198 }
 199
 200 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 201 sub ipc_do {
 202         my ($self, $sub, @args) = @_;
 203         if (my $w_req = $self->{-ipc_req}) { # run in worker
 204                 my $ipc_lock = $self->{-ipc_lock};
 205                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 206                 if (defined(wantarray)) {
 207                         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 208                         ipc_async_wait($self, -1);
 209                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 210                         my $ret = _get_rec($r_res) // die "no response on $sub";
 211                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 212                         wantarray ? @$ret : $$ret;
 213                 } else { # likely, fire-and-forget into pipe
 214                         _send_rec($w_req, [ undef , $sub, @args ]);
 215                 }
 216         } else { # run locally
 217                 $self->$sub(@args);
 218         }
 219 }
 220
 221 sub ipc_async {
 222         my ($self, $sub, $sub_args, $cb, $cb_arg) = @_;
 223         if (my $w_req = $self->{-ipc_req}) { # run in worker
 224                 my $rec = _pack_rec([ 1, $sub, @$sub_args ]);
 225                 my $cur_bytes = \($self->{-async_inflight_bytes} //= 0);
 226                 while (($$cur_bytes + length($rec)) > PIPE_BUF) {
 227                         ipc_async_wait($self, 1);
 228                 }
 229                 my $ipc_lock = $self->{-ipc_lock};
 230                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 231                 print $w_req $rec or croak "print: $!";
 232                 $$cur_bytes += length($rec);
 233                 push @{$self->{-async_inflight}},
 234                                 $sub, length($rec), $cb, $cb_arg;
 235         } else {
 236                 my $ret = [ eval { $self->$sub(@$sub_args) } ];
 237                 if (my $exc = $@) {
 238                         $ret = ( bless(\$exc, 'PublicInbox::IPC::Die') );
 239                 }
 240                 eval { $cb->($cb_arg, $ret) };
 241                 warn "E: $sub callback error: $@\n" if $@;
 242         }
 243 }
 244
 245 # needed when there's multiple IPC workers and the parent forking
 246 # causes newer siblings to inherit older siblings sockets
 247 sub ipc_sibling_atfork_child {
 248         my ($self) = @_;
 249         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 250         delete(@$self{qw(-ipc_req -ipc_res)});
 251         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 252 }
 253
 254 sub _recv_and_run {
 255         my ($self, $s2, $len, $full_stream) = @_;
 256         my @fds = $recv_cmd->($s2, my $buf, $len);
 257         my $n = length($buf // '') or return;
 258         my $nfd = 0;
 259         for my $fd (@fds) {
 260                 if (open(my $cmdfh, '+<&=', $fd)) {
 261                         $self->{$nfd++} = $cmdfh;
 262                         $cmdfh->autoflush(1);
 263                 } else {
 264                         die "$$ open(+<&=$fd) (FD:$nfd): $!";
 265                 }
 266         }
 267         while ($full_stream && $n < $len) {
 268                 my $r = sysread($s2, $buf, $len - $n, $n) // croak "read: $!";
 269                 croak "read EOF after $n/$len bytes" if $r == 0;
 270                 $n = length($buf);
 271         }
 272         # Sereal dies on truncated data, Storable returns undef
 273         my $args = thaw($buf) // die "thaw error on buffer of size: $n";
 274         undef $buf;
 275         my $sub = shift @$args;
 276         eval { $self->$sub(@$args) };
 277         warn "$$ wq_worker: $@" if $@ && ref($@) ne 'PublicInbox::SIGPIPE';
 278         delete @$self{0..($nfd-1)};
 279         $n;
 280 }
 281
 282 sub wq_worker_loop ($) {
 283         my ($self) = @_;
 284         my $len = $self->{wq_req_len} // (4096 * 33);
 285         my $s2 = $self->{-wq_s2} // die 'BUG: no -wq_s2';
 286         1 while (_recv_and_run($self, $s2, $len));
 287 }
 288
 289 sub do_sock_stream { # via wq_do, for big requests
 290         my ($self, $len) = @_;
 291         _recv_and_run($self, delete $self->{0}, $len, 1);
 292 }
 293
 294 sub wq_do { # always async
 295         my ($self, $sub, $ios, @args) = @_;
 296         if (my $s1 = $self->{-wq_s1}) { # run in worker
 297                 my $fds = [ map { fileno($_) } @$ios ];
 298                 my $n = $send_cmd->($s1, $fds, freeze([$sub, @args]), MSG_EOR);
 299                 return if defined($n);
 300                 croak "sendmsg error: $!" if $! != EMSGSIZE;
 301                 socketpair(my $r, my $w, AF_UNIX, SOCK_STREAM, 0) or
 302                         croak "socketpair: $!";
 303                 my $buf = freeze([$sub, @args]);
 304                 $n = $send_cmd->($s1, [ fileno($r) ],
 305                                 freeze(['do_sock_stream', length($buf)]),
 306                                 MSG_EOR) // croak "sendmsg: $!";
 307                 undef $r;
 308                 $n = $send_cmd->($w, $fds, $buf, 0) // croak "sendmsg: $!";
 309                 while ($n < length($buf)) {
 310                         my $x = syswrite($w, $buf, length($buf) - $n, $n) //
 311                                         croak "syswrite: $!";
 312                         croak "syswrite wrote 0 bytes" if $x == 0;
 313                         $n += $x;
 314                 }
 315         } else {
 316                 @$self{0..$#$ios} = @$ios;
 317                 eval { $self->$sub(@args) };
 318                 warn "wq_do: $@" if $@ && ref($@) ne 'PublicInbox::SIGPIPE';
 319                 delete @$self{0..$#$ios}; # don't close
 320         }
 321 }
 322
 323 sub _wq_worker_start ($$$) {
 324         my ($self, $oldset, $fields) = @_;
 325         my $seed = rand(0xffffffff);
 326         my $pid = fork // die "fork: $!";
 327         if ($pid == 0) {
 328                 srand($seed);
 329                 eval { PublicInbox::DS->Reset };
 330                 delete @$self{qw(-wq_s1 -wq_workers -wq_ppid)};
 331                 @$self{keys %$fields} = values(%$fields) if $fields;
 332                 $SIG{$_} = 'IGNORE' for (qw(PIPE));
 333                 $SIG{$_} = 'DEFAULT' for (qw(TTOU TTIN TERM QUIT INT CHLD));
 334                 local $0 = $self->{-wq_ident};
 335                 PublicInbox::DS::sig_setmask($oldset);
 336                 # ensure we properly exit even if warn() dies:
 337                 my $end = PublicInbox::OnDestroy->new($$, sub { exit(!!$@) });
 338                 eval {
 339                         my $on_destroy = $self->ipc_atfork_child;
 340                         local %SIG = %SIG;
 341                         wq_worker_loop($self);
 342                 };
 343                 warn "worker $self->{-wq_ident} PID:$$ died: $@" if $@;
 344                 undef $end; # trigger exit
 345         } else {
 346                 $self->{-wq_workers}->{$pid} = \undef;
 347         }
 348 }
 349
 350 # starts workqueue workers if Sereal or Storable is installed
 351 sub wq_workers_start {
 352         my ($self, $ident, $nr_workers, $oldset, $fields) = @_;
 353         ($enc && $send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 354         return if $self->{-wq_s1}; # idempotent
 355         $self->{-wq_s1} = $self->{-wq_s2} = undef;
 356         socketpair($self->{-wq_s1}, $self->{-wq_s2}, AF_UNIX, $SEQPACKET, 0) or
 357                 die "socketpair: $!";
 358         $self->ipc_atfork_prepare;
 359         $nr_workers //= 4;
 360         $nr_workers = $WQ_MAX_WORKERS if $nr_workers > $WQ_MAX_WORKERS;
 361         my $sigset = $oldset // PublicInbox::DS::block_signals();
 362         $self->{-wq_workers} = {};
 363         $self->{-wq_ident} = $ident;
 364         _wq_worker_start($self, $sigset, $fields) for (1..$nr_workers);
 365         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 366         $self->{-wq_ppid} = $$;
 367 }
 368
 369 sub wq_worker_incr { # SIGTTIN handler
 370         my ($self, $oldset, $fields) = @_;
 371         $self->{-wq_s2} or return;
 372         return if wq_workers($self) >= $WQ_MAX_WORKERS;
 373         $self->ipc_atfork_prepare;
 374         my $sigset = $oldset // PublicInbox::DS::block_signals();
 375         _wq_worker_start($self, $sigset, $fields);
 376         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 377 }
 378
 379 sub wq_exit { # wakes up wq_worker_decr_wait
 380         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 381         exit;
 382 }
 383
 384 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 385         my ($self) = @_;
 386         return unless wq_workers($self);
 387         my $s2 = $self->{-wq_s2} // die 'BUG: no wq_s2';
 388         $self->wq_do('wq_exit', [ $s2, $s2, $s2 ]);
 389         # caller must call wq_worker_decr_wait in main loop
 390 }
 391
 392 sub wq_worker_decr_wait {
 393         my ($self, $timeout) = @_;
 394         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 395         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 396         vec(my $rin = '', fileno($s1), 1) = 1;
 397         select(my $rout = $rin, undef, undef, $timeout) or
 398                 croak 'timed out waiting for wq_exit';
 399         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 400         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 401         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 402         dwaitpid($pid, \&ipc_worker_reap, $self);
 403 }
 404
 405 # set or retrieve number of workers
 406 sub wq_workers {
 407         my ($self, $nr) = @_;
 408         my $cur = $self->{-wq_workers} or return;
 409         if (defined $nr) {
 410                 while (scalar(keys(%$cur)) > $nr) {
 411                         $self->wq_worker_decr;
 412                         $self->wq_worker_decr_wait;
 413                 }
 414                 $self->wq_worker_incr while scalar(keys(%$cur)) < $nr;
 415         }
 416         scalar(keys(%$cur));
 417 }
 418
 419 sub wq_close {
 420         my ($self, $nohang) = @_;
 421         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 422         my $ppid = delete $self->{-wq_ppid} or return;
 423         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 424         return if $ppid != $$; # can't reap siblings or parents
 425         my @pids = map { $_ + 0 } keys %$workers;
 426         if ($nohang) {
 427                 push @{$self->{"-wq_old_pids.$$"}}, @pids;
 428         } else {
 429                 dwaitpid($_, \&ipc_worker_reap, $self) for @pids;
 430         }
 431 }
 432
 433 sub wq_kill_old {
 434         my ($self) = @_;
 435         my $pids = $self->{"-wq_old_pids.$$"} or return;
 436         kill 'TERM', @$pids;
 437 }
 438
 439 sub wq_kill {
 440         my ($self, $sig) = @_;
 441         my $workers = $self->{-wq_workers} or return;
 442         kill($sig // 'TERM', keys %$workers);
 443 }
 444
 445 sub WQ_MAX_WORKERS { $WQ_MAX_WORKERS }
 446
 447 sub DESTROY {
 448         my ($self) = @_;
 449         my $ppid = $self->{-wq_ppid};
 450         wq_kill($self) if $ppid && $ppid == $$;
 451         wq_close($self);
 452         wq_wait_old($self);
 453         ipc_worker_stop($self);
 454 }
 455
 456 # Sereal doesn't have dclone
 457 sub deep_clone { thaw(freeze($_[-1])) }
 458
 459 1;