lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 # we generate shell completion + help using %CMD and %OPTDESC,
 123 # see lei__complete() and PublicInbox::LeiHelp
 124 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 125 our %CMD = ( # sorted in order of importance/use:
 126 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 127         'stdin|', # /|\z/ must be first for lone dash
 128         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 129         sort|s=s reverse|r offset=i remote! local! external! pretty
 130         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 131         import-remote! import-before! lock=s@ rsyncable
 132         alert=s@ mua=s no-torsocks torsocks=s verbose|v+ quiet|q C=s@),
 133         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 134
 135 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 136         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local! C=s@),
 137         pass_through('git show') ],
 138
 139 'add-external' => [ 'LOCATION',
 140         'add/set priority of a publicinbox|extindex for extra matches',
 141         qw(boost=i c=s@ mirror=s no-torsocks torsocks=s inbox-version=i),
 142         qw(quiet|q verbose|v+ C=s@),
 143         index_opt(), PublicInbox::LeiQuery::curl_opt() ],
 144 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 145         qw(format|f=s z|0 globoff|g invert-match|v local remote C=s@) ],
 146 'forget-external' => [ 'LOCATION...|--prune',
 147         'exclude further results from a publicinbox|extindex',
 148         qw(prune quiet|q C=s@) ],
 149
 150 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 151                 qw(name-only format|f=s C=s@) ],
 152 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', qw(C=s@) ],
 153 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', qw(C=s@) ],
 154
 155 'plonk' => [ '--threads|--from=IDENT',
 156         'exclude mail matching From: or threads from non-Message-ID searches',
 157         qw(stdin| threads|t from|f=s mid=s oid=s C=s@) ],
 158 'mark' => [ 'MESSAGE_FLAGS...',
 159         'set/unset keywords on message(s) from stdin',
 160         qw(stdin| oid=s exact by-mid|mid:s C=s@) ],
 161 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 162         "exclude message(s) on stdin from `q' search results",
 163         qw(stdin| oid=s exact by-mid|mid:s quiet|q C=s@) ],
 164
 165 'purge-mailsource' => [ 'LOCATION|--all',
 166         'remove imported messages from IMAP, Maildirs, and MH',
 167         qw(exact! all jobs:i indexed C=s@) ],
 168
 169 # code repos are used for `show' to solve blobs from patch mails
 170 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 171         qw(boost=i C=s@) ],
 172 'ls-coderepo' => [ '[FILTER_TERMS...]',
 173                 'list known code repos', qw(format|f=s z C=s@) ],
 174 'forget-coderepo' => [ 'DIRNAME',
 175         'stop using repo to solve blobs from patches',
 176         qw(prune C=s@) ],
 177
 178 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 179         qw(import! kw|keywords|flags! interval=s recursive|r
 180         exclude=s include=s C=s@) ],
 181 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 182                 qw(format|f=s z C=s@) ],
 183 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 184 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 185 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 186         qw(prune C=s@) ],
 187
 188 'import' => [ 'LOCATION...|--stdin',
 189         'one-time import/update from URL or filesystem',
 190         qw(stdin| offset=i recursive|r exclude=s include|I=s
 191         lock=s@ in-format|F=s kw|keywords|flags! C=s@),
 192         ],
 193 'convert' => [ 'LOCATION...|--stdin',
 194         'one-time conversion from URL or filesystem to another format',
 195         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s quiet|q
 196         lock=s@ kw|keywords|flags! C=s@),
 197         ],
 198 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 199         "use a patch to generate a query for `lei q --stdin'",
 200         qw(stdin| want|w=s@ uri debug) ],
 201 'config' => [ '[...]', sub {
 202                 'git-config(1) wrapper for '._config_path($_[0]);
 203         }, qw(config-file|system|global|file|f=s), # for conflict detection
 204          qw(C=s@), pass_through('git config') ],
 205 'init' => [ '[DIRNAME]', sub {
 206         "initialize storage, default: ".store_path($_[0]);
 207         }, qw(quiet|q C=s@) ],
 208 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 209         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 210         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 211 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 212 'help' => [ '[SUBCOMMAND]', 'show help' ],
 213
 214 # XXX do we need this?
 215 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 216
 217 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 218         'rewrite git history in an attempt to improve compression',
 219         qw(gc! C=s@) ],
 220
 221 # internal commands are prefixed with '_'
 222 '_complete' => [ '[...]', 'internal shell completion helper',
 223                 pass_through('everything') ],
 224 ); # @CMD
 225
 226 # switch descriptions, try to keep consistent across commands
 227 # $spec: Getopt::Long option specification
 228 # $spec => [@ALLOWED_VALUES (default is first), $description],
 229 # $spec => $description
 230 # "$SUB_COMMAND TAB $spec" => as above
 231 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 232                         'specify message input format' ];
 233 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 234
 235 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 236 my %OPTDESC = (
 237 'help|h' => 'show this built-in help',
 238 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 239 'quiet|q' => 'be quiet',
 240 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 241         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 242
 243 'globoff|g' => "do not match locations using '*?' wildcards ".
 244                 "and\xa0'[]'\x{a0}ranges",
 245 'verbose|v+' => 'be more verbose',
 246 'external!' => 'do not use externals',
 247 'solve!' => 'do not attempt to reconstruct blobs from emails',
 248 'torsocks=s' => ['VAL|auto|no|yes',
 249                 'whether or not to wrap git and curl commands with torsocks'],
 250 'no-torsocks' => 'alias for --torsocks=no',
 251 'save-as=s' => ['NAME', 'save a search terms by given name'],
 252 'import-remote!' => 'do not memoize remote messages into local store',
 253
 254 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 255
 256 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 257                 'deduplication strategy'],
 258 'threads|t+' =>
 259         'return all messages in the same threads as the actual match(es)',
 260
 261 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 262                 'search prefixes to extract (default: dfpost7)' ],
 263
 264 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 265         'run command(s) or perform ops when done writing to output ' .
 266         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 267         'nothing otherwise)' ],
 268
 269 'augment|a' => 'augment --output destination instead of clobbering',
 270
 271 'output|mfolder|o=s' => [ 'MFOLDER',
 272         "destination (e.g.\xa0`/path/to/Maildir', ".
 273         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 274 'mua=s' => [ 'CMD',
 275         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 276
 277 'inbox-version=i' => [ 'NUM|1|2',
 278                 'force a public-inbox version with --mirror'],
 279 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 280
 281 # public-inbox-index options
 282 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 283 'compact' => 'run compact index after mirroring',
 284 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 285         "indexlevel with --mirror (default: full)" ],
 286 'max_size|max-size=s' => [ 'SIZE',
 287         'do not index messages larger than SIZE (default: infinity)' ],
 288 'batch_size|batch-size=s' => [ 'SIZE',
 289         'flush changes to OS after given number of bytes (default: 1m)' ],
 290 'sequential_shard|sequential-shard' =>
 291         'index Xapian shards sequentially for slow storage',
 292 'skip-docdata' =>
 293         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 294
 295 'format|f=s     q' => [
 296         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 297                 'specify output format, default depends on --output'],
 298 'exclude=s@     q' => [ 'LOCATION',
 299                 'exclude specified external(s) from search' ],
 300 'include|I=s@   q' => [ 'LOCATION',
 301                 'include specified external(s) in search' ],
 302 'only=s@        q' => [ 'LOCATION',
 303                 'only use specified external(s) for search' ],
 304 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 305                 'control number of search and writer jobs' ],
 306 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 307
 308 'in-format|F=s' => $stdin_formats,
 309 'format|f=s     ls-query' => $ls_format,
 310 'format|f=s     ls-external' => $ls_format,
 311
 312 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 313 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 314
 315 'sort|s=s' => [ 'VAL|received|relevance|docid',
 316                 "order of results is `--output'-dependent"],
 317 'reverse|r' => 'reverse search results', # like sort(1)
 318
 319 'boost=i' => 'increase/decrease priority of results (default: 0)',
 320
 321 'local' => 'limit operations to the local filesystem',
 322 'local!' => 'exclude results from the local filesystem',
 323 'remote' => 'limit operations to those requiring network access',
 324 'remote!' => 'prevent operations requiring network access',
 325
 326 'mid=s' => 'specify the Message-ID of a message',
 327 'oid=s' => 'specify the git object ID of a message',
 328
 329 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 330 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 331 'include=s' => 'include mailboxes/newsgroups based on pattern',
 332
 333 'exact' => 'operate on exact header matches only',
 334 'exact!' => 'rely on content match instead of exact header matches',
 335
 336 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 337
 338 'kw|keywords|flags!' => 'disable/enable importing flags',
 339
 340 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 341 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 342
 343 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 344 ); # %OPTDESC
 345
 346 my %CONFIG_KEYS = (
 347         'leistore.dir' => 'top-level storage location',
 348 );
 349
 350 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q); # internal workers
 351
 352 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 353 sub x_it ($$) {
 354         my ($self, $code) = @_;
 355         # make sure client sees stdout before exit
 356         $self->{1}->autoflush(1) if $self->{1};
 357         dump_and_clear_log();
 358         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 359                 send($s, "x_it $code", MSG_EOR);
 360         } elsif ($self->{oneshot}) {
 361                 # don't want to end up using $? from child processes
 362                 for my $f (@WQ_KEYS) {
 363                         my $wq = delete $self->{$f} or next;
 364                         $wq->DESTROY;
 365                 }
 366                 # cleanup anything that has tempfiles or open file handles
 367                 %PATH2CFG = ();
 368                 delete @$self{qw(ovv dedupe sto cfg)};
 369                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 370                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 371                         kill $signum, $$;
 372                         sleep(1) while 1; # wait for signal
 373                 } else {
 374                         $quit->($code >> 8);
 375                 }
 376         } # else ignore if client disconnected
 377 }
 378
 379 sub err ($;@) {
 380         my $self = shift;
 381         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 382         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 383         print $err @_, @eor and return;
 384         my $old_err = delete $self->{2};
 385         close($old_err) if $! == EPIPE && $old_err;
 386         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 387         print $err @_, @eor or print STDERR @_, @eor;
 388 }
 389
 390 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 391
 392 sub fail_handler ($;$$) {
 393         my ($lei, $code, $io) = @_;
 394         for my $f (@WQ_KEYS) {
 395                 my $wq = delete $lei->{$f} or next;
 396                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 397         }
 398         close($io) if $io; # needed to avoid warnings on SIGPIPE
 399         x_it($lei, $code // (1 << 8));
 400 }
 401
 402 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 403         fail_handler($_[0], 13, delete $_[0]->{1});
 404 }
 405
 406 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 407 sub sigint_reap {
 408         my ($pgid) = @_;
 409         dwaitpid($pgid) if kill('-INT', $pgid);
 410 }
 411
 412 sub fail ($$;$) {
 413         my ($self, $buf, $exit_code) = @_;
 414         err($self, $buf) if defined $buf;
 415         # calls fail_handler:
 416         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 417         x_it($self, ($exit_code // 1) << 8);
 418         undef;
 419 }
 420
 421 sub check_input_format ($;$) {
 422         my ($self, $files) = @_;
 423         my $opt_key = 'in-format';
 424         my $fmt = $self->{opt}->{$opt_key};
 425         if (!$fmt) {
 426                 my $err = $files ? "regular file(s):\n@$files" : '--stdin';
 427                 return fail($self, "--$opt_key unset for $err");
 428         }
 429         require PublicInbox::MboxLock if $files;
 430         require PublicInbox::MboxReader;
 431         return 1 if $fmt eq 'eml';
 432         # XXX: should this handle {gz,bz2,xz}? that's currently in LeiToMail
 433         PublicInbox::MboxReader->can($fmt) or
 434                 return fail($self, "--$opt_key=$fmt unrecognized");
 435         1;
 436 }
 437
 438 sub out ($;@) {
 439         my $self = shift;
 440         return if print { $self->{1} // return } @_; # likely
 441         return note_sigpipe($self, 1) if $! == EPIPE;
 442         my $err = "error writing to output: $!";
 443         delete $self->{1};
 444         fail($self, $err);
 445 }
 446
 447 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 448
 449 sub child_error { # passes non-fatal curl exit codes to user
 450         my ($self, $child_error, $msg) = @_; # child_error is $?
 451         $self->err($msg) if $msg;
 452         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 453                 # send to the parent lei-daemon or to lei(1) client
 454                 send($s, "child_error $child_error", MSG_EOR);
 455         } elsif (!$PublicInbox::DS::in_loop) {
 456                 $self->{child_error} = $child_error;
 457         } # else noop if client disconnected
 458 }
 459
 460 sub note_sigpipe { # triggers sigpipe_handler
 461         my ($self, $fd) = @_;
 462         close(delete($self->{$fd})); # explicit close silences Perl warning
 463         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 464         x_it($self, 13);
 465 }
 466
 467 sub lei_atfork_child {
 468         my ($self, $persist) = @_;
 469         # we need to explicitly close things which are on stack
 470         if ($persist) {
 471                 my @io = delete @$self{qw(0 1 2 sock)};
 472                 unless ($self->{oneshot}) {
 473                         close($_) for @io;
 474                 }
 475         } else {
 476                 delete $self->{0};
 477         }
 478         delete @$self{qw(cnv)};
 479         for (delete @$self{qw(3 old_1 au_done)}) {
 480                 close($_) if defined($_);
 481         }
 482         if (my $op_c = delete $self->{pkt_op_c}) {
 483                 close(delete $op_c->{sock});
 484         }
 485         if (my $pgr = delete $self->{pgr}) {
 486                 close($_) for (@$pgr[1,2]);
 487         }
 488         close $listener if $listener;
 489         undef $listener;
 490         %PATH2CFG = ();
 491         undef $errors_log;
 492         $quit = \&CORE::exit;
 493         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 494 }
 495
 496 sub workers_start {
 497         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 498         $ops = {
 499                 '!' => [ $lei->can('fail_handler'), $lei ],
 500                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 501                 'x_it' => [ $lei->can('x_it'), $lei ],
 502                 'child_error' => [ $lei->can('child_error'), $lei ],
 503                 %$ops
 504         };
 505         require PublicInbox::PktOp;
 506         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 507         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 508         delete $lei->{pkt_op_p};
 509         my $op = delete $lei->{pkt_op_c};
 510         $lei->event_step_init;
 511         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 512         $lei->{oneshot} ? $op : undef;
 513 }
 514
 515 sub _help {
 516         require PublicInbox::LeiHelp;
 517         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 518 }
 519
 520 sub optparse ($$$) {
 521         my ($self, $cmd, $argv) = @_;
 522         # allow _complete --help to complete, not show help
 523         return 1 if substr($cmd, 0, 1) eq '_';
 524         $self->{cmd} = $cmd;
 525         $OPT = $self->{opt} //= {};
 526         my $info = $CMD{$cmd} // [ '[...]' ];
 527         my ($proto, undef, @spec) = @$info;
 528         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 529         push @spec, qw(help|h);
 530         my $lone_dash;
 531         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 532                 $lone_dash = $spec[0];
 533                 $OPT->{$spec[0]} = \(my $var);
 534                 push @spec, '' => \$var;
 535         }
 536         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 537                 return _help($self, "bad arguments or options for $cmd");
 538         return _help($self) if $OPT->{help};
 539
 540         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 541
 542         # "-" aliases "stdin" or "clear"
 543         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 544
 545         my $i = 0;
 546         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 547         my ($err, $inf);
 548         my @args = split(/ /, $proto);
 549         for my $var (@args) {
 550                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 551                         $inf = defined($argv->[$i]) and last;
 552                         $var =~ s/\.\.\.\z//;
 553                         $err = "$var not supplied";
 554                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 555                         $argv->[$i++] // ($err = "$var not supplied");
 556                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 557                         $inf = 1;
 558                         last;
 559                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 560                         $i++;
 561                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 562                         $inf = 1 if index($var, '...') > 0;
 563                         my @or = split(/\|/, $var);
 564                         my $ok;
 565                         for my $o (@or) {
 566                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 567                                         $ok = defined($OPT->{$1});
 568                                         last if $ok;
 569                                 } elsif (defined($argv->[$i])) {
 570                                         $ok = 1;
 571                                         $i++;
 572                                         last;
 573                                 } # else continue looping
 574                         }
 575                         last if $ok;
 576                         my $last = pop @or;
 577                         $err = join(', ', @or) . " or $last must be set";
 578                 } else {
 579                         warn "BUG: can't parse `$var' in $proto";
 580                 }
 581                 last if $err;
 582         }
 583         if (!$inf && scalar(@$argv) > scalar(@args)) {
 584                 $err //= 'too many arguments';
 585         }
 586         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 587 }
 588
 589 sub dispatch {
 590         my ($self, $cmd, @argv) = @_;
 591         local $current_lei = $self; # for __WARN__
 592         dump_and_clear_log("from previous run\n");
 593         return _help($self, 'no command given') unless defined($cmd);
 594         while ($cmd eq '-C') { # do not support Getopt bundling for this
 595                 my $d = shift(@argv) // return fail($self, '-C DIRECTORY');
 596                 push @{$self->{opt}->{C}}, $d;
 597                 $cmd = shift(@argv) // return _help($self, 'no command given');
 598         }
 599         my $func = "lei_$cmd";
 600         $func =~ tr/-/_/;
 601         if (my $cb = __PACKAGE__->can($func)) {
 602                 optparse($self, $cmd, \@argv) or return;
 603                 if (my $chdir = $self->{opt}->{C}) {
 604                         for my $d (@$chdir) {
 605                                 next if $d eq ''; # same as git(1)
 606                                 chdir $d or return fail($self, "cd $d: $!");
 607                         }
 608                 }
 609                 $cb->($self, @argv);
 610         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 611                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 612                         or return _help($self, 'bad arguments or options');
 613                 _help($self);
 614         } else {
 615                 fail($self, "`$cmd' is not an lei command");
 616         }
 617 }
 618
 619 sub _lei_cfg ($;$) {
 620         my ($self, $creat) = @_;
 621         my $f = _config_path($self);
 622         my @st = stat($f);
 623         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 624         my ($sto, $sto_dir);
 625         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 626                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 627                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 628         }
 629         if (!@st) {
 630                 unless ($creat) {
 631                         delete $self->{cfg};
 632                         return bless {}, 'PublicInbox::Config';
 633                 }
 634                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 635                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 636                 open my $fh, '>>', $f or die "open($f): $!\n";
 637                 @st = stat($fh) or die "fstat($f): $!\n";
 638                 $cur_st = pack('dd', $st[10], $st[7]);
 639                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 640         }
 641         my $cfg = PublicInbox::Config::git_config_dump($f);
 642         bless $cfg, 'PublicInbox::Config';
 643         $cfg->{-st} = $cur_st;
 644         $cfg->{'-f'} = $f;
 645         if ($sto && File::Spec->canonpath($sto_dir) eq
 646                         File::Spec->canonpath($cfg->{'leistore.dir'})) {
 647                 $cfg->{-lei_store} = $sto;
 648         }
 649         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 650 }
 651
 652 sub _lei_store ($;$) {
 653         my ($self, $creat) = @_;
 654         my $cfg = _lei_cfg($self, $creat);
 655         $cfg->{-lei_store} //= do {
 656                 require PublicInbox::LeiStore;
 657                 my $dir = $cfg->{'leistore.dir'};
 658                 $dir //= $creat ? store_path($self) : return;
 659                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 660         };
 661 }
 662
 663 sub lei_show {
 664         my ($self, @argv) = @_;
 665 }
 666
 667 sub lei_mark {
 668         my ($self, @argv) = @_;
 669 }
 670
 671 sub _config {
 672         my ($self, @argv) = @_;
 673         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 674         my $cfg = _lei_cfg($self, 1);
 675         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 676         my %rdr = map { $_ => $self->{$_} } (0..2);
 677         waitpid(spawn($cmd, \%env, \%rdr), 0);
 678 }
 679
 680 sub lei_config {
 681         my ($self, @argv) = @_;
 682         $self->{opt}->{'config-file'} and return fail $self,
 683                 "config file switches not supported by `lei config'";
 684         _config(@_);
 685         x_it($self, $?) if $?;
 686 }
 687
 688 sub lei_import {
 689         require PublicInbox::LeiImport;
 690         PublicInbox::LeiImport->call(@_);
 691 }
 692
 693 sub lei_convert {
 694         require PublicInbox::LeiConvert;
 695         PublicInbox::LeiConvert->call(@_);
 696 }
 697
 698 sub lei_p2q {
 699         require PublicInbox::LeiP2q;
 700         PublicInbox::LeiP2q->call(@_);
 701 }
 702
 703 sub lei_init {
 704         my ($self, $dir) = @_;
 705         my $cfg = _lei_cfg($self, 1);
 706         my $cur = $cfg->{'leistore.dir'};
 707         $dir //= store_path($self);
 708         $dir = rel2abs($self, $dir);
 709         my @cur = stat($cur) if defined($cur);
 710         $cur = File::Spec->canonpath($cur // $dir);
 711         my @dir = stat($dir);
 712         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 713         if (@cur) {
 714                 if ($cur eq $dir) {
 715                         _lei_store($self, 1)->done;
 716                         return qerr($self, $exists);
 717                 }
 718
 719                 # some folks like symlinks and bind mounts :P
 720                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 721                         lei_config($self, 'leistore.dir', $dir);
 722                         _lei_store($self, 1)->done;
 723                         return qerr($self, "$exists (as $cur)");
 724                 }
 725                 return fail($self, <<"");
 726 E: leistore.dir=$cur already initialized and it is not $dir
 727
 728         }
 729         lei_config($self, 'leistore.dir', $dir);
 730         _lei_store($self, 1)->done;
 731         $exists //= "# leistore.dir=$dir newly initialized";
 732         return qerr($self, $exists);
 733 }
 734
 735 sub lei_daemon_pid { puts shift, $$ }
 736
 737 sub lei_daemon_kill {
 738         my ($self) = @_;
 739         my $sig = $self->{opt}->{signal} // 'TERM';
 740         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 741 }
 742
 743 sub lei_help { _help($_[0]) }
 744
 745 # Shell completion helper.  Used by lei-completion.bash and hopefully
 746 # other shells.  Try to do as much here as possible to avoid redundancy
 747 # and improve maintainability.
 748 sub lei__complete {
 749         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 750         shift @argv; # ignore "lei", the entire command is sent
 751         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 752         my $cmd = shift @argv;
 753         my $info = $CMD{$cmd} // do { # filter matching commands
 754                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 755                 return;
 756         };
 757         my ($proto, undef, @spec) = @$info;
 758         my $cur = pop @argv;
 759         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 760         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 761                 # gross special case since the only git-config options
 762                 # Consider moving to a table if we need more special cases
 763                 # we use Getopt::Long for are the ones we reject, so these
 764                 # are the ones we don't reject:
 765                 if ($cmd eq 'config') {
 766                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 767                         @spec = qw(add z|null get get-all unset unset-all
 768                                 replace-all get-urlmatch
 769                                 remove-section rename-section
 770                                 name-only list|l edit|e
 771                                 get-color-name get-colorbool);
 772                         # fall-through
 773                 }
 774                 # generate short/long names from Getopt::Long specs
 775                 puts $self, grep(/$re/, qw(--help -h -C), map {
 776                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 777                         } elsif (s/\+\z//) { # verbose|v+
 778                         } elsif (s/!\z//) {
 779                                 # negation: solve! => no-solve|solve
 780                                 s/([\w\-]+)/$1|no-$1/g
 781                         }
 782                         map {
 783                                 my $x = length > 1 ? "--$_" : "-$_";
 784                                 $x eq $_cur ? () : $x;
 785                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 786                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 787         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 788                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 789         }
 790
 791         # switch args (e.g. lei q -f mbox<TAB>)
 792         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 793                 my $opt = quotemeta $1;
 794                 puts $self, map {
 795                         my $v = $OPTDESC{$_};
 796                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 797                         # get rid of ALL CAPS placeholder (e.g "OUT")
 798                         # (TODO: completion for external paths)
 799                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 800                         @v;
 801                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 802         }
 803         $cmd =~ tr/-/_/;
 804         if (my $sub = $self->can("_complete_$cmd")) {
 805                 puts $self, $sub->($self, @argv, $cur ? ($cur) : ());
 806         }
 807         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 808         # proto parsing.
 809 }
 810
 811 sub exec_buf ($$) {
 812         my ($argv, $env) = @_;
 813         my $argc = scalar @$argv;
 814         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 815         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 816         $buf;
 817 }
 818
 819 sub start_mua {
 820         my ($self) = @_;
 821         my $mua = $self->{opt}->{mua} // return;
 822         my $mfolder = $self->{ovv}->{dst};
 823         my (@cmd, $replaced);
 824         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 825                 @cmd = ($mua, '-f');
 826         # TODO: help wanted: other common FOSS MUAs
 827         } else {
 828                 require Text::ParseWords;
 829                 @cmd = Text::ParseWords::shellwords($mua);
 830                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 831                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 832         }
 833         push @cmd, $mfolder unless defined($replaced);
 834         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 835                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 836         } elsif ($self->{oneshot}) {
 837                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 838         }
 839         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 840                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 841         }
 842         $self->{opt}->{quiet} = 1;
 843         delete $self->{-progress};
 844         delete $self->{opt}->{verbose};
 845 }
 846
 847 sub send_exec_cmd { # tell script/lei to execute a command
 848         my ($self, $io, $cmd, $env) = @_;
 849         my $sock = $self->{sock} // die 'lei client gone';
 850         my $fds = [ map { fileno($_) } @$io ];
 851         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 852 }
 853
 854 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 855         my ($self) = @_;
 856         my $alerts = $self->{opt}->{alert} // return;
 857         while (my $op = shift(@$alerts)) {
 858                 if ($op eq ':WINCH') {
 859                         # hit the process group that started the MUA
 860                         if ($self->{sock}) {
 861                                 send($self->{sock}, '-WINCH', MSG_EOR);
 862                         } elsif ($self->{oneshot}) {
 863                                 kill('-WINCH', $$);
 864                         }
 865                 } elsif ($op eq ':bell') {
 866                         out($self, "\a");
 867                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 868                         push @$alerts, split(/(?<!\\),/, $op);
 869                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 870                         my $cmd = $1; # run an arbitrary command
 871                         require Text::ParseWords;
 872                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 873                         if (my $s = $self->{sock}) {
 874                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 875                         } elsif ($self->{oneshot}) {
 876                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 877                         }
 878                 } else {
 879                         err($self, "W: unsupported --alert=$op"); # non-fatal
 880                 }
 881         }
 882 }
 883
 884 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 885 $path_to_fd{"/dev/fd/$_"} = $path_to_fd{"/proc/self/fd/$_"} for (0..2);
 886 sub fopen {
 887         my ($self, $mode, $path) = @_;
 888         rel2abs($self, $path);
 889         $path =~ tr!/!/!s;
 890         if (defined(my $fd = $path_to_fd{$path})) {
 891                 return $self->{$fd};
 892         }
 893         if ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) {
 894                 return fail($self, "cannot open $path from daemon");
 895         }
 896         open my $fh, $mode, $path or return;
 897         $fh;
 898 }
 899
 900 # caller needs to "-t $self->{1}" to check if tty
 901 sub start_pager {
 902         my ($self) = @_;
 903         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 904         chomp(my $pager = <$fh> // '');
 905         close($fh) or warn "`git var PAGER' error: \$?=$?";
 906         return if $pager eq 'cat' || $pager eq '';
 907         my $new_env = { LESS => 'FRX', LV => '-c' };
 908         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 909         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 910         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 911         my $pgr = [ undef, @$rdr{1, 2} ];
 912         my $env = $self->{env};
 913         if ($self->{sock}) { # lei(1) process runs it
 914                 delete @$new_env{keys %$env}; # only set iff unset
 915                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 916         } elsif ($self->{oneshot}) {
 917                 my $cmd = [$pager];
 918                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 919         } else {
 920                 die 'BUG: start_pager w/o socket';
 921         }
 922         $self->{1} = $wpager;
 923         $self->{2} = $wpager if -t $self->{2};
 924         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 925         $self->{pgr} = $pgr;
 926 }
 927
 928 sub stop_pager {
 929         my ($self) = @_;
 930         my $pgr = delete($self->{pgr}) or return;
 931         $self->{2} = $pgr->[2];
 932         # do not restore original stdout, just close it so we error out
 933         close(delete($self->{1})) if $self->{1};
 934 }
 935
 936 sub accept_dispatch { # Listener {post_accept} callback
 937         my ($sock) = @_; # ignore other
 938         $sock->autoflush(1);
 939         my $self = bless { sock => $sock }, __PACKAGE__;
 940         vec(my $rvec = '', fileno($sock), 1) = 1;
 941         select($rvec, undef, undef, 60) or
 942                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 943         # (4096 * 33) >MAX_ARG_STRLEN
 944         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 945         if (scalar(@fds) == 4) {
 946                 for my $i (0..3) {
 947                         my $fd = shift(@fds);
 948                         open($self->{$i}, '+<&=', $fd) and next;
 949                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 950                 }
 951         } elsif (!defined($fds[0])) {
 952                 warn(my $msg = "recv_cmd failed: $!");
 953                 return send($sock, $msg, MSG_EOR);
 954         } else {
 955                 return;
 956         }
 957         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 958         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 959         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 960         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 961                 return send($sock, 'request command truncated', MSG_EOR);
 962         my ($argc, @argv) = split(/\0/, $buf, -1);
 963         undef $buf;
 964         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 965         if (chdir($self->{3})) {
 966                 local %ENV = %env;
 967                 $self->{env} = \%env;
 968                 eval { dispatch($self, @argv) };
 969                 send($sock, $@, MSG_EOR) if $@;
 970         } else {
 971                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 972         }
 973 }
 974
 975 sub dclose {
 976         my ($self) = @_;
 977         delete $self->{-progress};
 978         for my $f (@WQ_KEYS) {
 979                 my $wq = delete $self->{$f} or next;
 980                 if ($wq->wq_kill) {
 981                         $wq->wq_close(0, undef, $self);
 982                 } elsif ($wq->wq_kill_old) {
 983                         $wq->wq_wait_old(undef, $self);
 984                 }
 985         }
 986         close(delete $self->{1}) if $self->{1}; # may reap_compress
 987         if (my $sto = delete $self->{sto}) {
 988                 $sto->ipc_do('done');
 989         }
 990         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 991 }
 992
 993 # for long-running results
 994 sub event_step {
 995         my ($self) = @_;
 996         local %ENV = %{$self->{env}};
 997         my $sock = $self->{sock};
 998         local $current_lei = $self;
 999         eval {
1000                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1001                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1002                                 return if $! == EAGAIN;
1003                                 next if $! == EINTR;
1004                                 last if $! == ECONNRESET;
1005                                 die "recvmsg: $!";
1006                         }
1007                         for my $fd (@fds) {
1008                                 open my $rfh, '+<&=', $fd;
1009                         }
1010                         die "unrecognized client signal: $buf";
1011                 }
1012                 dclose($self);
1013         };
1014         if (my $err = $@) {
1015                 eval { $self->fail($err) };
1016                 dclose($self);
1017         }
1018 }
1019
1020 sub event_step_init {
1021         my ($self) = @_;
1022         return if $self->{-event_init_done}++;
1023         if (my $sock = $self->{sock}) { # using DS->EventLoop
1024                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1025         }
1026 }
1027
1028 sub noop {}
1029
1030 sub oldset { $oldset }
1031
1032 sub dump_and_clear_log {
1033         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1034                 my @pfx = @_;
1035                 unshift(@pfx, "$errors_log ") if @pfx;
1036                 warn @pfx, do { local $/; <STDIN> };
1037                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1038         }
1039 }
1040
1041 # lei(1) calls this when it can't connect
1042 sub lazy_start {
1043         my ($path, $errno, $narg) = @_;
1044         local ($errors_log, $listener);
1045         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1046         $errors_log .= 'errors.log';
1047         my $addr = pack_sockaddr_un($path);
1048         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1049         $lk->lock_acquire;
1050         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1051         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1052                 return if connect($listener, $addr); # another process won
1053                 if ($errno == ECONNREFUSED && -S $path) {
1054                         unlink($path) or die "unlink($path): $!";
1055                 }
1056         } else {
1057                 $! = $errno; # allow interpolation to stringify in die
1058                 die "connect($path): $!";
1059         }
1060         umask(077) // die("umask(077): $!");
1061         bind($listener, $addr) or die "bind($path): $!";
1062         listen($listener, 1024) or die "listen: $!";
1063         $lk->lock_release;
1064         undef $lk;
1065         my @st = stat($path) or die "stat($path): $!";
1066         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1067         local $oldset = PublicInbox::DS::block_signals();
1068         if ($narg == 5) {
1069                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1070                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1071                         require PublicInbox::CmdIPC4;
1072                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1073                         PublicInbox::CmdIPC4->can('recv_cmd4');
1074                 };
1075         }
1076         $recv_cmd or die <<"";
1077 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1078
1079         require PublicInbox::Listener;
1080         require PublicInbox::EOFpipe;
1081         (-p STDOUT) or die "E: stdout must be a pipe\n";
1082         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1083         STDIN->autoflush(1);
1084         dump_and_clear_log("from previous daemon process:\n");
1085         POSIX::setsid() > 0 or die "setsid: $!";
1086         my $pid = fork // die "fork: $!";
1087         return if $pid;
1088         $0 = "lei-daemon $path";
1089         local %PATH2CFG;
1090         $listener->blocking(0);
1091         my $exit_code;
1092         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1093         local $quit = do {
1094                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1095                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1096                 sub {
1097                         $exit_code //= shift;
1098                         my $lis = $pil or exit($exit_code);
1099                         # closing eof_w triggers \&noop wakeup
1100                         $listener = $eof_w = $pil = $path = undef;
1101                         $lis->close; # DS::close
1102                         PublicInbox::DS->SetLoopTimeout(1000);
1103                 };
1104         };
1105         my $sig = {
1106                 CHLD => \&PublicInbox::DS::enqueue_reap,
1107                 QUIT => $quit,
1108                 INT => $quit,
1109                 TERM => $quit,
1110                 HUP => \&noop,
1111                 USR1 => \&noop,
1112                 USR2 => \&noop,
1113         };
1114         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1115         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1116         undef $sig;
1117         local $SIG{PIPE} = 'IGNORE';
1118         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1119                 undef $sigfd;
1120                 PublicInbox::DS->SetLoopTimeout(5000);
1121         } else {
1122                 # wake up every second to accept signals if we don't
1123                 # have signalfd or IO::KQueue:
1124                 PublicInbox::DS::sig_setmask($oldset);
1125                 PublicInbox::DS->SetLoopTimeout(1000);
1126         }
1127         PublicInbox::DS->SetPostLoopCallback(sub {
1128                 my ($dmap, undef) = @_;
1129                 if (@st = defined($path) ? stat($path) : ()) {
1130                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1131                                 warn "$path dev/ino changed, quitting\n";
1132                                 $path = undef;
1133                         }
1134                 } elsif (defined($path)) { # ENOENT is common
1135                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1136                         undef $path;
1137                         $quit->();
1138                 }
1139                 return 1 if defined($path);
1140                 my $now = now();
1141                 my $n = 0;
1142                 for my $s (values %$dmap) {
1143                         $s->can('busy') or next;
1144                         if ($s->busy($now)) {
1145                                 ++$n;
1146                         } else {
1147                                 $s->close;
1148                         }
1149                 }
1150                 $n; # true: continue, false: stop
1151         });
1152
1153         # STDIN was redirected to /dev/null above, closing STDERR and
1154         # STDOUT will cause the calling `lei' client process to finish
1155         # reading the <$daemon> pipe.
1156         local $SIG{__WARN__} = sub {
1157                 $current_lei ? err($current_lei, @_) : warn(
1158                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1159         };
1160         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1161         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1162         # $daemon pipe to `lei' closed, main loop begins:
1163         PublicInbox::DS->EventLoop;
1164         exit($exit_code // 0);
1165 }
1166
1167 sub busy { 1 } # prevent daemon-shutdown if client is connected
1168
1169 # for users w/o Socket::Msghdr installed or Inline::C enabled
1170 sub oneshot {
1171         my ($main_pkg) = @_;
1172         my $exit = $main_pkg->can('exit'); # caller may override exit()
1173         local $quit = $exit if $exit;
1174         local %PATH2CFG;
1175         umask(077) // die("umask(077): $!");
1176         my $self = bless {
1177                 oneshot => 1,
1178                 0 => *STDIN{GLOB},
1179                 1 => *STDOUT{GLOB},
1180                 2 => *STDERR{GLOB},
1181                 env => \%ENV
1182         }, __PACKAGE__;
1183         dispatch($self, @ARGV);
1184         x_it($self, $self->{child_error}) if $self->{child_error};
1185 }
1186
1187 # ensures stdout hits the FS before sock disconnects so a client
1188 # can immediately reread it
1189 sub DESTROY {
1190         my ($self) = @_;
1191         $self->{1}->autoflush(1) if $self->{1};
1192         stop_pager($self);
1193         my $err = $?;
1194         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1195         waitpid($_, 0) for keys %$oneshot_pids;
1196         $? = $err if $err; # preserve ->fail or ->x_it code
1197 }
1198
1199 1;