lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now dwaitpid);
  22 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $recv_3fds;
  29 my $GLP = Getopt::Long::Parser->new;
  30 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  31 my $GLP_PASS = Getopt::Long::Parser->new;
  32 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  33
  34 our %PATH2CFG; # persistent for socket daemon
  35
  36 # TBD: this is a documentation mechanism to show a subcommand
  37 # (may) pass options through to another command:
  38 sub pass_through { $GLP_PASS }
  39
  40 my $OPT;
  41 sub opt_dash ($$) {
  42         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  43         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  44         my $cb = sub { # Getopt::Long "<>" catch-all handler
  45                 my ($arg) = @_;
  46                 if ($arg =~ /\A-($re_str)\z/) {
  47                         $OPT->{$key} = $1;
  48                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  49                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  50                 # lone (single) dash is handled elsewhere
  51                 } elsif (substr($arg, 0, 1) eq '-') {
  52                         if ($OPT->{'--'}) {
  53                                 push @{$OPT->{-argv}}, $arg;
  54                         } else {
  55                                 die "bad argument: $arg\n";
  56                         }
  57                 } else {
  58                         push @{$OPT->{-argv}}, $arg;
  59                 }
  60         };
  61         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  62 }
  63
  64 sub _store_path ($) {
  65         my ($env) = @_;
  66         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  67                 ($env->{HOME} // '/nonexistent').'/.local/share')
  68                 .'/lei/store', $env->{PWD});
  69 }
  70
  71 sub _config_path ($) {
  72         my ($env) = @_;
  73         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  74                 ($env->{HOME} // '/nonexistent').'/.config')
  75                 .'/lei/config', $env->{PWD});
  76 }
  77
  78 # TODO: generate shell completion + help using %CMD and %OPTDESC
  79 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  80 our %CMD = ( # sorted in order of importance/use:
  81 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  82         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  83         sort|s=s@ reverse|r offset=i remote local! external!
  84         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  85
  86 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  87         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  88         pass_through('git show') ],
  89
  90 'add-external' => [ 'URL_OR_PATHNAME',
  91         'add/set priority of a publicinbox|extindex for extra matches',
  92         qw(boost=i quiet|q) ],
  93 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  94         qw(format|f=s z|0 local remote quiet|q) ],
  95 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  96         'exclude further results from a publicinbox|extindex',
  97         qw(prune quiet|q) ],
  98
  99 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 100                 qw(name-only format|f=s z) ],
 101 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 102 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 103
 104 'plonk' => [ '--thread|--from=IDENT',
 105         'exclude mail matching From: or thread from non-Message-ID searches',
 106         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 107 'mark' => [ 'MESSAGE_FLAGS...',
 108         'set/unset flags on message(s) from stdin',
 109         qw(stdin| oid=s exact by-mid|mid:s) ],
 110 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 111         "exclude message(s) on stdin from `q' search results",
 112         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 113
 114 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 115         'remove imported messages from IMAP, Maildirs, and MH',
 116         qw(exact! all jobs:i indexed) ],
 117
 118 # code repos are used for `show' to solve blobs from patch mails
 119 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 120         qw(boost=i) ],
 121 'ls-coderepo' => [ '[FILTER_TERMS...]',
 122                 'list known code repos', qw(format|f=s z) ],
 123 'forget-coderepo' => [ 'PATHNAME',
 124         'stop using repo to solve blobs from patches',
 125         qw(prune) ],
 126
 127 'add-watch' => [ '[URL_OR_PATHNAME]',
 128                 'watch for new messages and flag changes',
 129         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 130 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 131                 qw(format|f=s z) ],
 132 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 133 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 134 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 135         qw(prune) ],
 136
 137 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 138         'one-shot import/update from URL or filesystem',
 139         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 140         ],
 141
 142 'config' => [ '[...]', sub {
 143                 'git-config(1) wrapper for '._config_path($_[0]);
 144         }, qw(config-file|system|global|file|f=s), # for conflict detection
 145         pass_through('git config') ],
 146 'init' => [ '[PATHNAME]', sub {
 147                 'initialize storage, default: '._store_path($_[0]);
 148         }, qw(quiet|q) ],
 149 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 150         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 151 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 152 'help' => [ '[SUBCOMMAND]', 'show help' ],
 153
 154 # XXX do we need this?
 155 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 156
 157 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 158         'rewrite git history in an attempt to improve compression',
 159         'gc!' ],
 160
 161 # internal commands are prefixed with '_'
 162 '_complete' => [ '[...]', 'internal shell completion helper',
 163                 pass_through('everything') ],
 164 ); # @CMD
 165
 166 # switch descriptions, try to keep consistent across commands
 167 # $spec: Getopt::Long option specification
 168 # $spec => [@ALLOWED_VALUES (default is first), $description],
 169 # $spec => $description
 170 # "$SUB_COMMAND TAB $spec" => as above
 171 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 172                 'specify message input format' ];
 173 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 174
 175 my %OPTDESC = (
 176 'help|h' => 'show this built-in help',
 177 'quiet|q' => 'be quiet',
 178 'solve!' => 'do not attempt to reconstruct blobs from emails',
 179 'save-as=s' => ['NAME', 'save a search terms by given name'],
 180
 181 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 182
 183 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 184                 'deduplication strategy'],
 185 'show   thread|t' => 'display entire thread a message belongs to',
 186 'q      thread|t' =>
 187         'return all messages in the same thread as the actual match(es)',
 188 'augment|a' => 'augment --output destination instead of clobbering',
 189
 190 'output|o=s' => [ 'DEST',
 191         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 192
 193 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 194                         'message/object output format' ],
 195 'mark   format|f=s' => $stdin_formats,
 196 'forget format|f=s' => $stdin_formats,
 197 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 198                 'specify output format, default depends on --output'],
 199 'ls-query       format|f=s' => $ls_format,
 200 'ls-external    format|f=s' => $ls_format,
 201
 202 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 203 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 204
 205 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 206                 "order of results `--output'-dependent"],
 207
 208 'boost=i' => 'increase/decrease priority of results (default: 0)',
 209
 210 'local' => 'limit operations to the local filesystem',
 211 'local!' => 'exclude results from the local filesystem',
 212 'remote' => 'limit operations to those requiring network access',
 213 'remote!' => 'prevent operations requiring network access',
 214
 215 'mid=s' => 'specify the Message-ID of a message',
 216 'oid=s' => 'specify the git object ID of a message',
 217
 218 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 219 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 220 'include=s' => 'include mailboxes/newsgroups based on pattern',
 221
 222 'exact' => 'operate on exact header matches only',
 223 'exact!' => 'rely on content match instead of exact header matches',
 224
 225 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 226 'jobs:i' => 'set parallelism level',
 227
 228 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 229 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 230
 231 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 232 ); # %OPTDESC
 233
 234 my %CONFIG_KEYS = (
 235         'leistore.dir' => 'top-level storage location',
 236 );
 237
 238 sub x_it ($$) { # pronounced "exit"
 239         my ($self, $code) = @_;
 240         $self->{1}->autoflush(1); # make sure client sees stdout before exit
 241         if (my $sig = ($code & 127)) {
 242                 kill($sig, $self->{pid} // $$);
 243         } else {
 244                 $code >>= 8;
 245                 if (my $sock = $self->{sock}) {
 246                         say $sock "exit=$code";
 247                 } else { # for oneshot
 248                         $quit->($code);
 249                 }
 250         }
 251 }
 252
 253 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 254
 255 sub out ($;@) { print { shift->{1} } @_ }
 256
 257 sub err ($;@) {
 258         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 259 }
 260
 261 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 262
 263 sub fail ($$;$) {
 264         my ($self, $buf, $exit_code) = @_;
 265         err($self, $buf);
 266         x_it($self, ($exit_code // 1) << 8);
 267         undef;
 268 }
 269
 270 sub _help ($;$) {
 271         my ($self, $errmsg) = @_;
 272         my $cmd = $self->{cmd} // 'COMMAND';
 273         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 274         my @top = ($cmd, shift(@info) // ());
 275         my $cmd_desc = shift(@info);
 276         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 277         my @opt_desc;
 278         my $lpad = 2;
 279         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 280                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 281                 my $arg_vals = '';
 282                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 283
 284                 # lower-case is a keyword (e.g. `content', `oid'),
 285                 # ALL_CAPS is a string description (e.g. `PATH')
 286                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 287                         $desc .= "\ndefault: `$1'";
 288                 }
 289                 my (@vals, @s, @l);
 290                 my $x = $sw;
 291                 if ($x =~ s/!\z//) { # solve! => --no-solve
 292                         $x = "no-$x";
 293                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 294                         @vals = (' [', undef, ']');
 295                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 296                         @vals = (' ', undef);
 297                 } # else: no args $x = 'thread|t'
 298                 for (split(/\|/, $x)) { # help|h
 299                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 300                 }
 301                 if (!scalar(@vals)) { # no args 'thread|t'
 302                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 303                         $vals[1] = $1;
 304                 } else {
 305                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 306                 }
 307                 if ($arg_vals =~ /([,\|])/) {
 308                         my $sep = $1;
 309                         my @allow = split(/\Q$sep\E/, $arg_vals);
 310                         my $must = $sep eq '|' ? 'Must' : 'Can';
 311                         @allow = map { "`$_'" } @allow;
 312                         my $last = pop @allow;
 313                         $desc .= "\n$must be one of: " .
 314                                 join(', ', @allow) . " or $last";
 315                 }
 316                 my $lhs = join(', ', @s, @l) . join('', @vals);
 317                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 318                         $lhs =~ s/\A--/- , --/;
 319                 } else {
 320                         $lhs =~ s/\A--/    --/; # pad if no short options
 321                 }
 322                 $lpad = length($lhs) if length($lhs) > $lpad;
 323                 push @opt_desc, $lhs, $desc;
 324         }
 325         my $msg = $errmsg ? "E: $errmsg\n" : '';
 326         $msg .= <<EOF;
 327 usage: lei @top
 328   $cmd_desc
 329
 330 EOF
 331         $lpad += 2;
 332         local $Text::Wrap::columns = 78 - $lpad;
 333         my $padding = ' ' x ($lpad + 2);
 334         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 335                 $msg .= '  '.pack("A$lpad", $lhs);
 336                 $rhs = wrap('', '', $rhs);
 337                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 338                 $msg .= $rhs;
 339                 $msg .= "\n";
 340         }
 341         print { $self->{$errmsg ? 2 : 1} } $msg;
 342         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 343         undef;
 344 }
 345
 346 sub optparse ($$$) {
 347         my ($self, $cmd, $argv) = @_;
 348         $self->{cmd} = $cmd;
 349         $OPT = $self->{opt} = {};
 350         my $info = $CMD{$cmd} // [ '[...]' ];
 351         my ($proto, undef, @spec) = @$info;
 352         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 353         push @spec, qw(help|h);
 354         my $lone_dash;
 355         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 356                 $lone_dash = $spec[0];
 357                 $OPT->{$spec[0]} = \(my $var);
 358                 push @spec, '' => \$var;
 359         }
 360         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 361                 return _help($self, "bad arguments or options for $cmd");
 362         return _help($self) if $OPT->{help};
 363
 364         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 365
 366         # "-" aliases "stdin" or "clear"
 367         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 368
 369         my $i = 0;
 370         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 371         my ($err, $inf);
 372         my @args = split(/ /, $proto);
 373         for my $var (@args) {
 374                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 375                         $inf = defined($argv->[$i]) and last;
 376                         $var =~ s/\.\.\.\z//;
 377                         $err = "$var not supplied";
 378                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 379                         $argv->[$i++] // ($err = "$var not supplied");
 380                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 381                         $inf = 1;
 382                         last;
 383                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 384                         $i++;
 385                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 386                         my @or = split(/\|/, $var);
 387                         my $ok;
 388                         for my $o (@or) {
 389                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 390                                         $ok = defined($OPT->{$1});
 391                                         last;
 392                                 } elsif (defined($argv->[$i])) {
 393                                         $ok = 1;
 394                                         $i++;
 395                                         last;
 396                                 } # else continue looping
 397                         }
 398                         my $last = pop @or;
 399                         $err = join(', ', @or) . " or $last must be set";
 400                 } else {
 401                         warn "BUG: can't parse `$var' in $proto";
 402                 }
 403                 last if $err;
 404         }
 405         if (!$inf && scalar(@$argv) > scalar(@args)) {
 406                 $err //= 'too many arguments';
 407         }
 408         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 409 }
 410
 411 sub dispatch {
 412         my ($self, $cmd, @argv) = @_;
 413         local $SIG{__WARN__} = sub { err($self, @_) };
 414         return _help($self, 'no command given') unless defined($cmd);
 415         my $func = "lei_$cmd";
 416         $func =~ tr/-/_/;
 417         if (my $cb = __PACKAGE__->can($func)) {
 418                 optparse($self, $cmd, \@argv) or return;
 419                 $cb->($self, @argv);
 420         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 421                 my $opt = {};
 422                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 423                         return _help($self, 'bad arguments or options');
 424                 _help($self);
 425         } else {
 426                 fail($self, "`$cmd' is not an lei command");
 427         }
 428 }
 429
 430 sub _lei_cfg ($;$) {
 431         my ($self, $creat) = @_;
 432         my $f = _config_path($self->{env});
 433         my @st = stat($f);
 434         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 435         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 436                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 437         }
 438         if (!@st) {
 439                 unless ($creat) {
 440                         delete $self->{cfg};
 441                         return;
 442                 }
 443                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 444                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 445                 open my $fh, '>>', $f or die "open($f): $!\n";
 446                 @st = stat($fh) or die "fstat($f): $!\n";
 447                 $cur_st = pack('dd', $st[10], $st[7]);
 448                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 449         }
 450         my $cfg = PublicInbox::Config::git_config_dump($f);
 451         $cfg->{-st} = $cur_st;
 452         $cfg->{'-f'} = $f;
 453         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 454 }
 455
 456 sub _lei_store ($;$) {
 457         my ($self, $creat) = @_;
 458         my $cfg = _lei_cfg($self, $creat);
 459         $cfg->{-lei_store} //= do {
 460                 require PublicInbox::LeiStore;
 461                 my $dir = $cfg->{'leistore.dir'};
 462                 $dir //= _store_path($self->{env}) if $creat;
 463                 return unless $dir;
 464                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 465         };
 466 }
 467
 468 sub lei_show {
 469         my ($self, @argv) = @_;
 470 }
 471
 472 sub lei_query {
 473         my ($self, @argv) = @_;
 474 }
 475
 476 sub lei_mark {
 477         my ($self, @argv) = @_;
 478 }
 479
 480 sub lei_config {
 481         my ($self, @argv) = @_;
 482         $self->{opt}->{'config-file'} and return fail $self,
 483                 "config file switches not supported by `lei config'";
 484         my $env = $self->{env};
 485         delete local $env->{GIT_CONFIG};
 486         my $cfg = _lei_cfg($self, 1);
 487         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 488         my %rdr = map { $_ => $self->{$_} } (0..2);
 489         run_die($cmd, $env, \%rdr);
 490 }
 491
 492 sub lei_init {
 493         my ($self, $dir) = @_;
 494         my $cfg = _lei_cfg($self, 1);
 495         my $cur = $cfg->{'leistore.dir'};
 496         my $env = $self->{env};
 497         $dir //= _store_path($env);
 498         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 499         my @cur = stat($cur) if defined($cur);
 500         $cur = File::Spec->canonpath($cur // $dir);
 501         my @dir = stat($dir);
 502         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 503         if (@cur) {
 504                 if ($cur eq $dir) {
 505                         _lei_store($self, 1)->done;
 506                         return qerr($self, $exists);
 507                 }
 508
 509                 # some folks like symlinks and bind mounts :P
 510                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 511                         lei_config($self, 'leistore.dir', $dir);
 512                         _lei_store($self, 1)->done;
 513                         return qerr($self, "$exists (as $cur)");
 514                 }
 515                 return fail($self, <<"");
 516 E: leistore.dir=$cur already initialized and it is not $dir
 517
 518         }
 519         lei_config($self, 'leistore.dir', $dir);
 520         _lei_store($self, 1)->done;
 521         $exists //= "I: leistore.dir=$dir newly initialized";
 522         return qerr($self, $exists);
 523 }
 524
 525 sub lei_daemon_pid { puts shift, $$ }
 526
 527 sub lei_daemon_kill {
 528         my ($self) = @_;
 529         my $sig = $self->{opt}->{signal} // 'TERM';
 530         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 531 }
 532
 533 sub lei_help { _help($_[0]) }
 534
 535 # Shell completion helper.  Used by lei-completion.bash and hopefully
 536 # other shells.  Try to do as much here as possible to avoid redundancy
 537 # and improve maintainability.
 538 sub lei__complete {
 539         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 540         shift @argv; # ignore "lei", the entire command is sent
 541         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 542         my $cmd = shift @argv;
 543         my $info = $CMD{$cmd} // do { # filter matching commands
 544                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 545                 return;
 546         };
 547         my ($proto, undef, @spec) = @$info;
 548         my $cur = pop @argv;
 549         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 550         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 551                 # gross special case since the only git-config options
 552                 # Consider moving to a table if we need more special cases
 553                 # we use Getopt::Long for are the ones we reject, so these
 554                 # are the ones we don't reject:
 555                 if ($cmd eq 'config') {
 556                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 557                         @spec = qw(add z|null get get-all unset unset-all
 558                                 replace-all get-urlmatch
 559                                 remove-section rename-section
 560                                 name-only list|l edit|e
 561                                 get-color-name get-colorbool);
 562                         # fall-through
 563                 }
 564                 # TODO: arg support
 565                 puts $self, grep(/$re/, map { # generate short/long names
 566                         my $eq = '';
 567                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 568                                 $eq = '=';
 569                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 570                         } else { # negation: solve! => no-solve|solve
 571                                 s/\A(.+)!\z/no-$1|$1/;
 572                         }
 573                         map {
 574                                 length > 1 ? "--$_$eq" : "-$_"
 575                         } split(/\|/, $_, -1) # help|h
 576                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 577         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 578                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 579         }
 580         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 581         # proto parsing.
 582 }
 583
 584 sub reap_exec { # dwaitpid callback
 585         my ($self, $pid) = @_;
 586         x_it($self, $?);
 587 }
 588
 589 sub lei_git { # support passing through random git commands
 590         my ($self, @argv) = @_;
 591         my %rdr = map { $_ => $self->{$_} } (0..2);
 592         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 593         dwaitpid($pid, \&reap_exec, $self);
 594 }
 595
 596 # caller needs to "-t $self->{1}" to check if tty
 597 sub start_pager {
 598         my ($self) = @_;
 599         my $env = $self->{env};
 600         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 601         chomp(my $pager = <$fh> // '');
 602         close($fh) or warn "`git var PAGER' error: \$?=$?";
 603         return if $pager eq 'cat' || $pager eq '';
 604         $env->{LESS} //= 'FRX';
 605         $env->{LV} //= '-c';
 606         $env->{COLUMNS} //= 80; # TODO TIOCGWINSZ
 607         $env->{MORE} //= 'FRX' if $^O eq 'freebsd';
 608         pipe(my ($r, $w)) or return warn "pipe: $!";
 609         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 610         $self->{1} = $w;
 611         $self->{2} = $w if -t $self->{2};
 612         $self->{'pager.pid'} = spawn([$pager], $env, $rdr);
 613         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 614 }
 615
 616 sub accept_dispatch { # Listener {post_accept} callback
 617         my ($sock) = @_; # ignore other
 618         $sock->blocking(1);
 619         $sock->autoflush(1);
 620         my $self = bless { sock => $sock }, __PACKAGE__;
 621         vec(my $rin = '', fileno($sock), 1) = 1;
 622         # `say $sock' triggers "die" in lei(1)
 623         if (select(my $rout = $rin, undef, undef, 1)) {
 624                 my @fds = $recv_3fds->(fileno($sock));
 625                 if (scalar(@fds) == 3) {
 626                         my $i = 0;
 627                         for my $rdr (qw(<&= >&= >&=)) {
 628                                 my $fd = shift(@fds);
 629                                 if (open(my $fh, $rdr, $fd)) {
 630                                         $self->{$i++} = $fh;
 631                                 }  else {
 632                                         say $sock "open($rdr$fd) (FD=$i): $!";
 633                                         return;
 634                                 }
 635                         }
 636                 } else {
 637                         say $sock "recv_3fds failed: $!";
 638                         return;
 639                 }
 640         } else {
 641                 say $sock "timed out waiting to recv FDs";
 642                 return;
 643         }
 644         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 645         # $ARGV_STR = join("]\0[", @ARGV);
 646         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 647         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 648         my ($client_pid, $argv, $env) = do {
 649                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 650                 chomp(my $line = <$sock>);
 651                 split(/\0\0>/, $line, 3);
 652         };
 653         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 654         if (chdir($env{PWD})) {
 655                 local %ENV = %env;
 656                 $self->{env} = \%env;
 657                 $self->{pid} = $client_pid;
 658                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 659                 say $sock $@ if $@;
 660         } else {
 661                 say $sock "chdir($env{PWD}): $!"; # implicit close
 662         }
 663 }
 664
 665 # for long-running results
 666 sub event_step {
 667         my ($self) = @_;
 668         local %ENV = %{$self->{env}};
 669         eval {}; # TODO
 670         if ($@) {
 671                 say { $self->{sock} } $@;
 672                 $self->close; # PublicInbox::DS::close
 673         }
 674 }
 675
 676 sub noop {}
 677
 678 # lei(1) calls this when it can't connect
 679 sub lazy_start {
 680         my ($path, $errno, $nfd) = @_;
 681         if ($errno == ECONNREFUSED) {
 682                 unlink($path) or die "unlink($path): $!";
 683         } elsif ($errno != ENOENT) {
 684                 $! = $errno; # allow interpolation to stringify in die
 685                 die "connect($path): $!";
 686         }
 687         umask(077) // die("umask(077): $!");
 688         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 689         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 690         listen($l, 1024) or die "listen: $!";
 691         my @st = stat($path) or die "stat($path): $!";
 692         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 693         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 694         my $oldset = PublicInbox::Sigfd::block_signals();
 695         if ($nfd == 1) {
 696                 require IO::FDPass;
 697                 $recv_3fds = sub { map { IO::FDPass::recv($_[0]) } (0..2) };
 698         } elsif ($nfd == 3) {
 699                 $recv_3fds = PublicInbox::Spawn->can('recv_3fds');
 700         }
 701         $recv_3fds or die
 702                 "IO::FDPass missing or Inline::C not installed/configured\n";
 703         require PublicInbox::Listener;
 704         require PublicInbox::EOFpipe;
 705         (-p STDOUT) or die "E: stdout must be a pipe\n";
 706         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 707         POSIX::setsid() > 0 or die "setsid: $!";
 708         my $pid = fork // die "fork: $!";
 709         return if $pid;
 710         $0 = "lei-daemon $path";
 711         local %PATH2CFG;
 712         $_->blocking(0) for ($l, $eof_r, $eof_w);
 713         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 714         my $exit_code;
 715         local $quit = sub {
 716                 $exit_code //= shift;
 717                 my $listener = $l or exit($exit_code);
 718                 unlink($path) if defined($path);
 719                 # closing eof_w triggers \&noop wakeup
 720                 $eof_w = $l = $path = undef;
 721                 $listener->close; # DS::close
 722                 PublicInbox::DS->SetLoopTimeout(1000);
 723         };
 724         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 725         my $sig = {
 726                 CHLD => \&PublicInbox::DS::enqueue_reap,
 727                 QUIT => $quit,
 728                 INT => $quit,
 729                 TERM => $quit,
 730                 HUP => \&noop,
 731                 USR1 => \&noop,
 732                 USR2 => \&noop,
 733         };
 734         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 735         local %SIG = (%SIG, %$sig) if !$sigfd;
 736         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 737                 PublicInbox::DS->SetLoopTimeout(5000);
 738         } else {
 739                 # wake up every second to accept signals if we don't
 740                 # have signalfd or IO::KQueue:
 741                 PublicInbox::Sigfd::sig_setmask($oldset);
 742                 PublicInbox::DS->SetLoopTimeout(1000);
 743         }
 744         PublicInbox::DS->SetPostLoopCallback(sub {
 745                 my ($dmap, undef) = @_;
 746                 if (@st = defined($path) ? stat($path) : ()) {
 747                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 748                                 warn "$path dev/ino changed, quitting\n";
 749                                 $path = undef;
 750                         }
 751                 } elsif (defined($path)) {
 752                         warn "stat($path): $!, quitting ...\n";
 753                         undef $path; # don't unlink
 754                         $quit->();
 755                 }
 756                 return 1 if defined($path);
 757                 my $now = now();
 758                 my $n = 0;
 759                 for my $s (values %$dmap) {
 760                         $s->can('busy') or next;
 761                         if ($s->busy($now)) {
 762                                 ++$n;
 763                         } else {
 764                                 $s->close;
 765                         }
 766                 }
 767                 $n; # true: continue, false: stop
 768         });
 769
 770         # STDIN was redirected to /dev/null above, closing STDERR and
 771         # STDOUT will cause the calling `lei' client process to finish
 772         # reading the <$daemon> pipe.
 773         openlog($path, 'pid', 'user');
 774         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 775         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 776                 syslog('crit', "$@") if $@;
 777         });
 778         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 779         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 780         # $daemon pipe to `lei' closed, main loop begins:
 781         PublicInbox::DS->EventLoop;
 782         @$on_destroy = (); # cancel on_destroy if we get here
 783         exit($exit_code // 0);
 784 }
 785
 786 # for users w/o IO::FDPass
 787 sub oneshot {
 788         my ($main_pkg) = @_;
 789         my $exit = $main_pkg->can('exit'); # caller may override exit()
 790         local $quit = $exit if $exit;
 791         local %PATH2CFG;
 792         umask(077) // die("umask(077): $!");
 793         dispatch((bless {
 794                 0 => *STDIN{IO},
 795                 1 => *STDOUT{IO},
 796                 2 => *STDERR{IO},
 797                 env => \%ENV
 798         }, __PACKAGE__), @ARGV);
 799 }
 800
 801 # ensures stdout hits the FS before sock disconnects so a client
 802 # can immediately reread it
 803 sub DESTROY {
 804         my ($self) = @_;
 805         $self->{1}->autoflush(1);
 806         if (my $pid = delete $self->{'pager.pid'}) {
 807                 dwaitpid($pid, undef, $self->{sock});
 808         }
 809 }
 810
 811 1;