lib/PublicInbox/Inbox.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Represents a public-inbox (which may have multiple mailing addresses)
   5 package PublicInbox::Inbox;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Git;
   9 use PublicInbox::MID qw(mid2path);
  10 use PublicInbox::Eml;
  11
  12 # Long-running "git-cat-file --batch" processes won't notice
  13 # unlinked packs, so we need to restart those processes occasionally.
  14 # Xapian and SQLite file handles are mostly stable, but sometimes an
  15 # admin will attempt to replace them atomically after compact/vacuum
  16 # and we need to be prepared for that.
  17 my $cleanup_timer;
  18 my $cleanup_avail = -1; # 0, or 1
  19 my $have_devel_peek;
  20 my $CLEANUP = {}; # string(inbox) -> inbox
  21
  22 sub git_cleanup ($) {
  23         my ($self) = @_;
  24         my $git = $self->{git} or return;
  25         $git->cleanup;
  26 }
  27
  28 sub cleanup_task () {
  29         $cleanup_timer = undef;
  30         my $next = {};
  31         for my $ibx (values %$CLEANUP) {
  32                 my $again;
  33                 if ($have_devel_peek) {
  34                         foreach my $f (qw(search)) {
  35                                 # we bump refcnt by assigning tmp, here:
  36                                 my $tmp = $ibx->{$f} or next;
  37                                 next if Devel::Peek::SvREFCNT($tmp) > 2;
  38                                 delete $ibx->{$f};
  39                                 # refcnt is zero when tmp is out-of-scope
  40                         }
  41                 }
  42                 git_cleanup($ibx);
  43                 if (my $gits = $ibx->{-repo_objs}) {
  44                         foreach my $git (@$gits) {
  45                                 $again = 1 if $git->cleanup;
  46                         }
  47                 }
  48                 check_inodes($ibx);
  49                 if ($have_devel_peek) {
  50                         $again ||= !!$ibx->{search};
  51                 }
  52                 $next->{"$ibx"} = $ibx if $again;
  53         }
  54         $CLEANUP = $next;
  55 }
  56
  57 sub cleanup_possible () {
  58         # no need to require DS, here, if it were enabled another
  59         # module would've require'd it, already
  60         eval { PublicInbox::DS::in_loop() } or return 0;
  61
  62         eval {
  63                 require Devel::Peek; # needs separate package in Fedora
  64                 $have_devel_peek = 1;
  65         };
  66         1;
  67 }
  68
  69 sub _cleanup_later ($) {
  70         my ($self) = @_;
  71         $cleanup_avail = cleanup_possible() if $cleanup_avail < 0;
  72         return if $cleanup_avail != 1;
  73         $cleanup_timer ||= PublicInbox::DS::later(*cleanup_task);
  74         $CLEANUP->{"$self"} = $self;
  75 }
  76
  77 sub _set_uint ($$$) {
  78         my ($opts, $field, $default) = @_;
  79         my $val = $opts->{$field};
  80         if (defined $val) {
  81                 $val = $val->[-1] if ref($val) eq 'ARRAY';
  82                 $val = undef if $val !~ /\A[0-9]+\z/;
  83         }
  84         $opts->{$field} = $val || $default;
  85 }
  86
  87 sub _set_limiter ($$$) {
  88         my ($self, $pi_config, $pfx) = @_;
  89         my $lkey = "-${pfx}_limiter";
  90         $self->{$lkey} ||= do {
  91                 # full key is: publicinbox.$NAME.httpbackendmax
  92                 my $mkey = $pfx.'max';
  93                 my $val = $self->{$mkey} or return;
  94                 my $lim;
  95                 if ($val =~ /\A[0-9]+\z/) {
  96                         require PublicInbox::Qspawn;
  97                         $lim = PublicInbox::Qspawn::Limiter->new($val);
  98                 } elsif ($val =~ /\A[a-z][a-z0-9]*\z/) {
  99                         $lim = $pi_config->limiter($val);
 100                         warn "$mkey limiter=$val not found\n" if !$lim;
 101                 } else {
 102                         warn "$mkey limiter=$val not understood\n";
 103                 }
 104                 $lim;
 105         }
 106 }
 107
 108 sub new {
 109         my ($class, $opts) = @_;
 110         my $v = $opts->{address} ||= [ 'public-inbox@example.com' ];
 111         my $p = $opts->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
 112         $opts->{domain} = ($p =~ /\@(\S+)\z/) ? $1 : 'localhost';
 113         my $pi_config = delete $opts->{-pi_config};
 114         _set_limiter($opts, $pi_config, 'httpbackend');
 115         _set_uint($opts, 'feedmax', 25);
 116         $opts->{nntpserver} ||= $pi_config->{'publicinbox.nntpserver'};
 117         my $dir = $opts->{inboxdir};
 118         if (defined $dir && -f "$dir/inbox.lock") {
 119                 $opts->{version} = 2;
 120         }
 121
 122         # allow any combination of multi-line or comma-delimited hide entries
 123         my $hide = {};
 124         if (defined(my $h = $opts->{hide})) {
 125                 foreach my $v (@$h) {
 126                         $hide->{$_} = 1 foreach (split(/\s*,\s*/, $v));
 127                 }
 128                 $opts->{-hide} = $hide;
 129         }
 130         bless $opts, $class;
 131 }
 132
 133 sub version { $_[0]->{version} // 1 }
 134
 135 sub git_epoch {
 136         my ($self, $epoch) = @_;
 137         $self->version == 2 or return;
 138         $self->{"$epoch.git"} ||= do {
 139                 my $git_dir = "$self->{inboxdir}/git/$epoch.git";
 140                 my $g = PublicInbox::Git->new($git_dir);
 141                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 142                 # no cleanup needed, we never cat-file off this, only clone
 143                 $g;
 144         };
 145 }
 146
 147 sub git {
 148         my ($self) = @_;
 149         $self->{git} ||= do {
 150                 my $git_dir = $self->{inboxdir};
 151                 $git_dir .= '/all.git' if $self->version == 2;
 152                 my $g = PublicInbox::Git->new($git_dir);
 153                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 154                 _cleanup_later($self);
 155                 $g;
 156         };
 157 }
 158
 159 sub max_git_epoch {
 160         my ($self) = @_;
 161         return if $self->version < 2;
 162         my $cur = $self->{-max_git_epoch};
 163         my $changed = git($self)->alternates_changed;
 164         if (!defined($cur) || $changed) {
 165                 git_cleanup($self) if $changed;
 166                 my $gits = "$self->{inboxdir}/git";
 167                 if (opendir my $dh, $gits) {
 168                         my $max = -1;
 169                         while (defined(my $git_dir = readdir($dh))) {
 170                                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 171                                 $max = $1 if $1 > $max;
 172                         }
 173                         $cur = $self->{-max_git_epoch} = $max if $max >= 0;
 174                 } else {
 175                         warn "opendir $gits failed: $!\n";
 176                 }
 177         }
 178         $cur;
 179 }
 180
 181 sub mm {
 182         my ($self) = @_;
 183         $self->{mm} ||= eval {
 184                 require PublicInbox::Msgmap;
 185                 my $dir = $self->{inboxdir};
 186                 if ($self->version >= 2) {
 187                         PublicInbox::Msgmap->new_file("$dir/msgmap.sqlite3");
 188                 } else {
 189                         PublicInbox::Msgmap->new($dir);
 190                 }
 191         };
 192 }
 193
 194 sub search ($;$$) {
 195         my ($self, $over_only, $ctx) = @_;
 196         my $srch = $self->{search} ||= eval {
 197                 _cleanup_later($self);
 198                 require PublicInbox::Search;
 199                 PublicInbox::Search->new($self);
 200         };
 201         ($over_only || eval { $srch->xdb }) ? $srch : do {
 202                 $ctx and $ctx->{env}->{'psgi.errors'}->print(<<EOF);
 203 `$self->{name}' search went away unexpectedly
 204 EOF
 205                 undef;
 206         };
 207 }
 208
 209 sub over ($) {
 210         my ($self) = @_;
 211         my $srch = search($self, 1) or return;
 212         $self->{over} //= eval {
 213                 my $over = $srch->{over_ro};
 214                 $over->dbh; # may fail
 215                 $over;
 216         }
 217 }
 218
 219 sub try_cat {
 220         my ($path) = @_;
 221         my $rv = '';
 222         if (open(my $fh, '<', $path)) {
 223                 local $/;
 224                 $rv = <$fh>;
 225         }
 226         $rv;
 227 }
 228
 229 sub description {
 230         my ($self) = @_;
 231         ($self->{description} //= do {
 232                 my $desc = try_cat("$self->{inboxdir}/description");
 233                 local $/ = "\n";
 234                 chomp $desc;
 235                 utf8::decode($desc);
 236                 $desc =~ s/\s+/ /smg;
 237                 $desc eq '' ? undef : $desc;
 238         }) // '($INBOX_DIR/description missing)';
 239 }
 240
 241 sub cloneurl {
 242         my ($self) = @_;
 243         ($self->{cloneurl} //= do {
 244                 my $s = try_cat("$self->{inboxdir}/cloneurl");
 245                 my @urls = split(/\s+/s, $s);
 246                 scalar(@urls) ? \@urls : undef
 247         }) // [];
 248 }
 249
 250 sub base_url {
 251         my ($self, $env) = @_; # env - PSGI env
 252         if ($env) {
 253                 my $url = PublicInbox::Git::host_prefix_url($env, '');
 254                 # for mount in Plack::Builder
 255                 $url .= '/' if $url !~ m!/\z!;
 256                 return $url .= $self->{name} . '/';
 257         }
 258         # called from a non-PSGI environment (e.g. NNTP/POP3):
 259         $self->{-base_url} ||= do {
 260                 my $url = $self->{url}->[0] or return undef;
 261                 # expand protocol-relative URLs to HTTPS if we're
 262                 # not inside a web server
 263                 $url = "https:$url" if $url =~ m!\A//!;
 264                 $url .= '/' if $url !~ m!/\z!;
 265                 $url;
 266         };
 267 }
 268
 269 sub nntp_url {
 270         my ($self) = @_;
 271         $self->{-nntp_url} ||= do {
 272                 # no checking for nntp_usable here, we can point entirely
 273                 # to non-local servers or users run by a different user
 274                 my $ns = $self->{nntpserver};
 275                 my $group = $self->{newsgroup};
 276                 my @urls;
 277                 if ($ns && $group) {
 278                         $ns = [ $ns ] if ref($ns) ne 'ARRAY';
 279                         @urls = map {
 280                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 281                                 $u .= '/' if $u !~ m!/\z!;
 282                                 $u.$group;
 283                         } @$ns;
 284                 }
 285
 286                 my $mirrors = $self->{nntpmirror};
 287                 if ($mirrors) {
 288                         my @m;
 289                         foreach (@$mirrors) {
 290                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 291                                 if ($u =~ m!\Anntps?://[^/]+/?\z!) {
 292                                         if ($group) {
 293                                                 $u .= '/' if $u !~ m!/\z!;
 294                                                 $u .= $group;
 295                                         } else {
 296                                                 warn
 297 "publicinbox.$self->{name}.nntpmirror=$_ missing newsgroup name\n";
 298                                         }
 299                                 }
 300                                 # else: allow full URLs like:
 301                                 # nntp://news.example.com/alt.example
 302                                 push @m, $u;
 303                         }
 304
 305                         # List::Util::uniq requires Perl 5.26+, maybe we
 306                         # can use it by 2030 or so
 307                         my %seen;
 308                         @urls = grep { !$seen{$_}++ } (@urls, @m);
 309                 }
 310                 \@urls;
 311         };
 312 }
 313
 314 sub nntp_usable {
 315         my ($self) = @_;
 316         my $ret = mm($self) && over($self);
 317         $self->{mm} = $self->{over} = $self->{search} = undef;
 318         $ret;
 319 }
 320
 321 # for v1 users w/o SQLite only
 322 sub msg_by_path ($$) {
 323         my ($self, $path) = @_;
 324         git($self)->cat_file('HEAD:'.$path);
 325 }
 326
 327 sub msg_by_smsg ($$) {
 328         my ($self, $smsg) = @_;
 329
 330         # ghosts may have undef smsg (from SearchThread.node) or
 331         # no {blob} field
 332         return unless defined $smsg;
 333         defined(my $blob = $smsg->{blob}) or return;
 334
 335         git($self)->cat_file($blob);
 336 }
 337
 338 sub smsg_eml {
 339         my ($self, $smsg) = @_;
 340         my $bref = msg_by_smsg($self, $smsg) or return;
 341         my $eml = PublicInbox::Eml->new($bref);
 342         $smsg->populate($eml) unless exists($smsg->{num}); # v1 w/o SQLite
 343         $eml;
 344 }
 345
 346 sub mid2num($$) {
 347         my ($self, $mid) = @_;
 348         my $mm = mm($self) or return;
 349         $mm->num_for($mid);
 350 }
 351
 352 sub smsg_by_mid ($$) {
 353         my ($self, $mid) = @_;
 354         my $over = over($self) or return;
 355         # favor the Message-ID we used for the NNTP article number:
 356         defined(my $num = mid2num($self, $mid)) or return;
 357         my $smsg = $over->get_art($num) or return;
 358         PublicInbox::Smsg::psgi_cull($smsg);
 359 }
 360
 361 sub msg_by_mid ($$) {
 362         my ($self, $mid) = @_;
 363
 364         over($self) or
 365                 return msg_by_path($self, mid2path($mid));
 366
 367         my $smsg = smsg_by_mid($self, $mid);
 368         $smsg ? msg_by_smsg($self, $smsg) : undef;
 369 }
 370
 371 sub recent {
 372         my ($self, $opts, $after, $before) = @_;
 373         over($self)->recent($opts, $after, $before);
 374 }
 375
 376 sub modified {
 377         my ($self) = @_;
 378         if (my $over = over($self)) {
 379                 my $msgs = $over->recent({limit => 1});
 380                 if (my $smsg = $msgs->[0]) {
 381                         return $smsg->{ts};
 382                 }
 383                 return time;
 384         }
 385         git($self)->modified; # v1
 386 }
 387
 388 # returns prefix => pathname mapping
 389 # (pathname is NOT public, but prefix is used for Xapian queries)
 390 sub altid_map ($) {
 391         my ($self) = @_;
 392         $self->{-altid_map} //= eval {
 393                 require PublicInbox::AltId;
 394                 my $altid = $self->{altid} or return {};
 395                 my %h = map {;
 396                         my $x = PublicInbox::AltId->new($self, $_);
 397                         "$x->{prefix}" => $x->{filename}
 398                 } @$altid;
 399                 \%h;
 400         } // {};
 401 }
 402
 403 # $obj must respond to ->on_inbox_unlock, which takes Inbox ($self) as an arg
 404 sub subscribe_unlock {
 405         my ($self, $ident, $obj) = @_;
 406         $self->{unlock_subs}->{$ident} = $obj;
 407 }
 408
 409 sub unsubscribe_unlock {
 410         my ($self, $ident) = @_;
 411         delete $self->{unlock_subs}->{$ident};
 412 }
 413
 414 sub check_inodes ($) {
 415         my ($self) = @_;
 416         for (qw(over mm)) { # TODO: search
 417                 $self->{$_}->check_inodes if $self->{$_};
 418         }
 419 }
 420
 421 # called by inotify
 422 sub on_unlock {
 423         my ($self) = @_;
 424         check_inodes($self);
 425         my $subs = $self->{unlock_subs} or return;
 426         for (values %$subs) {
 427                 eval { $_->on_inbox_unlock($self) };
 428                 warn "E: $@ ($self->{inboxdir})\n" if $@;
 429         }
 430 }
 431
 432 1;