lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 our $current_lei;
  30 my ($recv_cmd, $send_cmd);
  31 my $GLP = Getopt::Long::Parser->new;
  32 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  33 my $GLP_PASS = Getopt::Long::Parser->new;
  34 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  35
  36 our %PATH2CFG; # persistent for socket daemon
  37 our @TO_CLOSE_ATFORK_CHILD;
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote local! external! pretty
  87         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  88
  89 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  90         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  91         pass_through('git show') ],
  92
  93 'add-external' => [ 'URL_OR_PATHNAME',
  94         'add/set priority of a publicinbox|extindex for extra matches',
  95         qw(boost=i quiet|q) ],
  96 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  97         qw(format|f=s z|0 local remote quiet|q) ],
  98 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  99         'exclude further results from a publicinbox|extindex',
 100         qw(prune quiet|q) ],
 101
 102 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 103                 qw(name-only format|f=s z) ],
 104 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 105 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 106
 107 'plonk' => [ '--thread|--from=IDENT',
 108         'exclude mail matching From: or thread from non-Message-ID searches',
 109         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 110 'mark' => [ 'MESSAGE_FLAGS...',
 111         'set/unset flags on message(s) from stdin',
 112         qw(stdin| oid=s exact by-mid|mid:s) ],
 113 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 114         "exclude message(s) on stdin from `q' search results",
 115         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 116
 117 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 118         'remove imported messages from IMAP, Maildirs, and MH',
 119         qw(exact! all jobs:i indexed) ],
 120
 121 # code repos are used for `show' to solve blobs from patch mails
 122 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 123         qw(boost=i) ],
 124 'ls-coderepo' => [ '[FILTER_TERMS...]',
 125                 'list known code repos', qw(format|f=s z) ],
 126 'forget-coderepo' => [ 'PATHNAME',
 127         'stop using repo to solve blobs from patches',
 128         qw(prune) ],
 129
 130 'add-watch' => [ '[URL_OR_PATHNAME]',
 131                 'watch for new messages and flag changes',
 132         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 133 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 134                 qw(format|f=s z) ],
 135 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 138         qw(prune) ],
 139
 140 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 141         'one-shot import/update from URL or filesystem',
 142         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 143         ],
 144
 145 'config' => [ '[...]', sub {
 146                 'git-config(1) wrapper for '._config_path($_[0]);
 147         }, qw(config-file|system|global|file|f=s), # for conflict detection
 148         pass_through('git config') ],
 149 'init' => [ '[PATHNAME]', sub {
 150                 'initialize storage, default: '._store_path($_[0]);
 151         }, qw(quiet|q) ],
 152 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 153         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 154 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 155 'help' => [ '[SUBCOMMAND]', 'show help' ],
 156
 157 # XXX do we need this?
 158 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 159
 160 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 161         'rewrite git history in an attempt to improve compression',
 162         'gc!' ],
 163
 164 # internal commands are prefixed with '_'
 165 '_complete' => [ '[...]', 'internal shell completion helper',
 166                 pass_through('everything') ],
 167 ); # @CMD
 168
 169 # switch descriptions, try to keep consistent across commands
 170 # $spec: Getopt::Long option specification
 171 # $spec => [@ALLOWED_VALUES (default is first), $description],
 172 # $spec => $description
 173 # "$SUB_COMMAND TAB $spec" => as above
 174 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 175                 'specify message input format' ];
 176 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 177
 178 my %OPTDESC = (
 179 'help|h' => 'show this built-in help',
 180 'quiet|q' => 'be quiet',
 181 'solve!' => 'do not attempt to reconstruct blobs from emails',
 182 'save-as=s' => ['NAME', 'save a search terms by given name'],
 183
 184 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 185
 186 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 187                 'deduplication strategy'],
 188 'show   thread|t' => 'display entire thread a message belongs to',
 189 'q      thread|t' =>
 190         'return all messages in the same thread as the actual match(es)',
 191 'augment|a' => 'augment --output destination instead of clobbering',
 192
 193 'output|o=s' => [ 'DEST',
 194         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 195
 196 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 197                         'message/object output format' ],
 198 'mark   format|f=s' => $stdin_formats,
 199 'forget format|f=s' => $stdin_formats,
 200 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 201                 'specify output format, default depends on --output'],
 202 'ls-query       format|f=s' => $ls_format,
 203 'ls-external    format|f=s' => $ls_format,
 204
 205 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 206 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 207
 208 'sort|s=s' => [ 'VAL|received,relevance,docid',
 209                 "order of results `--output'-dependent"],
 210 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 211
 212 'boost=i' => 'increase/decrease priority of results (default: 0)',
 213
 214 'local' => 'limit operations to the local filesystem',
 215 'local!' => 'exclude results from the local filesystem',
 216 'remote' => 'limit operations to those requiring network access',
 217 'remote!' => 'prevent operations requiring network access',
 218
 219 'mid=s' => 'specify the Message-ID of a message',
 220 'oid=s' => 'specify the git object ID of a message',
 221
 222 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 223 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 224 'include=s' => 'include mailboxes/newsgroups based on pattern',
 225
 226 'exact' => 'operate on exact header matches only',
 227 'exact!' => 'rely on content match instead of exact header matches',
 228
 229 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 230 'jobs:i' => 'set parallelism level',
 231
 232 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 233 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 234
 235 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 236 ); # %OPTDESC
 237
 238 my %CONFIG_KEYS = (
 239         'leistore.dir' => 'top-level storage location',
 240 );
 241
 242 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 243 sub x_it ($$) {
 244         my ($self, $code) = @_;
 245         # make sure client sees stdout before exit
 246         $self->{1}->autoflush(1) if $self->{1};
 247         if (my $sock = $self->{sock}) {
 248                 send($sock, "x_it $code", MSG_EOR);
 249         } elsif (!($code & 127)) { # oneshot, ignore signals
 250                 $quit->($code >> 8);
 251         }
 252 }
 253
 254 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 255
 256 sub out ($;@) { print { shift->{1} } @_ }
 257
 258 sub err ($;@) {
 259         my $self = shift;
 260         my $err = $self->{2} // *STDERR{IO};
 261         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 262 }
 263
 264 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 265
 266 sub fail ($$;$) {
 267         my ($self, $buf, $exit_code) = @_;
 268         err($self, $buf);
 269         x_it($self, ($exit_code // 1) << 8);
 270         undef;
 271 }
 272
 273 sub atfork_prepare_wq {
 274         my ($self, $wq) = @_;
 275         my $tcafc = $wq->{-ipc_atfork_child_close};
 276         push @$tcafc, @TO_CLOSE_ATFORK_CHILD;
 277         if (my $sock = $self->{sock}) {
 278                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 279         }
 280 }
 281
 282 # usage: my %sig = $lei->atfork_child_wq($wq);
 283 #        local @SIG{keys %sig} = values %sig;
 284 sub atfork_child_wq {
 285         my ($self, $wq) = @_;
 286         @$self{qw(0 1 2 sock)} = delete(@$wq{0..3});
 287         %PATH2CFG = ();
 288         $quit = \&CORE::exit;
 289         @TO_CLOSE_ATFORK_CHILD = ();
 290         (__WARN__ => sub { err($self, @_) },
 291         PIPE => sub {
 292                 $self->x_it(13); # SIGPIPE = 13
 293                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 294                 close(delete $self->{1});
 295                 # regular files and /dev/null (-c) won't trigger SIGPIPE
 296                 close(delete $self->{2}) unless (-f $self->{2} || -c _);
 297                 syswrite($self->{0}, '!') unless $self->{sock}; # for eof_wait
 298                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 299         });
 300 }
 301
 302 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 303 sub atfork_parent_wq {
 304         my ($self, $wq) = @_;
 305         if ($wq->wq_workers) {
 306                 my $env = delete $self->{env}; # env is inherited at fork
 307                 my $ret = bless { %$self }, ref($self);
 308                 $self->{env} = $env;
 309                 delete @$ret{qw(-lei_store cfg pgr)};
 310                 ($ret, delete @$ret{0..2}, delete($ret->{sock}) // ());
 311         } else {
 312                 ($self, @$self{0..2}, $self->{sock} // ());
 313         }
 314 }
 315
 316 sub _help ($;$) {
 317         my ($self, $errmsg) = @_;
 318         my $cmd = $self->{cmd} // 'COMMAND';
 319         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 320         my @top = ($cmd, shift(@info) // ());
 321         my $cmd_desc = shift(@info);
 322         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 323         my @opt_desc;
 324         my $lpad = 2;
 325         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 326                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 327                 my $arg_vals = '';
 328                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 329
 330                 # lower-case is a keyword (e.g. `content', `oid'),
 331                 # ALL_CAPS is a string description (e.g. `PATH')
 332                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 333                         $desc .= "\ndefault: `$1'";
 334                 }
 335                 my (@vals, @s, @l);
 336                 my $x = $sw;
 337                 if ($x =~ s/!\z//) { # solve! => --no-solve
 338                         $x = "no-$x";
 339                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 340                         @vals = (' [', undef, ']');
 341                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 342                         @vals = (' ', undef);
 343                 } # else: no args $x = 'thread|t'
 344                 for (split(/\|/, $x)) { # help|h
 345                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 346                 }
 347                 if (!scalar(@vals)) { # no args 'thread|t'
 348                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 349                         $vals[1] = $1;
 350                 } else {
 351                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 352                 }
 353                 if ($arg_vals =~ /([,\|])/) {
 354                         my $sep = $1;
 355                         my @allow = split(/\Q$sep\E/, $arg_vals);
 356                         my $must = $sep eq '|' ? 'Must' : 'Can';
 357                         @allow = map { "`$_'" } @allow;
 358                         my $last = pop @allow;
 359                         $desc .= "\n$must be one of: " .
 360                                 join(', ', @allow) . " or $last";
 361                 }
 362                 my $lhs = join(', ', @s, @l) . join('', @vals);
 363                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 364                         $lhs =~ s/\A--/- , --/;
 365                 } else {
 366                         $lhs =~ s/\A--/    --/; # pad if no short options
 367                 }
 368                 $lpad = length($lhs) if length($lhs) > $lpad;
 369                 push @opt_desc, $lhs, $desc;
 370         }
 371         my $msg = $errmsg ? "E: $errmsg\n" : '';
 372         $msg .= <<EOF;
 373 usage: lei @top
 374   $cmd_desc
 375
 376 EOF
 377         $lpad += 2;
 378         local $Text::Wrap::columns = 78 - $lpad;
 379         my $padding = ' ' x ($lpad + 2);
 380         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 381                 $msg .= '  '.pack("A$lpad", $lhs);
 382                 $rhs = wrap('', '', $rhs);
 383                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 384                 $msg .= $rhs;
 385                 $msg .= "\n";
 386         }
 387         print { $self->{$errmsg ? 2 : 1} } $msg;
 388         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 389         undef;
 390 }
 391
 392 sub optparse ($$$) {
 393         my ($self, $cmd, $argv) = @_;
 394         $self->{cmd} = $cmd;
 395         $OPT = $self->{opt} = {};
 396         my $info = $CMD{$cmd} // [ '[...]' ];
 397         my ($proto, undef, @spec) = @$info;
 398         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 399         push @spec, qw(help|h);
 400         my $lone_dash;
 401         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 402                 $lone_dash = $spec[0];
 403                 $OPT->{$spec[0]} = \(my $var);
 404                 push @spec, '' => \$var;
 405         }
 406         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 407                 return _help($self, "bad arguments or options for $cmd");
 408         return _help($self) if $OPT->{help};
 409
 410         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 411
 412         # "-" aliases "stdin" or "clear"
 413         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 414
 415         my $i = 0;
 416         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 417         my ($err, $inf);
 418         my @args = split(/ /, $proto);
 419         for my $var (@args) {
 420                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 421                         $inf = defined($argv->[$i]) and last;
 422                         $var =~ s/\.\.\.\z//;
 423                         $err = "$var not supplied";
 424                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 425                         $argv->[$i++] // ($err = "$var not supplied");
 426                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 427                         $inf = 1;
 428                         last;
 429                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 430                         $i++;
 431                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 432                         my @or = split(/\|/, $var);
 433                         my $ok;
 434                         for my $o (@or) {
 435                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 436                                         $ok = defined($OPT->{$1});
 437                                         last;
 438                                 } elsif (defined($argv->[$i])) {
 439                                         $ok = 1;
 440                                         $i++;
 441                                         last;
 442                                 } # else continue looping
 443                         }
 444                         my $last = pop @or;
 445                         $err = join(', ', @or) . " or $last must be set";
 446                 } else {
 447                         warn "BUG: can't parse `$var' in $proto";
 448                 }
 449                 last if $err;
 450         }
 451         if (!$inf && scalar(@$argv) > scalar(@args)) {
 452                 $err //= 'too many arguments';
 453         }
 454         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 455 }
 456
 457 sub dispatch {
 458         my ($self, $cmd, @argv) = @_;
 459         local $current_lei = $self; # for __WARN__
 460         return _help($self, 'no command given') unless defined($cmd);
 461         my $func = "lei_$cmd";
 462         $func =~ tr/-/_/;
 463         if (my $cb = __PACKAGE__->can($func)) {
 464                 optparse($self, $cmd, \@argv) or return;
 465                 $cb->($self, @argv);
 466         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 467                 my $opt = {};
 468                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 469                         return _help($self, 'bad arguments or options');
 470                 _help($self);
 471         } else {
 472                 fail($self, "`$cmd' is not an lei command");
 473         }
 474 }
 475
 476 sub _lei_cfg ($;$) {
 477         my ($self, $creat) = @_;
 478         my $f = _config_path($self->{env});
 479         my @st = stat($f);
 480         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 481         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 482                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 483         }
 484         if (!@st) {
 485                 unless ($creat) {
 486                         delete $self->{cfg};
 487                         return;
 488                 }
 489                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 490                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 491                 open my $fh, '>>', $f or die "open($f): $!\n";
 492                 @st = stat($fh) or die "fstat($f): $!\n";
 493                 $cur_st = pack('dd', $st[10], $st[7]);
 494                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 495         }
 496         my $cfg = PublicInbox::Config::git_config_dump($f);
 497         $cfg->{-st} = $cur_st;
 498         $cfg->{'-f'} = $f;
 499         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 500 }
 501
 502 sub _lei_store ($;$) {
 503         my ($self, $creat) = @_;
 504         my $cfg = _lei_cfg($self, $creat);
 505         $cfg->{-lei_store} //= do {
 506                 require PublicInbox::LeiStore;
 507                 my $dir = $cfg->{'leistore.dir'};
 508                 $dir //= _store_path($self->{env}) if $creat;
 509                 return unless $dir;
 510                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 511         };
 512 }
 513
 514 sub lei_show {
 515         my ($self, @argv) = @_;
 516 }
 517
 518 sub lei_mark {
 519         my ($self, @argv) = @_;
 520 }
 521
 522 sub lei_config {
 523         my ($self, @argv) = @_;
 524         $self->{opt}->{'config-file'} and return fail $self,
 525                 "config file switches not supported by `lei config'";
 526         my $env = $self->{env};
 527         delete local $env->{GIT_CONFIG};
 528         my $cfg = _lei_cfg($self, 1);
 529         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 530         my %rdr = map { $_ => $self->{$_} } (0..2);
 531         run_die($cmd, $env, \%rdr);
 532 }
 533
 534 sub lei_init {
 535         my ($self, $dir) = @_;
 536         my $cfg = _lei_cfg($self, 1);
 537         my $cur = $cfg->{'leistore.dir'};
 538         my $env = $self->{env};
 539         $dir //= _store_path($env);
 540         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 541         my @cur = stat($cur) if defined($cur);
 542         $cur = File::Spec->canonpath($cur // $dir);
 543         my @dir = stat($dir);
 544         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 545         if (@cur) {
 546                 if ($cur eq $dir) {
 547                         _lei_store($self, 1)->done;
 548                         return qerr($self, $exists);
 549                 }
 550
 551                 # some folks like symlinks and bind mounts :P
 552                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 553                         lei_config($self, 'leistore.dir', $dir);
 554                         _lei_store($self, 1)->done;
 555                         return qerr($self, "$exists (as $cur)");
 556                 }
 557                 return fail($self, <<"");
 558 E: leistore.dir=$cur already initialized and it is not $dir
 559
 560         }
 561         lei_config($self, 'leistore.dir', $dir);
 562         _lei_store($self, 1)->done;
 563         $exists //= "I: leistore.dir=$dir newly initialized";
 564         return qerr($self, $exists);
 565 }
 566
 567 sub lei_daemon_pid { puts shift, $$ }
 568
 569 sub lei_daemon_kill {
 570         my ($self) = @_;
 571         my $sig = $self->{opt}->{signal} // 'TERM';
 572         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 573 }
 574
 575 sub lei_help { _help($_[0]) }
 576
 577 # Shell completion helper.  Used by lei-completion.bash and hopefully
 578 # other shells.  Try to do as much here as possible to avoid redundancy
 579 # and improve maintainability.
 580 sub lei__complete {
 581         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 582         shift @argv; # ignore "lei", the entire command is sent
 583         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 584         my $cmd = shift @argv;
 585         my $info = $CMD{$cmd} // do { # filter matching commands
 586                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 587                 return;
 588         };
 589         my ($proto, undef, @spec) = @$info;
 590         my $cur = pop @argv;
 591         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 592         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 593                 # gross special case since the only git-config options
 594                 # Consider moving to a table if we need more special cases
 595                 # we use Getopt::Long for are the ones we reject, so these
 596                 # are the ones we don't reject:
 597                 if ($cmd eq 'config') {
 598                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 599                         @spec = qw(add z|null get get-all unset unset-all
 600                                 replace-all get-urlmatch
 601                                 remove-section rename-section
 602                                 name-only list|l edit|e
 603                                 get-color-name get-colorbool);
 604                         # fall-through
 605                 }
 606                 # TODO: arg support
 607                 puts $self, grep(/$re/, map { # generate short/long names
 608                         my $eq = '';
 609                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 610                                 $eq = '=';
 611                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 612                         } else { # negation: solve! => no-solve|solve
 613                                 s/\A(.+)!\z/no-$1|$1/;
 614                         }
 615                         map {
 616                                 length > 1 ? "--$_$eq" : "-$_"
 617                         } split(/\|/, $_, -1) # help|h
 618                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 619         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 620                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 621         }
 622         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 623         # proto parsing.
 624 }
 625
 626 sub reap_exec { # dwaitpid callback
 627         my ($self, $pid) = @_;
 628         x_it($self, $?);
 629 }
 630
 631 sub lei_git { # support passing through random git commands
 632         my ($self, @argv) = @_;
 633         my %rdr = map { $_ => $self->{$_} } (0..2);
 634         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 635         dwaitpid($pid, \&reap_exec, $self);
 636 }
 637
 638 # caller needs to "-t $self->{1}" to check if tty
 639 sub start_pager {
 640         my ($self) = @_;
 641         my $env = $self->{env};
 642         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 643         chomp(my $pager = <$fh> // '');
 644         close($fh) or warn "`git var PAGER' error: \$?=$?";
 645         return if $pager eq 'cat' || $pager eq '';
 646         # TODO TIOCGWINSZ
 647         my %new_env = (LESS => 'FRX', LV => '-c', COLUMNS => 80);
 648         $new_env{MORE} = 'FRX' if $^O eq 'freebsd';
 649         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 650         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 651         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 652         if (my $sock = $self->{sock}) { # lei(1) process runs it
 653                 delete @new_env{keys %$env}; # only set iff unset
 654                 my $buf = "exec 1\0".$pager;
 655                 while (my ($k, $v) = each %new_env) { $buf .= "\0$k=$v" };
 656                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 657                 $send_cmd->($sock, $fds, $buf, MSG_EOR);
 658         } else {
 659                 $pgr->[0] = spawn([$pager], $env, $rdr);
 660         }
 661         $self->{1} = $wpager;
 662         $self->{2} = $wpager if -t $self->{2};
 663         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 664         $self->{pgr} = $pgr;
 665 }
 666
 667 sub stop_pager {
 668         my ($self) = @_;
 669         my $pgr = delete($self->{pgr}) or return;
 670         $self->{2} = $pgr->[2];
 671         # do not restore original stdout, just close it so we error out
 672         close(delete($self->{1})) if $self->{1};
 673         my $pid = $pgr->[0];
 674         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 675 }
 676
 677 sub accept_dispatch { # Listener {post_accept} callback
 678         my ($sock) = @_; # ignore other
 679         $sock->autoflush(1);
 680         my $self = bless { sock => $sock }, __PACKAGE__;
 681         vec(my $rvec = '', fileno($sock), 1) = 1;
 682         select($rvec, undef, undef, 1) or
 683                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 684         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 685         if (scalar(@fds) == 4) {
 686                 my $i = 0;
 687                 for my $rdr (qw(<&= >&= >&= <&=)) {
 688                         my $fd = shift(@fds);
 689                         open($self->{$i++}, $rdr, $fd) and next;
 690                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 691                 }
 692         } else {
 693                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 694         }
 695         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 696         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 697         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 698         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 699                 return send($sock, 'request command truncated', MSG_EOR);
 700         my ($argc, @argv) = split(/\0/, $buf, -1);
 701         undef $buf;
 702         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 703         if (chdir(delete($self->{3}))) {
 704                 local %ENV = %env;
 705                 $self->{env} = \%env;
 706                 eval { dispatch($self, @argv) };
 707                 send($sock, $@, MSG_EOR) if $@;
 708         } else {
 709                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 710         }
 711 }
 712
 713 sub dclose {
 714         my ($self) = @_;
 715         delete $self->{lxs}; # stops LeiXSearch queries
 716         $self->close if $self->{sock}; # PublicInbox::DS::close
 717 }
 718
 719 # for long-running results
 720 sub event_step {
 721         my ($self) = @_;
 722         local %ENV = %{$self->{env}};
 723         my $sock = $self->{sock};
 724         eval {
 725                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 726                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 727                                 return if $! == EAGAIN;
 728                                 next if $! == EINTR;
 729                                 last if $! == ECONNRESET;
 730                                 die "recvmsg: $!";
 731                         }
 732                         for my $fd (@fds) {
 733                                 open my $rfh, '+<&=', $fd;
 734                         }
 735                         die "unrecognized client signal: $buf";
 736                 }
 737                 dclose($self);
 738         };
 739         if (my $err = $@) {
 740                 eval { $self->fail($err) };
 741                 dclose($self);
 742         }
 743 }
 744
 745 sub event_step_init {
 746         my ($self) = @_;
 747         if (my $sock = $self->{sock}) { # using DS->EventLoop
 748                 $sock->blocking(0);
 749                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 750         }
 751 }
 752
 753 sub noop {}
 754
 755 our $oldset; sub oldset { $oldset }
 756
 757 # lei(1) calls this when it can't connect
 758 sub lazy_start {
 759         my ($path, $errno, $narg) = @_;
 760         if ($errno == ECONNREFUSED) {
 761                 unlink($path) or die "unlink($path): $!";
 762         } elsif ($errno != ENOENT) {
 763                 $! = $errno; # allow interpolation to stringify in die
 764                 die "connect($path): $!";
 765         }
 766         umask(077) // die("umask(077): $!");
 767         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 768         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 769         listen($l, 1024) or die "listen: $!";
 770         my @st = stat($path) or die "stat($path): $!";
 771         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 772         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 773         local $oldset = PublicInbox::DS::block_signals();
 774         if ($narg == 5) {
 775                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 776                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 777                         require PublicInbox::CmdIPC4;
 778                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 779                         PublicInbox::CmdIPC4->can('recv_cmd4');
 780                 };
 781         }
 782         $recv_cmd or die <<"";
 783 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 784
 785         require PublicInbox::Listener;
 786         require PublicInbox::EOFpipe;
 787         (-p STDOUT) or die "E: stdout must be a pipe\n";
 788         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 789         POSIX::setsid() > 0 or die "setsid: $!";
 790         my $pid = fork // die "fork: $!";
 791         return if $pid;
 792         $0 = "lei-daemon $path";
 793         local %PATH2CFG;
 794         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 795         $l->blocking(0);
 796         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 797         my $exit_code;
 798         local $quit = sub {
 799                 $exit_code //= shift;
 800                 my $listener = $l or exit($exit_code);
 801                 # closing eof_w triggers \&noop wakeup
 802                 $eof_w = $l = $path = undef;
 803                 $listener->close; # DS::close
 804                 PublicInbox::DS->SetLoopTimeout(1000);
 805         };
 806         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 807         undef $eof_r;
 808         my $sig = {
 809                 CHLD => \&PublicInbox::DS::enqueue_reap,
 810                 QUIT => $quit,
 811                 INT => $quit,
 812                 TERM => $quit,
 813                 HUP => \&noop,
 814                 USR1 => \&noop,
 815                 USR2 => \&noop,
 816         };
 817         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 818         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 819         undef $sig;
 820         local $SIG{PIPE} = 'IGNORE';
 821         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 822                 undef $sigfd;
 823                 PublicInbox::DS->SetLoopTimeout(5000);
 824         } else {
 825                 # wake up every second to accept signals if we don't
 826                 # have signalfd or IO::KQueue:
 827                 PublicInbox::DS::sig_setmask($oldset);
 828                 PublicInbox::DS->SetLoopTimeout(1000);
 829         }
 830         PublicInbox::DS->SetPostLoopCallback(sub {
 831                 my ($dmap, undef) = @_;
 832                 if (@st = defined($path) ? stat($path) : ()) {
 833                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 834                                 warn "$path dev/ino changed, quitting\n";
 835                                 $path = undef;
 836                         }
 837                 } elsif (defined($path)) {
 838                         warn "stat($path): $!, quitting ...\n";
 839                         undef $path; # don't unlink
 840                         $quit->();
 841                 }
 842                 return 1 if defined($path);
 843                 my $now = now();
 844                 my $n = 0;
 845                 for my $s (values %$dmap) {
 846                         $s->can('busy') or next;
 847                         if ($s->busy($now)) {
 848                                 ++$n;
 849                         } else {
 850                                 $s->close;
 851                         }
 852                 }
 853                 $n; # true: continue, false: stop
 854         });
 855
 856         # STDIN was redirected to /dev/null above, closing STDERR and
 857         # STDOUT will cause the calling `lei' client process to finish
 858         # reading the <$daemon> pipe.
 859         openlog($path, 'pid', 'user');
 860         local $SIG{__WARN__} = sub {
 861                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 862         };
 863         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 864                 syslog('crit', "$@") if $@;
 865         });
 866         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 867         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 868         # $daemon pipe to `lei' closed, main loop begins:
 869         PublicInbox::DS->EventLoop;
 870         @$on_destroy = (); # cancel on_destroy if we get here
 871         exit($exit_code // 0);
 872 }
 873
 874 # for users w/o Socket::Msghdr
 875 sub oneshot {
 876         my ($main_pkg) = @_;
 877         my $exit = $main_pkg->can('exit'); # caller may override exit()
 878         local $quit = $exit if $exit;
 879         local %PATH2CFG;
 880         umask(077) // die("umask(077): $!");
 881         dispatch((bless {
 882                 0 => *STDIN{GLOB},
 883                 1 => *STDOUT{GLOB},
 884                 2 => *STDERR{GLOB},
 885                 env => \%ENV
 886         }, __PACKAGE__), @ARGV);
 887 }
 888
 889 # ensures stdout hits the FS before sock disconnects so a client
 890 # can immediately reread it
 891 sub DESTROY {
 892         my ($self) = @_;
 893         $self->{1}->autoflush(1) if $self->{1};
 894         stop_pager($self);
 895 }
 896
 897 1;