lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub _store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub index_opt {
 101         # TODO: drop underscore variants everywhere, they're undocumented
 102         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 103         max_size|max-size=s sequential_shard|sequential-shard
 104         batch_size|batch-size=s skip-docdata)
 105 }
 106
 107 # we generate shell completion + help using %CMD and %OPTDESC,
 108 # see lei__complete() and PublicInbox::LeiHelp
 109 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 110 our %CMD = ( # sorted in order of importance/use:
 111 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 112         'stdin|', # /|\z/ must be first for lone dash
 113         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 114         sort|s=s reverse|r offset=i remote! local! external! pretty
 115         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 116         import-remote! import-before! lock=s@ rsyncable
 117         alert=s@ mua=s no-torsocks torsocks=s verbose|v+ quiet|q C=s@),
 118         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 119
 120 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 121         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local! C=s@),
 122         pass_through('git show') ],
 123
 124 'add-external' => [ 'LOCATION',
 125         'add/set priority of a publicinbox|extindex for extra matches',
 126         qw(boost=i c=s@ mirror=s no-torsocks torsocks=s inbox-version=i),
 127         qw(quiet|q verbose|v+ C=s@),
 128         index_opt(), PublicInbox::LeiQuery::curl_opt() ],
 129 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 130         qw(format|f=s z|0 globoff|g invert-match|v local remote C=s@) ],
 131 'forget-external' => [ 'LOCATION...|--prune',
 132         'exclude further results from a publicinbox|extindex',
 133         qw(prune quiet|q C=s@) ],
 134
 135 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 136                 qw(name-only format|f=s C=s@) ],
 137 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', qw(C=s@) ],
 138 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', qw(C=s@) ],
 139
 140 'plonk' => [ '--threads|--from=IDENT',
 141         'exclude mail matching From: or threads from non-Message-ID searches',
 142         qw(stdin| threads|t from|f=s mid=s oid=s C=s@) ],
 143 'mark' => [ 'MESSAGE_FLAGS...',
 144         'set/unset keywords on message(s) from stdin',
 145         qw(stdin| oid=s exact by-mid|mid:s C=s@) ],
 146 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 147         "exclude message(s) on stdin from `q' search results",
 148         qw(stdin| oid=s exact by-mid|mid:s quiet|q C=s@) ],
 149
 150 'purge-mailsource' => [ 'LOCATION|--all',
 151         'remove imported messages from IMAP, Maildirs, and MH',
 152         qw(exact! all jobs:i indexed C=s@) ],
 153
 154 # code repos are used for `show' to solve blobs from patch mails
 155 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 156         qw(boost=i C=s@) ],
 157 'ls-coderepo' => [ '[FILTER_TERMS...]',
 158                 'list known code repos', qw(format|f=s z C=s@) ],
 159 'forget-coderepo' => [ 'DIRNAME',
 160         'stop using repo to solve blobs from patches',
 161         qw(prune C=s@) ],
 162
 163 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 164         qw(import! kw|keywords|flags! interval=s recursive|r
 165         exclude=s include=s C=s@) ],
 166 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 167                 qw(format|f=s z C=s@) ],
 168 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 169 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 170 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 171         qw(prune C=s@) ],
 172
 173 'import' => [ 'LOCATION...|--stdin',
 174         'one-time import/update from URL or filesystem',
 175         qw(stdin| offset=i recursive|r exclude=s include|I=s
 176         lock=s@ in-format|F=s kw|keywords|flags! C=s@),
 177         ],
 178 'convert' => [ 'LOCATION...|--stdin',
 179         'one-time conversion from URL or filesystem to another format',
 180         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s quiet|q
 181         lock=s@ kw|keywords|flags! C=s@),
 182         ],
 183 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 184         "use a patch to generate a query for `lei q --stdin'",
 185         qw(stdin| want|w=s@ uri debug) ],
 186 'config' => [ '[...]', sub {
 187                 'git-config(1) wrapper for '._config_path($_[0]);
 188         }, qw(config-file|system|global|file|f=s), # for conflict detection
 189          qw(C=s@), pass_through('git config') ],
 190 'init' => [ '[DIRNAME]', sub {
 191         "initialize storage, default: "._store_path($_[0]);
 192         }, qw(quiet|q C=s@) ],
 193 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 194         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 195         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 196 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 197 'help' => [ '[SUBCOMMAND]', 'show help' ],
 198
 199 # XXX do we need this?
 200 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 201
 202 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 203         'rewrite git history in an attempt to improve compression',
 204         qw(gc! C=s@) ],
 205
 206 # internal commands are prefixed with '_'
 207 '_complete' => [ '[...]', 'internal shell completion helper',
 208                 pass_through('everything') ],
 209 ); # @CMD
 210
 211 # switch descriptions, try to keep consistent across commands
 212 # $spec: Getopt::Long option specification
 213 # $spec => [@ALLOWED_VALUES (default is first), $description],
 214 # $spec => $description
 215 # "$SUB_COMMAND TAB $spec" => as above
 216 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 217                         'specify message input format' ];
 218 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 219
 220 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 221 my %OPTDESC = (
 222 'help|h' => 'show this built-in help',
 223 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 224 'quiet|q' => 'be quiet',
 225 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 226         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 227
 228 'globoff|g' => "do not match locations using '*?' wildcards ".
 229                 "and\xa0'[]'\x{a0}ranges",
 230 'verbose|v+' => 'be more verbose',
 231 'external!' => 'do not use externals',
 232 'solve!' => 'do not attempt to reconstruct blobs from emails',
 233 'torsocks=s' => ['VAL|auto|no|yes',
 234                 'whether or not to wrap git and curl commands with torsocks'],
 235 'no-torsocks' => 'alias for --torsocks=no',
 236 'save-as=s' => ['NAME', 'save a search terms by given name'],
 237 'import-remote!' => 'do not memoize remote messages into local store',
 238
 239 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 240
 241 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 242                 'deduplication strategy'],
 243 'threads|t+' =>
 244         'return all messages in the same threads as the actual match(es)',
 245
 246 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 247                 'search prefixes to extract (default: dfpost7)' ],
 248
 249 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 250         'run command(s) or perform ops when done writing to output ' .
 251         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 252         'nothing otherwise)' ],
 253
 254 'augment|a' => 'augment --output destination instead of clobbering',
 255
 256 'output|mfolder|o=s' => [ 'MFOLDER',
 257         "destination (e.g.\xa0`/path/to/Maildir', ".
 258         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 259 'mua=s' => [ 'CMD',
 260         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 261
 262 'inbox-version=i' => [ 'NUM|1|2',
 263                 'force a public-inbox version with --mirror'],
 264 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 265
 266 # public-inbox-index options
 267 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 268 'compact' => 'run compact index after mirroring',
 269 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 270         "indexlevel with --mirror (default: full)" ],
 271 'max_size|max-size=s' => [ 'SIZE',
 272         'do not index messages larger than SIZE (default: infinity)' ],
 273 'batch_size|batch-size=s' => [ 'SIZE',
 274         'flush changes to OS after given number of bytes (default: 1m)' ],
 275 'sequential_shard|sequential-shard' =>
 276         'index Xapian shards sequentially for slow storage',
 277 'skip-docdata' =>
 278         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 279
 280 'format|f=s     q' => [
 281         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 282                 'specify output format, default depends on --output'],
 283 'exclude=s@     q' => [ 'LOCATION',
 284                 'exclude specified external(s) from search' ],
 285 'include|I=s@   q' => [ 'LOCATION',
 286                 'include specified external(s) in search' ],
 287 'only=s@        q' => [ 'LOCATION',
 288                 'only use specified external(s) for search' ],
 289 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 290                 'control number of search and writer jobs' ],
 291 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 292
 293 'in-format|F=s' => $stdin_formats,
 294 'format|f=s     ls-query' => $ls_format,
 295 'format|f=s     ls-external' => $ls_format,
 296
 297 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 298 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 299
 300 'sort|s=s' => [ 'VAL|received|relevance|docid',
 301                 "order of results is `--output'-dependent"],
 302 'reverse|r' => 'reverse search results', # like sort(1)
 303
 304 'boost=i' => 'increase/decrease priority of results (default: 0)',
 305
 306 'local' => 'limit operations to the local filesystem',
 307 'local!' => 'exclude results from the local filesystem',
 308 'remote' => 'limit operations to those requiring network access',
 309 'remote!' => 'prevent operations requiring network access',
 310
 311 'mid=s' => 'specify the Message-ID of a message',
 312 'oid=s' => 'specify the git object ID of a message',
 313
 314 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 315 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 316 'include=s' => 'include mailboxes/newsgroups based on pattern',
 317
 318 'exact' => 'operate on exact header matches only',
 319 'exact!' => 'rely on content match instead of exact header matches',
 320
 321 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 322
 323 'kw|keywords|flags!' => 'disable/enable importing flags',
 324
 325 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 326 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 327
 328 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 329 ); # %OPTDESC
 330
 331 my %CONFIG_KEYS = (
 332         'leistore.dir' => 'top-level storage location',
 333 );
 334
 335 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q); # internal workers
 336
 337 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 338 sub x_it ($$) {
 339         my ($self, $code) = @_;
 340         # make sure client sees stdout before exit
 341         $self->{1}->autoflush(1) if $self->{1};
 342         dump_and_clear_log();
 343         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 344                 send($s, "x_it $code", MSG_EOR);
 345         } elsif ($self->{oneshot}) {
 346                 # don't want to end up using $? from child processes
 347                 for my $f (@WQ_KEYS) {
 348                         my $wq = delete $self->{$f} or next;
 349                         $wq->DESTROY;
 350                 }
 351                 # cleanup anything that has tempfiles or open file handles
 352                 %PATH2CFG = ();
 353                 delete @$self{qw(ovv dedupe sto cfg)};
 354                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 355                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 356                         kill $signum, $$;
 357                         sleep(1) while 1; # wait for signal
 358                 } else {
 359                         $quit->($code >> 8);
 360                 }
 361         } # else ignore if client disconnected
 362 }
 363
 364 sub err ($;@) {
 365         my $self = shift;
 366         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 367         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 368         print $err @_, @eor and return;
 369         my $old_err = delete $self->{2};
 370         close($old_err) if $! == EPIPE && $old_err;
 371         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 372         print $err @_, @eor or print STDERR @_, @eor;
 373 }
 374
 375 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 376
 377 sub fail_handler ($;$$) {
 378         my ($lei, $code, $io) = @_;
 379         for my $f (@WQ_KEYS) {
 380                 my $wq = delete $lei->{$f} or next;
 381                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 382         }
 383         close($io) if $io; # needed to avoid warnings on SIGPIPE
 384         x_it($lei, $code // (1 << 8));
 385 }
 386
 387 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 388         fail_handler($_[0], 13, delete $_[0]->{1});
 389 }
 390
 391 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 392 sub sigint_reap {
 393         my ($pgid) = @_;
 394         dwaitpid($pgid) if kill('-INT', $pgid);
 395 }
 396
 397 sub fail ($$;$) {
 398         my ($self, $buf, $exit_code) = @_;
 399         err($self, $buf) if defined $buf;
 400         # calls fail_handler:
 401         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 402         x_it($self, ($exit_code // 1) << 8);
 403         undef;
 404 }
 405
 406 sub check_input_format ($;$) {
 407         my ($self, $files) = @_;
 408         my $opt_key = 'in-format';
 409         my $fmt = $self->{opt}->{$opt_key};
 410         if (!$fmt) {
 411                 my $err = $files ? "regular file(s):\n@$files" : '--stdin';
 412                 return fail($self, "--$opt_key unset for $err");
 413         }
 414         require PublicInbox::MboxLock if $files;
 415         return 1 if $fmt eq 'eml';
 416         # XXX: should this handle {gz,bz2,xz}? that's currently in LeiToMail
 417         require PublicInbox::MboxReader;
 418         PublicInbox::MboxReader->can($fmt) or
 419                 return fail($self, "--$opt_key=$fmt unrecognized");
 420         1;
 421 }
 422
 423 sub out ($;@) {
 424         my $self = shift;
 425         return if print { $self->{1} // return } @_; # likely
 426         return note_sigpipe($self, 1) if $! == EPIPE;
 427         my $err = "error writing to output: $!";
 428         delete $self->{1};
 429         fail($self, $err);
 430 }
 431
 432 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 433
 434 sub child_error { # passes non-fatal curl exit codes to user
 435         my ($self, $child_error, $msg) = @_; # child_error is $?
 436         $self->err($msg) if $msg;
 437         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 438                 # send to the parent lei-daemon or to lei(1) client
 439                 send($s, "child_error $child_error", MSG_EOR);
 440         } elsif (!$PublicInbox::DS::in_loop) {
 441                 $self->{child_error} = $child_error;
 442         } # else noop if client disconnected
 443 }
 444
 445 sub note_sigpipe { # triggers sigpipe_handler
 446         my ($self, $fd) = @_;
 447         close(delete($self->{$fd})); # explicit close silences Perl warning
 448         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 449         x_it($self, 13);
 450 }
 451
 452 sub lei_atfork_child {
 453         my ($self, $persist) = @_;
 454         # we need to explicitly close things which are on stack
 455         if ($persist) {
 456                 my @io = delete @$self{qw(0 1 2 sock)};
 457                 unless ($self->{oneshot}) {
 458                         close($_) for @io;
 459                 }
 460         } else {
 461                 delete $self->{0};
 462         }
 463         delete @$self{qw(cnv)};
 464         for (delete @$self{qw(3 old_1 au_done)}) {
 465                 close($_) if defined($_);
 466         }
 467         if (my $op_c = delete $self->{pkt_op_c}) {
 468                 close(delete $op_c->{sock});
 469         }
 470         if (my $pgr = delete $self->{pgr}) {
 471                 close($_) for (@$pgr[1,2]);
 472         }
 473         close $listener if $listener;
 474         undef $listener;
 475         %PATH2CFG = ();
 476         undef $errors_log;
 477         $quit = \&CORE::exit;
 478         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 479 }
 480
 481 sub workers_start {
 482         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 483         $ops = {
 484                 '!' => [ $lei->can('fail_handler'), $lei ],
 485                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 486                 'x_it' => [ $lei->can('x_it'), $lei ],
 487                 'child_error' => [ $lei->can('child_error'), $lei ],
 488                 %$ops
 489         };
 490         require PublicInbox::PktOp;
 491         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 492         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 493         delete $lei->{pkt_op_p};
 494         my $op = delete $lei->{pkt_op_c};
 495         $lei->event_step_init;
 496         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 497         $lei->{oneshot} ? $op : undef;
 498 }
 499
 500 sub _help {
 501         require PublicInbox::LeiHelp;
 502         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 503 }
 504
 505 sub optparse ($$$) {
 506         my ($self, $cmd, $argv) = @_;
 507         # allow _complete --help to complete, not show help
 508         return 1 if substr($cmd, 0, 1) eq '_';
 509         $self->{cmd} = $cmd;
 510         $OPT = $self->{opt} //= {};
 511         my $info = $CMD{$cmd} // [ '[...]' ];
 512         my ($proto, undef, @spec) = @$info;
 513         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 514         push @spec, qw(help|h);
 515         my $lone_dash;
 516         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 517                 $lone_dash = $spec[0];
 518                 $OPT->{$spec[0]} = \(my $var);
 519                 push @spec, '' => \$var;
 520         }
 521         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 522                 return _help($self, "bad arguments or options for $cmd");
 523         return _help($self) if $OPT->{help};
 524
 525         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 526
 527         # "-" aliases "stdin" or "clear"
 528         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 529
 530         my $i = 0;
 531         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 532         my ($err, $inf);
 533         my @args = split(/ /, $proto);
 534         for my $var (@args) {
 535                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 536                         $inf = defined($argv->[$i]) and last;
 537                         $var =~ s/\.\.\.\z//;
 538                         $err = "$var not supplied";
 539                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 540                         $argv->[$i++] // ($err = "$var not supplied");
 541                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 542                         $inf = 1;
 543                         last;
 544                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 545                         $i++;
 546                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 547                         $inf = 1 if index($var, '...') > 0;
 548                         my @or = split(/\|/, $var);
 549                         my $ok;
 550                         for my $o (@or) {
 551                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 552                                         $ok = defined($OPT->{$1});
 553                                         last if $ok;
 554                                 } elsif (defined($argv->[$i])) {
 555                                         $ok = 1;
 556                                         $i++;
 557                                         last;
 558                                 } # else continue looping
 559                         }
 560                         last if $ok;
 561                         my $last = pop @or;
 562                         $err = join(', ', @or) . " or $last must be set";
 563                 } else {
 564                         warn "BUG: can't parse `$var' in $proto";
 565                 }
 566                 last if $err;
 567         }
 568         if (!$inf && scalar(@$argv) > scalar(@args)) {
 569                 $err //= 'too many arguments';
 570         }
 571         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 572 }
 573
 574 sub dispatch {
 575         my ($self, $cmd, @argv) = @_;
 576         local $current_lei = $self; # for __WARN__
 577         dump_and_clear_log("from previous run\n");
 578         return _help($self, 'no command given') unless defined($cmd);
 579         while ($cmd eq '-C') { # do not support Getopt bundling for this
 580                 my $d = shift(@argv) // return fail($self, '-C DIRECTORY');
 581                 push @{$self->{opt}->{C}}, $d;
 582                 $cmd = shift(@argv) // return _help($self, 'no command given');
 583         }
 584         my $func = "lei_$cmd";
 585         $func =~ tr/-/_/;
 586         if (my $cb = __PACKAGE__->can($func)) {
 587                 optparse($self, $cmd, \@argv) or return;
 588                 if (my $chdir = $self->{opt}->{C}) {
 589                         for my $d (@$chdir) {
 590                                 next if $d eq ''; # same as git(1)
 591                                 chdir $d or return fail($self, "cd $d: $!");
 592                         }
 593                 }
 594                 $cb->($self, @argv);
 595         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 596                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 597                         or return _help($self, 'bad arguments or options');
 598                 _help($self);
 599         } else {
 600                 fail($self, "`$cmd' is not an lei command");
 601         }
 602 }
 603
 604 sub _lei_cfg ($;$) {
 605         my ($self, $creat) = @_;
 606         my $f = _config_path($self);
 607         my @st = stat($f);
 608         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 609         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 610                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 611         }
 612         if (!@st) {
 613                 unless ($creat) {
 614                         delete $self->{cfg};
 615                         return bless {}, 'PublicInbox::Config';
 616                 }
 617                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 618                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 619                 open my $fh, '>>', $f or die "open($f): $!\n";
 620                 @st = stat($fh) or die "fstat($f): $!\n";
 621                 $cur_st = pack('dd', $st[10], $st[7]);
 622                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 623         }
 624         my $cfg = PublicInbox::Config::git_config_dump($f);
 625         bless $cfg, 'PublicInbox::Config';
 626         $cfg->{-st} = $cur_st;
 627         $cfg->{'-f'} = $f;
 628         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 629 }
 630
 631 sub _lei_store ($;$) {
 632         my ($self, $creat) = @_;
 633         my $cfg = _lei_cfg($self, $creat);
 634         $cfg->{-lei_store} //= do {
 635                 require PublicInbox::LeiStore;
 636                 my $dir = $cfg->{'leistore.dir'};
 637                 $dir //= $creat ? _store_path($self) : return;
 638                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 639         };
 640 }
 641
 642 sub lei_show {
 643         my ($self, @argv) = @_;
 644 }
 645
 646 sub lei_mark {
 647         my ($self, @argv) = @_;
 648 }
 649
 650 sub _config {
 651         my ($self, @argv) = @_;
 652         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 653         my $cfg = _lei_cfg($self, 1);
 654         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 655         my %rdr = map { $_ => $self->{$_} } (0..2);
 656         waitpid(spawn($cmd, \%env, \%rdr), 0);
 657 }
 658
 659 sub lei_config {
 660         my ($self, @argv) = @_;
 661         $self->{opt}->{'config-file'} and return fail $self,
 662                 "config file switches not supported by `lei config'";
 663         _config(@_);
 664         x_it($self, $?) if $?;
 665 }
 666
 667 sub lei_import {
 668         require PublicInbox::LeiImport;
 669         PublicInbox::LeiImport->call(@_);
 670 }
 671
 672 sub lei_convert {
 673         require PublicInbox::LeiConvert;
 674         PublicInbox::LeiConvert->call(@_);
 675 }
 676
 677 sub lei_p2q {
 678         require PublicInbox::LeiP2q;
 679         PublicInbox::LeiP2q->call(@_);
 680 }
 681
 682 sub lei_init {
 683         my ($self, $dir) = @_;
 684         my $cfg = _lei_cfg($self, 1);
 685         my $cur = $cfg->{'leistore.dir'};
 686         $dir //= _store_path($self);
 687         $dir = rel2abs($self, $dir);
 688         my @cur = stat($cur) if defined($cur);
 689         $cur = File::Spec->canonpath($cur // $dir);
 690         my @dir = stat($dir);
 691         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 692         if (@cur) {
 693                 if ($cur eq $dir) {
 694                         _lei_store($self, 1)->done;
 695                         return qerr($self, $exists);
 696                 }
 697
 698                 # some folks like symlinks and bind mounts :P
 699                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 700                         lei_config($self, 'leistore.dir', $dir);
 701                         _lei_store($self, 1)->done;
 702                         return qerr($self, "$exists (as $cur)");
 703                 }
 704                 return fail($self, <<"");
 705 E: leistore.dir=$cur already initialized and it is not $dir
 706
 707         }
 708         lei_config($self, 'leistore.dir', $dir);
 709         _lei_store($self, 1)->done;
 710         $exists //= "# leistore.dir=$dir newly initialized";
 711         return qerr($self, $exists);
 712 }
 713
 714 sub lei_daemon_pid { puts shift, $$ }
 715
 716 sub lei_daemon_kill {
 717         my ($self) = @_;
 718         my $sig = $self->{opt}->{signal} // 'TERM';
 719         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 720 }
 721
 722 sub lei_help { _help($_[0]) }
 723
 724 # Shell completion helper.  Used by lei-completion.bash and hopefully
 725 # other shells.  Try to do as much here as possible to avoid redundancy
 726 # and improve maintainability.
 727 sub lei__complete {
 728         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 729         shift @argv; # ignore "lei", the entire command is sent
 730         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 731         my $cmd = shift @argv;
 732         my $info = $CMD{$cmd} // do { # filter matching commands
 733                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 734                 return;
 735         };
 736         my ($proto, undef, @spec) = @$info;
 737         my $cur = pop @argv;
 738         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 739         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 740                 # gross special case since the only git-config options
 741                 # Consider moving to a table if we need more special cases
 742                 # we use Getopt::Long for are the ones we reject, so these
 743                 # are the ones we don't reject:
 744                 if ($cmd eq 'config') {
 745                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 746                         @spec = qw(add z|null get get-all unset unset-all
 747                                 replace-all get-urlmatch
 748                                 remove-section rename-section
 749                                 name-only list|l edit|e
 750                                 get-color-name get-colorbool);
 751                         # fall-through
 752                 }
 753                 # generate short/long names from Getopt::Long specs
 754                 puts $self, grep(/$re/, qw(--help -h -C), map {
 755                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 756                         } elsif (s/\+\z//) { # verbose|v+
 757                         } elsif (s/!\z//) {
 758                                 # negation: solve! => no-solve|solve
 759                                 s/([\w\-]+)/$1|no-$1/g
 760                         }
 761                         map {
 762                                 my $x = length > 1 ? "--$_" : "-$_";
 763                                 $x eq $cur ? () : $x;
 764                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 765                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 766         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 767                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 768         }
 769
 770         # switch args (e.g. lei q -f mbox<TAB>)
 771         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 772                 my $opt = quotemeta $1;
 773                 puts $self, map {
 774                         my $v = $OPTDESC{$_};
 775                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 776                         # get rid of ALL CAPS placeholder (e.g "OUT")
 777                         # (TODO: completion for external paths)
 778                         shift(@v) if uc($v[0]) eq $v[0];
 779                         @v;
 780                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 781         }
 782         $cmd =~ tr/-/_/;
 783         if (my $sub = $self->can("_complete_$cmd")) {
 784                 puts $self, $sub->($self, @argv, $cur);
 785         }
 786         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 787         # proto parsing.
 788 }
 789
 790 sub exec_buf ($$) {
 791         my ($argv, $env) = @_;
 792         my $argc = scalar @$argv;
 793         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 794         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 795         $buf;
 796 }
 797
 798 sub start_mua {
 799         my ($self) = @_;
 800         my $mua = $self->{opt}->{mua} // return;
 801         my $mfolder = $self->{ovv}->{dst};
 802         my (@cmd, $replaced);
 803         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 804                 @cmd = ($mua, '-f');
 805         # TODO: help wanted: other common FOSS MUAs
 806         } else {
 807                 require Text::ParseWords;
 808                 @cmd = Text::ParseWords::shellwords($mua);
 809                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 810                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 811         }
 812         push @cmd, $mfolder unless defined($replaced);
 813         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 814                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 815         } elsif ($self->{oneshot}) {
 816                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 817         }
 818         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 819                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 820         }
 821         $self->{opt}->{quiet} = 1;
 822         delete $self->{-progress};
 823         delete $self->{opt}->{verbose};
 824 }
 825
 826 sub send_exec_cmd { # tell script/lei to execute a command
 827         my ($self, $io, $cmd, $env) = @_;
 828         my $sock = $self->{sock} // die 'lei client gone';
 829         my $fds = [ map { fileno($_) } @$io ];
 830         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 831 }
 832
 833 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 834         my ($self) = @_;
 835         my $alerts = $self->{opt}->{alert} // return;
 836         while (my $op = shift(@$alerts)) {
 837                 if ($op eq ':WINCH') {
 838                         # hit the process group that started the MUA
 839                         if ($self->{sock}) {
 840                                 send($self->{sock}, '-WINCH', MSG_EOR);
 841                         } elsif ($self->{oneshot}) {
 842                                 kill('-WINCH', $$);
 843                         }
 844                 } elsif ($op eq ':bell') {
 845                         out($self, "\a");
 846                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 847                         push @$alerts, split(/(?<!\\),/, $op);
 848                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 849                         my $cmd = $1; # run an arbitrary command
 850                         require Text::ParseWords;
 851                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 852                         if (my $s = $self->{sock}) {
 853                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 854                         } elsif ($self->{oneshot}) {
 855                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 856                         }
 857                 } else {
 858                         err($self, "W: unsupported --alert=$op"); # non-fatal
 859                 }
 860         }
 861 }
 862
 863 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 864 $path_to_fd{"/dev/fd/$_"} = $path_to_fd{"/proc/self/fd/$_"} for (0..2);
 865 sub fopen {
 866         my ($self, $mode, $path) = @_;
 867         rel2abs($self, $path);
 868         $path =~ tr!/!/!s;
 869         if (defined(my $fd = $path_to_fd{$path})) {
 870                 return $self->{$fd};
 871         }
 872         if ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) {
 873                 return fail($self, "cannot open $path from daemon");
 874         }
 875         open my $fh, $mode, $path or return;
 876         $fh;
 877 }
 878
 879 # caller needs to "-t $self->{1}" to check if tty
 880 sub start_pager {
 881         my ($self) = @_;
 882         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 883         chomp(my $pager = <$fh> // '');
 884         close($fh) or warn "`git var PAGER' error: \$?=$?";
 885         return if $pager eq 'cat' || $pager eq '';
 886         my $new_env = { LESS => 'FRX', LV => '-c' };
 887         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 888         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 889         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 890         my $pgr = [ undef, @$rdr{1, 2} ];
 891         my $env = $self->{env};
 892         if ($self->{sock}) { # lei(1) process runs it
 893                 delete @$new_env{keys %$env}; # only set iff unset
 894                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 895         } elsif ($self->{oneshot}) {
 896                 my $cmd = [$pager];
 897                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 898         } else {
 899                 die 'BUG: start_pager w/o socket';
 900         }
 901         $self->{1} = $wpager;
 902         $self->{2} = $wpager if -t $self->{2};
 903         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 904         $self->{pgr} = $pgr;
 905 }
 906
 907 sub stop_pager {
 908         my ($self) = @_;
 909         my $pgr = delete($self->{pgr}) or return;
 910         $self->{2} = $pgr->[2];
 911         # do not restore original stdout, just close it so we error out
 912         close(delete($self->{1})) if $self->{1};
 913 }
 914
 915 sub accept_dispatch { # Listener {post_accept} callback
 916         my ($sock) = @_; # ignore other
 917         $sock->autoflush(1);
 918         my $self = bless { sock => $sock }, __PACKAGE__;
 919         vec(my $rvec = '', fileno($sock), 1) = 1;
 920         select($rvec, undef, undef, 60) or
 921                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 922         # (4096 * 33) >MAX_ARG_STRLEN
 923         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 924         if (scalar(@fds) == 4) {
 925                 for my $i (0..3) {
 926                         my $fd = shift(@fds);
 927                         open($self->{$i}, '+<&=', $fd) and next;
 928                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 929                 }
 930         } elsif (!defined($fds[0])) {
 931                 warn(my $msg = "recv_cmd failed: $!");
 932                 return send($sock, $msg, MSG_EOR);
 933         } else {
 934                 return;
 935         }
 936         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 937         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 938         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 939         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 940                 return send($sock, 'request command truncated', MSG_EOR);
 941         my ($argc, @argv) = split(/\0/, $buf, -1);
 942         undef $buf;
 943         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 944         if (chdir($self->{3})) {
 945                 local %ENV = %env;
 946                 $self->{env} = \%env;
 947                 eval { dispatch($self, @argv) };
 948                 send($sock, $@, MSG_EOR) if $@;
 949         } else {
 950                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 951         }
 952 }
 953
 954 sub dclose {
 955         my ($self) = @_;
 956         delete $self->{-progress};
 957         for my $f (@WQ_KEYS) {
 958                 my $wq = delete $self->{$f} or next;
 959                 if ($wq->wq_kill) {
 960                         $wq->wq_close(0, undef, $self);
 961                 } elsif ($wq->wq_kill_old) {
 962                         $wq->wq_wait_old(undef, $self);
 963                 }
 964         }
 965         close(delete $self->{1}) if $self->{1}; # may reap_compress
 966         if (my $sto = delete $self->{sto}) {
 967                 $sto->ipc_do('done');
 968         }
 969         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 970 }
 971
 972 # for long-running results
 973 sub event_step {
 974         my ($self) = @_;
 975         local %ENV = %{$self->{env}};
 976         my $sock = $self->{sock};
 977         local $current_lei = $self;
 978         eval {
 979                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 980                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 981                                 return if $! == EAGAIN;
 982                                 next if $! == EINTR;
 983                                 last if $! == ECONNRESET;
 984                                 die "recvmsg: $!";
 985                         }
 986                         for my $fd (@fds) {
 987                                 open my $rfh, '+<&=', $fd;
 988                         }
 989                         die "unrecognized client signal: $buf";
 990                 }
 991                 dclose($self);
 992         };
 993         if (my $err = $@) {
 994                 eval { $self->fail($err) };
 995                 dclose($self);
 996         }
 997 }
 998
 999 sub event_step_init {
1000         my ($self) = @_;
1001         return if $self->{-event_init_done}++;
1002         if (my $sock = $self->{sock}) { # using DS->EventLoop
1003                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1004         }
1005 }
1006
1007 sub noop {}
1008
1009 sub oldset { $oldset }
1010
1011 sub dump_and_clear_log {
1012         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1013                 my @pfx = @_;
1014                 unshift(@pfx, "$errors_log ") if @pfx;
1015                 warn @pfx, do { local $/; <STDIN> };
1016                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1017         }
1018 }
1019
1020 # lei(1) calls this when it can't connect
1021 sub lazy_start {
1022         my ($path, $errno, $narg) = @_;
1023         local ($errors_log, $listener);
1024         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1025         $errors_log .= 'errors.log';
1026         my $addr = pack_sockaddr_un($path);
1027         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1028         $lk->lock_acquire;
1029         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1030         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1031                 return if connect($listener, $addr); # another process won
1032                 if ($errno == ECONNREFUSED && -S $path) {
1033                         unlink($path) or die "unlink($path): $!";
1034                 }
1035         } else {
1036                 $! = $errno; # allow interpolation to stringify in die
1037                 die "connect($path): $!";
1038         }
1039         umask(077) // die("umask(077): $!");
1040         bind($listener, $addr) or die "bind($path): $!";
1041         listen($listener, 1024) or die "listen: $!";
1042         $lk->lock_release;
1043         undef $lk;
1044         my @st = stat($path) or die "stat($path): $!";
1045         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1046         local $oldset = PublicInbox::DS::block_signals();
1047         if ($narg == 5) {
1048                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1049                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1050                         require PublicInbox::CmdIPC4;
1051                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1052                         PublicInbox::CmdIPC4->can('recv_cmd4');
1053                 };
1054         }
1055         $recv_cmd or die <<"";
1056 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1057
1058         require PublicInbox::Listener;
1059         require PublicInbox::EOFpipe;
1060         (-p STDOUT) or die "E: stdout must be a pipe\n";
1061         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1062         STDIN->autoflush(1);
1063         dump_and_clear_log("from previous daemon process:\n");
1064         POSIX::setsid() > 0 or die "setsid: $!";
1065         my $pid = fork // die "fork: $!";
1066         return if $pid;
1067         $0 = "lei-daemon $path";
1068         local %PATH2CFG;
1069         $listener->blocking(0);
1070         my $exit_code;
1071         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1072         local $quit = do {
1073                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1074                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1075                 sub {
1076                         $exit_code //= shift;
1077                         my $lis = $pil or exit($exit_code);
1078                         # closing eof_w triggers \&noop wakeup
1079                         $listener = $eof_w = $pil = $path = undef;
1080                         $lis->close; # DS::close
1081                         PublicInbox::DS->SetLoopTimeout(1000);
1082                 };
1083         };
1084         my $sig = {
1085                 CHLD => \&PublicInbox::DS::enqueue_reap,
1086                 QUIT => $quit,
1087                 INT => $quit,
1088                 TERM => $quit,
1089                 HUP => \&noop,
1090                 USR1 => \&noop,
1091                 USR2 => \&noop,
1092         };
1093         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1094         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1095         undef $sig;
1096         local $SIG{PIPE} = 'IGNORE';
1097         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1098                 undef $sigfd;
1099                 PublicInbox::DS->SetLoopTimeout(5000);
1100         } else {
1101                 # wake up every second to accept signals if we don't
1102                 # have signalfd or IO::KQueue:
1103                 PublicInbox::DS::sig_setmask($oldset);
1104                 PublicInbox::DS->SetLoopTimeout(1000);
1105         }
1106         PublicInbox::DS->SetPostLoopCallback(sub {
1107                 my ($dmap, undef) = @_;
1108                 if (@st = defined($path) ? stat($path) : ()) {
1109                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1110                                 warn "$path dev/ino changed, quitting\n";
1111                                 $path = undef;
1112                         }
1113                 } elsif (defined($path)) { # ENOENT is common
1114                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1115                         undef $path;
1116                         $quit->();
1117                 }
1118                 return 1 if defined($path);
1119                 my $now = now();
1120                 my $n = 0;
1121                 for my $s (values %$dmap) {
1122                         $s->can('busy') or next;
1123                         if ($s->busy($now)) {
1124                                 ++$n;
1125                         } else {
1126                                 $s->close;
1127                         }
1128                 }
1129                 $n; # true: continue, false: stop
1130         });
1131
1132         # STDIN was redirected to /dev/null above, closing STDERR and
1133         # STDOUT will cause the calling `lei' client process to finish
1134         # reading the <$daemon> pipe.
1135         local $SIG{__WARN__} = sub {
1136                 $current_lei ? err($current_lei, @_) : warn(
1137                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1138         };
1139         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1140         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1141         # $daemon pipe to `lei' closed, main loop begins:
1142         PublicInbox::DS->EventLoop;
1143         exit($exit_code // 0);
1144 }
1145
1146 sub busy { 1 } # prevent daemon-shutdown if client is connected
1147
1148 # for users w/o Socket::Msghdr installed or Inline::C enabled
1149 sub oneshot {
1150         my ($main_pkg) = @_;
1151         my $exit = $main_pkg->can('exit'); # caller may override exit()
1152         local $quit = $exit if $exit;
1153         local %PATH2CFG;
1154         umask(077) // die("umask(077): $!");
1155         my $self = bless {
1156                 oneshot => 1,
1157                 0 => *STDIN{GLOB},
1158                 1 => *STDOUT{GLOB},
1159                 2 => *STDERR{GLOB},
1160                 env => \%ENV
1161         }, __PACKAGE__;
1162         dispatch($self, @ARGV);
1163         x_it($self, $self->{child_error}) if $self->{child_error};
1164 }
1165
1166 # ensures stdout hits the FS before sock disconnects so a client
1167 # can immediately reread it
1168 sub DESTROY {
1169         my ($self) = @_;
1170         $self->{1}->autoflush(1) if $self->{1};
1171         stop_pager($self);
1172         my $err = $?;
1173         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1174         waitpid($_, 0) for keys %$oneshot_pids;
1175         $? = $err if $err; # preserve ->fail or ->x_it code
1176 }
1177
1178 1;