lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 # we generate shell completion + help using %CMD and %OPTDESC,
 123 # see lei__complete() and PublicInbox::LeiHelp
 124 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 125 our %CMD = ( # sorted in order of importance/use:
 126 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 127         'stdin|', # /|\z/ must be first for lone dash
 128         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 129         sort|s=s reverse|r offset=i remote! local! external! pretty
 130         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 131         import-remote! import-before! lock=s@ rsyncable
 132         alert=s@ mua=s no-torsocks torsocks=s verbose|v+ quiet|q C=s@),
 133         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 134
 135 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 136         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local! C=s@),
 137         pass_through('git show') ],
 138
 139 'add-external' => [ 'LOCATION',
 140         'add/set priority of a publicinbox|extindex for extra matches',
 141         qw(boost=i c=s@ mirror=s no-torsocks torsocks=s inbox-version=i),
 142         qw(quiet|q verbose|v+ C=s@),
 143         index_opt(), PublicInbox::LeiQuery::curl_opt() ],
 144 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 145         qw(format|f=s z|0 globoff|g invert-match|v local remote C=s@) ],
 146 'forget-external' => [ 'LOCATION...|--prune',
 147         'exclude further results from a publicinbox|extindex',
 148         qw(prune quiet|q C=s@) ],
 149
 150 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 151                 qw(name-only format|f=s C=s@) ],
 152 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', qw(C=s@) ],
 153 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', qw(C=s@) ],
 154
 155 'plonk' => [ '--threads|--from=IDENT',
 156         'exclude mail matching From: or threads from non-Message-ID searches',
 157         qw(stdin| threads|t from|f=s mid=s oid=s C=s@) ],
 158 'mark' => [ 'MESSAGE_FLAGS...',
 159         'set/unset keywords on message(s) from stdin',
 160         qw(stdin| oid=s exact by-mid|mid:s C=s@) ],
 161 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 162         "exclude message(s) on stdin from `q' search results",
 163         qw(stdin| oid=s exact by-mid|mid:s quiet|q C=s@) ],
 164
 165 'purge-mailsource' => [ 'LOCATION|--all',
 166         'remove imported messages from IMAP, Maildirs, and MH',
 167         qw(exact! all jobs:i indexed C=s@) ],
 168
 169 # code repos are used for `show' to solve blobs from patch mails
 170 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 171         qw(boost=i C=s@) ],
 172 'ls-coderepo' => [ '[FILTER_TERMS...]',
 173                 'list known code repos', qw(format|f=s z C=s@) ],
 174 'forget-coderepo' => [ 'DIRNAME',
 175         'stop using repo to solve blobs from patches',
 176         qw(prune C=s@) ],
 177
 178 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 179         qw(import! kw|keywords|flags! interval=s recursive|r
 180         exclude=s include=s C=s@) ],
 181 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 182                 qw(format|f=s z C=s@) ],
 183 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 184 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 185 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 186         qw(prune C=s@) ],
 187
 188 'import' => [ 'LOCATION...|--stdin',
 189         'one-time import/update from URL or filesystem',
 190         qw(stdin| offset=i recursive|r exclude=s include|I=s
 191         lock=s@ in-format|F=s kw|keywords|flags! C=s@),
 192         ],
 193 'convert' => [ 'LOCATION...|--stdin',
 194         'one-time conversion from URL or filesystem to another format',
 195         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s quiet|q
 196         lock=s@ kw|keywords|flags! C=s@),
 197         ],
 198 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 199         "use a patch to generate a query for `lei q --stdin'",
 200         qw(stdin| want|w=s@ uri debug) ],
 201 'config' => [ '[...]', sub {
 202                 'git-config(1) wrapper for '._config_path($_[0]);
 203         }, qw(config-file|system|global|file|f=s), # for conflict detection
 204          qw(C=s@), pass_through('git config') ],
 205 'init' => [ '[DIRNAME]', sub {
 206         "initialize storage, default: ".store_path($_[0]);
 207         }, qw(quiet|q C=s@) ],
 208 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 209         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 210         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 211 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 212 'help' => [ '[SUBCOMMAND]', 'show help' ],
 213
 214 # XXX do we need this?
 215 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 216
 217 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 218         'rewrite git history in an attempt to improve compression',
 219         qw(gc! C=s@) ],
 220
 221 # internal commands are prefixed with '_'
 222 '_complete' => [ '[...]', 'internal shell completion helper',
 223                 pass_through('everything') ],
 224 ); # @CMD
 225
 226 # switch descriptions, try to keep consistent across commands
 227 # $spec: Getopt::Long option specification
 228 # $spec => [@ALLOWED_VALUES (default is first), $description],
 229 # $spec => $description
 230 # "$SUB_COMMAND TAB $spec" => as above
 231 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 232                         'specify message input format' ];
 233 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 234
 235 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 236 my %OPTDESC = (
 237 'help|h' => 'show this built-in help',
 238 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 239 'quiet|q' => 'be quiet',
 240 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 241         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 242
 243 'globoff|g' => "do not match locations using '*?' wildcards ".
 244                 "and\xa0'[]'\x{a0}ranges",
 245 'verbose|v+' => 'be more verbose',
 246 'external!' => 'do not use externals',
 247 'solve!' => 'do not attempt to reconstruct blobs from emails',
 248 'torsocks=s' => ['VAL|auto|no|yes',
 249                 'whether or not to wrap git and curl commands with torsocks'],
 250 'no-torsocks' => 'alias for --torsocks=no',
 251 'save-as=s' => ['NAME', 'save a search terms by given name'],
 252 'import-remote!' => 'do not memoize remote messages into local store',
 253
 254 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 255
 256 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 257                 'deduplication strategy'],
 258 'threads|t+' =>
 259         'return all messages in the same threads as the actual match(es)',
 260
 261 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 262                 'search prefixes to extract (default: dfpost7)' ],
 263
 264 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 265         'run command(s) or perform ops when done writing to output ' .
 266         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 267         'nothing otherwise)' ],
 268
 269 'augment|a' => 'augment --output destination instead of clobbering',
 270
 271 'output|mfolder|o=s' => [ 'MFOLDER',
 272         "destination (e.g.\xa0`/path/to/Maildir', ".
 273         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 274 'mua=s' => [ 'CMD',
 275         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 276
 277 'inbox-version=i' => [ 'NUM|1|2',
 278                 'force a public-inbox version with --mirror'],
 279 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 280
 281 # public-inbox-index options
 282 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 283 'compact' => 'run compact index after mirroring',
 284 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 285         "indexlevel with --mirror (default: full)" ],
 286 'max_size|max-size=s' => [ 'SIZE',
 287         'do not index messages larger than SIZE (default: infinity)' ],
 288 'batch_size|batch-size=s' => [ 'SIZE',
 289         'flush changes to OS after given number of bytes (default: 1m)' ],
 290 'sequential_shard|sequential-shard' =>
 291         'index Xapian shards sequentially for slow storage',
 292 'skip-docdata' =>
 293         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 294
 295 'format|f=s     q' => [
 296         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 297                 'specify output format, default depends on --output'],
 298 'exclude=s@     q' => [ 'LOCATION',
 299                 'exclude specified external(s) from search' ],
 300 'include|I=s@   q' => [ 'LOCATION',
 301                 'include specified external(s) in search' ],
 302 'only=s@        q' => [ 'LOCATION',
 303                 'only use specified external(s) for search' ],
 304 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 305                 'control number of search and writer jobs' ],
 306 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 307
 308 'in-format|F=s' => $stdin_formats,
 309 'format|f=s     ls-query' => $ls_format,
 310 'format|f=s     ls-external' => $ls_format,
 311
 312 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 313 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 314
 315 'sort|s=s' => [ 'VAL|received|relevance|docid',
 316                 "order of results is `--output'-dependent"],
 317 'reverse|r' => 'reverse search results', # like sort(1)
 318
 319 'boost=i' => 'increase/decrease priority of results (default: 0)',
 320
 321 'local' => 'limit operations to the local filesystem',
 322 'local!' => 'exclude results from the local filesystem',
 323 'remote' => 'limit operations to those requiring network access',
 324 'remote!' => 'prevent operations requiring network access',
 325
 326 'mid=s' => 'specify the Message-ID of a message',
 327 'oid=s' => 'specify the git object ID of a message',
 328
 329 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 330 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 331 'include=s' => 'include mailboxes/newsgroups based on pattern',
 332
 333 'exact' => 'operate on exact header matches only',
 334 'exact!' => 'rely on content match instead of exact header matches',
 335
 336 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 337
 338 'kw|keywords|flags!' => 'disable/enable importing flags',
 339
 340 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 341 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 342
 343 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 344 ); # %OPTDESC
 345
 346 my %CONFIG_KEYS = (
 347         'leistore.dir' => 'top-level storage location',
 348 );
 349
 350 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q); # internal workers
 351
 352 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 353 sub x_it ($$) {
 354         my ($self, $code) = @_;
 355         # make sure client sees stdout before exit
 356         $self->{1}->autoflush(1) if $self->{1};
 357         dump_and_clear_log();
 358         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 359                 send($s, "x_it $code", MSG_EOR);
 360         } elsif ($self->{oneshot}) {
 361                 # don't want to end up using $? from child processes
 362                 for my $f (@WQ_KEYS) {
 363                         my $wq = delete $self->{$f} or next;
 364                         $wq->DESTROY;
 365                 }
 366                 # cleanup anything that has tempfiles or open file handles
 367                 %PATH2CFG = ();
 368                 delete @$self{qw(ovv dedupe sto cfg)};
 369                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 370                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 371                         kill $signum, $$;
 372                         sleep(1) while 1; # wait for signal
 373                 } else {
 374                         $quit->($code >> 8);
 375                 }
 376         } # else ignore if client disconnected
 377 }
 378
 379 sub err ($;@) {
 380         my $self = shift;
 381         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 382         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 383         print $err @_, @eor and return;
 384         my $old_err = delete $self->{2};
 385         close($old_err) if $! == EPIPE && $old_err;
 386         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 387         print $err @_, @eor or print STDERR @_, @eor;
 388 }
 389
 390 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 391
 392 sub fail_handler ($;$$) {
 393         my ($lei, $code, $io) = @_;
 394         for my $f (@WQ_KEYS) {
 395                 my $wq = delete $lei->{$f} or next;
 396                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 397         }
 398         close($io) if $io; # needed to avoid warnings on SIGPIPE
 399         x_it($lei, $code // (1 << 8));
 400 }
 401
 402 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 403         fail_handler($_[0], 13, delete $_[0]->{1});
 404 }
 405
 406 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 407 sub sigint_reap {
 408         my ($pgid) = @_;
 409         dwaitpid($pgid) if kill('-INT', $pgid);
 410 }
 411
 412 sub fail ($$;$) {
 413         my ($self, $buf, $exit_code) = @_;
 414         err($self, $buf) if defined $buf;
 415         # calls fail_handler:
 416         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 417         x_it($self, ($exit_code // 1) << 8);
 418         undef;
 419 }
 420
 421 sub check_input_format ($;$) {
 422         my ($self, $files) = @_;
 423         my $opt_key = 'in-format';
 424         my $fmt = $self->{opt}->{$opt_key};
 425         if (!$fmt) {
 426                 my $err = $files ? "regular file(s):\n@$files" : '--stdin';
 427                 return fail($self, "--$opt_key unset for $err");
 428         }
 429         require PublicInbox::MboxLock if $files;
 430         require PublicInbox::MboxReader;
 431         return 1 if $fmt eq 'eml';
 432         # XXX: should this handle {gz,bz2,xz}? that's currently in LeiToMail
 433         PublicInbox::MboxReader->can($fmt) or
 434                 return fail($self, "--$opt_key=$fmt unrecognized");
 435         1;
 436 }
 437
 438 sub out ($;@) {
 439         my $self = shift;
 440         return if print { $self->{1} // return } @_; # likely
 441         return note_sigpipe($self, 1) if $! == EPIPE;
 442         my $err = "error writing to output: $!";
 443         delete $self->{1};
 444         fail($self, $err);
 445 }
 446
 447 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 448
 449 sub child_error { # passes non-fatal curl exit codes to user
 450         my ($self, $child_error, $msg) = @_; # child_error is $?
 451         $self->err($msg) if $msg;
 452         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 453                 # send to the parent lei-daemon or to lei(1) client
 454                 send($s, "child_error $child_error", MSG_EOR);
 455         } elsif (!$PublicInbox::DS::in_loop) {
 456                 $self->{child_error} = $child_error;
 457         } # else noop if client disconnected
 458 }
 459
 460 sub note_sigpipe { # triggers sigpipe_handler
 461         my ($self, $fd) = @_;
 462         close(delete($self->{$fd})); # explicit close silences Perl warning
 463         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 464         x_it($self, 13);
 465 }
 466
 467 sub lei_atfork_child {
 468         my ($self, $persist) = @_;
 469         # we need to explicitly close things which are on stack
 470         if ($persist) {
 471                 my @io = delete @$self{qw(0 1 2 sock)};
 472                 unless ($self->{oneshot}) {
 473                         close($_) for @io;
 474                 }
 475         } else {
 476                 delete $self->{0};
 477         }
 478         delete @$self{qw(cnv)};
 479         for (delete @$self{qw(3 old_1 au_done)}) {
 480                 close($_) if defined($_);
 481         }
 482         if (my $op_c = delete $self->{pkt_op_c}) {
 483                 close(delete $op_c->{sock});
 484         }
 485         if (my $pgr = delete $self->{pgr}) {
 486                 close($_) for (@$pgr[1,2]);
 487         }
 488         close $listener if $listener;
 489         undef $listener;
 490         %PATH2CFG = ();
 491         undef $errors_log;
 492         $quit = \&CORE::exit;
 493         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 494 }
 495
 496 sub workers_start {
 497         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 498         $ops = {
 499                 '!' => [ $lei->can('fail_handler'), $lei ],
 500                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 501                 'x_it' => [ $lei->can('x_it'), $lei ],
 502                 'child_error' => [ $lei->can('child_error'), $lei ],
 503                 %$ops
 504         };
 505         require PublicInbox::PktOp;
 506         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 507         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 508         delete $lei->{pkt_op_p};
 509         my $op = delete $lei->{pkt_op_c};
 510         $lei->event_step_init;
 511         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 512         $lei->{oneshot} ? $op : undef;
 513 }
 514
 515 sub _help {
 516         require PublicInbox::LeiHelp;
 517         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 518 }
 519
 520 sub optparse ($$$) {
 521         my ($self, $cmd, $argv) = @_;
 522         # allow _complete --help to complete, not show help
 523         return 1 if substr($cmd, 0, 1) eq '_';
 524         $self->{cmd} = $cmd;
 525         $OPT = $self->{opt} //= {};
 526         my $info = $CMD{$cmd} // [ '[...]' ];
 527         my ($proto, undef, @spec) = @$info;
 528         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 529         push @spec, qw(help|h);
 530         my $lone_dash;
 531         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 532                 $lone_dash = $spec[0];
 533                 $OPT->{$spec[0]} = \(my $var);
 534                 push @spec, '' => \$var;
 535         }
 536         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 537                 return _help($self, "bad arguments or options for $cmd");
 538         return _help($self) if $OPT->{help};
 539
 540         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 541
 542         # "-" aliases "stdin" or "clear"
 543         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 544
 545         my $i = 0;
 546         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 547         my ($err, $inf);
 548         my @args = split(/ /, $proto);
 549         for my $var (@args) {
 550                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 551                         $inf = defined($argv->[$i]) and last;
 552                         $var =~ s/\.\.\.\z//;
 553                         $err = "$var not supplied";
 554                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 555                         $argv->[$i++] // ($err = "$var not supplied");
 556                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 557                         $inf = 1;
 558                         last;
 559                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 560                         $i++;
 561                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 562                         $inf = 1 if index($var, '...') > 0;
 563                         my @or = split(/\|/, $var);
 564                         my $ok;
 565                         for my $o (@or) {
 566                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 567                                         $ok = defined($OPT->{$1});
 568                                         last if $ok;
 569                                 } elsif (defined($argv->[$i])) {
 570                                         $ok = 1;
 571                                         $i++;
 572                                         last;
 573                                 } # else continue looping
 574                         }
 575                         last if $ok;
 576                         my $last = pop @or;
 577                         $err = join(', ', @or) . " or $last must be set";
 578                 } else {
 579                         warn "BUG: can't parse `$var' in $proto";
 580                 }
 581                 last if $err;
 582         }
 583         if (!$inf && scalar(@$argv) > scalar(@args)) {
 584                 $err //= 'too many arguments';
 585         }
 586         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 587 }
 588
 589 sub dispatch {
 590         my ($self, $cmd, @argv) = @_;
 591         local $current_lei = $self; # for __WARN__
 592         dump_and_clear_log("from previous run\n");
 593         return _help($self, 'no command given') unless defined($cmd);
 594         while ($cmd eq '-C') { # do not support Getopt bundling for this
 595                 my $d = shift(@argv) // return fail($self, '-C DIRECTORY');
 596                 push @{$self->{opt}->{C}}, $d;
 597                 $cmd = shift(@argv) // return _help($self, 'no command given');
 598         }
 599         my $func = "lei_$cmd";
 600         $func =~ tr/-/_/;
 601         my $cb = __PACKAGE__->can($func) // ($CMD{$cmd} ? do {
 602                 my $mod = "PublicInbox::Lei\u$cmd";
 603                 ($INC{"PublicInbox/Lei\u$cmd.pm"} //
 604                         eval("require $mod")) ? $mod->can($func) : undef;
 605         } : undef);
 606         if ($cb) {
 607                 optparse($self, $cmd, \@argv) or return;
 608                 if (my $chdir = $self->{opt}->{C}) {
 609                         for my $d (@$chdir) {
 610                                 next if $d eq ''; # same as git(1)
 611                                 chdir $d or return fail($self, "cd $d: $!");
 612                         }
 613                 }
 614                 $cb->($self, @argv);
 615         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 616                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 617                         or return _help($self, 'bad arguments or options');
 618                 _help($self);
 619         } else {
 620                 fail($self, "`$cmd' is not an lei command");
 621         }
 622 }
 623
 624 sub _lei_cfg ($;$) {
 625         my ($self, $creat) = @_;
 626         my $f = _config_path($self);
 627         my @st = stat($f);
 628         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 629         my ($sto, $sto_dir);
 630         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 631                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 632                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 633         }
 634         if (!@st) {
 635                 unless ($creat) {
 636                         delete $self->{cfg};
 637                         return bless {}, 'PublicInbox::Config';
 638                 }
 639                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 640                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 641                 open my $fh, '>>', $f or die "open($f): $!\n";
 642                 @st = stat($fh) or die "fstat($f): $!\n";
 643                 $cur_st = pack('dd', $st[10], $st[7]);
 644                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 645         }
 646         my $cfg = PublicInbox::Config::git_config_dump($f);
 647         bless $cfg, 'PublicInbox::Config';
 648         $cfg->{-st} = $cur_st;
 649         $cfg->{'-f'} = $f;
 650         if ($sto && File::Spec->canonpath($sto_dir) eq
 651                         File::Spec->canonpath($cfg->{'leistore.dir'})) {
 652                 $cfg->{-lei_store} = $sto;
 653         }
 654         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 655 }
 656
 657 sub _lei_store ($;$) {
 658         my ($self, $creat) = @_;
 659         my $cfg = _lei_cfg($self, $creat);
 660         $cfg->{-lei_store} //= do {
 661                 require PublicInbox::LeiStore;
 662                 my $dir = $cfg->{'leistore.dir'};
 663                 $dir //= $creat ? store_path($self) : return;
 664                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 665         };
 666 }
 667
 668 sub lei_show {
 669         my ($self, @argv) = @_;
 670 }
 671
 672 sub lei_mark {
 673         my ($self, @argv) = @_;
 674 }
 675
 676 sub _config {
 677         my ($self, @argv) = @_;
 678         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 679         my $cfg = _lei_cfg($self, 1);
 680         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 681         my %rdr = map { $_ => $self->{$_} } (0..2);
 682         waitpid(spawn($cmd, \%env, \%rdr), 0);
 683 }
 684
 685 sub lei_config {
 686         my ($self, @argv) = @_;
 687         $self->{opt}->{'config-file'} and return fail $self,
 688                 "config file switches not supported by `lei config'";
 689         _config(@_);
 690         x_it($self, $?) if $?;
 691 }
 692
 693 sub lei_init {
 694         my ($self, $dir) = @_;
 695         my $cfg = _lei_cfg($self, 1);
 696         my $cur = $cfg->{'leistore.dir'};
 697         $dir //= store_path($self);
 698         $dir = rel2abs($self, $dir);
 699         my @cur = stat($cur) if defined($cur);
 700         $cur = File::Spec->canonpath($cur // $dir);
 701         my @dir = stat($dir);
 702         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 703         if (@cur) {
 704                 if ($cur eq $dir) {
 705                         _lei_store($self, 1)->done;
 706                         return qerr($self, $exists);
 707                 }
 708
 709                 # some folks like symlinks and bind mounts :P
 710                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 711                         lei_config($self, 'leistore.dir', $dir);
 712                         _lei_store($self, 1)->done;
 713                         return qerr($self, "$exists (as $cur)");
 714                 }
 715                 return fail($self, <<"");
 716 E: leistore.dir=$cur already initialized and it is not $dir
 717
 718         }
 719         lei_config($self, 'leistore.dir', $dir);
 720         _lei_store($self, 1)->done;
 721         $exists //= "# leistore.dir=$dir newly initialized";
 722         return qerr($self, $exists);
 723 }
 724
 725 sub lei_daemon_pid { puts shift, $$ }
 726
 727 sub lei_daemon_kill {
 728         my ($self) = @_;
 729         my $sig = $self->{opt}->{signal} // 'TERM';
 730         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 731 }
 732
 733 sub lei_help { _help($_[0]) }
 734
 735 # Shell completion helper.  Used by lei-completion.bash and hopefully
 736 # other shells.  Try to do as much here as possible to avoid redundancy
 737 # and improve maintainability.
 738 sub lei__complete {
 739         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 740         shift @argv; # ignore "lei", the entire command is sent
 741         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 742         my $cmd = shift @argv;
 743         my $info = $CMD{$cmd} // do { # filter matching commands
 744                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 745                 return;
 746         };
 747         my ($proto, undef, @spec) = @$info;
 748         my $cur = pop @argv;
 749         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 750         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 751                 # gross special case since the only git-config options
 752                 # Consider moving to a table if we need more special cases
 753                 # we use Getopt::Long for are the ones we reject, so these
 754                 # are the ones we don't reject:
 755                 if ($cmd eq 'config') {
 756                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 757                         @spec = qw(add z|null get get-all unset unset-all
 758                                 replace-all get-urlmatch
 759                                 remove-section rename-section
 760                                 name-only list|l edit|e
 761                                 get-color-name get-colorbool);
 762                         # fall-through
 763                 }
 764                 # generate short/long names from Getopt::Long specs
 765                 puts $self, grep(/$re/, qw(--help -h -C), map {
 766                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 767                         } elsif (s/\+\z//) { # verbose|v+
 768                         } elsif (s/!\z//) {
 769                                 # negation: solve! => no-solve|solve
 770                                 s/([\w\-]+)/$1|no-$1/g
 771                         }
 772                         map {
 773                                 my $x = length > 1 ? "--$_" : "-$_";
 774                                 $x eq $_cur ? () : $x;
 775                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 776                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 777         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 778                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 779         }
 780
 781         # switch args (e.g. lei q -f mbox<TAB>)
 782         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 783                 my $opt = quotemeta $1;
 784                 puts $self, map {
 785                         my $v = $OPTDESC{$_};
 786                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 787                         # get rid of ALL CAPS placeholder (e.g "OUT")
 788                         # (TODO: completion for external paths)
 789                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 790                         @v;
 791                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 792         }
 793         $cmd =~ tr/-/_/;
 794         if (my $sub = $self->can("_complete_$cmd")) {
 795                 puts $self, $sub->($self, @argv, $cur ? ($cur) : ());
 796         }
 797         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 798         # proto parsing.
 799 }
 800
 801 sub exec_buf ($$) {
 802         my ($argv, $env) = @_;
 803         my $argc = scalar @$argv;
 804         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 805         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 806         $buf;
 807 }
 808
 809 sub start_mua {
 810         my ($self) = @_;
 811         my $mua = $self->{opt}->{mua} // return;
 812         my $mfolder = $self->{ovv}->{dst};
 813         my (@cmd, $replaced);
 814         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 815                 @cmd = ($mua, '-f');
 816         # TODO: help wanted: other common FOSS MUAs
 817         } else {
 818                 require Text::ParseWords;
 819                 @cmd = Text::ParseWords::shellwords($mua);
 820                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 821                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 822         }
 823         push @cmd, $mfolder unless defined($replaced);
 824         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 825                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 826         } elsif ($self->{oneshot}) {
 827                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 828         }
 829         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 830                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 831         }
 832         $self->{opt}->{quiet} = 1;
 833         delete $self->{-progress};
 834         delete $self->{opt}->{verbose};
 835 }
 836
 837 sub send_exec_cmd { # tell script/lei to execute a command
 838         my ($self, $io, $cmd, $env) = @_;
 839         my $sock = $self->{sock} // die 'lei client gone';
 840         my $fds = [ map { fileno($_) } @$io ];
 841         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 842 }
 843
 844 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 845         my ($self) = @_;
 846         my $alerts = $self->{opt}->{alert} // return;
 847         while (my $op = shift(@$alerts)) {
 848                 if ($op eq ':WINCH') {
 849                         # hit the process group that started the MUA
 850                         if ($self->{sock}) {
 851                                 send($self->{sock}, '-WINCH', MSG_EOR);
 852                         } elsif ($self->{oneshot}) {
 853                                 kill('-WINCH', $$);
 854                         }
 855                 } elsif ($op eq ':bell') {
 856                         out($self, "\a");
 857                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 858                         push @$alerts, split(/(?<!\\),/, $op);
 859                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 860                         my $cmd = $1; # run an arbitrary command
 861                         require Text::ParseWords;
 862                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 863                         if (my $s = $self->{sock}) {
 864                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 865                         } elsif ($self->{oneshot}) {
 866                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 867                         }
 868                 } else {
 869                         err($self, "W: unsupported --alert=$op"); # non-fatal
 870                 }
 871         }
 872 }
 873
 874 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 875 $path_to_fd{"/dev/fd/$_"} = $path_to_fd{"/proc/self/fd/$_"} for (0..2);
 876 sub fopen {
 877         my ($self, $mode, $path) = @_;
 878         rel2abs($self, $path);
 879         $path =~ tr!/!/!s;
 880         if (defined(my $fd = $path_to_fd{$path})) {
 881                 return $self->{$fd};
 882         }
 883         if ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) {
 884                 return fail($self, "cannot open $path from daemon");
 885         }
 886         open my $fh, $mode, $path or return;
 887         $fh;
 888 }
 889
 890 # caller needs to "-t $self->{1}" to check if tty
 891 sub start_pager {
 892         my ($self) = @_;
 893         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 894         chomp(my $pager = <$fh> // '');
 895         close($fh) or warn "`git var PAGER' error: \$?=$?";
 896         return if $pager eq 'cat' || $pager eq '';
 897         my $new_env = { LESS => 'FRX', LV => '-c' };
 898         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 899         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 900         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 901         my $pgr = [ undef, @$rdr{1, 2} ];
 902         my $env = $self->{env};
 903         if ($self->{sock}) { # lei(1) process runs it
 904                 delete @$new_env{keys %$env}; # only set iff unset
 905                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 906         } elsif ($self->{oneshot}) {
 907                 my $cmd = [$pager];
 908                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 909         } else {
 910                 die 'BUG: start_pager w/o socket';
 911         }
 912         $self->{1} = $wpager;
 913         $self->{2} = $wpager if -t $self->{2};
 914         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 915         $self->{pgr} = $pgr;
 916 }
 917
 918 sub stop_pager {
 919         my ($self) = @_;
 920         my $pgr = delete($self->{pgr}) or return;
 921         $self->{2} = $pgr->[2];
 922         # do not restore original stdout, just close it so we error out
 923         close(delete($self->{1})) if $self->{1};
 924 }
 925
 926 sub accept_dispatch { # Listener {post_accept} callback
 927         my ($sock) = @_; # ignore other
 928         $sock->autoflush(1);
 929         my $self = bless { sock => $sock }, __PACKAGE__;
 930         vec(my $rvec = '', fileno($sock), 1) = 1;
 931         select($rvec, undef, undef, 60) or
 932                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 933         # (4096 * 33) >MAX_ARG_STRLEN
 934         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 935         if (scalar(@fds) == 4) {
 936                 for my $i (0..3) {
 937                         my $fd = shift(@fds);
 938                         open($self->{$i}, '+<&=', $fd) and next;
 939                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 940                 }
 941         } elsif (!defined($fds[0])) {
 942                 warn(my $msg = "recv_cmd failed: $!");
 943                 return send($sock, $msg, MSG_EOR);
 944         } else {
 945                 return;
 946         }
 947         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 948         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 949         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 950         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 951                 return send($sock, 'request command truncated', MSG_EOR);
 952         my ($argc, @argv) = split(/\0/, $buf, -1);
 953         undef $buf;
 954         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 955         if (chdir($self->{3})) {
 956                 local %ENV = %env;
 957                 $self->{env} = \%env;
 958                 eval { dispatch($self, @argv) };
 959                 send($sock, $@, MSG_EOR) if $@;
 960         } else {
 961                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 962         }
 963 }
 964
 965 sub dclose {
 966         my ($self) = @_;
 967         delete $self->{-progress};
 968         for my $f (@WQ_KEYS) {
 969                 my $wq = delete $self->{$f} or next;
 970                 if ($wq->wq_kill) {
 971                         $wq->wq_close(0, undef, $self);
 972                 } elsif ($wq->wq_kill_old) {
 973                         $wq->wq_wait_old(undef, $self);
 974                 }
 975         }
 976         close(delete $self->{1}) if $self->{1}; # may reap_compress
 977         if (my $sto = delete $self->{sto}) {
 978                 $sto->ipc_do('done');
 979         }
 980         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 981 }
 982
 983 # for long-running results
 984 sub event_step {
 985         my ($self) = @_;
 986         local %ENV = %{$self->{env}};
 987         my $sock = $self->{sock};
 988         local $current_lei = $self;
 989         eval {
 990                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 991                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 992                                 return if $! == EAGAIN;
 993                                 next if $! == EINTR;
 994                                 last if $! == ECONNRESET;
 995                                 die "recvmsg: $!";
 996                         }
 997                         for my $fd (@fds) {
 998                                 open my $rfh, '+<&=', $fd;
 999                         }
1000                         die "unrecognized client signal: $buf";
1001                 }
1002                 dclose($self);
1003         };
1004         if (my $err = $@) {
1005                 eval { $self->fail($err) };
1006                 dclose($self);
1007         }
1008 }
1009
1010 sub event_step_init {
1011         my ($self) = @_;
1012         return if $self->{-event_init_done}++;
1013         if (my $sock = $self->{sock}) { # using DS->EventLoop
1014                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1015         }
1016 }
1017
1018 sub noop {}
1019
1020 sub oldset { $oldset }
1021
1022 sub dump_and_clear_log {
1023         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1024                 my @pfx = @_;
1025                 unshift(@pfx, "$errors_log ") if @pfx;
1026                 warn @pfx, do { local $/; <STDIN> };
1027                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1028         }
1029 }
1030
1031 # lei(1) calls this when it can't connect
1032 sub lazy_start {
1033         my ($path, $errno, $narg) = @_;
1034         local ($errors_log, $listener);
1035         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1036         $errors_log .= 'errors.log';
1037         my $addr = pack_sockaddr_un($path);
1038         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1039         $lk->lock_acquire;
1040         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1041         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1042                 return if connect($listener, $addr); # another process won
1043                 if ($errno == ECONNREFUSED && -S $path) {
1044                         unlink($path) or die "unlink($path): $!";
1045                 }
1046         } else {
1047                 $! = $errno; # allow interpolation to stringify in die
1048                 die "connect($path): $!";
1049         }
1050         umask(077) // die("umask(077): $!");
1051         bind($listener, $addr) or die "bind($path): $!";
1052         listen($listener, 1024) or die "listen: $!";
1053         $lk->lock_release;
1054         undef $lk;
1055         my @st = stat($path) or die "stat($path): $!";
1056         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1057         local $oldset = PublicInbox::DS::block_signals();
1058         if ($narg == 5) {
1059                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1060                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1061                         require PublicInbox::CmdIPC4;
1062                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1063                         PublicInbox::CmdIPC4->can('recv_cmd4');
1064                 };
1065         }
1066         $recv_cmd or die <<"";
1067 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1068
1069         require PublicInbox::Listener;
1070         require PublicInbox::EOFpipe;
1071         (-p STDOUT) or die "E: stdout must be a pipe\n";
1072         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1073         STDIN->autoflush(1);
1074         dump_and_clear_log("from previous daemon process:\n");
1075         POSIX::setsid() > 0 or die "setsid: $!";
1076         my $pid = fork // die "fork: $!";
1077         return if $pid;
1078         $0 = "lei-daemon $path";
1079         local %PATH2CFG;
1080         $listener->blocking(0);
1081         my $exit_code;
1082         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1083         local $quit = do {
1084                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1085                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1086                 sub {
1087                         $exit_code //= shift;
1088                         my $lis = $pil or exit($exit_code);
1089                         # closing eof_w triggers \&noop wakeup
1090                         $listener = $eof_w = $pil = $path = undef;
1091                         $lis->close; # DS::close
1092                         PublicInbox::DS->SetLoopTimeout(1000);
1093                 };
1094         };
1095         my $sig = {
1096                 CHLD => \&PublicInbox::DS::enqueue_reap,
1097                 QUIT => $quit,
1098                 INT => $quit,
1099                 TERM => $quit,
1100                 HUP => \&noop,
1101                 USR1 => \&noop,
1102                 USR2 => \&noop,
1103         };
1104         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1105         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1106         undef $sig;
1107         local $SIG{PIPE} = 'IGNORE';
1108         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1109                 undef $sigfd;
1110                 PublicInbox::DS->SetLoopTimeout(5000);
1111         } else {
1112                 # wake up every second to accept signals if we don't
1113                 # have signalfd or IO::KQueue:
1114                 PublicInbox::DS::sig_setmask($oldset);
1115                 PublicInbox::DS->SetLoopTimeout(1000);
1116         }
1117         PublicInbox::DS->SetPostLoopCallback(sub {
1118                 my ($dmap, undef) = @_;
1119                 if (@st = defined($path) ? stat($path) : ()) {
1120                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1121                                 warn "$path dev/ino changed, quitting\n";
1122                                 $path = undef;
1123                         }
1124                 } elsif (defined($path)) { # ENOENT is common
1125                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1126                         undef $path;
1127                         $quit->();
1128                 }
1129                 return 1 if defined($path);
1130                 my $now = now();
1131                 my $n = 0;
1132                 for my $s (values %$dmap) {
1133                         $s->can('busy') or next;
1134                         if ($s->busy($now)) {
1135                                 ++$n;
1136                         } else {
1137                                 $s->close;
1138                         }
1139                 }
1140                 $n; # true: continue, false: stop
1141         });
1142
1143         # STDIN was redirected to /dev/null above, closing STDERR and
1144         # STDOUT will cause the calling `lei' client process to finish
1145         # reading the <$daemon> pipe.
1146         local $SIG{__WARN__} = sub {
1147                 $current_lei ? err($current_lei, @_) : warn(
1148                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1149         };
1150         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1151         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1152         # $daemon pipe to `lei' closed, main loop begins:
1153         PublicInbox::DS->EventLoop;
1154         exit($exit_code // 0);
1155 }
1156
1157 sub busy { 1 } # prevent daemon-shutdown if client is connected
1158
1159 # for users w/o Socket::Msghdr installed or Inline::C enabled
1160 sub oneshot {
1161         my ($main_pkg) = @_;
1162         my $exit = $main_pkg->can('exit'); # caller may override exit()
1163         local $quit = $exit if $exit;
1164         local %PATH2CFG;
1165         umask(077) // die("umask(077): $!");
1166         my $self = bless {
1167                 oneshot => 1,
1168                 0 => *STDIN{GLOB},
1169                 1 => *STDOUT{GLOB},
1170                 2 => *STDERR{GLOB},
1171                 env => \%ENV
1172         }, __PACKAGE__;
1173         dispatch($self, @ARGV);
1174         x_it($self, $self->{child_error}) if $self->{child_error};
1175 }
1176
1177 # ensures stdout hits the FS before sock disconnects so a client
1178 # can immediately reread it
1179 sub DESTROY {
1180         my ($self) = @_;
1181         $self->{1}->autoflush(1) if $self->{1};
1182         stop_pager($self);
1183         my $err = $?;
1184         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1185         waitpid($_, 0) for keys %$oneshot_pids;
1186         $? = $err if $err; # preserve ->fail or ->x_it code
1187 }
1188
1189 1;