lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         mua-cmd|mua=s no-torsocks torsocks=s verbose|v
 108         received-after=s received-before=s sent-after=s sent-since=s),
 109         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 110
 111 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 112         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 113         pass_through('git show') ],
 114
 115 'add-external' => [ 'URL_OR_PATHNAME',
 116         'add/set priority of a publicinbox|extindex for extra matches',
 117         qw(boost=i quiet|q) ],
 118 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 119         qw(format|f=s z|0 local remote quiet|q) ],
 120 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 121         'exclude further results from a publicinbox|extindex',
 122         qw(prune quiet|q) ],
 123
 124 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 125                 qw(name-only format|f=s z) ],
 126 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 127 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 128
 129 'plonk' => [ '--thread|--from=IDENT',
 130         'exclude mail matching From: or thread from non-Message-ID searches',
 131         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 132 'mark' => [ 'MESSAGE_FLAGS...',
 133         'set/unset flags on message(s) from stdin',
 134         qw(stdin| oid=s exact by-mid|mid:s) ],
 135 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 136         "exclude message(s) on stdin from `q' search results",
 137         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 138
 139 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 140         'remove imported messages from IMAP, Maildirs, and MH',
 141         qw(exact! all jobs:i indexed) ],
 142
 143 # code repos are used for `show' to solve blobs from patch mails
 144 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 145         qw(boost=i) ],
 146 'ls-coderepo' => [ '[FILTER_TERMS...]',
 147                 'list known code repos', qw(format|f=s z) ],
 148 'forget-coderepo' => [ 'PATHNAME',
 149         'stop using repo to solve blobs from patches',
 150         qw(prune) ],
 151
 152 'add-watch' => [ '[URL_OR_PATHNAME]',
 153                 'watch for new messages and flag changes',
 154         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 155 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 156                 qw(format|f=s z) ],
 157 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 158 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 160         qw(prune) ],
 161
 162 'import' => [ 'URL_OR_PATHNAME|--stdin',
 163         'one-shot import/update from URL or filesystem',
 164         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 165         ],
 166
 167 'config' => [ '[...]', sub {
 168                 'git-config(1) wrapper for '._config_path($_[0]);
 169         }, qw(config-file|system|global|file|f=s), # for conflict detection
 170         pass_through('git config') ],
 171 'init' => [ '[PATHNAME]', sub {
 172                 'initialize storage, default: '._store_path($_[0]);
 173         }, qw(quiet|q) ],
 174 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 175         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 176 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 177 'help' => [ '[SUBCOMMAND]', 'show help' ],
 178
 179 # XXX do we need this?
 180 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 181
 182 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 183         'rewrite git history in an attempt to improve compression',
 184         'gc!' ],
 185
 186 # internal commands are prefixed with '_'
 187 '_complete' => [ '[...]', 'internal shell completion helper',
 188                 pass_through('everything') ],
 189 ); # @CMD
 190
 191 # switch descriptions, try to keep consistent across commands
 192 # $spec: Getopt::Long option specification
 193 # $spec => [@ALLOWED_VALUES (default is first), $description],
 194 # $spec => $description
 195 # "$SUB_COMMAND TAB $spec" => as above
 196 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 197                 'specify message input format' ];
 198 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 199
 200 my %OPTDESC = (
 201 'help|h' => 'show this built-in help',
 202 'quiet|q' => 'be quiet',
 203 'verbose|v' => 'be more verbose',
 204 'solve!' => 'do not attempt to reconstruct blobs from emails',
 205 'torsocks=s' => ['auto|no|yes',
 206                 'whether or not to wrap git and curl commands with torsocks'],
 207 'no-torsocks' => 'alias for --torsocks=no',
 208 'save-as=s' => ['NAME', 'save a search terms by given name'],
 209
 210 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 211
 212 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 213                 'deduplication strategy'],
 214 'show   thread|t' => 'display entire thread a message belongs to',
 215 'q      thread|t' =>
 216         'return all messages in the same thread as the actual match(es)',
 217 'augment|a' => 'augment --output destination instead of clobbering',
 218
 219 'output|mfolder|o=s' => [ 'DEST',
 220         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 221 'mua-cmd|mua=s' => [ 'COMMAND',
 222         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 223
 224 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 225                         'message/object output format' ],
 226 'mark   format|f=s' => $stdin_formats,
 227 'forget format|f=s' => $stdin_formats,
 228 'q      format|f=s' => [
 229         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 230                 'specify output format, default depends on --output'],
 231 'ls-query       format|f=s' => $ls_format,
 232 'ls-external    format|f=s' => $ls_format,
 233
 234 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 235 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 236
 237 'sort|s=s' => [ 'VAL|received,relevance,docid',
 238                 "order of results `--output'-dependent"],
 239 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 240
 241 'boost=i' => 'increase/decrease priority of results (default: 0)',
 242
 243 'local' => 'limit operations to the local filesystem',
 244 'local!' => 'exclude results from the local filesystem',
 245 'remote' => 'limit operations to those requiring network access',
 246 'remote!' => 'prevent operations requiring network access',
 247
 248 'mid=s' => 'specify the Message-ID of a message',
 249 'oid=s' => 'specify the git object ID of a message',
 250
 251 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 252 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 253 'include=s' => 'include mailboxes/newsgroups based on pattern',
 254
 255 'exact' => 'operate on exact header matches only',
 256 'exact!' => 'rely on content match instead of exact header matches',
 257
 258 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 259 'jobs:i' => 'set parallelism level',
 260
 261 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 262 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 263
 264 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 265 ); # %OPTDESC
 266
 267 my %CONFIG_KEYS = (
 268         'leistore.dir' => 'top-level storage location',
 269 );
 270
 271 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 272 sub x_it ($$) {
 273         my ($self, $code) = @_;
 274         # make sure client sees stdout before exit
 275         $self->{1}->autoflush(1) if $self->{1};
 276         dump_and_clear_log();
 277         if (my $sock = $self->{sock}) {
 278                 send($sock, "x_it $code", MSG_EOR);
 279         } elsif (my $signum = ($code & 127)) { # oneshot, usually SIGPIPE (13)
 280                 $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 281                 kill $signum, $$;
 282                 sleep; # wait for signal
 283         } else { # oneshot
 284                 # don't want to end up using $? from child processes
 285                 for my $f (qw(lxs l2m)) {
 286                         my $wq = delete $self->{$f} or next;
 287                         $wq->DESTROY;
 288                 }
 289                 $quit->($code >> 8);
 290         }
 291 }
 292
 293 sub err ($;@) {
 294         my $self = shift;
 295         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 296         my $eor = (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 297         print $err @_, $eor and return;
 298         my $old_err = delete $self->{2};
 299         close($old_err) if $! == EPIPE && $old_err;;
 300         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 301         print $err @_, $eor or print STDERR @_, $eor;
 302 }
 303
 304 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 305
 306 sub fail ($$;$) {
 307         my ($self, $buf, $exit_code) = @_;
 308         err($self, $buf);
 309         x_it($self, ($exit_code // 1) << 8);
 310         undef;
 311 }
 312
 313 sub out ($;@) {
 314         my $self = shift;
 315         return if print { $self->{1} // return } @_; # likely
 316         return note_sigpipe($self, 1) if $! == EPIPE;
 317         my $err = "error writing to stdout: $!";
 318         delete $self->{1};
 319         fail($self, $err);
 320 }
 321
 322 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 323
 324 sub child_error { # passes non-fatal curl exit codes to user
 325         my ($self, $child_error) = @_; # child_error is $?
 326         if (my $sock = $self->{sock}) { # send to lei(1) client
 327                 send($sock, "child_error $child_error", MSG_EOR);
 328         } else { # oneshot
 329                 $self->{child_error} = $child_error;
 330         }
 331         undef;
 332 }
 333
 334 sub atfork_prepare_wq {
 335         my ($self, $wq) = @_;
 336         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 337         if (my $sock = $self->{sock}) {
 338                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 339         }
 340         if (my $pgr = $self->{pgr}) {
 341                 push @$tcafc, @$pgr[1,2];
 342         }
 343         if (my $old_1 = $self->{old_1}) {
 344                 push @$tcafc, $old_1;
 345         }
 346         for my $f (qw(lxs l2m)) {
 347                 my $ipc = $self->{$f} or next;
 348                 push @$tcafc, grep { defined }
 349                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 350         }
 351 }
 352
 353 sub io_restore ($$) {
 354         my ($dst, $src) = @_;
 355         for my $i (0..2) { # standard FDs
 356                 my $io = delete $src->{$i} or next;
 357                 $dst->{$i} = $io;
 358         }
 359         for my $i (3..9) { # named (non-standard) FDs
 360                 my $io = $src->{$i} or next;
 361                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 362                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 363                 $dst->{$f} = $io;
 364                 delete $src->{$i};
 365         }
 366 }
 367
 368 # triggers sigpipe_handler
 369 sub note_sigpipe {
 370         my ($self, $fd) = @_;
 371         close(delete($self->{$fd})); # explicit close silences Perl warning
 372         syswrite($self->{op_pipe}, '!') if $self->{op_pipe};
 373         x_it($self, 13);
 374 }
 375
 376 sub atfork_child_wq {
 377         my ($self, $wq) = @_;
 378         io_restore($self, $wq);
 379         -p $self->{op_pipe} or die 'BUG: {op_pipe} expected';
 380         io_restore($self->{l2m}, $wq);
 381         %PATH2CFG = ();
 382         undef $errors_log;
 383         $quit = \&CORE::exit;
 384         $current_lei = $self; # for SIG{__WARN__}
 385 }
 386
 387 sub io_extract ($;@) {
 388         my ($obj, @fields) = @_;
 389         my @io;
 390         for my $f (@fields) {
 391                 my $io = delete $obj->{$f} or next;
 392                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 393                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 394                 push @io, $io;
 395         }
 396         @io
 397 }
 398
 399 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 400 sub atfork_parent_wq {
 401         my ($self, $wq) = @_;
 402         my $env = delete $self->{env}; # env is inherited at fork
 403         my $lei = bless { %$self }, ref($self);
 404         for my $f (qw(dedupe ovv)) {
 405                 my $tmp = delete($lei->{$f}) or next;
 406                 $lei->{$f} = $wq->deep_clone($tmp);
 407         }
 408         $self->{env} = $env;
 409         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 410         my @io = (delete(@$lei{qw(0 1 2)}),
 411                         io_extract($lei, qw(sock op_pipe startq)));
 412         my $l2m = $lei->{l2m};
 413         if ($l2m && $l2m != $wq) { # $wq == lxs
 414                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 415                         push @io, io_extract($l2m, '-wq_s1');
 416                         $l2m->{-wq_s1} = $wq_s1;
 417                 }
 418                 $l2m->wq_close(1);
 419         }
 420         ($lei, @io);
 421 }
 422
 423 sub _help ($;$) {
 424         my ($self, $errmsg) = @_;
 425         my $cmd = $self->{cmd} // 'COMMAND';
 426         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 427         my @top = ($cmd, shift(@info) // ());
 428         my $cmd_desc = shift(@info);
 429         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 430         my @opt_desc;
 431         my $lpad = 2;
 432         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 433                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 434                 my $arg_vals = '';
 435                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 436
 437                 # lower-case is a keyword (e.g. `content', `oid'),
 438                 # ALL_CAPS is a string description (e.g. `PATH')
 439                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 440                         $desc .= "\ndefault: `$1'";
 441                 }
 442                 my (@vals, @s, @l);
 443                 my $x = $sw;
 444                 if ($x =~ s/!\z//) { # solve! => --no-solve
 445                         $x = "no-$x";
 446                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 447                         @vals = (' [', undef, ']');
 448                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 449                         @vals = (' ', undef);
 450                 } # else: no args $x = 'thread|t'
 451                 for (split(/\|/, $x)) { # help|h
 452                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 453                 }
 454                 if (!scalar(@vals)) { # no args 'thread|t'
 455                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 456                         $vals[1] = $1;
 457                 } else {
 458                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 459                 }
 460                 if ($arg_vals =~ /([,\|])/) {
 461                         my $sep = $1;
 462                         my @allow = split(/\Q$sep\E/, $arg_vals);
 463                         my $must = $sep eq '|' ? 'Must' : 'Can';
 464                         @allow = map { "`$_'" } @allow;
 465                         my $last = pop @allow;
 466                         $desc .= "\n$must be one of: " .
 467                                 join(', ', @allow) . " or $last";
 468                 }
 469                 my $lhs = join(', ', @s, @l) . join('', @vals);
 470                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 471                         $lhs =~ s/\A--/- , --/;
 472                 } else {
 473                         $lhs =~ s/\A--/    --/; # pad if no short options
 474                 }
 475                 $lpad = length($lhs) if length($lhs) > $lpad;
 476                 push @opt_desc, $lhs, $desc;
 477         }
 478         my $msg = $errmsg ? "E: $errmsg\n" : '';
 479         $msg .= <<EOF;
 480 usage: lei @top
 481   $cmd_desc
 482
 483 EOF
 484         $lpad += 2;
 485         local $Text::Wrap::columns = 78 - $lpad;
 486         my $padding = ' ' x ($lpad + 2);
 487         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 488                 $msg .= '  '.pack("A$lpad", $lhs);
 489                 $rhs = wrap('', '', $rhs);
 490                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 491                 $msg .= $rhs;
 492                 $msg .= "\n";
 493         }
 494         print { $self->{$errmsg ? 2 : 1} } $msg;
 495         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 496         undef;
 497 }
 498
 499 sub optparse ($$$) {
 500         my ($self, $cmd, $argv) = @_;
 501         $self->{cmd} = $cmd;
 502         $OPT = $self->{opt} = {};
 503         my $info = $CMD{$cmd} // [ '[...]' ];
 504         my ($proto, undef, @spec) = @$info;
 505         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 506         push @spec, qw(help|h);
 507         my $lone_dash;
 508         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 509                 $lone_dash = $spec[0];
 510                 $OPT->{$spec[0]} = \(my $var);
 511                 push @spec, '' => \$var;
 512         }
 513         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 514                 return _help($self, "bad arguments or options for $cmd");
 515         return _help($self) if $OPT->{help};
 516
 517         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 518
 519         # "-" aliases "stdin" or "clear"
 520         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 521
 522         my $i = 0;
 523         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 524         my ($err, $inf);
 525         my @args = split(/ /, $proto);
 526         for my $var (@args) {
 527                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 528                         $inf = defined($argv->[$i]) and last;
 529                         $var =~ s/\.\.\.\z//;
 530                         $err = "$var not supplied";
 531                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 532                         $argv->[$i++] // ($err = "$var not supplied");
 533                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 534                         $inf = 1;
 535                         last;
 536                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 537                         $i++;
 538                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 539                         my @or = split(/\|/, $var);
 540                         my $ok;
 541                         for my $o (@or) {
 542                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 543                                         $ok = defined($OPT->{$1});
 544                                         last;
 545                                 } elsif (defined($argv->[$i])) {
 546                                         $ok = 1;
 547                                         $i++;
 548                                         last;
 549                                 } # else continue looping
 550                         }
 551                         last if $ok;
 552                         my $last = pop @or;
 553                         $err = join(', ', @or) . " or $last must be set";
 554                 } else {
 555                         warn "BUG: can't parse `$var' in $proto";
 556                 }
 557                 last if $err;
 558         }
 559         if (!$inf && scalar(@$argv) > scalar(@args)) {
 560                 $err //= 'too many arguments';
 561         }
 562         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 563 }
 564
 565 sub dispatch {
 566         my ($self, $cmd, @argv) = @_;
 567         local $current_lei = $self; # for __WARN__
 568         dump_and_clear_log("from previous run\n");
 569         return _help($self, 'no command given') unless defined($cmd);
 570         my $func = "lei_$cmd";
 571         $func =~ tr/-/_/;
 572         if (my $cb = __PACKAGE__->can($func)) {
 573                 optparse($self, $cmd, \@argv) or return;
 574                 $cb->($self, @argv);
 575         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 576                 my $opt = {};
 577                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 578                         return _help($self, 'bad arguments or options');
 579                 _help($self);
 580         } else {
 581                 fail($self, "`$cmd' is not an lei command");
 582         }
 583 }
 584
 585 sub _lei_cfg ($;$) {
 586         my ($self, $creat) = @_;
 587         my $f = _config_path($self);
 588         my @st = stat($f);
 589         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 590         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 591                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 592         }
 593         if (!@st) {
 594                 unless ($creat) {
 595                         delete $self->{cfg};
 596                         return;
 597                 }
 598                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 599                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 600                 open my $fh, '>>', $f or die "open($f): $!\n";
 601                 @st = stat($fh) or die "fstat($f): $!\n";
 602                 $cur_st = pack('dd', $st[10], $st[7]);
 603                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 604         }
 605         my $cfg = PublicInbox::Config::git_config_dump($f);
 606         $cfg->{-st} = $cur_st;
 607         $cfg->{'-f'} = $f;
 608         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 609 }
 610
 611 sub _lei_store ($;$) {
 612         my ($self, $creat) = @_;
 613         my $cfg = _lei_cfg($self, $creat);
 614         $cfg->{-lei_store} //= do {
 615                 require PublicInbox::LeiStore;
 616                 my $dir = $cfg->{'leistore.dir'};
 617                 $dir //= $creat ? _store_path($self) : return;
 618                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 619         };
 620 }
 621
 622 sub lei_show {
 623         my ($self, @argv) = @_;
 624 }
 625
 626 sub lei_mark {
 627         my ($self, @argv) = @_;
 628 }
 629
 630 sub _config {
 631         my ($self, @argv) = @_;
 632         my $env = $self->{env};
 633         delete local $env->{GIT_CONFIG};
 634         delete local $ENV{GIT_CONFIG};
 635         my $cfg = _lei_cfg($self, 1);
 636         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 637         my %rdr = map { $_ => $self->{$_} } (0..2);
 638         waitpid(spawn($cmd, $env, \%rdr), 0);
 639 }
 640
 641 sub lei_config {
 642         my ($self, @argv) = @_;
 643         $self->{opt}->{'config-file'} and return fail $self,
 644                 "config file switches not supported by `lei config'";
 645         _config(@_);
 646         x_it($self, $?) if $?;
 647 }
 648
 649 sub lei_init {
 650         my ($self, $dir) = @_;
 651         my $cfg = _lei_cfg($self, 1);
 652         my $cur = $cfg->{'leistore.dir'};
 653         $dir //= _store_path($self);
 654         $dir = rel2abs($self, $dir);
 655         my @cur = stat($cur) if defined($cur);
 656         $cur = File::Spec->canonpath($cur // $dir);
 657         my @dir = stat($dir);
 658         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 659         if (@cur) {
 660                 if ($cur eq $dir) {
 661                         _lei_store($self, 1)->done;
 662                         return qerr($self, $exists);
 663                 }
 664
 665                 # some folks like symlinks and bind mounts :P
 666                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 667                         lei_config($self, 'leistore.dir', $dir);
 668                         _lei_store($self, 1)->done;
 669                         return qerr($self, "$exists (as $cur)");
 670                 }
 671                 return fail($self, <<"");
 672 E: leistore.dir=$cur already initialized and it is not $dir
 673
 674         }
 675         lei_config($self, 'leistore.dir', $dir);
 676         _lei_store($self, 1)->done;
 677         $exists //= "I: leistore.dir=$dir newly initialized";
 678         return qerr($self, $exists);
 679 }
 680
 681 sub lei_daemon_pid { puts shift, $$ }
 682
 683 sub lei_daemon_kill {
 684         my ($self) = @_;
 685         my $sig = $self->{opt}->{signal} // 'TERM';
 686         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 687 }
 688
 689 sub lei_help { _help($_[0]) }
 690
 691 # Shell completion helper.  Used by lei-completion.bash and hopefully
 692 # other shells.  Try to do as much here as possible to avoid redundancy
 693 # and improve maintainability.
 694 sub lei__complete {
 695         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 696         shift @argv; # ignore "lei", the entire command is sent
 697         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 698         my $cmd = shift @argv;
 699         my $info = $CMD{$cmd} // do { # filter matching commands
 700                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 701                 return;
 702         };
 703         my ($proto, undef, @spec) = @$info;
 704         my $cur = pop @argv;
 705         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 706         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 707                 # gross special case since the only git-config options
 708                 # Consider moving to a table if we need more special cases
 709                 # we use Getopt::Long for are the ones we reject, so these
 710                 # are the ones we don't reject:
 711                 if ($cmd eq 'config') {
 712                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 713                         @spec = qw(add z|null get get-all unset unset-all
 714                                 replace-all get-urlmatch
 715                                 remove-section rename-section
 716                                 name-only list|l edit|e
 717                                 get-color-name get-colorbool);
 718                         # fall-through
 719                 }
 720                 puts $self, grep(/$re/, map { # generate short/long names
 721                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 722                         } else { # negation: solve! => no-solve|solve
 723                                 s/\A(.+)!\z/no-$1|$1/;
 724                         }
 725                         map {
 726                                 my $x = length > 1 ? "--$_" : "-$_";
 727                                 $x eq $cur ? () : $x;
 728                         } split(/\|/, $_, -1) # help|h
 729                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 730         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 731                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 732         }
 733
 734         # switch args (e.g. lei q -f mbox<TAB>)
 735         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 736                 my $opt = quotemeta $1;
 737                 puts $self, map {
 738                         my $v = $OPTDESC{$_};
 739                         $v = $v->[0] if ref($v);
 740                         my @v = split(/\|/, $v);
 741                         # get rid of ALL CAPS placeholder (e.g "OUT")
 742                         # (TODO: completion for external paths)
 743                         shift(@v) if uc($v[0]) eq $v[0];
 744                         @v;
 745                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 746         }
 747         $cmd =~ tr/-/_/;
 748         if (my $sub = $self->can("_complete_$cmd")) {
 749                 puts $self, $sub->($self, @argv, $cur);
 750         }
 751         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 752         # proto parsing.
 753 }
 754
 755 sub exec_buf ($$) {
 756         my ($argv, $env) = @_;
 757         my $argc = scalar @$argv;
 758         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 759         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 760         $buf;
 761 }
 762
 763 sub start_mua {
 764         my ($self) = @_;
 765         my $mua = $self->{opt}->{'mua-cmd'} // return;
 766         my $mfolder = $self->{ovv}->{dst};
 767         my (@cmd, $replaced);
 768         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 769                 @cmd = ($mua, '-f');
 770         # TODO: help wanted: other common FOSS MUAs
 771         } else {
 772                 require Text::ParseWords;
 773                 my @cmd = Text::ParseWords::shellwords($mua);
 774                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 775                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 776         }
 777         push @cmd, $mfolder unless defined($replaced);
 778         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 779                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 780         } else { # oneshot
 781                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 782         }
 783 }
 784
 785 # caller needs to "-t $self->{1}" to check if tty
 786 sub start_pager {
 787         my ($self) = @_;
 788         my $env = $self->{env};
 789         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 790         chomp(my $pager = <$fh> // '');
 791         close($fh) or warn "`git var PAGER' error: \$?=$?";
 792         return if $pager eq 'cat' || $pager eq '';
 793         # TODO TIOCGWINSZ
 794         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 795         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 796         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 797         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 798         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 799         if (my $sock = $self->{sock}) { # lei(1) process runs it
 800                 delete @$new_env{keys %$env}; # only set iff unset
 801                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 802                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 803         } else {
 804                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 805         }
 806         $self->{1} = $wpager;
 807         $self->{2} = $wpager if -t $self->{2};
 808         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 809         $self->{pgr} = $pgr;
 810 }
 811
 812 sub stop_pager {
 813         my ($self) = @_;
 814         my $pgr = delete($self->{pgr}) or return;
 815         $self->{2} = $pgr->[2];
 816         # do not restore original stdout, just close it so we error out
 817         close(delete($self->{1})) if $self->{1};
 818         my $pid = $pgr->[0];
 819         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 820 }
 821
 822 sub accept_dispatch { # Listener {post_accept} callback
 823         my ($sock) = @_; # ignore other
 824         $sock->autoflush(1);
 825         my $self = bless { sock => $sock }, __PACKAGE__;
 826         vec(my $rvec = '', fileno($sock), 1) = 1;
 827         select($rvec, undef, undef, 1) or
 828                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 829         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 830         if (scalar(@fds) == 4) {
 831                 for my $i (0..3) {
 832                         my $fd = shift(@fds);
 833                         open($self->{$i}, '+<&=', $fd) and next;
 834                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 835                 }
 836         } else {
 837                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 838         }
 839         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 840         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 841         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 842         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 843                 return send($sock, 'request command truncated', MSG_EOR);
 844         my ($argc, @argv) = split(/\0/, $buf, -1);
 845         undef $buf;
 846         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 847         if (chdir($self->{3})) {
 848                 local %ENV = %env;
 849                 $self->{env} = \%env;
 850                 eval { dispatch($self, @argv) };
 851                 send($sock, $@, MSG_EOR) if $@;
 852         } else {
 853                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 854         }
 855 }
 856
 857 sub dclose {
 858         my ($self) = @_;
 859         for my $f (qw(lxs l2m)) {
 860                 my $wq = delete $self->{$f} or next;
 861                 if ($wq->wq_kill) {
 862                         $wq->wq_close
 863                 } elsif ($wq->wq_kill_old) {
 864                         $wq->wq_wait_old($self);
 865                 }
 866         }
 867         close(delete $self->{1}) if $self->{1}; # may reap_compress
 868         $self->close if $self->{sock}; # PublicInbox::DS::close
 869 }
 870
 871 # for long-running results
 872 sub event_step {
 873         my ($self) = @_;
 874         local %ENV = %{$self->{env}};
 875         my $sock = $self->{sock};
 876         local $current_lei = $self;
 877         eval {
 878                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 879                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 880                                 return if $! == EAGAIN;
 881                                 next if $! == EINTR;
 882                                 last if $! == ECONNRESET;
 883                                 die "recvmsg: $!";
 884                         }
 885                         for my $fd (@fds) {
 886                                 open my $rfh, '+<&=', $fd;
 887                         }
 888                         die "unrecognized client signal: $buf";
 889                 }
 890                 dclose($self);
 891         };
 892         if (my $err = $@) {
 893                 eval { $self->fail($err) };
 894                 dclose($self);
 895         }
 896 }
 897
 898 sub event_step_init {
 899         my ($self) = @_;
 900         if (my $sock = $self->{sock}) { # using DS->EventLoop
 901                 $sock->blocking(0);
 902                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 903         }
 904 }
 905
 906 sub noop {}
 907
 908 our $oldset; sub oldset { $oldset }
 909
 910 sub dump_and_clear_log {
 911         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 912                 my @pfx = @_;
 913                 unshift(@pfx, "$errors_log ") if @pfx;
 914                 warn @pfx, do { local $/; <STDIN> };
 915                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 916         }
 917 }
 918
 919 # lei(1) calls this when it can't connect
 920 sub lazy_start {
 921         my ($path, $errno, $narg) = @_;
 922         if ($errno == ECONNREFUSED) {
 923                 unlink($path) or die "unlink($path): $!";
 924         } elsif ($errno != ENOENT) {
 925                 $! = $errno; # allow interpolation to stringify in die
 926                 die "connect($path): $!";
 927         }
 928         if (eval { require BSD::Resource }) {
 929                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 930                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 931                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 932         }
 933         umask(077) // die("umask(077): $!");
 934         local $listener;
 935         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 936         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 937         listen($listener, 1024) or die "listen: $!";
 938         my @st = stat($path) or die "stat($path): $!";
 939         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 940         local $oldset = PublicInbox::DS::block_signals();
 941         if ($narg == 5) {
 942                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 943                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 944                         require PublicInbox::CmdIPC4;
 945                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 946                         PublicInbox::CmdIPC4->can('recv_cmd4');
 947                 };
 948         }
 949         $recv_cmd or die <<"";
 950 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 951
 952         require PublicInbox::Listener;
 953         require PublicInbox::EOFpipe;
 954         (-p STDOUT) or die "E: stdout must be a pipe\n";
 955         local $errors_log;
 956         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 957         $errors_log .= 'errors.log';
 958         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 959         STDIN->autoflush(1);
 960         dump_and_clear_log("from previous daemon process:\n");
 961         POSIX::setsid() > 0 or die "setsid: $!";
 962         my $pid = fork // die "fork: $!";
 963         return if $pid;
 964         $0 = "lei-daemon $path";
 965         local %PATH2CFG;
 966         $listener->blocking(0);
 967         my $exit_code;
 968         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 969         local $quit = do {
 970                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 971                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 972                 sub {
 973                         $exit_code //= shift;
 974                         my $lis = $pil or exit($exit_code);
 975                         # closing eof_w triggers \&noop wakeup
 976                         $listener = $eof_w = $pil = $path = undef;
 977                         $lis->close; # DS::close
 978                         PublicInbox::DS->SetLoopTimeout(1000);
 979                 };
 980         };
 981         my $sig = {
 982                 CHLD => \&PublicInbox::DS::enqueue_reap,
 983                 QUIT => $quit,
 984                 INT => $quit,
 985                 TERM => $quit,
 986                 HUP => \&noop,
 987                 USR1 => \&noop,
 988                 USR2 => \&noop,
 989         };
 990         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 991         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 992         undef $sig;
 993         local $SIG{PIPE} = 'IGNORE';
 994         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 995                 undef $sigfd;
 996                 PublicInbox::DS->SetLoopTimeout(5000);
 997         } else {
 998                 # wake up every second to accept signals if we don't
 999                 # have signalfd or IO::KQueue:
1000                 PublicInbox::DS::sig_setmask($oldset);
1001                 PublicInbox::DS->SetLoopTimeout(1000);
1002         }
1003         PublicInbox::DS->SetPostLoopCallback(sub {
1004                 my ($dmap, undef) = @_;
1005                 if (@st = defined($path) ? stat($path) : ()) {
1006                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1007                                 warn "$path dev/ino changed, quitting\n";
1008                                 $path = undef;
1009                         }
1010                 } elsif (defined($path)) { # ENOENT is common
1011                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1012                         undef $path;
1013                         $quit->();
1014                 }
1015                 return 1 if defined($path);
1016                 my $now = now();
1017                 my $n = 0;
1018                 for my $s (values %$dmap) {
1019                         $s->can('busy') or next;
1020                         if ($s->busy($now)) {
1021                                 ++$n;
1022                         } else {
1023                                 $s->close;
1024                         }
1025                 }
1026                 $n; # true: continue, false: stop
1027         });
1028
1029         # STDIN was redirected to /dev/null above, closing STDERR and
1030         # STDOUT will cause the calling `lei' client process to finish
1031         # reading the <$daemon> pipe.
1032         local $SIG{__WARN__} = sub {
1033                 $current_lei ? err($current_lei, @_) : warn(
1034                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1035         };
1036         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1037         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1038         # $daemon pipe to `lei' closed, main loop begins:
1039         PublicInbox::DS->EventLoop;
1040         exit($exit_code // 0);
1041 }
1042
1043 # for users w/o Socket::Msghdr installed or Inline::C enabled
1044 sub oneshot {
1045         my ($main_pkg) = @_;
1046         my $exit = $main_pkg->can('exit'); # caller may override exit()
1047         local $quit = $exit if $exit;
1048         local %PATH2CFG;
1049         umask(077) // die("umask(077): $!");
1050         my $self = bless {
1051                 0 => *STDIN{GLOB},
1052                 1 => *STDOUT{GLOB},
1053                 2 => *STDERR{GLOB},
1054                 env => \%ENV
1055         }, __PACKAGE__;
1056         dispatch($self, @ARGV);
1057         x_it($self, $self->{child_error}) if $self->{child_error};
1058 }
1059
1060 # ensures stdout hits the FS before sock disconnects so a client
1061 # can immediately reread it
1062 sub DESTROY {
1063         my ($self) = @_;
1064         $self->{1}->autoflush(1) if $self->{1};
1065         stop_pager($self);
1066         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1067                 waitpid($mua_pid, 0);
1068         }
1069 }
1070
1071 1;