lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 return $p;
  74         }
  75         my $pwd = $self->{env}->{PWD};
  76         my $cwd;
  77         if (defined $pwd) {
  78                 my $xcwd = $self->{3} //
  79                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  99                 .'/lei');
 100 }
 101
 102 sub store_path ($) { share_path($_[0]) . '/store' }
 103
 104 sub _config_path ($) {
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 108                 .'/lei/config');
 109 }
 110
 111 sub cache_dir ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 115                 .'/lei');
 116 }
 117
 118 sub ale {
 119         my ($self) = @_;
 120         $self->{ale} //= do {
 121                 require PublicInbox::LeiALE;
 122                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 123         };
 124 }
 125
 126 sub index_opt {
 127         # TODO: drop underscore variants everywhere, they're undocumented
 128         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 129         max_size|max-size=s sequential_shard|sequential-shard
 130         batch_size|batch-size=s skip-docdata)
 131 }
 132
 133 my @c_opt = qw(c=s@ C=s@ quiet|q);
 134 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 135         import-remote! no-torsocks torsocks=s),
 136         PublicInbox::LeiQuery::curl_opt());
 137
 138 # we don't support -C as an alias for --find-copies since it's already
 139 # used for chdir
 140 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 141         output-indicator-context=s indent-heuristic!
 142         minimal patience histogram anchored=s@ diff-algorithm=s
 143         color-moved=s color-moved-ws=s no-color-moved no-color-moved-ws
 144         word-diff:s word-diff-regex=s color-words:s no-renames
 145         rename-empty! check ws-error-highlight=s full-index binary
 146         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 147         find-copies-harder irreversible-delete|D l=i diff-filter=s
 148         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 149         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 150         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 151         inter-hunk-context=i function-context|W exit-code ext-diff
 152         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 153         line-prefix=s);
 154
 155 # we generate shell completion + help using %CMD and %OPTDESC,
 156 # see lei__complete() and PublicInbox::LeiHelp
 157 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 158 our %CMD = ( # sorted in order of importance/use:
 159 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 160         'stdin|', # /|\z/ must be first for lone dash
 161         @lxs_opt,
 162         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 163         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 164         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 165         color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 166
 167 'up' => [ 'OUTPUT|--all', 'update saved search',
 168         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 169
 170 'lcat' => [ '--stdin|MSGID_OR_URL..', 'display local copy of message(s)',
 171         'stdin|', # /|\z/ must be first for lone dash
 172         # some of these options are ridiculous for lcat
 173         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 174         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 175         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 176         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 177
 178 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 179         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 180         @lxs_opt, @c_opt ],
 181
 182 'rediff' => [ '[--stdin|LOCATION...]',
 183                 'regenerate a diff with different options',
 184         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 185         @diff_opt, @lxs_opt, @c_opt ],
 186
 187 'add-external' => [ 'LOCATION',
 188         'add/set priority of a publicinbox|extindex for extra matches',
 189         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 190         verbose|v+), @c_opt, index_opt(),
 191         PublicInbox::LeiQuery::curl_opt() ],
 192 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 193         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 194 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 195 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 196                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 197 'forget-external' => [ 'LOCATION...|--prune',
 198         'exclude further results from a publicinbox|extindex',
 199         qw(prune), @c_opt ],
 200
 201 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 202                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 203 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 204                 qw(verbose|v+), @c_opt ],
 205 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 206                         @c_opt ],
 207
 208 'plonk' => [ '--threads|--from=IDENT',
 209         'exclude mail matching From: or threads from non-Message-ID searches',
 210         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 211 'tag' => [ 'KEYWORDS...',
 212         'set/unset keywords and/or labels on message(s)',
 213         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 214         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 215         pass_through('-kw:foo for delete') ],
 216 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 217         "exclude message(s) on stdin from `q' search results",
 218         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 219
 220 'purge-mailsource' => [ 'LOCATION|--all',
 221         'remove imported messages from IMAP, Maildirs, and MH',
 222         qw(exact! all jobs:i indexed), @c_opt ],
 223
 224 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 225         qw(import! kw! interval=s recursive|r
 226         exclude=s include=s), @c_opt ],
 227 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 228                 qw(format|f=s z), @c_opt ],
 229 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 230 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 231 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 232         qw(prune), @c_opt ],
 233
 234 'import' => [ 'LOCATION...|--stdin',
 235         'one-time import/update from URL or filesystem',
 236         qw(stdin| offset=i recursive|r exclude=s include|I=s
 237         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 238         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 239 'convert' => [ 'LOCATION...|--stdin',
 240         'one-time conversion from URL or filesystem to another format',
 241         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 242         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 243 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 244         "use a patch to generate a query for `lei q --stdin'",
 245         qw(stdin| want|w=s@ uri debug), @c_opt ],
 246 'config' => [ '[...]', sub {
 247                 'git-config(1) wrapper for '._config_path($_[0]);
 248         }, qw(config-file|system|global|file|f=s), # for conflict detection
 249          qw(c=s@ C=s@), pass_through('git config') ],
 250 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 251         qw(pretty ascii dir=s), @c_opt ],
 252
 253 'init' => [ '[DIRNAME]', sub {
 254         "initialize storage, default: ".store_path($_[0]);
 255         }, @c_opt ],
 256 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 257         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 258         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 259 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 260 'help' => [ '[SUBCOMMAND]', 'show help' ],
 261
 262 # XXX do we need this?
 263 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 264
 265 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 266         'rewrite git history in an attempt to improve compression',
 267         qw(gc!), @c_opt ],
 268
 269 # internal commands are prefixed with '_'
 270 '_complete' => [ '[...]', 'internal shell completion helper',
 271                 pass_through('everything') ],
 272 ); # @CMD
 273
 274 # switch descriptions, try to keep consistent across commands
 275 # $spec: Getopt::Long option specification
 276 # $spec => [@ALLOWED_VALUES (default is first), $description],
 277 # $spec => $description
 278 # "$SUB_COMMAND TAB $spec" => as above
 279 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 280                         'specify message input format' ];
 281 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 282
 283 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 284 my %OPTDESC = (
 285 'help|h' => 'show this built-in help',
 286 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 287 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 288 'quiet|q' => 'be quiet',
 289 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 290         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 291
 292 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 293 'globoff|g' => "do not match locations using '*?' wildcards ".
 294                 "and\xa0'[]'\x{a0}ranges",
 295 'invert-match|v' => 'select non-matching lines',
 296 'color!' => 'disable color (for --format=text)',
 297 'verbose|v+' => 'be more verbose',
 298 'external!' => 'do not use externals',
 299 'mail!' => 'do not look in mail storage for OID',
 300 'cwd!' => 'do not look in git repo of current working directory',
 301 'oid-a|A=s' => 'pre-image OID',
 302 'path-a|a=s' => 'pre-image pathname associated with OID',
 303 'path-b|b=s' => 'post-image pathname associated with OID',
 304 'git-dir=s@' => 'additional git repository to scan',
 305 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 306         "proxy for (e.g. `socks5h://0:9050')" ],
 307 'torsocks=s' => ['VAL|auto|no|yes',
 308                 'whether or not to wrap git and curl commands with torsocks'],
 309 'no-torsocks' => 'alias for --torsocks=no',
 310 'save' =>  "save a search for `lei up'",
 311 'import-remote!' => 'do not memoize remote messages into local store',
 312
 313 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 314
 315 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 316                 'deduplication strategy'],
 317 'threads|t+' =>
 318         'return all messages in the same threads as the actual match(es)',
 319
 320 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 321                 'search prefixes to extract (default: dfpost7)' ],
 322
 323 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 324         'run command(s) or perform ops when done writing to output ' .
 325         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 326         'nothing otherwise)' ],
 327
 328 'augment|a' => 'augment --output destination instead of clobbering',
 329
 330 'output|mfolder|o=s' => [ 'MFOLDER',
 331         "destination (e.g.\xa0`/path/to/Maildir', ".
 332         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 333 'mua=s' => [ 'CMD',
 334         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 335
 336 'inbox-version=i' => [ 'NUM|1|2',
 337                 'force a public-inbox version with --mirror'],
 338 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 339
 340 # public-inbox-index options
 341 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 342 'compact' => 'run compact index after mirroring',
 343 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 344         "indexlevel with --mirror (default: full)" ],
 345 'max_size|max-size=s' => [ 'SIZE',
 346         'do not index messages larger than SIZE (default: infinity)' ],
 347 'batch_size|batch-size=s' => [ 'SIZE',
 348         'flush changes to OS after given number of bytes (default: 1m)' ],
 349 'sequential_shard|sequential-shard' =>
 350         'index Xapian shards sequentially for slow storage',
 351 'skip-docdata' =>
 352         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 353
 354 'format|f=s     q' => [
 355         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 356                 'specify output format, default depends on --output'],
 357 'exclude=s@     q' => [ 'LOCATION',
 358                 'exclude specified external(s) from search' ],
 359 'include|I=s@   q' => [ 'LOCATION',
 360                 'include specified external(s) in search' ],
 361 'only=s@        q' => [ 'LOCATION',
 362                 'only use specified external(s) for search' ],
 363 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 364                 'control number of search and writer jobs' ],
 365 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 366
 367 'in-format|F=s' => $stdin_formats,
 368 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 369                         'listing output format' ],
 370 'l      ls-search' => 'long listing format',
 371 'format|f=s     ls-external' => $ls_format,
 372
 373 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 374 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 375
 376 'sort|s=s' => [ 'VAL|received|relevance|docid',
 377                 "order of results is `--output'-dependent"],
 378 'reverse|r' => 'reverse search results', # like sort(1)
 379
 380 'boost=i' => 'increase/decrease priority of results (default: 0)',
 381
 382 'local' => 'limit operations to the local filesystem',
 383 'local!' => 'exclude results from the local filesystem',
 384 'remote' => 'limit operations to those requiring network access',
 385 'remote!' => 'prevent operations requiring network access',
 386
 387 'all:s  up' => ['local', 'update all (local) saved searches' ],
 388
 389 'mid=s' => 'specify the Message-ID of a message',
 390 'oid=s' => 'specify the git object ID of a message',
 391
 392 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 393 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 394 'include=s' => 'include mailboxes/newsgroups based on pattern',
 395
 396 'exact' => 'operate on exact header matches only',
 397 'exact!' => 'rely on content match instead of exact header matches',
 398
 399 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 400
 401 'kw!' => 'disable/enable importing keywords (aka "flags")',
 402
 403 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 404 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 405
 406 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 407 ); # %OPTDESC
 408
 409 my %CONFIG_KEYS = (
 410         'leistore.dir' => 'top-level storage location',
 411 );
 412
 413 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 414
 415 sub _drop_wq {
 416         my ($self) = @_;
 417         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 418                 if ($wq->wq_kill) {
 419                         $wq->wq_close(0, undef, $self);
 420                 } elsif ($wq->wq_kill_old) {
 421                         $wq->wq_wait_old(undef, $self);
 422                 }
 423                 $wq->DESTROY;
 424         }
 425 }
 426
 427 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 428 sub x_it ($$) {
 429         my ($self, $code) = @_;
 430         # make sure client sees stdout before exit
 431         $self->{1}->autoflush(1) if $self->{1};
 432         dump_and_clear_log();
 433         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 434                 send($s, "x_it $code", MSG_EOR);
 435         } elsif ($self->{oneshot}) {
 436                 # don't want to end up using $? from child processes
 437                 _drop_wq($self);
 438                 # cleanup anything that has tempfiles or open file handles
 439                 %PATH2CFG = ();
 440                 delete @$self{qw(ovv dedupe sto cfg)};
 441                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 442                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 443                         kill $signum, $$;
 444                         sleep(1) while 1; # wait for signal
 445                 } else {
 446                         $quit->($code >> 8);
 447                 }
 448         } # else ignore if client disconnected
 449 }
 450
 451 sub err ($;@) {
 452         my $self = shift;
 453         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 454         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 455         print $err @_, @eor and return;
 456         my $old_err = delete $self->{2};
 457         close($old_err) if $! == EPIPE && $old_err;
 458         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 459         print $err @_, @eor or print STDERR @_, @eor;
 460 }
 461
 462 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 463
 464 sub fail_handler ($;$$) {
 465         my ($lei, $code, $io) = @_;
 466         close($io) if $io; # needed to avoid warnings on SIGPIPE
 467         _drop_wq($lei);
 468         x_it($lei, $code // (1 << 8));
 469 }
 470
 471 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 472         fail_handler($_[0], 13, delete $_[0]->{1});
 473 }
 474
 475 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 476 sub sigint_reap {
 477         my ($pgid) = @_;
 478         dwaitpid($pgid) if kill('-INT', $pgid);
 479 }
 480
 481 sub fail ($$;$) {
 482         my ($self, $buf, $exit_code) = @_;
 483         err($self, $buf) if defined $buf;
 484         # calls fail_handler:
 485         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 486         x_it($self, ($exit_code // 1) << 8);
 487         undef;
 488 }
 489
 490 sub out ($;@) {
 491         my $self = shift;
 492         return if print { $self->{1} // return } @_; # likely
 493         return note_sigpipe($self, 1) if $! == EPIPE;
 494         my $err = "error writing to output: $!";
 495         delete $self->{1};
 496         fail($self, $err);
 497 }
 498
 499 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 500
 501 sub child_error { # passes non-fatal curl exit codes to user
 502         my ($self, $child_error, $msg) = @_; # child_error is $?
 503         $self->err($msg) if $msg;
 504         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 505                 # send to the parent lei-daemon or to lei(1) client
 506                 send($s, "child_error $child_error", MSG_EOR);
 507         } elsif (!$PublicInbox::DS::in_loop) {
 508                 $self->{child_error} = $child_error;
 509         } # else noop if client disconnected
 510 }
 511
 512 sub note_sigpipe { # triggers sigpipe_handler
 513         my ($self, $fd) = @_;
 514         close(delete($self->{$fd})); # explicit close silences Perl warning
 515         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 516         x_it($self, 13);
 517 }
 518
 519 sub _lei_atfork_child {
 520         my ($self, $persist) = @_;
 521         # we need to explicitly close things which are on stack
 522         if ($persist) {
 523                 chdir '/' or die "chdir(/): $!";
 524                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 525                 if (my $cfg = $self->{cfg}) {
 526                         delete $cfg->{-lei_store};
 527                 }
 528         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 529                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 530                 STDERR->autoflush(1);
 531         }
 532         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 533         if (my $op_c = delete $self->{pkt_op_c}) {
 534                 close(delete $op_c->{sock});
 535         }
 536         if (my $pgr = delete $self->{pgr}) {
 537                 close($_) for (@$pgr[1,2]);
 538         }
 539         close $listener if $listener;
 540         undef $listener;
 541         %PATH2CFG = ();
 542         undef $errors_log;
 543         $quit = \&CORE::exit;
 544         $self->{-eml_noisy} or # only "lei import" sets this atm
 545                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 546         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 547 }
 548
 549 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 550         my ($self) = @_;
 551         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 552                 $op->close; # PublicInbox::PktOp::close
 553         }
 554         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 555         close $unclosed_after_die;
 556 }
 557
 558 sub pkt_op_pair {
 559         my ($self) = @_;
 560         require PublicInbox::OnDestroy;
 561         require PublicInbox::PktOp;
 562         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 563         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 564         $end;
 565 }
 566
 567 sub workers_start {
 568         my ($lei, $wq, $jobs, $ops) = @_;
 569         $ops = {
 570                 '!' => [ \&fail_handler, $lei ],
 571                 '|' => [ \&sigpipe_handler, $lei ],
 572                 'x_it' => [ \&x_it, $lei ],
 573                 'child_error' => [ \&child_error, $lei ],
 574                 ($ops ? %$ops : ()),
 575         };
 576         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 577         my $end = $lei->pkt_op_pair;
 578         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 579         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 580         delete $lei->{pkt_op_p};
 581         my $op_c = delete $lei->{pkt_op_c};
 582         @$end = ();
 583         $lei->event_step_init;
 584         ($op_c, $ops);
 585 }
 586
 587 sub _help {
 588         require PublicInbox::LeiHelp;
 589         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 590 }
 591
 592 sub optparse ($$$) {
 593         my ($self, $cmd, $argv) = @_;
 594         # allow _complete --help to complete, not show help
 595         return 1 if substr($cmd, 0, 1) eq '_';
 596         $self->{cmd} = $cmd;
 597         $OPT = $self->{opt} //= {};
 598         my $info = $CMD{$cmd} // [ '[...]' ];
 599         my ($proto, undef, @spec) = @$info;
 600         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 601         push @spec, qw(help|h);
 602         my $lone_dash;
 603         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 604                 $lone_dash = $spec[0];
 605                 $OPT->{$spec[0]} = \(my $var);
 606                 push @spec, '' => \$var;
 607         }
 608         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 609                 return _help($self, "bad arguments or options for $cmd");
 610         return _help($self) if $OPT->{help};
 611
 612         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 613
 614         # "-" aliases "stdin" or "clear"
 615         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 616
 617         my $i = 0;
 618         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 619         my ($err, $inf);
 620         my @args = split(/ /, $proto);
 621         for my $var (@args) {
 622                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 623                         $inf = defined($argv->[$i]) and last;
 624                         $var =~ s/\.\.\.\z//;
 625                         $err = "$var not supplied";
 626                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 627                         $argv->[$i++] // ($err = "$var not supplied");
 628                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 629                         $inf = 1;
 630                         last;
 631                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 632                         $i++;
 633                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 634                         $inf = 1 if index($var, '...') > 0;
 635                         my @or = split(/\|/, $var);
 636                         my $ok;
 637                         for my $o (@or) {
 638                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 639                                         $ok = defined($OPT->{$1});
 640                                         last if $ok;
 641                                 } elsif (defined($argv->[$i])) {
 642                                         $ok = 1;
 643                                         $i++;
 644                                         last;
 645                                 } # else continue looping
 646                         }
 647                         last if $ok;
 648                         my $last = pop @or;
 649                         $err = join(', ', @or) . " or $last must be set";
 650                 } else {
 651                         warn "BUG: can't parse `$var' in $proto";
 652                 }
 653                 last if $err;
 654         }
 655         if (!$inf && scalar(@$argv) > scalar(@args)) {
 656                 $err //= 'too many arguments';
 657         }
 658         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 659 }
 660
 661 sub _tmp_cfg { # for lei -c <name>=<value> ...
 662         my ($self) = @_;
 663         my $cfg = _lei_cfg($self, 1);
 664         require File::Temp;
 665         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 666         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 667         $ft->autoflush(1);
 668         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 669 [include]
 670         path = $cfg->{-f}
 671 EOM
 672         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 673         for (@{$self->{opt}->{c}}) {
 674                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 675 `-c $_' is not of the form -c <name>=<value>'
 676 EOM
 677                 my $name = $1;
 678                 my $value = $2 // 1;
 679                 _config($self, '--add', $name, $value);
 680                 if (defined(my $v = $tmp->{$name})) {
 681                         if (ref($v) eq 'ARRAY') {
 682                                 push @$v, $value;
 683                         } else {
 684                                 $tmp->{$name} = [ $v, $value ];
 685                         }
 686                 } else {
 687                         $tmp->{$name} = $value;
 688                 }
 689         }
 690 }
 691
 692 sub lazy_cb ($$$) {
 693         my ($self, $cmd, $pfx) = @_;
 694         my $ucmd = $cmd;
 695         $ucmd =~ tr/-/_/;
 696         my $cb;
 697         $cb = $self->can($pfx.$ucmd) and return $cb;
 698         my $base = $ucmd;
 699         $base =~ s/_([a-z])/\u$1/g;
 700         my $pkg = "PublicInbox::Lei\u$base";
 701         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 702                 $pkg->can($pfx.$ucmd) : undef;
 703 }
 704
 705 sub dispatch {
 706         my ($self, $cmd, @argv) = @_;
 707         local $current_lei = $self; # for __WARN__
 708         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 709         dump_and_clear_log("from previous run\n");
 710         return _help($self, 'no command given') unless defined($cmd);
 711         # do not support Getopt bundling for this
 712         while ($cmd eq '-C' || $cmd eq '-c') {
 713                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 714                                         '-C DIRECTORY' : '-c <name>=<value>');
 715                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 716                 $cmd = shift(@argv) // return _help($self, 'no command given');
 717         }
 718         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 719                 optparse($self, $cmd, \@argv) or return;
 720                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 721                 if (my $chdir = $self->{opt}->{C}) {
 722                         for my $d (@$chdir) {
 723                                 next if $d eq ''; # same as git(1)
 724                                 chdir $d or return fail($self, "cd $d: $!");
 725                         }
 726                         if (delete $self->{3}) { # update cwd for rel2abs
 727                                 opendir my $dh, '.' or
 728                                         return fail($self, "opendir . $!");
 729                                 $self->{3} = $dh;
 730                         }
 731                 }
 732                 $cb->($self, @argv);
 733         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 734                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 735                         or return _help($self, 'bad arguments or options');
 736                 _help($self);
 737         } else {
 738                 fail($self, "`$cmd' is not an lei command");
 739         }
 740 }
 741
 742 sub _lei_cfg ($;$) {
 743         my ($self, $creat) = @_;
 744         return $self->{cfg} if $self->{cfg};
 745         my $f = _config_path($self);
 746         my @st = stat($f);
 747         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 748         my ($sto, $sto_dir);
 749         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 750                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 751                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 752         }
 753         if (!@st) {
 754                 unless ($creat) {
 755                         delete $self->{cfg};
 756                         return bless {}, 'PublicInbox::Config';
 757                 }
 758                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 759                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 760                 open my $fh, '>>', $f or die "open($f): $!\n";
 761                 @st = stat($fh) or die "fstat($f): $!\n";
 762                 $cur_st = pack('dd', $st[10], $st[7]);
 763                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 764         }
 765         my $cfg = PublicInbox::Config->git_config_dump($f);
 766         $cfg->{-st} = $cur_st;
 767         $cfg->{'-f'} = $f;
 768         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 769                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 770                                                 store_path($self))) {
 771                 $cfg->{-lei_store} = $sto;
 772         }
 773         if (scalar(keys %PATH2CFG) > 5) {
 774                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 775                 for my $k (keys %PATH2CFG) {
 776                         delete($PATH2CFG{$k}) unless -f $k
 777                 }
 778         }
 779         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 780 }
 781
 782 sub _lei_store ($;$) {
 783         my ($self, $creat) = @_;
 784         my $cfg = _lei_cfg($self, $creat);
 785         $cfg->{-lei_store} //= do {
 786                 require PublicInbox::LeiStore;
 787                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 788                 return unless $creat || -d $dir;
 789                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 790         };
 791 }
 792
 793 sub _config {
 794         my ($self, @argv) = @_;
 795         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 796         my $cfg = _lei_cfg($self, 1);
 797         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 798         my %rdr = map { $_ => $self->{$_} } (0..2);
 799         waitpid(spawn($cmd, \%env, \%rdr), 0);
 800 }
 801
 802 sub lei_config {
 803         my ($self, @argv) = @_;
 804         $self->{opt}->{'config-file'} and return fail $self,
 805                 "config file switches not supported by `lei config'";
 806         _config(@_);
 807         x_it($self, $?) if $?;
 808 }
 809
 810 sub lei_daemon_pid { puts shift, $$ }
 811
 812 sub lei_daemon_kill {
 813         my ($self) = @_;
 814         my $sig = $self->{opt}->{signal} // 'TERM';
 815         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 816 }
 817
 818 # Shell completion helper.  Used by lei-completion.bash and hopefully
 819 # other shells.  Try to do as much here as possible to avoid redundancy
 820 # and improve maintainability.
 821 sub lei__complete {
 822         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 823         shift @argv; # ignore "lei", the entire command is sent
 824         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 825         my $cmd = shift @argv;
 826         my $info = $CMD{$cmd} // do { # filter matching commands
 827                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 828                 return;
 829         };
 830         my ($proto, undef, @spec) = @$info;
 831         my $cur = pop @argv;
 832         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 833         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 834                 # gross special case since the only git-config options
 835                 # Consider moving to a table if we need more special cases
 836                 # we use Getopt::Long for are the ones we reject, so these
 837                 # are the ones we don't reject:
 838                 if ($cmd eq 'config') {
 839                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 840                         @spec = qw(add z|null get get-all unset unset-all
 841                                 replace-all get-urlmatch
 842                                 remove-section rename-section
 843                                 name-only list|l edit|e
 844                                 get-color-name get-colorbool);
 845                         # fall-through
 846                 }
 847                 # generate short/long names from Getopt::Long specs
 848                 puts $self, grep(/$re/, qw(--help -h -C), map {
 849                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 850                         } elsif (s/\+\z//) { # verbose|v+
 851                         } elsif (s/!\z//) {
 852                                 # negation: mail! => no-mail|mail
 853                                 s/([\w\-]+)/$1|no-$1/g
 854                         }
 855                         map {
 856                                 my $x = length > 1 ? "--$_" : "-$_";
 857                                 $x eq $_cur ? () : $x;
 858                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 859                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 860         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 861                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 862         }
 863
 864         # switch args (e.g. lei q -f mbox<TAB>)
 865         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 866                 my $opt = quotemeta $1;
 867                 puts $self, map {
 868                         my $v = $OPTDESC{$_};
 869                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 870                         # get rid of ALL CAPS placeholder (e.g "OUT")
 871                         # (TODO: completion for external paths)
 872                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 873                         @v;
 874                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 875         }
 876         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 877                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 878         }
 879         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 880         # proto parsing.
 881 }
 882
 883 sub exec_buf ($$) {
 884         my ($argv, $env) = @_;
 885         my $argc = scalar @$argv;
 886         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 887         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 888         $buf;
 889 }
 890
 891 sub start_mua {
 892         my ($self) = @_;
 893         my $mua = $self->{opt}->{mua} // return;
 894         my $mfolder = $self->{ovv}->{dst};
 895         my (@cmd, $replaced);
 896         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 897                 @cmd = ($mua, '-f');
 898         # TODO: help wanted: other common FOSS MUAs
 899         } else {
 900                 require Text::ParseWords;
 901                 @cmd = Text::ParseWords::shellwords($mua);
 902                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 903                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 904         }
 905         push @cmd, $mfolder unless defined($replaced);
 906         if ($self->{sock}) { # lei(1) client process runs it
 907                 # restore terminal: echo $query | lei q -stdin --mua=...
 908                 my $io = [];
 909                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 910                 send_exec_cmd($self, $io, \@cmd, {});
 911         } elsif ($self->{oneshot}) {
 912                 my $pid = fork // die "fork: $!";
 913                 if ($pid > 0) { # original process
 914                         if ($self->{opt}->{stdin} && -t STDOUT) {
 915                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 916                         }
 917                         exec(@cmd);
 918                         warn "exec @cmd: $!\n";
 919                         POSIX::_exit(1);
 920                 }
 921                 POSIX::setsid() > 0 or die "setsid: $!";
 922         }
 923         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 924                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 925         }
 926         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 927         $self->{opt}->{quiet} = 1;
 928         delete $self->{-progress};
 929         delete $self->{opt}->{verbose};
 930 }
 931
 932 sub send_exec_cmd { # tell script/lei to execute a command
 933         my ($self, $io, $cmd, $env) = @_;
 934         my $sock = $self->{sock} // die 'lei client gone';
 935         my $fds = [ map { fileno($_) } @$io ];
 936         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 937 }
 938
 939 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 940         my ($self) = @_;
 941         my $alerts = $self->{opt}->{alert} // return;
 942         while (my $op = shift(@$alerts)) {
 943                 if ($op eq ':WINCH') {
 944                         # hit the process group that started the MUA
 945                         if ($self->{sock}) {
 946                                 send($self->{sock}, '-WINCH', MSG_EOR);
 947                         } elsif ($self->{oneshot}) {
 948                                 kill('-WINCH', $$);
 949                         }
 950                 } elsif ($op eq ':bell') {
 951                         out($self, "\a");
 952                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 953                         push @$alerts, split(/(?<!\\),/, $op);
 954                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 955                         my $cmd = $1; # run an arbitrary command
 956                         require Text::ParseWords;
 957                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 958                         if (my $s = $self->{sock}) {
 959                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 960                         } elsif ($self->{oneshot}) {
 961                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 962                         }
 963                 } else {
 964                         err($self, "W: unsupported --alert=$op"); # non-fatal
 965                 }
 966         }
 967 }
 968
 969 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 970 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 971
 972 # this also normalizes the path
 973 sub path_to_fd {
 974         my ($self, $path) = @_;
 975         $path = rel2abs($self, $path);
 976         $path =~ tr!/!/!s;
 977         $path_to_fd{$path} // (
 978                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 979                         fail($self, "cannot open $path from daemon") : -1
 980         );
 981 }
 982
 983 # caller needs to "-t $self->{1}" to check if tty
 984 sub start_pager {
 985         my ($self) = @_;
 986         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 987         chomp(my $pager = <$fh> // '');
 988         close($fh) or warn "`git var PAGER' error: \$?=$?";
 989         return if $pager eq 'cat' || $pager eq '';
 990         my $new_env = { LESS => 'FRX', LV => '-c' };
 991         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 992         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 993         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 994         my $pgr = [ undef, @$rdr{1, 2} ];
 995         my $env = $self->{env};
 996         if ($self->{sock}) { # lei(1) process runs it
 997                 delete @$new_env{keys %$env}; # only set iff unset
 998                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 999         } elsif ($self->{oneshot}) {
1000                 my $cmd = [$pager];
1001                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
1002         } else {
1003                 die 'BUG: start_pager w/o socket';
1004         }
1005         $self->{1} = $wpager;
1006         $self->{2} = $wpager if -t $self->{2};
1007         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1008         $self->{pgr} = $pgr;
1009 }
1010
1011 sub stop_pager {
1012         my ($self) = @_;
1013         my $pgr = delete($self->{pgr}) or return;
1014         $self->{2} = $pgr->[2];
1015         # do not restore original stdout, just close it so we error out
1016         close(delete($self->{1})) if $self->{1};
1017 }
1018
1019 sub accept_dispatch { # Listener {post_accept} callback
1020         my ($sock) = @_; # ignore other
1021         $sock->autoflush(1);
1022         my $self = bless { sock => $sock }, __PACKAGE__;
1023         vec(my $rvec = '', fileno($sock), 1) = 1;
1024         select($rvec, undef, undef, 60) or
1025                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1026         # (4096 * 33) >MAX_ARG_STRLEN
1027         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1028         if (!defined($fds[0])) {
1029                 warn(my $msg = "recv_cmd failed: $!");
1030                 return send($sock, $msg, MSG_EOR);
1031         } else {
1032                 my $i = 0;
1033                 for my $fd (@fds) {
1034                         open($self->{$i++}, '+<&=', $fd) and next;
1035                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1036                 }
1037                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1038         }
1039         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1040         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1041         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1042                 return send($sock, 'request command truncated', MSG_EOR);
1043         my ($argc, @argv) = split(/\0/, $buf, -1);
1044         undef $buf;
1045         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1046         if (chdir($self->{3})) {
1047                 local %ENV = %env;
1048                 $self->{env} = \%env;
1049                 eval { dispatch($self, @argv) };
1050                 send($sock, $@, MSG_EOR) if $@;
1051         } else {
1052                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1053         }
1054 }
1055
1056 sub dclose {
1057         my ($self) = @_;
1058         delete $self->{-progress};
1059         _drop_wq($self);
1060         close(delete $self->{1}) if $self->{1}; # may reap_compress
1061         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1062 }
1063
1064 # for long-running results
1065 sub event_step {
1066         my ($self) = @_;
1067         local %ENV = %{$self->{env}};
1068         my $sock = $self->{sock};
1069         local $current_lei = $self;
1070         eval {
1071                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1072                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1073                                 return if $! == EAGAIN;
1074                                 next if $! == EINTR;
1075                                 last if $! == ECONNRESET;
1076                                 die "recvmsg: $!";
1077                         }
1078                         for my $fd (@fds) {
1079                                 open my $rfh, '+<&=', $fd;
1080                         }
1081                         die "unrecognized client signal: $buf";
1082                 }
1083                 dclose($self);
1084         };
1085         if (my $err = $@) {
1086                 eval { $self->fail($err) };
1087                 dclose($self);
1088         }
1089 }
1090
1091 sub event_step_init {
1092         my ($self) = @_;
1093         return if $self->{-event_init_done}++;
1094         if (my $sock = $self->{sock}) { # using DS->EventLoop
1095                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1096         }
1097 }
1098
1099 sub noop {}
1100
1101 sub oldset { $oldset }
1102
1103 sub dump_and_clear_log {
1104         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1105                 my @pfx = @_;
1106                 unshift(@pfx, "$errors_log ") if @pfx;
1107                 warn @pfx, do { local $/; <STDIN> };
1108                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1109         }
1110 }
1111
1112 # lei(1) calls this when it can't connect
1113 sub lazy_start {
1114         my ($path, $errno, $narg) = @_;
1115         local ($errors_log, $listener);
1116         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1117         $errors_log .= 'errors.log';
1118         my $addr = pack_sockaddr_un($path);
1119         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1120         $lk->lock_acquire;
1121         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1122         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1123                 return if connect($listener, $addr); # another process won
1124                 if ($errno == ECONNREFUSED && -S $path) {
1125                         unlink($path) or die "unlink($path): $!";
1126                 }
1127         } else {
1128                 $! = $errno; # allow interpolation to stringify in die
1129                 die "connect($path): $!";
1130         }
1131         umask(077) // die("umask(077): $!");
1132         bind($listener, $addr) or die "bind($path): $!";
1133         listen($listener, 1024) or die "listen: $!";
1134         $lk->lock_release;
1135         undef $lk;
1136         my @st = stat($path) or die "stat($path): $!";
1137         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1138         local $oldset = PublicInbox::DS::block_signals();
1139         if ($narg == 5) {
1140                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1141                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1142                         require PublicInbox::CmdIPC4;
1143                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1144                         PublicInbox::CmdIPC4->can('recv_cmd4');
1145                 };
1146         }
1147         $recv_cmd or die <<"";
1148 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1149
1150         require PublicInbox::Listener;
1151         require PublicInbox::EOFpipe;
1152         (-p STDOUT) or die "E: stdout must be a pipe\n";
1153         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1154         STDIN->autoflush(1);
1155         dump_and_clear_log("from previous daemon process:\n");
1156         POSIX::setsid() > 0 or die "setsid: $!";
1157         my $pid = fork // die "fork: $!";
1158         return if $pid;
1159         $0 = "lei-daemon $path";
1160         local %PATH2CFG;
1161         $listener->blocking(0);
1162         my $exit_code;
1163         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1164         local $quit = do {
1165                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1166                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1167                 sub {
1168                         $exit_code //= shift;
1169                         my $lis = $pil or exit($exit_code);
1170                         # closing eof_w triggers \&noop wakeup
1171                         $listener = $eof_w = $pil = $path = undef;
1172                         $lis->close; # DS::close
1173                         PublicInbox::DS->SetLoopTimeout(1000);
1174                 };
1175         };
1176         my $sig = {
1177                 CHLD => \&PublicInbox::DS::enqueue_reap,
1178                 QUIT => $quit,
1179                 INT => $quit,
1180                 TERM => $quit,
1181                 HUP => \&noop,
1182                 USR1 => \&noop,
1183                 USR2 => \&noop,
1184         };
1185         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1186         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1187         undef $sig;
1188         local $SIG{PIPE} = 'IGNORE';
1189         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1190                 undef $sigfd;
1191                 PublicInbox::DS->SetLoopTimeout(5000);
1192         } else {
1193                 # wake up every second to accept signals if we don't
1194                 # have signalfd or IO::KQueue:
1195                 PublicInbox::DS::sig_setmask($oldset);
1196                 PublicInbox::DS->SetLoopTimeout(1000);
1197         }
1198         PublicInbox::DS->SetPostLoopCallback(sub {
1199                 my ($dmap, undef) = @_;
1200                 if (@st = defined($path) ? stat($path) : ()) {
1201                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1202                                 warn "$path dev/ino changed, quitting\n";
1203                                 $path = undef;
1204                         }
1205                 } elsif (defined($path)) { # ENOENT is common
1206                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1207                         undef $path;
1208                         $quit->();
1209                 }
1210                 return 1 if defined($path);
1211                 my $now = now();
1212                 my $n = 0;
1213                 for my $s (values %$dmap) {
1214                         $s->can('busy') or next;
1215                         if ($s->busy($now)) {
1216                                 ++$n;
1217                         } else {
1218                                 $s->close;
1219                         }
1220                 }
1221                 $n; # true: continue, false: stop
1222         });
1223
1224         # STDIN was redirected to /dev/null above, closing STDERR and
1225         # STDOUT will cause the calling `lei' client process to finish
1226         # reading the <$daemon> pipe.
1227         local $SIG{__WARN__} = sub {
1228                 $current_lei ? err($current_lei, @_) : warn(
1229                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1230         };
1231         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1232         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1233         # $daemon pipe to `lei' closed, main loop begins:
1234         PublicInbox::DS->EventLoop;
1235         exit($exit_code // 0);
1236 }
1237
1238 sub busy { 1 } # prevent daemon-shutdown if client is connected
1239
1240 # for users w/o Socket::Msghdr installed or Inline::C enabled
1241 sub oneshot {
1242         my ($main_pkg) = @_;
1243         my $exit = $main_pkg->can('exit'); # caller may override exit()
1244         local $quit = $exit if $exit;
1245         local %PATH2CFG;
1246         umask(077) // die("umask(077): $!");
1247         my $self = bless { oneshot => 1, env => \%ENV }, __PACKAGE__;
1248         for (0..2) { open($self->{$_}, '+<&=', $_) or die "open fd=$_: $!" }
1249         dispatch($self, @ARGV);
1250         x_it($self, $self->{child_error}) if $self->{child_error};
1251 }
1252
1253 # ensures stdout hits the FS before sock disconnects so a client
1254 # can immediately reread it
1255 sub DESTROY {
1256         my ($self) = @_;
1257         $self->{1}->autoflush(1) if $self->{1};
1258         stop_pager($self);
1259         my $err = $?;
1260         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1261         waitpid($_, 0) for keys %$oneshot_pids;
1262         $? = $err if $err; # preserve ->fail or ->x_it code
1263 }
1264
1265 sub wq_done_wait { # dwaitpid callback
1266         my ($arg, $pid) = @_;
1267         my ($wq, $lei) = @$arg;
1268         my $err_type = $lei->{-err_type};
1269         $? and $lei->child_error($?,
1270                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1271         $lei->dclose;
1272 }
1273
1274 sub wq_eof { # EOF callback for main daemon
1275         my ($lei) = @_;
1276         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1277         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1278 }
1279
1280 1;