lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'verbose|v' => 'be more verbose',
 205 'solve!' => 'do not attempt to reconstruct blobs from emails',
 206 'torsocks=s' => ['auto|no|yes',
 207                 'whether or not to wrap git and curl commands with torsocks'],
 208 'no-torsocks' => 'alias for --torsocks=no',
 209 'save-as=s' => ['NAME', 'save a search terms by given name'],
 210
 211 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 212
 213 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 214                 'deduplication strategy'],
 215 'show   thread|t' => 'display entire thread a message belongs to',
 216 'q      thread|t' =>
 217         'return all messages in the same thread as the actual match(es)',
 218 'augment|a' => 'augment --output destination instead of clobbering',
 219
 220 'output|mfolder|o=s' => [ 'DEST',
 221         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 222 'mua-cmd|mua=s' => [ 'COMMAND',
 223         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 224
 225 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 226                         'message/object output format' ],
 227 'mark   format|f=s' => $stdin_formats,
 228 'forget format|f=s' => $stdin_formats,
 229 'q      format|f=s' => [
 230         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 231                 'specify output format, default depends on --output'],
 232 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 233                 'exclude specified external(s) from search' ],
 234 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 235                 'include specified external(s) in search' ],
 236 'q      only=s@' => [ 'URL_OR_PATHNAME',
 237                 'only use specified external(s) for search' ],
 238
 239 'ls-query       format|f=s' => $ls_format,
 240 'ls-external    format|f=s' => $ls_format,
 241
 242 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 243 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 244
 245 'sort|s=s' => [ 'VAL|received,relevance,docid',
 246                 "order of results `--output'-dependent"],
 247 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 248
 249 'boost=i' => 'increase/decrease priority of results (default: 0)',
 250
 251 'local' => 'limit operations to the local filesystem',
 252 'local!' => 'exclude results from the local filesystem',
 253 'remote' => 'limit operations to those requiring network access',
 254 'remote!' => 'prevent operations requiring network access',
 255
 256 'mid=s' => 'specify the Message-ID of a message',
 257 'oid=s' => 'specify the git object ID of a message',
 258
 259 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 260 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 261 'include=s' => 'include mailboxes/newsgroups based on pattern',
 262
 263 'exact' => 'operate on exact header matches only',
 264 'exact!' => 'rely on content match instead of exact header matches',
 265
 266 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 267 'jobs:i' => 'set parallelism level',
 268
 269 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 270 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 271
 272 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 273 ); # %OPTDESC
 274
 275 my %CONFIG_KEYS = (
 276         'leistore.dir' => 'top-level storage location',
 277 );
 278
 279 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 280 sub x_it ($$) {
 281         my ($self, $code) = @_;
 282         # make sure client sees stdout before exit
 283         $self->{1}->autoflush(1) if $self->{1};
 284         dump_and_clear_log();
 285         if (my $sock = $self->{sock}) {
 286                 send($sock, "x_it $code", MSG_EOR);
 287         } elsif (my $signum = ($code & 127)) { # oneshot, usually SIGPIPE (13)
 288                 $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 289                 kill $signum, $$;
 290                 sleep; # wait for signal
 291         } else { # oneshot
 292                 # don't want to end up using $? from child processes
 293                 for my $f (qw(lxs l2m)) {
 294                         my $wq = delete $self->{$f} or next;
 295                         $wq->DESTROY;
 296                 }
 297                 $quit->($code >> 8);
 298         }
 299 }
 300
 301 sub err ($;@) {
 302         my $self = shift;
 303         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 304         my $eor = (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 305         print $err @_, $eor and return;
 306         my $old_err = delete $self->{2};
 307         close($old_err) if $! == EPIPE && $old_err;;
 308         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 309         print $err @_, $eor or print STDERR @_, $eor;
 310 }
 311
 312 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 313
 314 sub fail ($$;$) {
 315         my ($self, $buf, $exit_code) = @_;
 316         err($self, $buf) if defined $buf;
 317         send($self->{pkt_op}, '!', MSG_EOR) if $self->{pkt_op}; # fail_handler
 318         x_it($self, ($exit_code // 1) << 8);
 319         undef;
 320 }
 321
 322 sub out ($;@) {
 323         my $self = shift;
 324         return if print { $self->{1} // return } @_; # likely
 325         return note_sigpipe($self, 1) if $! == EPIPE;
 326         my $err = "error writing to stdout: $!";
 327         delete $self->{1};
 328         fail($self, $err);
 329 }
 330
 331 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 332
 333 sub child_error { # passes non-fatal curl exit codes to user
 334         my ($self, $child_error) = @_; # child_error is $?
 335         if (my $sock = $self->{sock}) { # send to lei(1) client
 336                 send($sock, "child_error $child_error", MSG_EOR);
 337         } else { # oneshot
 338                 $self->{child_error} = $child_error;
 339         }
 340         undef;
 341 }
 342
 343 sub atfork_prepare_wq {
 344         my ($self, $wq) = @_;
 345         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 346         if (my $sock = $self->{sock}) {
 347                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 348         }
 349         if (my $pgr = $self->{pgr}) {
 350                 push @$tcafc, @$pgr[1,2];
 351         }
 352         if (my $old_1 = $self->{old_1}) {
 353                 push @$tcafc, $old_1;
 354         }
 355         for my $f (qw(lxs l2m)) {
 356                 my $ipc = $self->{$f} or next;
 357                 push @$tcafc, grep { defined }
 358                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 359         }
 360 }
 361
 362 sub io_restore ($$) {
 363         my ($dst, $src) = @_;
 364         for my $i (0..2) { # standard FDs
 365                 my $io = delete $src->{$i} or next;
 366                 $dst->{$i} = $io;
 367         }
 368         for my $i (3..9) { # named (non-standard) FDs
 369                 my $io = $src->{$i} or next;
 370                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 371                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 372                 $dst->{$f} = $io;
 373                 delete $src->{$i};
 374         }
 375 }
 376
 377 sub note_sigpipe { # triggers sigpipe_handler
 378         my ($self, $fd) = @_;
 379         close(delete($self->{$fd})); # explicit close silences Perl warning
 380         send($self->{pkt_op}, '|', MSG_EOR) if $self->{pkt_op};
 381         x_it($self, 13);
 382 }
 383
 384 sub atfork_child_wq {
 385         my ($self, $wq) = @_;
 386         io_restore($self, $wq);
 387         -S $self->{pkt_op} or die 'BUG: {pkt_op} expected';
 388         io_restore($self->{l2m}, $wq);
 389         %PATH2CFG = ();
 390         undef $errors_log;
 391         $quit = \&CORE::exit;
 392         $current_lei = $self; # for SIG{__WARN__}
 393 }
 394
 395 sub io_extract ($;@) {
 396         my ($obj, @fields) = @_;
 397         my @io;
 398         for my $f (@fields) {
 399                 my $io = delete $obj->{$f} or next;
 400                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 401                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 402                 push @io, $io;
 403         }
 404         @io
 405 }
 406
 407 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 408 sub atfork_parent_wq {
 409         my ($self, $wq) = @_;
 410         my $env = delete $self->{env}; # env is inherited at fork
 411         my $lei = bless { %$self }, ref($self);
 412         for my $f (qw(dedupe ovv)) {
 413                 my $tmp = delete($lei->{$f}) or next;
 414                 $lei->{$f} = $wq->deep_clone($tmp);
 415         }
 416         $self->{env} = $env;
 417         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 418         my @io = (delete(@$lei{qw(0 1 2)}),
 419                         io_extract($lei, qw(sock pkt_op startq)));
 420         my $l2m = $lei->{l2m};
 421         if ($l2m && $l2m != $wq) { # $wq == lxs
 422                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 423                         push @io, io_extract($l2m, '-wq_s1');
 424                         $l2m->{-wq_s1} = $wq_s1;
 425                 }
 426                 $l2m->wq_close(1);
 427         }
 428         ($lei, @io);
 429 }
 430
 431 sub _help ($;$) {
 432         my ($self, $errmsg) = @_;
 433         my $cmd = $self->{cmd} // 'COMMAND';
 434         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 435         my @top = ($cmd, shift(@info) // ());
 436         my $cmd_desc = shift(@info);
 437         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 438         my @opt_desc;
 439         my $lpad = 2;
 440         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 441                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 442                 my $arg_vals = '';
 443                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 444
 445                 # lower-case is a keyword (e.g. `content', `oid'),
 446                 # ALL_CAPS is a string description (e.g. `PATH')
 447                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 448                         $desc .= "\ndefault: `$1'";
 449                 }
 450                 my (@vals, @s, @l);
 451                 my $x = $sw;
 452                 if ($x =~ s/!\z//) { # solve! => --no-solve
 453                         $x = "no-$x";
 454                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 455                         @vals = (' [', undef, ']');
 456                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 457                         @vals = (' ', undef);
 458                 } # else: no args $x = 'thread|t'
 459                 for (split(/\|/, $x)) { # help|h
 460                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 461                 }
 462                 if (!scalar(@vals)) { # no args 'thread|t'
 463                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 464                         $vals[1] = $1;
 465                 } else {
 466                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 467                 }
 468                 if ($arg_vals =~ /([,\|])/) {
 469                         my $sep = $1;
 470                         my @allow = split(/\Q$sep\E/, $arg_vals);
 471                         my $must = $sep eq '|' ? 'Must' : 'Can';
 472                         @allow = map { "`$_'" } @allow;
 473                         my $last = pop @allow;
 474                         $desc .= "\n$must be one of: " .
 475                                 join(', ', @allow) . " or $last";
 476                 }
 477                 my $lhs = join(', ', @s, @l) . join('', @vals);
 478                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 479                         $lhs =~ s/\A--/- , --/;
 480                 } else {
 481                         $lhs =~ s/\A--/    --/; # pad if no short options
 482                 }
 483                 $lpad = length($lhs) if length($lhs) > $lpad;
 484                 push @opt_desc, $lhs, $desc;
 485         }
 486         my $msg = $errmsg ? "E: $errmsg\n" : '';
 487         $msg .= <<EOF;
 488 usage: lei @top
 489   $cmd_desc
 490
 491 EOF
 492         $lpad += 2;
 493         local $Text::Wrap::columns = 78 - $lpad;
 494         my $padding = ' ' x ($lpad + 2);
 495         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 496                 $msg .= '  '.pack("A$lpad", $lhs);
 497                 $rhs = wrap('', '', $rhs);
 498                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 499                 $msg .= $rhs;
 500                 $msg .= "\n";
 501         }
 502         print { $self->{$errmsg ? 2 : 1} } $msg;
 503         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 504         undef;
 505 }
 506
 507 sub optparse ($$$) {
 508         my ($self, $cmd, $argv) = @_;
 509         $self->{cmd} = $cmd;
 510         $OPT = $self->{opt} = {};
 511         my $info = $CMD{$cmd} // [ '[...]' ];
 512         my ($proto, undef, @spec) = @$info;
 513         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 514         push @spec, qw(help|h);
 515         my $lone_dash;
 516         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 517                 $lone_dash = $spec[0];
 518                 $OPT->{$spec[0]} = \(my $var);
 519                 push @spec, '' => \$var;
 520         }
 521         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 522                 return _help($self, "bad arguments or options for $cmd");
 523         return _help($self) if $OPT->{help};
 524
 525         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 526
 527         # "-" aliases "stdin" or "clear"
 528         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 529
 530         my $i = 0;
 531         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 532         my ($err, $inf);
 533         my @args = split(/ /, $proto);
 534         for my $var (@args) {
 535                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 536                         $inf = defined($argv->[$i]) and last;
 537                         $var =~ s/\.\.\.\z//;
 538                         $err = "$var not supplied";
 539                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 540                         $argv->[$i++] // ($err = "$var not supplied");
 541                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 542                         $inf = 1;
 543                         last;
 544                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 545                         $i++;
 546                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 547                         my @or = split(/\|/, $var);
 548                         my $ok;
 549                         for my $o (@or) {
 550                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 551                                         $ok = defined($OPT->{$1});
 552                                         last;
 553                                 } elsif (defined($argv->[$i])) {
 554                                         $ok = 1;
 555                                         $i++;
 556                                         last;
 557                                 } # else continue looping
 558                         }
 559                         last if $ok;
 560                         my $last = pop @or;
 561                         $err = join(', ', @or) . " or $last must be set";
 562                 } else {
 563                         warn "BUG: can't parse `$var' in $proto";
 564                 }
 565                 last if $err;
 566         }
 567         if (!$inf && scalar(@$argv) > scalar(@args)) {
 568                 $err //= 'too many arguments';
 569         }
 570         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 571 }
 572
 573 sub dispatch {
 574         my ($self, $cmd, @argv) = @_;
 575         local $current_lei = $self; # for __WARN__
 576         dump_and_clear_log("from previous run\n");
 577         return _help($self, 'no command given') unless defined($cmd);
 578         my $func = "lei_$cmd";
 579         $func =~ tr/-/_/;
 580         if (my $cb = __PACKAGE__->can($func)) {
 581                 optparse($self, $cmd, \@argv) or return;
 582                 $cb->($self, @argv);
 583         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 584                 my $opt = {};
 585                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 586                         return _help($self, 'bad arguments or options');
 587                 _help($self);
 588         } else {
 589                 fail($self, "`$cmd' is not an lei command");
 590         }
 591 }
 592
 593 sub _lei_cfg ($;$) {
 594         my ($self, $creat) = @_;
 595         my $f = _config_path($self);
 596         my @st = stat($f);
 597         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 598         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 599                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 600         }
 601         if (!@st) {
 602                 unless ($creat) {
 603                         delete $self->{cfg};
 604                         return;
 605                 }
 606                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 607                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 608                 open my $fh, '>>', $f or die "open($f): $!\n";
 609                 @st = stat($fh) or die "fstat($f): $!\n";
 610                 $cur_st = pack('dd', $st[10], $st[7]);
 611                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 612         }
 613         my $cfg = PublicInbox::Config::git_config_dump($f);
 614         $cfg->{-st} = $cur_st;
 615         $cfg->{'-f'} = $f;
 616         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 617 }
 618
 619 sub _lei_store ($;$) {
 620         my ($self, $creat) = @_;
 621         my $cfg = _lei_cfg($self, $creat);
 622         $cfg->{-lei_store} //= do {
 623                 require PublicInbox::LeiStore;
 624                 my $dir = $cfg->{'leistore.dir'};
 625                 $dir //= $creat ? _store_path($self) : return;
 626                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 627         };
 628 }
 629
 630 sub lei_show {
 631         my ($self, @argv) = @_;
 632 }
 633
 634 sub lei_mark {
 635         my ($self, @argv) = @_;
 636 }
 637
 638 sub _config {
 639         my ($self, @argv) = @_;
 640         my $env = $self->{env};
 641         delete local $env->{GIT_CONFIG};
 642         delete local $ENV{GIT_CONFIG};
 643         my $cfg = _lei_cfg($self, 1);
 644         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 645         my %rdr = map { $_ => $self->{$_} } (0..2);
 646         waitpid(spawn($cmd, $env, \%rdr), 0);
 647 }
 648
 649 sub lei_config {
 650         my ($self, @argv) = @_;
 651         $self->{opt}->{'config-file'} and return fail $self,
 652                 "config file switches not supported by `lei config'";
 653         _config(@_);
 654         x_it($self, $?) if $?;
 655 }
 656
 657 sub lei_init {
 658         my ($self, $dir) = @_;
 659         my $cfg = _lei_cfg($self, 1);
 660         my $cur = $cfg->{'leistore.dir'};
 661         $dir //= _store_path($self);
 662         $dir = rel2abs($self, $dir);
 663         my @cur = stat($cur) if defined($cur);
 664         $cur = File::Spec->canonpath($cur // $dir);
 665         my @dir = stat($dir);
 666         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 667         if (@cur) {
 668                 if ($cur eq $dir) {
 669                         _lei_store($self, 1)->done;
 670                         return qerr($self, $exists);
 671                 }
 672
 673                 # some folks like symlinks and bind mounts :P
 674                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 675                         lei_config($self, 'leistore.dir', $dir);
 676                         _lei_store($self, 1)->done;
 677                         return qerr($self, "$exists (as $cur)");
 678                 }
 679                 return fail($self, <<"");
 680 E: leistore.dir=$cur already initialized and it is not $dir
 681
 682         }
 683         lei_config($self, 'leistore.dir', $dir);
 684         _lei_store($self, 1)->done;
 685         $exists //= "I: leistore.dir=$dir newly initialized";
 686         return qerr($self, $exists);
 687 }
 688
 689 sub lei_daemon_pid { puts shift, $$ }
 690
 691 sub lei_daemon_kill {
 692         my ($self) = @_;
 693         my $sig = $self->{opt}->{signal} // 'TERM';
 694         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 695 }
 696
 697 sub lei_help { _help($_[0]) }
 698
 699 # Shell completion helper.  Used by lei-completion.bash and hopefully
 700 # other shells.  Try to do as much here as possible to avoid redundancy
 701 # and improve maintainability.
 702 sub lei__complete {
 703         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 704         shift @argv; # ignore "lei", the entire command is sent
 705         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 706         my $cmd = shift @argv;
 707         my $info = $CMD{$cmd} // do { # filter matching commands
 708                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 709                 return;
 710         };
 711         my ($proto, undef, @spec) = @$info;
 712         my $cur = pop @argv;
 713         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 714         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 715                 # gross special case since the only git-config options
 716                 # Consider moving to a table if we need more special cases
 717                 # we use Getopt::Long for are the ones we reject, so these
 718                 # are the ones we don't reject:
 719                 if ($cmd eq 'config') {
 720                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 721                         @spec = qw(add z|null get get-all unset unset-all
 722                                 replace-all get-urlmatch
 723                                 remove-section rename-section
 724                                 name-only list|l edit|e
 725                                 get-color-name get-colorbool);
 726                         # fall-through
 727                 }
 728                 puts $self, grep(/$re/, map { # generate short/long names
 729                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 730                         } else { # negation: solve! => no-solve|solve
 731                                 s/\A(.+)!\z/no-$1|$1/;
 732                         }
 733                         map {
 734                                 my $x = length > 1 ? "--$_" : "-$_";
 735                                 $x eq $cur ? () : $x;
 736                         } split(/\|/, $_, -1) # help|h
 737                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 738         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 739                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 740         }
 741
 742         # switch args (e.g. lei q -f mbox<TAB>)
 743         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 744                 my $opt = quotemeta $1;
 745                 puts $self, map {
 746                         my $v = $OPTDESC{$_};
 747                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 748                         # get rid of ALL CAPS placeholder (e.g "OUT")
 749                         # (TODO: completion for external paths)
 750                         shift(@v) if uc($v[0]) eq $v[0];
 751                         @v;
 752                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 753         }
 754         $cmd =~ tr/-/_/;
 755         if (my $sub = $self->can("_complete_$cmd")) {
 756                 puts $self, $sub->($self, @argv, $cur);
 757         }
 758         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 759         # proto parsing.
 760 }
 761
 762 sub exec_buf ($$) {
 763         my ($argv, $env) = @_;
 764         my $argc = scalar @$argv;
 765         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 766         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 767         $buf;
 768 }
 769
 770 sub start_mua {
 771         my ($self) = @_;
 772         my $mua = $self->{opt}->{'mua-cmd'} // return;
 773         my $mfolder = $self->{ovv}->{dst};
 774         my (@cmd, $replaced);
 775         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 776                 @cmd = ($mua, '-f');
 777         # TODO: help wanted: other common FOSS MUAs
 778         } else {
 779                 require Text::ParseWords;
 780                 my @cmd = Text::ParseWords::shellwords($mua);
 781                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 782                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 783         }
 784         push @cmd, $mfolder unless defined($replaced);
 785         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 786                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 787         } else { # oneshot
 788                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 789         }
 790 }
 791
 792 # caller needs to "-t $self->{1}" to check if tty
 793 sub start_pager {
 794         my ($self) = @_;
 795         my $env = $self->{env};
 796         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 797         chomp(my $pager = <$fh> // '');
 798         close($fh) or warn "`git var PAGER' error: \$?=$?";
 799         return if $pager eq 'cat' || $pager eq '';
 800         # TODO TIOCGWINSZ
 801         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 802         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 803         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 804         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 805         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 806         if (my $sock = $self->{sock}) { # lei(1) process runs it
 807                 delete @$new_env{keys %$env}; # only set iff unset
 808                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 809                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 810         } else {
 811                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 812         }
 813         $self->{1} = $wpager;
 814         $self->{2} = $wpager if -t $self->{2};
 815         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 816         $self->{pgr} = $pgr;
 817 }
 818
 819 sub stop_pager {
 820         my ($self) = @_;
 821         my $pgr = delete($self->{pgr}) or return;
 822         $self->{2} = $pgr->[2];
 823         # do not restore original stdout, just close it so we error out
 824         close(delete($self->{1})) if $self->{1};
 825         my $pid = $pgr->[0];
 826         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 827 }
 828
 829 sub accept_dispatch { # Listener {post_accept} callback
 830         my ($sock) = @_; # ignore other
 831         $sock->autoflush(1);
 832         my $self = bless { sock => $sock }, __PACKAGE__;
 833         vec(my $rvec = '', fileno($sock), 1) = 1;
 834         select($rvec, undef, undef, 60) or
 835                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 836         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 837         if (scalar(@fds) == 4) {
 838                 for my $i (0..3) {
 839                         my $fd = shift(@fds);
 840                         open($self->{$i}, '+<&=', $fd) and next;
 841                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 842                 }
 843         } else {
 844                 my $msg = "recv_cmd failed: $!";
 845                 warn $msg;
 846                 return send($sock, $msg, MSG_EOR);
 847         }
 848         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 849         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 850         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 851         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 852                 return send($sock, 'request command truncated', MSG_EOR);
 853         my ($argc, @argv) = split(/\0/, $buf, -1);
 854         undef $buf;
 855         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 856         if (chdir($self->{3})) {
 857                 local %ENV = %env;
 858                 $self->{env} = \%env;
 859                 eval { dispatch($self, @argv) };
 860                 send($sock, $@, MSG_EOR) if $@;
 861         } else {
 862                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 863         }
 864 }
 865
 866 sub dclose {
 867         my ($self) = @_;
 868         for my $f (qw(lxs l2m)) {
 869                 my $wq = delete $self->{$f} or next;
 870                 if ($wq->wq_kill) {
 871                         $wq->wq_close
 872                 } elsif ($wq->wq_kill_old) {
 873                         $wq->wq_wait_old($self);
 874                 }
 875         }
 876         close(delete $self->{1}) if $self->{1}; # may reap_compress
 877         $self->close if $self->{sock}; # PublicInbox::DS::close
 878 }
 879
 880 # for long-running results
 881 sub event_step {
 882         my ($self) = @_;
 883         local %ENV = %{$self->{env}};
 884         my $sock = $self->{sock};
 885         local $current_lei = $self;
 886         eval {
 887                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 888                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 889                                 return if $! == EAGAIN;
 890                                 next if $! == EINTR;
 891                                 last if $! == ECONNRESET;
 892                                 die "recvmsg: $!";
 893                         }
 894                         for my $fd (@fds) {
 895                                 open my $rfh, '+<&=', $fd;
 896                         }
 897                         die "unrecognized client signal: $buf";
 898                 }
 899                 dclose($self);
 900         };
 901         if (my $err = $@) {
 902                 eval { $self->fail($err) };
 903                 dclose($self);
 904         }
 905 }
 906
 907 sub event_step_init {
 908         my ($self) = @_;
 909         if (my $sock = $self->{sock}) { # using DS->EventLoop
 910                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 911         }
 912 }
 913
 914 sub noop {}
 915
 916 our $oldset; sub oldset { $oldset }
 917
 918 sub dump_and_clear_log {
 919         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 920                 my @pfx = @_;
 921                 unshift(@pfx, "$errors_log ") if @pfx;
 922                 warn @pfx, do { local $/; <STDIN> };
 923                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 924         }
 925 }
 926
 927 # lei(1) calls this when it can't connect
 928 sub lazy_start {
 929         my ($path, $errno, $narg) = @_;
 930         if ($errno == ECONNREFUSED) {
 931                 unlink($path) or die "unlink($path): $!";
 932         } elsif ($errno != ENOENT) {
 933                 $! = $errno; # allow interpolation to stringify in die
 934                 die "connect($path): $!";
 935         }
 936         if (eval { require BSD::Resource }) {
 937                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 938                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 939                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 940         }
 941         umask(077) // die("umask(077): $!");
 942         local $listener;
 943         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 944         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 945         listen($listener, 1024) or die "listen: $!";
 946         my @st = stat($path) or die "stat($path): $!";
 947         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 948         local $oldset = PublicInbox::DS::block_signals();
 949         if ($narg == 5) {
 950                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 951                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 952                         require PublicInbox::CmdIPC4;
 953                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 954                         PublicInbox::CmdIPC4->can('recv_cmd4');
 955                 };
 956         }
 957         $recv_cmd or die <<"";
 958 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 959
 960         require PublicInbox::Listener;
 961         require PublicInbox::EOFpipe;
 962         (-p STDOUT) or die "E: stdout must be a pipe\n";
 963         local $errors_log;
 964         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 965         $errors_log .= 'errors.log';
 966         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 967         STDIN->autoflush(1);
 968         dump_and_clear_log("from previous daemon process:\n");
 969         POSIX::setsid() > 0 or die "setsid: $!";
 970         my $pid = fork // die "fork: $!";
 971         return if $pid;
 972         $0 = "lei-daemon $path";
 973         local %PATH2CFG;
 974         $listener->blocking(0);
 975         my $exit_code;
 976         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 977         local $quit = do {
 978                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 979                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 980                 sub {
 981                         $exit_code //= shift;
 982                         my $lis = $pil or exit($exit_code);
 983                         # closing eof_w triggers \&noop wakeup
 984                         $listener = $eof_w = $pil = $path = undef;
 985                         $lis->close; # DS::close
 986                         PublicInbox::DS->SetLoopTimeout(1000);
 987                 };
 988         };
 989         my $sig = {
 990                 CHLD => \&PublicInbox::DS::enqueue_reap,
 991                 QUIT => $quit,
 992                 INT => $quit,
 993                 TERM => $quit,
 994                 HUP => \&noop,
 995                 USR1 => \&noop,
 996                 USR2 => \&noop,
 997         };
 998         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 999         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1000         undef $sig;
