lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123
 124 # we generate shell completion + help using %CMD and %OPTDESC,
 125 # see lei__complete() and PublicInbox::LeiHelp
 126 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 127 our %CMD = ( # sorted in order of importance/use:
 128 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 129         'stdin|', # /|\z/ must be first for lone dash
 130         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 131         sort|s=s reverse|r offset=i remote! local! external! pretty
 132         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 133         import-remote! import-before! lock=s@ rsyncable
 134         alert=s@ mua=s no-torsocks torsocks=s verbose|v+), @c_opt,
 135         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 136
 137 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 138         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local!
 139         verbose|v+), @c_opt, pass_through('git show') ],
 140
 141 'add-external' => [ 'LOCATION',
 142         'add/set priority of a publicinbox|extindex for extra matches',
 143         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 144         verbose|v+), @c_opt, index_opt(),
 145         PublicInbox::LeiQuery::curl_opt() ],
 146 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 147         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 148 'forget-external' => [ 'LOCATION...|--prune',
 149         'exclude further results from a publicinbox|extindex',
 150         qw(prune), @c_opt ],
 151
 152 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 153                 qw(name-only format|f=s), @c_opt ],
 154 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 155 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 156
 157 'plonk' => [ '--threads|--from=IDENT',
 158         'exclude mail matching From: or threads from non-Message-ID searches',
 159         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 160 'mark' => [ 'KEYWORDS...',
 161         'set/unset keywords on message(s)',
 162         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 163         pass_through('-kw:foo for delete') ],
 164 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 165         "exclude message(s) on stdin from `q' search results",
 166         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 167
 168 'purge-mailsource' => [ 'LOCATION|--all',
 169         'remove imported messages from IMAP, Maildirs, and MH',
 170         qw(exact! all jobs:i indexed), @c_opt ],
 171
 172 # code repos are used for `show' to solve blobs from patch mails
 173 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 174         qw(boost=i), @c_opt ],
 175 'ls-coderepo' => [ '[FILTER_TERMS...]',
 176                 'list known code repos', qw(format|f=s z), @c_opt ],
 177 'forget-coderepo' => [ 'DIRNAME',
 178         'stop using repo to solve blobs from patches',
 179         qw(prune), @c_opt ],
 180
 181 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 182         qw(import! kw|keywords|flags! interval=s recursive|r
 183         exclude=s include=s), @c_opt ],
 184 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 185                 qw(format|f=s z), @c_opt ],
 186 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 187 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 188 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 189         qw(prune), @c_opt ],
 190
 191 'import' => [ 'LOCATION...|--stdin',
 192         'one-time import/update from URL or filesystem',
 193         qw(stdin| offset=i recursive|r exclude=s include|I=s
 194         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 195 'convert' => [ 'LOCATION...|--stdin',
 196         'one-time conversion from URL or filesystem to another format',
 197         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 198         lock=s@ kw|keywords|flags!), @c_opt ],
 199 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 200         "use a patch to generate a query for `lei q --stdin'",
 201         qw(stdin| want|w=s@ uri debug), @c_opt ],
 202 'config' => [ '[...]', sub {
 203                 'git-config(1) wrapper for '._config_path($_[0]);
 204         }, qw(config-file|system|global|file|f=s), # for conflict detection
 205          qw(c=s@ C=s@), pass_through('git config') ],
 206 'init' => [ '[DIRNAME]', sub {
 207         "initialize storage, default: ".store_path($_[0]);
 208         }, @c_opt ],
 209 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 210         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 211         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 212 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 213 'help' => [ '[SUBCOMMAND]', 'show help' ],
 214
 215 # XXX do we need this?
 216 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 217
 218 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 219         'rewrite git history in an attempt to improve compression',
 220         qw(gc!), @c_opt ],
 221
 222 # internal commands are prefixed with '_'
 223 '_complete' => [ '[...]', 'internal shell completion helper',
 224                 pass_through('everything') ],
 225 ); # @CMD
 226
 227 # switch descriptions, try to keep consistent across commands
 228 # $spec: Getopt::Long option specification
 229 # $spec => [@ALLOWED_VALUES (default is first), $description],
 230 # $spec => $description
 231 # "$SUB_COMMAND TAB $spec" => as above
 232 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 233                         'specify message input format' ];
 234 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 235
 236 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 237 my %OPTDESC = (
 238 'help|h' => 'show this built-in help',
 239 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 240 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 241 'quiet|q' => 'be quiet',
 242 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 243         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 244
 245 'globoff|g' => "do not match locations using '*?' wildcards ".
 246                 "and\xa0'[]'\x{a0}ranges",
 247 'verbose|v+' => 'be more verbose',
 248 'external!' => 'do not use externals',
 249 'solve!' => 'do not attempt to reconstruct blobs from emails',
 250 'torsocks=s' => ['VAL|auto|no|yes',
 251                 'whether or not to wrap git and curl commands with torsocks'],
 252 'no-torsocks' => 'alias for --torsocks=no',
 253 'save-as=s' => ['NAME', 'save a search terms by given name'],
 254 'import-remote!' => 'do not memoize remote messages into local store',
 255
 256 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 257
 258 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 259                 'deduplication strategy'],
 260 'threads|t+' =>
 261         'return all messages in the same threads as the actual match(es)',
 262
 263 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 264                 'search prefixes to extract (default: dfpost7)' ],
 265
 266 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 267         'run command(s) or perform ops when done writing to output ' .
 268         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 269         'nothing otherwise)' ],
 270
 271 'augment|a' => 'augment --output destination instead of clobbering',
 272
 273 'output|mfolder|o=s' => [ 'MFOLDER',
 274         "destination (e.g.\xa0`/path/to/Maildir', ".
 275         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 276 'mua=s' => [ 'CMD',
 277         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 278
 279 'inbox-version=i' => [ 'NUM|1|2',
 280                 'force a public-inbox version with --mirror'],
 281 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 282
 283 # public-inbox-index options
 284 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 285 'compact' => 'run compact index after mirroring',
 286 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 287         "indexlevel with --mirror (default: full)" ],
 288 'max_size|max-size=s' => [ 'SIZE',
 289         'do not index messages larger than SIZE (default: infinity)' ],
 290 'batch_size|batch-size=s' => [ 'SIZE',
 291         'flush changes to OS after given number of bytes (default: 1m)' ],
 292 'sequential_shard|sequential-shard' =>
 293         'index Xapian shards sequentially for slow storage',
 294 'skip-docdata' =>
 295         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 296
 297 'format|f=s     q' => [
 298         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 299                 'specify output format, default depends on --output'],
 300 'exclude=s@     q' => [ 'LOCATION',
 301                 'exclude specified external(s) from search' ],
 302 'include|I=s@   q' => [ 'LOCATION',
 303                 'include specified external(s) in search' ],
 304 'only=s@        q' => [ 'LOCATION',
 305                 'only use specified external(s) for search' ],
 306 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 307                 'control number of search and writer jobs' ],
 308 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 309
 310 'in-format|F=s' => $stdin_formats,
 311 'format|f=s     ls-query' => $ls_format,
 312 'format|f=s     ls-external' => $ls_format,
 313
 314 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 315 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 316
 317 'sort|s=s' => [ 'VAL|received|relevance|docid',
 318                 "order of results is `--output'-dependent"],
 319 'reverse|r' => 'reverse search results', # like sort(1)
 320
 321 'boost=i' => 'increase/decrease priority of results (default: 0)',
 322
 323 'local' => 'limit operations to the local filesystem',
 324 'local!' => 'exclude results from the local filesystem',
 325 'remote' => 'limit operations to those requiring network access',
 326 'remote!' => 'prevent operations requiring network access',
 327
 328 'mid=s' => 'specify the Message-ID of a message',
 329 'oid=s' => 'specify the git object ID of a message',
 330
 331 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 332 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 333 'include=s' => 'include mailboxes/newsgroups based on pattern',
 334
 335 'exact' => 'operate on exact header matches only',
 336 'exact!' => 'rely on content match instead of exact header matches',
 337
 338 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 339
 340 'kw|keywords|flags!' => 'disable/enable importing flags',
 341
 342 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 343 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 344
 345 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 346 ); # %OPTDESC
 347
 348 my %CONFIG_KEYS = (
 349         'leistore.dir' => 'top-level storage location',
 350 );
 351
 352 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q mark); # internal workers
 353
 354 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 355 sub x_it ($$) {
 356         my ($self, $code) = @_;
 357         # make sure client sees stdout before exit
 358         $self->{1}->autoflush(1) if $self->{1};
 359         dump_and_clear_log();
 360         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 361                 send($s, "x_it $code", MSG_EOR);
 362         } elsif ($self->{oneshot}) {
 363                 # don't want to end up using $? from child processes
 364                 for my $f (@WQ_KEYS) {
 365                         my $wq = delete $self->{$f} or next;
 366                         $wq->DESTROY;
 367                 }
 368                 # cleanup anything that has tempfiles or open file handles
 369                 %PATH2CFG = ();
 370                 delete @$self{qw(ovv dedupe sto cfg)};
 371                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 372                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 373                         kill $signum, $$;
 374                         sleep(1) while 1; # wait for signal
 375                 } else {
 376                         $quit->($code >> 8);
 377                 }
 378         } # else ignore if client disconnected
 379 }
 380
 381 sub err ($;@) {
 382         my $self = shift;
 383         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 384         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 385         print $err @_, @eor and return;
 386         my $old_err = delete $self->{2};
 387         close($old_err) if $! == EPIPE && $old_err;
 388         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 389         print $err @_, @eor or print STDERR @_, @eor;
 390 }
 391
 392 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 393
 394 sub fail_handler ($;$$) {
 395         my ($lei, $code, $io) = @_;
 396         for my $f (@WQ_KEYS) {
 397                 my $wq = delete $lei->{$f} or next;
 398                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 399         }
 400         close($io) if $io; # needed to avoid warnings on SIGPIPE
 401         x_it($lei, $code // (1 << 8));
 402 }
 403
 404 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 405         fail_handler($_[0], 13, delete $_[0]->{1});
 406 }
 407
 408 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 409 sub sigint_reap {
 410         my ($pgid) = @_;
 411         dwaitpid($pgid) if kill('-INT', $pgid);
 412 }
 413
 414 sub fail ($$;$) {
 415         my ($self, $buf, $exit_code) = @_;
 416         err($self, $buf) if defined $buf;
 417         # calls fail_handler:
 418         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 419         x_it($self, ($exit_code // 1) << 8);
 420         undef;
 421 }
 422
 423 sub out ($;@) {
 424         my $self = shift;
 425         return if print { $self->{1} // return } @_; # likely
 426         return note_sigpipe($self, 1) if $! == EPIPE;
 427         my $err = "error writing to output: $!";
 428         delete $self->{1};
 429         fail($self, $err);
 430 }
 431
 432 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 433
 434 sub child_error { # passes non-fatal curl exit codes to user
 435         my ($self, $child_error, $msg) = @_; # child_error is $?
 436         $self->err($msg) if $msg;
 437         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 438                 # send to the parent lei-daemon or to lei(1) client
 439                 send($s, "child_error $child_error", MSG_EOR);
 440         } elsif (!$PublicInbox::DS::in_loop) {
 441                 $self->{child_error} = $child_error;
 442         } # else noop if client disconnected
 443 }
 444
 445 sub note_sigpipe { # triggers sigpipe_handler
 446         my ($self, $fd) = @_;
 447         close(delete($self->{$fd})); # explicit close silences Perl warning
 448         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 449         x_it($self, 13);
 450 }
 451
 452 sub _lei_atfork_child {
 453         my ($self, $persist) = @_;
 454         # we need to explicitly close things which are on stack
 455         if ($persist) {
 456                 chdir '/' or die "chdir(/): $!";
 457                 my @io = delete @$self{qw(0 1 2 sock)};
 458                 unless ($self->{oneshot}) {
 459                         close($_) for @io;
 460                 }
 461         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 462                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 463                 delete $self->{0};
 464         }
 465         delete @$self{qw(cnv mark imp)};
 466         for (delete @$self{qw(3 old_1 au_done)}) {
 467                 close($_) if defined($_);
 468         }
 469         if (my $op_c = delete $self->{pkt_op_c}) {
 470                 close(delete $op_c->{sock});
 471         }
 472         if (my $pgr = delete $self->{pgr}) {
 473                 close($_) for (@$pgr[1,2]);
 474         }
 475         close $listener if $listener;
 476         undef $listener;
 477         %PATH2CFG = ();
 478         undef $errors_log;
 479         $quit = \&CORE::exit;
 480         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 481 }
 482
 483 sub workers_start {
 484         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 485         $ops = {
 486                 '!' => [ \&fail_handler, $lei ],
 487                 '|' => [ \&sigpipe_handler, $lei ],
 488                 'x_it' => [ \&x_it, $lei ],
 489                 'child_error' => [ \&child_error, $lei ],
 490                 ($ops ? %$ops : ()),
 491         };
 492         $ops->{''} //= [ \&dclose, $lei ];
 493         require PublicInbox::PktOp;
 494         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 495         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 496         delete $lei->{pkt_op_p};
 497         my $op = delete $lei->{pkt_op_c};
 498         $lei->event_step_init;
 499         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 500         $lei->{oneshot} ? $op : undef;
 501 }
 502
 503 sub _help {
 504         require PublicInbox::LeiHelp;
 505         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 506 }
 507
 508 sub optparse ($$$) {
 509         my ($self, $cmd, $argv) = @_;
 510         # allow _complete --help to complete, not show help
 511         return 1 if substr($cmd, 0, 1) eq '_';
 512         $self->{cmd} = $cmd;
 513         $OPT = $self->{opt} //= {};
 514         my $info = $CMD{$cmd} // [ '[...]' ];
 515         my ($proto, undef, @spec) = @$info;
 516         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 517         push @spec, qw(help|h);
 518         my $lone_dash;
 519         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 520                 $lone_dash = $spec[0];
 521                 $OPT->{$spec[0]} = \(my $var);
 522                 push @spec, '' => \$var;
 523         }
 524         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 525                 return _help($self, "bad arguments or options for $cmd");
 526         return _help($self) if $OPT->{help};
 527
 528         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 529
 530         # "-" aliases "stdin" or "clear"
 531         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 532
 533         my $i = 0;
 534         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 535         my ($err, $inf);
 536         my @args = split(/ /, $proto);
 537         for my $var (@args) {
 538                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 539                         $inf = defined($argv->[$i]) and last;
 540                         $var =~ s/\.\.\.\z//;
 541                         $err = "$var not supplied";
 542                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 543                         $argv->[$i++] // ($err = "$var not supplied");
 544                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 545                         $inf = 1;
 546                         last;
 547                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 548                         $i++;
 549                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 550                         $inf = 1 if index($var, '...') > 0;
 551                         my @or = split(/\|/, $var);
 552                         my $ok;
 553                         for my $o (@or) {
 554                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 555                                         $ok = defined($OPT->{$1});
 556                                         last if $ok;
 557                                 } elsif (defined($argv->[$i])) {
 558                                         $ok = 1;
 559                                         $i++;
 560                                         last;
 561                                 } # else continue looping
 562                         }
 563                         last if $ok;
 564                         my $last = pop @or;
 565                         $err = join(', ', @or) . " or $last must be set";
 566                 } else {
 567                         warn "BUG: can't parse `$var' in $proto";
 568                 }
 569                 last if $err;
 570         }
 571         if (!$inf && scalar(@$argv) > scalar(@args)) {
 572                 $err //= 'too many arguments';
 573         }
 574         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 575 }
 576
 577 sub _tmp_cfg { # for lei -c <name>=<value> ...
 578         my ($self) = @_;
 579         my $cfg = _lei_cfg($self, 1);
 580         require File::Temp;
 581         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 582         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 583         $ft->autoflush(1);
 584         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 585 [include]
 586         path = $cfg->{-f}
 587 EOM
 588         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 589         for (@{$self->{opt}->{c}}) {
 590                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 591 `-c $_' is not of the form -c <name>=<value>'
 592 EOM
 593                 my $name = $1;
 594                 my $value = $2 // 1;
 595                 _config($self, '--add', $name, $value);
 596                 if (defined(my $v = $tmp->{$name})) {
 597                         if (ref($v) eq 'ARRAY') {
 598                                 push @$v, $value;
 599                         } else {
 600                                 $tmp->{$name} = [ $v, $value ];
 601                         }
 602                 } else {
 603                         $tmp->{$name} = $value;
 604                 }
 605         }
 606 }
 607
 608 sub lazy_cb ($$$) {
 609         my ($self, $cmd, $pfx) = @_;
 610         my $ucmd = $cmd;
 611         $ucmd =~ tr/-/_/;
 612         my $cb;
 613         $cb = $self->can($pfx.$ucmd) and return $cb;
 614         my $base = $ucmd;
 615         $base =~ s/_([a-z])/\u$1/g;
 616         my $pkg = "PublicInbox::Lei\u$base";
 617         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 618                 $pkg->can($pfx.$ucmd) : undef;
 619 }
 620
 621 sub dispatch {
 622         my ($self, $cmd, @argv) = @_;
 623         local $current_lei = $self; # for __WARN__
 624         dump_and_clear_log("from previous run\n");
 625         return _help($self, 'no command given') unless defined($cmd);
 626         # do not support Getopt bundling for this
 627         while ($cmd eq '-C' || $cmd eq '-c') {
 628                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 629                                         '-C DIRECTORY' : '-c <name>=<value>');
 630                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 631                 $cmd = shift(@argv) // return _help($self, 'no command given');
 632         }
 633         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 634                 optparse($self, $cmd, \@argv) or return;
 635                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 636                 if (my $chdir = $self->{opt}->{C}) {
 637                         for my $d (@$chdir) {
 638                                 next if $d eq ''; # same as git(1)
 639                                 chdir $d or return fail($self, "cd $d: $!");
 640                         }
 641                 }
 642                 $cb->($self, @argv);
 643         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 644                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 645                         or return _help($self, 'bad arguments or options');
 646                 _help($self);
 647         } else {
 648                 fail($self, "`$cmd' is not an lei command");
 649         }
 650 }
 651
 652 sub _lei_cfg ($;$) {
 653         my ($self, $creat) = @_;
 654         return $self->{cfg} if $self->{cfg};
 655         my $f = _config_path($self);
 656         my @st = stat($f);
 657         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 658         my ($sto, $sto_dir);
 659         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 660                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 661                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 662         }
 663         if (!@st) {
 664                 unless ($creat) {
 665                         delete $self->{cfg};
 666                         return bless {}, 'PublicInbox::Config';
 667                 }
 668                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 669                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 670                 open my $fh, '>>', $f or die "open($f): $!\n";
 671                 @st = stat($fh) or die "fstat($f): $!\n";
 672                 $cur_st = pack('dd', $st[10], $st[7]);
 673                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 674         }
 675         my $cfg = PublicInbox::Config::git_config_dump($f);
 676         bless $cfg, 'PublicInbox::Config';
 677         $cfg->{-st} = $cur_st;
 678         $cfg->{'-f'} = $f;
 679         if ($sto && File::Spec->canonpath($sto_dir) eq
 680                         File::Spec->canonpath($cfg->{'leistore.dir'})) {
 681                 $cfg->{-lei_store} = $sto;
 682         }
 683         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 684 }
 685
 686 sub _lei_store ($;$) {
 687         my ($self, $creat) = @_;
 688         my $cfg = _lei_cfg($self, $creat);
 689         $cfg->{-lei_store} //= do {
 690                 require PublicInbox::LeiStore;
 691                 my $dir = $cfg->{'leistore.dir'};
 692                 $dir //= $creat ? store_path($self) : return;
 693                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 694         };
 695 }
 696
 697 sub lei_show {
 698         my ($self, @argv) = @_;
 699 }
 700
 701 sub _config {
 702         my ($self, @argv) = @_;
 703         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 704         my $cfg = _lei_cfg($self, 1);
 705         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 706         my %rdr = map { $_ => $self->{$_} } (0..2);
 707         waitpid(spawn($cmd, \%env, \%rdr), 0);
 708 }
 709
 710 sub lei_config {
 711         my ($self, @argv) = @_;
 712         $self->{opt}->{'config-file'} and return fail $self,
 713                 "config file switches not supported by `lei config'";
 714         _config(@_);
 715         x_it($self, $?) if $?;
 716 }
 717
 718 sub lei_init {
 719         my ($self, $dir) = @_;
 720         my $cfg = _lei_cfg($self, 1);
 721         my $cur = $cfg->{'leistore.dir'};
 722         $dir //= store_path($self);
 723         $dir = rel2abs($self, $dir);
 724         my @cur = stat($cur) if defined($cur);
 725         $cur = File::Spec->canonpath($cur // $dir);
 726         my @dir = stat($dir);
 727         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 728         if (@cur) {
 729                 if ($cur eq $dir) {
 730                         _lei_store($self, 1)->done;
 731                         return qerr($self, $exists);
 732                 }
 733
 734                 # some folks like symlinks and bind mounts :P
 735                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 736                         lei_config($self, 'leistore.dir', $dir);
 737                         _lei_store($self, 1)->done;
 738                         return qerr($self, "$exists (as $cur)");
 739                 }
 740                 return fail($self, <<"");
 741 E: leistore.dir=$cur already initialized and it is not $dir
 742
 743         }
 744         lei_config($self, 'leistore.dir', $dir);
 745         _lei_store($self, 1)->done;
 746         $exists //= "# leistore.dir=$dir newly initialized";
 747         return qerr($self, $exists);
 748 }
 749
 750 sub lei_daemon_pid { puts shift, $$ }
 751
 752 sub lei_daemon_kill {
 753         my ($self) = @_;
 754         my $sig = $self->{opt}->{signal} // 'TERM';
 755         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 756 }
 757
 758 sub lei_help { _help($_[0]) }
 759
 760 # Shell completion helper.  Used by lei-completion.bash and hopefully
 761 # other shells.  Try to do as much here as possible to avoid redundancy
 762 # and improve maintainability.
 763 sub lei__complete {
 764         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 765         shift @argv; # ignore "lei", the entire command is sent
 766         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 767         my $cmd = shift @argv;
 768         my $info = $CMD{$cmd} // do { # filter matching commands
 769                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 770                 return;
 771         };
 772         my ($proto, undef, @spec) = @$info;
 773         my $cur = pop @argv;
 774         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 775         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 776                 # gross special case since the only git-config options
 777                 # Consider moving to a table if we need more special cases
 778                 # we use Getopt::Long for are the ones we reject, so these
 779                 # are the ones we don't reject:
 780                 if ($cmd eq 'config') {
 781                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 782                         @spec = qw(add z|null get get-all unset unset-all
 783                                 replace-all get-urlmatch
 784                                 remove-section rename-section
 785                                 name-only list|l edit|e
 786                                 get-color-name get-colorbool);
 787                         # fall-through
 788                 }
 789                 # generate short/long names from Getopt::Long specs
 790                 puts $self, grep(/$re/, qw(--help -h -C), map {
 791                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 792                         } elsif (s/\+\z//) { # verbose|v+
 793                         } elsif (s/!\z//) {
 794                                 # negation: solve! => no-solve|solve
 795                                 s/([\w\-]+)/$1|no-$1/g
 796                         }
 797                         map {
 798                                 my $x = length > 1 ? "--$_" : "-$_";
 799                                 $x eq $_cur ? () : $x;
 800                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 801                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 802         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 803                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 804         }
 805
 806         # switch args (e.g. lei q -f mbox<TAB>)
 807         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 808                 my $opt = quotemeta $1;
 809                 puts $self, map {
 810                         my $v = $OPTDESC{$_};
 811                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 812                         # get rid of ALL CAPS placeholder (e.g "OUT")
 813                         # (TODO: completion for external paths)
 814                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 815                         @v;
 816                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 817         }
 818         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 819                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 820         }
 821         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 822         # proto parsing.
 823 }
 824
 825 sub exec_buf ($$) {
 826         my ($argv, $env) = @_;
 827         my $argc = scalar @$argv;
 828         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 829         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 830         $buf;
 831 }
 832
 833 sub start_mua {
 834         my ($self) = @_;
 835         my $mua = $self->{opt}->{mua} // return;
 836         my $mfolder = $self->{ovv}->{dst};
 837         my (@cmd, $replaced);
 838         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 839                 @cmd = ($mua, '-f');
 840         # TODO: help wanted: other common FOSS MUAs
 841         } else {
 842                 require Text::ParseWords;
 843                 @cmd = Text::ParseWords::shellwords($mua);
 844                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 845                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 846         }
 847         push @cmd, $mfolder unless defined($replaced);
 848         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 849                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 850         } elsif ($self->{oneshot}) {
 851                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 852         }
 853         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 854                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 855         }
 856         $self->{opt}->{quiet} = 1;
 857         delete $self->{-progress};
 858         delete $self->{opt}->{verbose};
 859 }
 860
 861 sub send_exec_cmd { # tell script/lei to execute a command
 862         my ($self, $io, $cmd, $env) = @_;
 863         my $sock = $self->{sock} // die 'lei client gone';
 864         my $fds = [ map { fileno($_) } @$io ];
 865         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 866 }
 867
 868 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 869         my ($self) = @_;
 870         my $alerts = $self->{opt}->{alert} // return;
 871         while (my $op = shift(@$alerts)) {
 872                 if ($op eq ':WINCH') {
 873                         # hit the process group that started the MUA
 874                         if ($self->{sock}) {
 875                                 send($self->{sock}, '-WINCH', MSG_EOR);
 876                         } elsif ($self->{oneshot}) {
 877                                 kill('-WINCH', $$);
 878                         }
 879                 } elsif ($op eq ':bell') {
 880                         out($self, "\a");
 881                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 882                         push @$alerts, split(/(?<!\\),/, $op);
 883                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 884                         my $cmd = $1; # run an arbitrary command
 885                         require Text::ParseWords;
 886                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 887                         if (my $s = $self->{sock}) {
 888                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 889                         } elsif ($self->{oneshot}) {
 890                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 891                         }
 892                 } else {
 893                         err($self, "W: unsupported --alert=$op"); # non-fatal
 894                 }
 895         }
 896 }
 897
 898 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 899 $path_to_fd{"/dev/fd/$_"} = $path_to_fd{"/proc/self/fd/$_"} for (0..2);
 900 sub fopen {
 901         my ($self, $mode, $path) = @_;
 902         rel2abs($self, $path);
 903         $path =~ tr!/!/!s;
 904         if (defined(my $fd = $path_to_fd{$path})) {
 905                 return $self->{$fd};
 906         }
 907         if ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) {
 908                 return fail($self, "cannot open $path from daemon");
 909         }
 910         open my $fh, $mode, $path or return;
 911         $fh;
 912 }
 913
 914 # caller needs to "-t $self->{1}" to check if tty
 915 sub start_pager {
 916         my ($self) = @_;
 917         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 918         chomp(my $pager = <$fh> // '');
 919         close($fh) or warn "`git var PAGER' error: \$?=$?";
 920         return if $pager eq 'cat' || $pager eq '';
 921         my $new_env = { LESS => 'FRX', LV => '-c' };
 922         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 923         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 924         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 925         my $pgr = [ undef, @$rdr{1, 2} ];
 926         my $env = $self->{env};
 927         if ($self->{sock}) { # lei(1) process runs it
 928                 delete @$new_env{keys %$env}; # only set iff unset
 929                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 930         } elsif ($self->{oneshot}) {
 931                 my $cmd = [$pager];
 932                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 933         } else {
 934                 die 'BUG: start_pager w/o socket';
 935         }
 936         $self->{1} = $wpager;
 937         $self->{2} = $wpager if -t $self->{2};
 938         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 939         $self->{pgr} = $pgr;
 940 }
 941
 942 sub stop_pager {
 943         my ($self) = @_;
 944         my $pgr = delete($self->{pgr}) or return;
 945         $self->{2} = $pgr->[2];
 946         # do not restore original stdout, just close it so we error out
 947         close(delete($self->{1})) if $self->{1};
 948 }
 949
 950 sub accept_dispatch { # Listener {post_accept} callback
 951         my ($sock) = @_; # ignore other
 952         $sock->autoflush(1);
 953         my $self = bless { sock => $sock }, __PACKAGE__;
 954         vec(my $rvec = '', fileno($sock), 1) = 1;
 955         select($rvec, undef, undef, 60) or
 956                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 957         # (4096 * 33) >MAX_ARG_STRLEN
 958         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 959         if (scalar(@fds) == 4) {
 960                 for my $i (0..3) {
 961                         my $fd = shift(@fds);
 962                         open($self->{$i}, '+<&=', $fd) and next;
 963                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 964                 }
 965         } elsif (!defined($fds[0])) {
 966                 warn(my $msg = "recv_cmd failed: $!");
 967                 return send($sock, $msg, MSG_EOR);
 968         } else {
 969                 return;
 970         }
 971         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 972         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 973         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 974         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 975                 return send($sock, 'request command truncated', MSG_EOR);
 976         my ($argc, @argv) = split(/\0/, $buf, -1);
 977         undef $buf;
 978         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 979         if (chdir($self->{3})) {
 980                 local %ENV = %env;
 981                 $self->{env} = \%env;
 982                 eval { dispatch($self, @argv) };
 983                 send($sock, $@, MSG_EOR) if $@;
 984         } else {
 985                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 986         }
 987 }
 988
 989 sub dclose {
 990         my ($self) = @_;
 991         delete $self->{-progress};
 992         for my $f (@WQ_KEYS) {
 993                 my $wq = delete $self->{$f} or next;
 994                 if ($wq->wq_kill) {
 995                         $wq->wq_close(0, undef, $self);
 996                 } elsif ($wq->wq_kill_old) {
 997                         $wq->wq_wait_old(undef, $self);
 998                 }
 999         }
1000         close(delete $self->{1}) if $self->{1}; # may reap_compress
1001         if (my $sto = delete $self->{sto}) {
1002                 $sto->ipc_do('done');
1003         }
1004         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1005 }
1006
1007 # for long-running results
1008 sub event_step {
1009         my ($self) = @_;
1010         local %ENV = %{$self->{env}};
1011         my $sock = $self->{sock};
1012         local $current_lei = $self;
1013         eval {
1014                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1015                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1016                                 return if $! == EAGAIN;
1017                                 next if $! == EINTR;
1018                                 last if $! == ECONNRESET;
1019                                 die "recvmsg: $!";
1020                         }
1021                         for my $fd (@fds) {
1022                                 open my $rfh, '+<&=', $fd;
1023                         }
1024                         die "unrecognized client signal: $buf";
1025                 }
1026                 dclose($self);
1027         };
1028         if (my $err = $@) {
1029                 eval { $self->fail($err) };
1030                 dclose($self);
1031         }
1032 }
1033
1034 sub event_step_init {
1035         my ($self) = @_;
1036         return if $self->{-event_init_done}++;
1037         if (my $sock = $self->{sock}) { # using DS->EventLoop
1038                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1039         }
1040 }
1041
1042 sub noop {}
1043
1044 sub oldset { $oldset }
1045
1046 sub dump_and_clear_log {
1047         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1048                 my @pfx = @_;
1049                 unshift(@pfx, "$errors_log ") if @pfx;
1050                 warn @pfx, do { local $/; <STDIN> };
1051                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1052         }
1053 }
1054
1055 # lei(1) calls this when it can't connect
1056 sub lazy_start {
1057         my ($path, $errno, $narg) = @_;
1058         local ($errors_log, $listener);
1059         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1060         $errors_log .= 'errors.log';
1061         my $addr = pack_sockaddr_un($path);
1062         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1063         $lk->lock_acquire;
1064         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1065         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1066                 return if connect($listener, $addr); # another process won
1067                 if ($errno == ECONNREFUSED && -S $path) {
1068                         unlink($path) or die "unlink($path): $!";
1069                 }
1070         } else {
1071                 $! = $errno; # allow interpolation to stringify in die
1072                 die "connect($path): $!";
1073         }
1074         umask(077) // die("umask(077): $!");
1075         bind($listener, $addr) or die "bind($path): $!";
1076         listen($listener, 1024) or die "listen: $!";
1077         $lk->lock_release;
1078         undef $lk;
1079         my @st = stat($path) or die "stat($path): $!";
1080         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1081         local $oldset = PublicInbox::DS::block_signals();
1082         if ($narg == 5) {
1083                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1084                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1085                         require PublicInbox::CmdIPC4;
1086                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1087                         PublicInbox::CmdIPC4->can('recv_cmd4');
1088                 };
1089         }
1090         $recv_cmd or die <<"";
1091 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1092
1093         require PublicInbox::Listener;
1094         require PublicInbox::EOFpipe;
1095         (-p STDOUT) or die "E: stdout must be a pipe\n";
1096         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1097         STDIN->autoflush(1);
1098         dump_and_clear_log("from previous daemon process:\n");
1099         POSIX::setsid() > 0 or die "setsid: $!";
1100         my $pid = fork // die "fork: $!";
1101         return if $pid;
1102         $0 = "lei-daemon $path";
1103         local %PATH2CFG;
1104         $listener->blocking(0);
1105         my $exit_code;
1106         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1107         local $quit = do {
1108                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1109                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1110                 sub {
1111                         $exit_code //= shift;
1112                         my $lis = $pil or exit($exit_code);
1113                         # closing eof_w triggers \&noop wakeup
1114                         $listener = $eof_w = $pil = $path = undef;
1115                         $lis->close; # DS::close
1116                         PublicInbox::DS->SetLoopTimeout(1000);
1117                 };
1118         };
1119         my $sig = {
1120                 CHLD => \&PublicInbox::DS::enqueue_reap,
1121                 QUIT => $quit,
1122                 INT => $quit,
1123                 TERM => $quit,
1124                 HUP => \&noop,
1125                 USR1 => \&noop,
1126                 USR2 => \&noop,
1127         };
1128         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1129         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1130         undef $sig;
1131         local $SIG{PIPE} = 'IGNORE';
1132         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1133                 undef $sigfd;
1134                 PublicInbox::DS->SetLoopTimeout(5000);
1135         } else {
1136                 # wake up every second to accept signals if we don't
1137                 # have signalfd or IO::KQueue:
1138                 PublicInbox::DS::sig_setmask($oldset);
1139                 PublicInbox::DS->SetLoopTimeout(1000);
1140         }
1141         PublicInbox::DS->SetPostLoopCallback(sub {
1142                 my ($dmap, undef) = @_;
1143                 if (@st = defined($path) ? stat($path) : ()) {
1144                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1145                                 warn "$path dev/ino changed, quitting\n";
1146                                 $path = undef;
1147                         }
1148                 } elsif (defined($path)) { # ENOENT is common
1149                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1150                         undef $path;
1151                         $quit->();
1152                 }
1153                 return 1 if defined($path);
1154                 my $now = now();
1155                 my $n = 0;
1156                 for my $s (values %$dmap) {
1157                         $s->can('busy') or next;
1158                         if ($s->busy($now)) {
1159                                 ++$n;
1160                         } else {
1161                                 $s->close;
1162                         }
1163                 }
1164                 $n; # true: continue, false: stop
1165         });
1166
1167         # STDIN was redirected to /dev/null above, closing STDERR and
1168         # STDOUT will cause the calling `lei' client process to finish
1169         # reading the <$daemon> pipe.
1170         local $SIG{__WARN__} = sub {
1171                 $current_lei ? err($current_lei, @_) : warn(
1172                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1173         };
1174         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1175         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1176         # $daemon pipe to `lei' closed, main loop begins:
1177         PublicInbox::DS->EventLoop;
1178         exit($exit_code // 0);
1179 }
1180
1181 sub busy { 1 } # prevent daemon-shutdown if client is connected
1182
1183 # for users w/o Socket::Msghdr installed or Inline::C enabled
1184 sub oneshot {
1185         my ($main_pkg) = @_;
1186         my $exit = $main_pkg->can('exit'); # caller may override exit()
1187         local $quit = $exit if $exit;
1188         local %PATH2CFG;
1189         umask(077) // die("umask(077): $!");
1190         my $self = bless {
1191                 oneshot => 1,
1192                 0 => *STDIN{GLOB},
1193                 1 => *STDOUT{GLOB},
1194                 2 => *STDERR{GLOB},
1195                 env => \%ENV
1196         }, __PACKAGE__;
1197         dispatch($self, @ARGV);
1198         x_it($self, $self->{child_error}) if $self->{child_error};
1199 }
1200
1201 # ensures stdout hits the FS before sock disconnects so a client
1202 # can immediately reread it
1203 sub DESTROY {
1204         my ($self) = @_;
1205         $self->{1}->autoflush(1) if $self->{1};
1206         stop_pager($self);
1207         my $err = $?;
1208         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1209         waitpid($_, 0) for keys %$oneshot_pids;
1210         $? = $err if $err; # preserve ->fail or ->x_it code
1211 }
1212
1213 1;