lib/PublicInbox/IPC.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # base class for remote IPC calls and workqueues, requires Storable or Sereal
   5 package PublicInbox::IPC;
   6 use strict;
   7 use v5.10.1;
   8 use Carp qw(confess croak);
   9 use PublicInbox::DS qw(dwaitpid);
  10 use PublicInbox::Spawn;
  11 use POSIX qw(WNOHANG);
  12 use Socket qw(AF_UNIX MSG_EOR);
  13 my $SEQPACKET = eval { Socket::SOCK_SEQPACKET() }; # portable enough?
  14 use constant PIPE_BUF => $^O eq 'linux' ? 4096 : POSIX::_POSIX_PIPE_BUF();
  15 my ($enc, $dec);
  16 # ->imports at BEGIN turns sereal_*_with_object into custom ops on 5.14+
  17 # and eliminate method call overhead
  18 BEGIN {
  19         eval {
  20                 require Sereal::Encoder;
  21                 require Sereal::Decoder;
  22                 Sereal::Encoder->import('sereal_encode_with_object');
  23                 Sereal::Decoder->import('sereal_decode_with_object');
  24                 ($enc, $dec) = (Sereal::Encoder->new, Sereal::Decoder->new);
  25         };
  26 };
  27
  28 if ($enc && $dec) { # should be custom ops
  29         *freeze = sub ($) { sereal_encode_with_object $enc, $_[0] };
  30         *thaw = sub ($) { sereal_decode_with_object $dec, $_[0], my $ret };
  31 } else {
  32         eval { # some distros have Storable as a separate package from Perl
  33                 require Storable;
  34                 Storable->import(qw(freeze thaw));
  35                 $enc = 1;
  36         } // warn("Storable (part of Perl) missing: $@\n");
  37 }
  38
  39 my $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  40 my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
  41         require PublicInbox::CmdIPC4;
  42         $recv_cmd //= PublicInbox::CmdIPC4->can('recv_cmd4');
  43         PublicInbox::CmdIPC4->can('send_cmd4');
  44 } // do {
  45         require PublicInbox::CmdIPC1;
  46         $recv_cmd = PublicInbox::CmdIPC1->can('recv_cmd1');
  47         PublicInbox::CmdIPC1->can('send_cmd1');
  48 };
  49
  50 sub _get_rec ($) {
  51         my ($r) = @_;
  52         defined(my $len = <$r>) or return;
  53         chop($len) eq "\n" or croak "no LF byte in $len";
  54         defined(my $n = read($r, my $buf, $len)) or croak "read error: $!";
  55         $n == $len or croak "short read: $n != $len";
  56         thaw($buf);
  57 }
  58
  59 sub _pack_rec ($) {
  60         my ($ref) = @_;
  61         my $buf = freeze($ref);
  62         length($buf) . "\n" . $buf;
  63 }
  64
  65 sub _send_rec ($$) {
  66         my ($w, $ref) = @_;
  67         print $w _pack_rec($ref) or croak "print: $!";
  68 }
  69
  70 sub ipc_return ($$$) {
  71         my ($w, $ret, $exc) = @_;
  72         _send_rec($w, $exc ? bless(\$exc, 'PublicInbox::IPC::Die') : $ret);
  73 }
  74
  75 sub ipc_worker_loop ($$$) {
  76         my ($self, $r_req, $w_res) = @_;
  77         my ($rec, $wantarray, $sub, @args);
  78         local $/ = "\n";
  79         while ($rec = _get_rec($r_req)) {
  80                 ($wantarray, $sub, @args) = @$rec;
  81                 # no waiting if client doesn't care,
  82                 # this is the overwhelmingly likely case
  83                 if (!defined($wantarray)) {
  84                         eval { $self->$sub(@args) };
  85                         warn "$$ die: $@ (from nowait $sub)\n" if $@;
  86                 } elsif ($wantarray) {
  87                         my @ret = eval { $self->$sub(@args) };
  88                         ipc_return($w_res, \@ret, $@);
  89                 } else { # '' => wantscalar
  90                         my $ret = eval { $self->$sub(@args) };
  91                         ipc_return($w_res, \$ret, $@);
  92                 }
  93         }
  94 }
  95
  96 # starts a worker if Sereal or Storable is installed
  97 sub ipc_worker_spawn {
  98         my ($self, $ident, $oldset) = @_;
  99         return unless $enc; # no Sereal or Storable
 100         return if ($self->{-ipc_ppid} // -1) == $$; # idempotent
 101         delete(@$self{qw(-ipc_req -ipc_res -ipc_ppid -ipc_pid)});
 102         pipe(my ($r_req, $w_req)) or die "pipe: $!";
 103         pipe(my ($r_res, $w_res)) or die "pipe: $!";
 104         my $sigset = $oldset // PublicInbox::DS::block_signals();
 105         my $parent = $$;
 106         $self->ipc_atfork_parent;
 107         defined(my $pid = fork) or die "fork: $!";
 108         if ($pid == 0) {
 109                 eval { PublicInbox::DS->Reset };
 110                 $self->{-ipc_parent_pid} = $parent;
 111                 $w_req = $r_res = undef;
 112                 $w_res->autoflush(1);
 113                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
 114                 local $0 = $ident;
 115                 PublicInbox::DS::sig_setmask($sigset);
 116                 my $on_destroy = $self->ipc_atfork_child;
 117                 eval { ipc_worker_loop($self, $r_req, $w_res) };
 118                 die "worker $ident PID:$$ died: $@\n" if $@;
 119                 exit;
 120         }
 121         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 122         $r_req = $w_res = undef;
 123         $w_req->autoflush(1);
 124         $self->{-ipc_req} = $w_req;
 125         $self->{-ipc_res} = $r_res;
 126         $self->{-ipc_ppid} = $$;
 127         $self->{-ipc_pid} = $pid;
 128 }
 129
 130 sub ipc_worker_reap { # dwaitpid callback
 131         my ($self, $pid) = @_;
 132         warn "PID:$pid died with \$?=$?\n" if $?;
 133 }
 134
 135 # for base class, override in sub classes
 136 sub ipc_atfork_parent {}
 137 sub ipc_atfork_child {}
 138
 139 # idempotent, can be called regardless of whether worker is active or not
 140 sub ipc_worker_stop {
 141         my ($self) = @_;
 142         my ($pid, $ppid) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 143         my ($w_req, $r_res) = delete(@$self{qw(-ipc_req -ipc_res)});
 144         if (!$w_req && !$r_res) {
 145                 die "unexpected PID:$pid without IPC pipes" if $pid;
 146                 return; # idempotent
 147         }
 148         die 'no PID with IPC pipes' unless $pid;
 149         $w_req = $r_res = undef;
 150
 151         return if $$ != $ppid;
 152         dwaitpid($pid, \&ipc_worker_reap, $self);
 153 }
 154
 155 # use this if we have multiple readers reading curl or "pigz -dc"
 156 # and writing to the same store
 157 sub ipc_lock_init {
 158         my ($self, $f) = @_;
 159         require PublicInbox::Lock;
 160         $self->{-ipc_lock} //= bless { lock_path => $f }, 'PublicInbox::Lock'
 161 }
 162
 163 sub ipc_async_wait ($$) {
 164         my ($self, $max) = @_; # max == -1 to wait for all
 165         my $aif = $self->{-async_inflight} or return;
 166         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 167         while (my ($sub, $bytes, $cb, $cb_arg) = splice(@$aif, 0, 4)) {
 168                 my $ret = _get_rec($r_res) //
 169                         die "no response on $sub (req.size=$bytes)";
 170                 $self->{-async_inflight_bytes} -= $bytes;
 171
 172                 eval { $cb->($cb_arg, $ret) };
 173                 warn "E: $sub callback error: $@\n" if $@;
 174                 return if --$max == 0;
 175         }
 176 }
 177
 178 # call $self->$sub(@args), on a worker if ipc_worker_spawn was used
 179 sub ipc_do {
 180         my ($self, $sub, @args) = @_;
 181         if (my $w_req = $self->{-ipc_req}) { # run in worker
 182                 my $ipc_lock = $self->{-ipc_lock};
 183                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 184                 if (defined(wantarray)) {
 185                         my $r_res = $self->{-ipc_res} or die 'BUG: no ipc_res';
 186                         ipc_async_wait($self, -1);
 187                         _send_rec($w_req, [ wantarray, $sub, @args ]);
 188                         my $ret = _get_rec($r_res) // die "no response on $sub";
 189                         die $$ret if ref($ret) eq 'PublicInbox::IPC::Die';
 190                         wantarray ? @$ret : $$ret;
 191                 } else { # likely, fire-and-forget into pipe
 192                         _send_rec($w_req, [ undef , $sub, @args ]);
 193                 }
 194         } else { # run locally
 195                 $self->$sub(@args);
 196         }
 197 }
 198
 199 sub ipc_async {
 200         my ($self, $sub, $sub_args, $cb, $cb_arg) = @_;
 201         if (my $w_req = $self->{-ipc_req}) { # run in worker
 202                 my $rec = _pack_rec([ 1, $sub, @$sub_args ]);
 203                 my $cur_bytes = \($self->{-async_inflight_bytes} //= 0);
 204                 while (($$cur_bytes + length($rec)) > PIPE_BUF) {
 205                         ipc_async_wait($self, 1);
 206                 }
 207                 my $ipc_lock = $self->{-ipc_lock};
 208                 my $lock = $ipc_lock ? $ipc_lock->lock_for_scope : undef;
 209                 print $w_req $rec or croak "print: $!";
 210                 $$cur_bytes += length($rec);
 211                 push @{$self->{-async_inflight}},
 212                                 $sub, length($rec), $cb, $cb_arg;
 213         } else {
 214                 my $ret = [ eval { $self->$sub(@$sub_args) } ];
 215                 if (my $exc = $@) {
 216                         $ret = ( bless(\$exc, 'PublicInbox::IPC::Die') );
 217                 }
 218                 eval { $cb->($cb_arg, $ret) };
 219                 warn "E: $sub callback error: $@\n" if $@;
 220         }
 221 }
 222
 223 # needed when there's multiple IPC workers and the parent forking
 224 # causes newer siblings to inherit older siblings sockets
 225 sub ipc_sibling_atfork_child {
 226         my ($self) = @_;
 227         my ($pid, undef) = delete(@$self{qw(-ipc_pid -ipc_ppid)});
 228         delete(@$self{qw(-ipc_req -ipc_res)});
 229         $pid == $$ and die "BUG: $$ ipc_atfork_child called on itself";
 230 }
 231
 232 sub wq_worker_loop ($) {
 233         my ($self) = @_;
 234         my $buf;
 235         my $len = $self->{wq_req_len} // (4096 * 33);
 236         my ($rec, $sub, @args);
 237         my $s2 = $self->{-wq_s2} // die 'BUG: no -wq_s2';
 238         until ($self->{-wq_quit}) {
 239                 my (@fds) = $recv_cmd->($s2, $buf, $len) or return; # EOF
 240                 my $i = 0;
 241                 my @m = @{$self->{wq_open_modes} // [qw( +<&= >&= >&= )]};
 242                 for my $fd (@fds) {
 243                         my $mode = shift(@m);
 244                         if (open(my $fh, $mode, $fd)) {
 245                                 $self->{$i++} = $fh;
 246                         } else {
 247                                 die "$$ open($mode$fd) (FD:$i): $!";
 248                         }
 249                 }
 250                 # Sereal dies, Storable returns undef
 251                 $rec = thaw($buf) //
 252                         die "thaw error on buffer of size:".length($buf);
 253                 ($sub, @args) = @$rec;
 254                 eval { $self->$sub(@args) };
 255                 warn "$$ wq_worker: $@" if $@;
 256                 delete @$self{0, 1, 2};
 257         }
 258 }
 259
 260 sub wq_do { # always async
 261         my ($self, $sub, $in, $out, $err, @args) = @_;
 262         if (my $s1 = $self->{-wq_s1}) { # run in worker
 263                 $_ = fileno($_) for ($in, $out, $err);
 264                 $send_cmd->($s1, $in, $out, $err,
 265                                 freeze([$sub, @args]), MSG_EOR);
 266         } else {
 267                 @$self{0, 1, 2} = ($in, $out, $err);
 268                 eval { $self->$sub(@args) };
 269                 warn "wq_do: $@" if $@;
 270                 delete @$self{0, 1, 2};
 271         }
 272 }
 273
 274 sub _wq_worker_start ($$) {
 275         my ($self, $oldset) = @_;
 276         my $pid = fork // die "fork: $!";
 277         if ($pid == 0) {
 278                 eval { PublicInbox::DS->Reset };
 279                 close(delete $self->{-wq_s1});
 280                 delete $self->{qw(-wq_workers -wq_quit)};
 281                 my $quit = sub { $self->{-wq_quit} = 1 };
 282                 $SIG{$_} = $quit for (qw(TERM INT QUIT));
 283                 $SIG{$_} = 'IGNORE' for (qw(TTOU TTIN));
 284                 local $0 = $self->{-wq_ident};
 285                 PublicInbox::DS::sig_setmask($oldset);
 286                 my $on_destroy = $self->ipc_atfork_child;
 287                 eval { wq_worker_loop($self) };
 288                 die "worker $self->{-wq_ident} PID:$$ died: $@\n" if $@;
 289                 exit;
 290         } else {
 291                 $self->{-wq_workers}->{$pid} = \undef;
 292         }
 293 }
 294
 295 # starts workqueue workers if Sereal or Storable is installed
 296 sub wq_workers_start {
 297         my ($self, $ident, $nr_workers, $oldset) = @_;
 298         ($enc && $send_cmd && $recv_cmd && defined($SEQPACKET)) or return;
 299         return if $self->{-wq_s1}; # idempotent
 300         my ($s1, $s2);
 301         socketpair($s1, $s2, AF_UNIX, $SEQPACKET, 0) or die "socketpair: $!";
 302         $self->ipc_atfork_parent;
 303         $nr_workers //= 4;
 304         my $sigset = $oldset // PublicInbox::DS::block_signals();
 305         $self->{-wq_workers} = {};
 306         $self->{-wq_ident} = $ident;
 307         $self->{-wq_s1} = $s1;
 308         $self->{-wq_s2} = $s2;
 309         _wq_worker_start($self, $sigset) for (1..$nr_workers);
 310         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 311         $self->{-wq_ppid} = $$;
 312 }
 313
 314 sub wq_worker_incr { # SIGTTIN handler
 315         my ($self, $oldset) = @_;
 316         $self->{-wq_s2} or return;
 317         $self->ipc_atfork_parent;
 318         my $sigset = $oldset // PublicInbox::DS::block_signals();
 319         _wq_worker_start($self, $sigset);
 320         PublicInbox::DS::sig_setmask($sigset) unless $oldset;
 321 }
 322
 323 sub wq_exit { # wakes up wq_worker_decr_wait
 324         send($_[0]->{-wq_s2}, $$, MSG_EOR) // die "$$ send: $!";
 325         exit;
 326 }
 327
 328 sub wq_worker_decr { # SIGTTOU handler, kills first idle worker
 329         my ($self) = @_;
 330         my $workers = $self->{-wq_workers} or return;
 331         my $s2 = $self->{-wq_s2} // die 'BUG: no wq_s2';
 332         $self->wq_do('wq_exit', $s2, $s2, $s2);
 333         $self->{-wq_exit_pending}++;
 334         # caller must call wq_worker_decr_wait in main loop
 335 }
 336
 337 sub wq_worker_decr_wait {
 338         my ($self, $timeout) = @_;
 339         return if $self->{-wq_ppid} != $$; # can't reap siblings or parents
 340         my $s1 = $self->{-wq_s1} // croak 'BUG: no wq_s1';
 341         vec(my $rin = '', fileno($s1), 1) = 1;
 342         select(my $rout = $rin, undef, undef, $timeout) or
 343                 croak 'timed out waiting for wq_exit';
 344         recv($s1, my $pid, 64, 0) // croak "recv: $!";
 345         my $workers = $self->{-wq_workers} // croak 'BUG: no wq_workers';
 346         delete $workers->{$pid} // croak "BUG: PID:$pid invalid";
 347         $self->{-wq_exit_pending}--;
 348         dwaitpid($pid, \&ipc_worker_reap, $self);
 349 }
 350
 351 sub wq_close {
 352         my ($self) = @_;
 353         delete @$self{qw(-wq_s1 -wq_s2)} or return;
 354         my $ppid = delete $self->{-wq_ppid} // die 'BUG: no wq_ppid';
 355         my $workers = delete $self->{-wq_workers} // die 'BUG: no wq_workers';
 356         return if $ppid != $$; # can't reap siblings or parents
 357         for my $pid (keys %$workers) {
 358                 dwaitpid($pid, \&ipc_worker_reap, $self);
 359         }
 360 }
 361
 362 1;