1001         local $SIG{PIPE} = 'IGNORE';
1002         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1003                 undef $sigfd;
1004                 PublicInbox::DS->SetLoopTimeout(5000);
1005         } else {
1006                 # wake up every second to accept signals if we don't
1007                 # have signalfd or IO::KQueue:
1008                 PublicInbox::DS::sig_setmask($oldset);
1009                 PublicInbox::DS->SetLoopTimeout(1000);
1010         }
1011         PublicInbox::DS->SetPostLoopCallback(sub {
1012                 my ($dmap, undef) = @_;
1013                 if (@st = defined($path) ? stat($path) : ()) {
1014                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1015                                 warn "$path dev/ino changed, quitting\n";
1016                                 $path = undef;
1017                         }
1018                 } elsif (defined($path)) { # ENOENT is common
1019                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1020                         undef $path;
1021                         $quit->();
1022                 }
1023                 return 1 if defined($path);
1024                 my $now = now();
1025                 my $n = 0;
1026                 for my $s (values %$dmap) {
1027                         $s->can('busy') or next;
1028                         if ($s->busy($now)) {
1029                                 ++$n;
1030                         } else {
1031                                 $s->close;
1032                         }
1033                 }
1034                 $n; # true: continue, false: stop
1035         });
1036
1037         # STDIN was redirected to /dev/null above, closing STDERR and
1038         # STDOUT will cause the calling `lei' client process to finish
1039         # reading the <$daemon> pipe.
1040         local $SIG{__WARN__} = sub {
1041                 $current_lei ? err($current_lei, @_) : warn(
1042                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1043         };
1044         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1045         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1046         # $daemon pipe to `lei' closed, main loop begins:
1047         PublicInbox::DS->EventLoop;
1048         exit($exit_code // 0);
1049 }
1050
1051 # for users w/o Socket::Msghdr installed or Inline::C enabled
1052 sub oneshot {
1053         my ($main_pkg) = @_;
1054         my $exit = $main_pkg->can('exit'); # caller may override exit()
1055         local $quit = $exit if $exit;
1056         local %PATH2CFG;
1057         umask(077) // die("umask(077): $!");
1058         my $self = bless {
1059                 0 => *STDIN{GLOB},
1060                 1 => *STDOUT{GLOB},
1061                 2 => *STDERR{GLOB},
1062                 env => \%ENV
1063         }, __PACKAGE__;
1064         dispatch($self, @ARGV);
1065         x_it($self, $self->{child_error}) if $self->{child_error};
1066 }
1067
1068 # ensures stdout hits the FS before sock disconnects so a client
1069 # can immediately reread it
1070 sub DESTROY {
1071         my ($self) = @_;
1072         $self->{1}->autoflush(1) if $self->{1};
1073         stop_pager($self);
1074         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1075                 waitpid($mua_pid, 0);
1076         }
1077 }
1078
1079 1;