lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 use Sys::Syslog qw(openlog syslog closelog);
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  33         $recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  41 our %LIVE_SOCK; # "GLOB(0x....)" => $lei->{sock}
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         my $cwd;
  81         if (defined $pwd) {
  82                 my $xcwd = $self->{3} //
  83                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  84                 if (my @st_pwd = stat($pwd)) {
  85                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  86                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  87                                 $self->{env}->{PWD} = $pwd = undef;
  88                 } else { # PWD was invalid
  89                         $self->{env}->{PWD} = $pwd = undef;
  90                 }
  91         }
  92         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  93         File::Spec->rel2abs($p, $pwd);
  94 }
  95
  96 # abs_path resolves symlinks in parent iff all parents exist
  97 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  98
  99 sub canonpath_harder {
 100         my $p = $_[-1]; # $_[0] may be self
 101         $p = File::Spec->canonpath($p);
 102         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 103 }
 104
 105 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 109                 .'/lei');
 110 }
 111
 112 sub store_path ($) { share_path($_[0]) . '/store' }
 113
 114 sub _config_path ($) {
 115         my ($self) = @_;
 116         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 117                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 118                 .'/lei/config');
 119 }
 120
 121 sub cache_dir ($) {
 122         my ($self) = @_;
 123         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 124                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 125                 .'/lei');
 126 }
 127
 128 sub url_folder_cache {
 129         my ($self) = @_;
 130         require PublicInbox::SharedKV; # URI => updated_at_sec_
 131         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 132 }
 133
 134 sub ale {
 135         my ($self) = @_;
 136         $self->{ale} //= do {
 137                 require PublicInbox::LeiALE;
 138                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 139         };
 140 }
 141
 142 sub index_opt {
 143         # TODO: drop underscore variants everywhere, they're undocumented
 144         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 145         max_size|max-size=s sequential-shard
 146         batch_size|batch-size=s skip-docdata)
 147 }
 148
 149 my @c_opt = qw(c=s@ C=s@ quiet|q);
 150 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 151         import-remote! no-torsocks torsocks=s),
 152         PublicInbox::LeiQuery::curl_opt());
 153
 154 # we don't support -C as an alias for --find-copies since it's already
 155 # used for chdir
 156 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 157         output-indicator-context=s indent-heuristic!
 158         minimal patience histogram anchored=s@ diff-algorithm=s
 159         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 160         word-diff:s word-diff-regex=s color-words:s no-renames
 161         rename-empty! check ws-error-highlight=s full-index binary
 162         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 163         find-copies-harder irreversible-delete|D l=i diff-filter=s
 164         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 165         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 166         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 167         inter-hunk-context=i function-context|W exit-code ext-diff
 168         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 169         line-prefix=s);
 170
 171 # we generate shell completion + help using %CMD and %OPTDESC,
 172 # see lei__complete() and PublicInbox::LeiHelp
 173 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 174 our %CMD = ( # sorted in order of importance/use:
 175 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 176         'stdin|', # /|\z/ must be first for lone dash
 177         @lxs_opt,
 178         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 179         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 180         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 181         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 182
 183 'up' => [ 'OUTPUT...|--all', 'update saved search',
 184         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 185
 186 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 187         'stdin|', # /|\z/ must be first for lone dash
 188         # some of these options are ridiculous for lcat
 189         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 190         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 191         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 192         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 193
 194 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 195         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 196         @lxs_opt, @c_opt ],
 197
 198 'rediff' => [ '--stdin|LOCATION...',
 199                 'regenerate a diff with different options',
 200         'stdin|', # /|\z/ must be first for lone dash
 201         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 202         @diff_opt, @lxs_opt, @c_opt ],
 203
 204 'add-external' => [ 'LOCATION',
 205         'add/set priority of a publicinbox|extindex for extra matches',
 206         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 207         verbose|v+), @c_opt, index_opt(),
 208         PublicInbox::LeiQuery::curl_opt() ],
 209 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 210         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 211 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 212 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 213                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 214 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 215                 qw(z|0 ascii l url), @c_opt ],
 216 'forget-external' => [ 'LOCATION...|--prune',
 217         'exclude further results from a publicinbox|extindex',
 218         qw(prune), @c_opt ],
 219
 220 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 221                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 222 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 223                 qw(verbose|v+), @c_opt ],
 224 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 225                         @c_opt ],
 226 'rm' => [ '--stdin|LOCATION...',
 227         'remove a message from the index and prevent reindexing',
 228         'stdin|', # /|\z/ must be first for lone dash
 229         @c_opt ],
 230 'plonk' => [ '--threads|--from=IDENT',
 231         'exclude mail matching From: or threads from non-Message-ID searches',
 232         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 233 'tag' => [ 'KEYWORDS...',
 234         'set/unset keywords and/or labels on message(s)',
 235         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 236         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 237         pass_through('-kw:foo for delete') ],
 238
 239 'purge-mailsource' => [ 'LOCATION|--all',
 240         'remove imported messages from IMAP, Maildirs, and MH',
 241         qw(exact! all jobs:i indexed), @c_opt ],
 242
 243 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 244         qw(poll-interval=s state=s recursive|r), @c_opt ],
 245 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 246         qw(recursive|r), @c_opt ],
 247 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 248                 qw(l z|0), @c_opt ],
 249 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 250 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 251 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 252         qw(prune), @c_opt ],
 253
 254 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 255         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 256         verbose|v+ incremental!),
 257          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 258          @c_opt ],
 259 'import' => [ 'LOCATION...|--stdin',
 260         'one-time import/update from URL or filesystem',
 261         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 262         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 263         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 264 'forget-mail-sync' => [ 'LOCATION...',
 265         'forget sync information for a mail folder', @c_opt ],
 266 'prune-mail-sync' => [ 'LOCATION...|--all',
 267         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 268 'export-kw' => [ 'LOCATION...|--all',
 269         'one-time export of keywords of sync sources',
 270         qw(all:s mode=s), @c_opt ],
 271 'convert' => [ 'LOCATION...|--stdin',
 272         'one-time conversion from URL or filesystem to another format',
 273         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 274         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 275 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 276         "use a patch to generate a query for `lei q --stdin'",
 277         qw(stdin| want|w=s@ uri debug), @c_opt ],
 278 'config' => [ '[...]', sub {
 279                 'git-config(1) wrapper for '._config_path($_[0]);
 280         }, qw(config-file|system|global|file|f=s), # for conflict detection
 281          qw(c=s@ C=s@), pass_through('git config') ],
 282 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 283         qw(pretty ascii dir=s), @c_opt ],
 284
 285 'init' => [ '[DIRNAME]', sub {
 286         "initialize storage, default: ".store_path($_[0]);
 287         }, @c_opt ],
 288 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 289         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 290         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 291 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 292 'help' => [ '[SUBCOMMAND]', 'show help' ],
 293
 294 # TODO
 295 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 296 #       'rewrite git history in an attempt to improve compression',
 297 #       qw(gc!), @c_opt ],
 298 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 299 #
 300 # internal commands are prefixed with '_'
 301 '_complete' => [ '[...]', 'internal shell completion helper',
 302                 pass_through('everything') ],
 303 ); # @CMD
 304
 305 # switch descriptions, try to keep consistent across commands
 306 # $spec: Getopt::Long option specification
 307 # $spec => [@ALLOWED_VALUES (default is first), $description],
 308 # $spec => $description
 309 # "$SUB_COMMAND TAB $spec" => as above
 310 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 311                         'specify message input format' ];
 312 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 313
 314 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 315 my %OPTDESC = (
 316 'help|h' => 'show this built-in help',
 317 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 318 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 319 'quiet|q' => 'be quiet',
 320 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 321         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 322
 323 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 324 'globoff|g' => "do not match locations using '*?' wildcards ".
 325                 "and\xa0'[]'\x{a0}ranges",
 326 'invert-match|v' => 'select non-matching lines',
 327 'color!' => 'disable color (for --format=text)',
 328 'verbose|v+' => 'be more verbose',
 329 'external!' => 'do not use externals',
 330 'mail!' => 'do not look in mail storage for OID',
 331 'cwd!' => 'do not look in git repo of current working directory',
 332 'oid-a|A=s' => 'pre-image OID',
 333 'path-a|a=s' => 'pre-image pathname associated with OID',
 334 'path-b|b=s' => 'post-image pathname associated with OID',
 335 'git-dir=s@' => 'additional git repository to scan',
 336 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 337 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 338         "proxy for (e.g. `socks5h://0:9050')" ],
 339 'torsocks=s' => ['VAL|auto|no|yes',
 340                 'whether or not to wrap git and curl commands with torsocks'],
 341 'no-torsocks' => 'alias for --torsocks=no',
 342 'save!' =>  "do not save a search for `lei up'",
 343 'import-remote!' => 'do not memoize remote messages into local store',
 344
 345 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 346
 347 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 348                 'deduplication strategy'],
 349 'threads|t+' =>
 350         'return all messages in the same threads as the actual match(es)',
 351
 352 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 353                 'search prefixes to extract (default: dfpost7)' ],
 354
 355 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 356         'run command(s) or perform ops when done writing to output ' .
 357         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 358         'nothing otherwise)' ],
 359
 360 'augment|a' => 'augment --output destination instead of clobbering',
 361
 362 'output|mfolder|o=s' => [ 'MFOLDER',
 363         "destination (e.g.\xa0`/path/to/Maildir', ".
 364         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 365 'mua=s' => [ 'CMD',
 366         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 367 'new-only       import' => 'only import new messages from IMAP source',
 368
 369 'inbox-version=i' => [ 'NUM|1|2',
 370                 'force a public-inbox version with --mirror'],
 371 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 372
 373 # public-inbox-index options
 374 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 375 'compact' => 'run compact index after mirroring',
 376 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 377         "indexlevel with --mirror (default: full)" ],
 378 'max_size|max-size=s' => [ 'SIZE',
 379         'do not index messages larger than SIZE (default: infinity)' ],
 380 'batch_size|batch-size=s' => [ 'SIZE',
 381         'flush changes to OS after given number of bytes (default: 1m)' ],
 382 'sequential-shard' =>
 383         'index Xapian shards sequentially for slow storage',
 384 'skip-docdata' =>
 385         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 386
 387 'format|f=s     q' => [
 388         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 389                 'specify output format, default depends on --output'],
 390 'exclude=s@     q' => [ 'LOCATION',
 391                 'exclude specified external(s) from search' ],
 392 'include|I=s@   q' => [ 'LOCATION',
 393                 'include specified external(s) in search' ],
 394 'only=s@        q' => [ 'LOCATION',
 395                 'only use specified external(s) for search' ],
 396 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 397                 'control number of search and writer jobs' ],
 398 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 399
 400 'in-format|F=s' => $stdin_formats,
 401 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 402                         'listing output format' ],
 403 'l      ls-search' => 'long listing format',
 404 'l      ls-watch' => 'long listing format',
 405 'l      ls-mail-source' => 'long listing format',
 406 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 407 'format|f=s     ls-external' => $ls_format,
 408
 409 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 410 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 411
 412 'sort|s=s' => [ 'VAL|received|relevance|docid',
 413                 "order of results is `--output'-dependent"],
 414 'reverse|r' => 'reverse search results', # like sort(1)
 415
 416 'boost=i' => 'increase/decrease priority of results (default: 0)',
 417
 418 'local' => 'limit operations to the local filesystem',
 419 'local!' => 'exclude results from the local filesystem',
 420 'remote' => 'limit operations to those requiring network access',
 421 'remote!' => 'prevent operations requiring network access',
 422
 423 'all:s  up' => ['local', 'update all (local) saved searches' ],
 424
 425 'mid=s' => 'specify the Message-ID of a message',
 426 'oid=s' => 'specify the git object ID of a message',
 427
 428 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 429 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 430 'include=s' => 'include mailboxes/newsgroups based on pattern',
 431
 432 'exact' => 'operate on exact header matches only',
 433 'exact!' => 'rely on content match instead of exact header matches',
 434
 435 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 436
 437 'kw!' => 'disable/enable importing keywords (aka "flags")',
 438
 439 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 440 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 441
 442 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 443 ); # %OPTDESC
 444
 445 my %CONFIG_KEYS = (
 446         'leistore.dir' => 'top-level storage location',
 447 );
 448
 449 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 450
 451 sub _drop_wq {
 452         my ($self) = @_;
 453         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 454                 if ($wq->wq_kill) {
 455                         $wq->wq_close(0, undef, $self);
 456                 } elsif ($wq->wq_kill_old) {
 457                         $wq->wq_wait_old(undef, $self);
 458                 }
 459                 $wq->DESTROY;
 460         }
 461 }
 462
 463 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 464 sub x_it ($$) {
 465         my ($self, $code) = @_;
 466         # make sure client sees stdout before exit
 467         $self->{1}->autoflush(1) if $self->{1};
 468         stop_pager($self);
 469         if ($self->{pkt_op_p}) { # to top lei-daemon
 470                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 471         } elsif ($self->{sock}) { # to lei(1) client
 472                 send($self->{sock}, "x_it $code", MSG_EOR);
 473         } # else ignore if client disconnected
 474 }
 475
 476 sub err ($;@) {
 477         my $self = shift;
 478         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 479         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 480         print $err @_, @eor and return;
 481         my $old_err = delete $self->{2};
 482         close($old_err) if $! == EPIPE && $old_err;
 483         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 484         print $err @_, @eor or print STDERR @_, @eor;
 485 }
 486
 487 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 488
 489 sub qfin { # show message on finalization (LeiFinmsg)
 490         my ($lei, $msg) = @_;
 491         return if $lei->{opt}->{quiet};
 492         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 493 }
 494
 495 sub fail_handler ($;$$) {
 496         my ($lei, $code, $io) = @_;
 497         close($io) if $io; # needed to avoid warnings on SIGPIPE
 498         _drop_wq($lei);
 499         x_it($lei, $code // (1 << 8));
 500 }
 501
 502 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 503         fail_handler($_[0], 13, delete $_[0]->{1});
 504 }
 505
 506 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 507 sub sigint_reap {
 508         my ($pgid) = @_;
 509         dwaitpid($pgid) if kill('-INT', $pgid);
 510 }
 511
 512 sub fail ($$;$) {
 513         my ($self, $buf, $exit_code) = @_;
 514         $self->{failed}++;
 515         err($self, $buf) if defined $buf;
 516         # calls fail_handler:
 517         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 518         x_it($self, ($exit_code // 1) << 8);
 519         undef;
 520 }
 521
 522 sub out ($;@) {
 523         my $self = shift;
 524         return if print { $self->{1} // return } @_; # likely
 525         return note_sigpipe($self, 1) if $! == EPIPE;
 526         my $err = "error writing to output: $!";
 527         delete $self->{1};
 528         fail($self, $err);
 529 }
 530
 531 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 532
 533 sub child_error { # passes non-fatal curl exit codes to user
 534         my ($self, $child_error, $msg) = @_; # child_error is $?
 535         $self->err($msg) if $msg;
 536         if ($self->{pkt_op_p}) { # to top lei-daemon
 537                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 538         } elsif ($self->{sock}) { # to lei(1) client
 539                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 540         } # else noop if client disconnected
 541 }
 542
 543 sub note_sigpipe { # triggers sigpipe_handler
 544         my ($self, $fd) = @_;
 545         close(delete($self->{$fd})); # explicit close silences Perl warning
 546         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 547         x_it($self, 13);
 548 }
 549
 550 sub _lei_atfork_child {
 551         my ($self, $persist) = @_;
 552         # we need to explicitly close things which are on stack
 553         if ($persist) {
 554                 chdir '/' or die "chdir(/): $!";
 555                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 556                 if (my $cfg = $self->{cfg}) {
 557                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 558                 }
 559         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 560                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 561                 STDERR->autoflush(1);
 562         }
 563         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 564         if (my $op_c = delete $self->{pkt_op_c}) {
 565                 close(delete $op_c->{sock});
 566         }
 567         if (my $pgr = delete $self->{pgr}) {
 568                 close($_) for (@$pgr[1,2]);
 569         }
 570         close $listener if $listener;
 571         undef $listener;
 572         $dir_idle->force_close if $dir_idle;
 573         %PATH2CFG = ();
 574         $MDIR2CFGPATH = {};
 575         %LIVE_SOCK = ();
 576         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 577         undef $errors_log;
 578         $quit = \&CORE::exit;
 579         $self->{-eml_noisy} or # only "lei import" sets this atm
 580                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 581         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 582 }
 583
 584 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 585         my ($self) = @_;
 586         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 587                 $op->close; # PublicInbox::PktOp::close
 588         }
 589         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 590         close $pkt_op_p->{op_p};
 591 }
 592
 593 sub pkt_op_pair {
 594         my ($self) = @_;
 595         require PublicInbox::OnDestroy;
 596         require PublicInbox::PktOp;
 597         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 598         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 599         $end;
 600 }
 601
 602 sub incr {
 603         my ($self, $field, $nr) = @_;
 604         $self->{counters}->{$field} += $nr;
 605 }
 606
 607 sub workers_start {
 608         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 609         $ops = {
 610                 '!' => [ \&fail_handler, $lei ],
 611                 '|' => [ \&sigpipe_handler, $lei ],
 612                 'x_it' => [ \&x_it, $lei ],
 613                 'child_error' => [ \&child_error, $lei ],
 614                 'incr' => [ \&incr, $lei ],
 615                 ($ops ? %$ops : ()),
 616         };
 617         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 618         my $end = $lei->pkt_op_pair;
 619         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 620         $flds->{lei} = $lei;
 621         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 622         delete $lei->{pkt_op_p};
 623         my $op_c = delete $lei->{pkt_op_c};
 624         @$end = ();
 625         $lei->event_step_init;
 626         ($op_c, $ops);
 627 }
 628
 629 # call this when we're ready to wait on events and yield to other clients
 630 sub wait_wq_events {
 631         my ($lei, $op_c, $ops) = @_;
 632         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 633                 $wq->wq_close(1);
 634         }
 635         $op_c->{ops} = $ops;
 636 }
 637
 638 sub _help {
 639         require PublicInbox::LeiHelp;
 640         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 641 }
 642
 643 sub optparse ($$$) {
 644         my ($self, $cmd, $argv) = @_;
 645         # allow _complete --help to complete, not show help
 646         return 1 if substr($cmd, 0, 1) eq '_';
 647         $self->{cmd} = $cmd;
 648         $OPT = $self->{opt} //= {};
 649         my $info = $CMD{$cmd} // [ '[...]' ];
 650         my ($proto, undef, @spec) = @$info;
 651         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 652         push @spec, qw(help|h);
 653         my $lone_dash;
 654         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 655                 $lone_dash = $spec[0];
 656                 $OPT->{$spec[0]} = \(my $var);
 657                 push @spec, '' => \$var;
 658         }
 659         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 660                 return _help($self, "bad arguments or options for $cmd");
 661         return _help($self) if $OPT->{help};
 662
 663         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 664
 665         # "-" aliases "stdin" or "clear"
 666         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 667
 668         my $i = 0;
 669         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 670         my ($err, $inf);
 671         my @args = split(/ /, $proto);
 672         for my $var (@args) {
 673                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 674                         $inf = defined($argv->[$i]) and last;
 675                         $var =~ s/\.\.\.\z//;
 676                         $err = "$var not supplied";
 677                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 678                         $argv->[$i++] // ($err = "$var not supplied");
 679                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 680                         $inf = 1;
 681                         last;
 682                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 683                         $i++;
 684                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 685                         $inf = 1 if index($var, '...') > 0;
 686                         my @or = split(/\|/, $var);
 687                         my $ok;
 688                         for my $o (@or) {
 689                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 690                                         my $sw = $1;
 691                                         # assume pipe/regular file on stdin
 692                                         # w/o args means stdin
 693                                         if ($sw eq 'stdin' && !@$argv &&
 694                                                         (-p $self->{0} ||
 695                                                          -f _) && -r _) {
 696                                                 $OPT->{stdin} //= 1;
 697                                         }
 698                                         $ok = defined($OPT->{$sw});
 699                                         last if $ok;
 700                                 } elsif (defined($argv->[$i])) {
 701                                         $ok = 1;
 702                                         $i++;
 703                                         last;
 704                                 } # else continue looping
 705                         }
 706                         last if $ok;
 707                         my $last = pop @or;
 708                         $err = join(', ', @or) . " or $last must be set";
 709                 } else {
 710                         warn "BUG: can't parse `$var' in $proto";
 711                 }
 712                 last if $err;
 713         }
 714         if (!$inf && scalar(@$argv) > scalar(@args)) {
 715                 $err //= 'too many arguments';
 716         }
 717         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 718 }
 719
 720 sub _tmp_cfg { # for lei -c <name>=<value> ...
 721         my ($self) = @_;
 722         my $cfg = _lei_cfg($self, 1);
 723         require File::Temp;
 724         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 725         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 726         $ft->autoflush(1);
 727         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 728 [include]
 729         path = $cfg->{-f}
 730 EOM
 731         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 732         for (@{$self->{opt}->{c}}) {
 733                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 734 `-c $_' is not of the form -c <name>=<value>'
 735 EOM
 736                 my $name = $1;
 737                 my $value = $2 // 1;
 738                 _config($self, '--add', $name, $value);
 739                 if (defined(my $v = $tmp->{$name})) {
 740                         if (ref($v) eq 'ARRAY') {
 741                                 push @$v, $value;
 742                         } else {
 743                                 $tmp->{$name} = [ $v, $value ];
 744                         }
 745                 } else {
 746                         $tmp->{$name} = $value;
 747                 }
 748         }
 749 }
 750
 751 sub lazy_cb ($$$) {
 752         my ($self, $cmd, $pfx) = @_;
 753         my $ucmd = $cmd;
 754         $ucmd =~ tr/-/_/;
 755         my $cb;
 756         $cb = $self->can($pfx.$ucmd) and return $cb;
 757         my $base = $ucmd;
 758         $base =~ s/_([a-z])/\u$1/g;
 759         my $pkg = "PublicInbox::Lei\u$base";
 760         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 761                 $pkg->can($pfx.$ucmd) : undef;
 762 }
 763
 764 sub dispatch {
 765         my ($self, $cmd, @argv) = @_;
 766         local $current_lei = $self; # for __WARN__
 767         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 768         return _help($self, 'no command given') unless defined($cmd);
 769         # do not support Getopt bundling for this
 770         while ($cmd eq '-C' || $cmd eq '-c') {
 771                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 772                                         '-C DIRECTORY' : '-c <name>=<value>');
 773                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 774                 $cmd = shift(@argv) // return _help($self, 'no command given');
 775         }
 776         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 777                 optparse($self, $cmd, \@argv) or return;
 778                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 779                 if (my $chdir = $self->{opt}->{C}) {
 780                         for my $d (@$chdir) {
 781                                 next if $d eq ''; # same as git(1)
 782                                 chdir $d or return fail($self, "cd $d: $!");
 783                         }
 784                         open $self->{3}, '.' or return fail($self, "open . $!");
 785                 }
 786                 $cb->($self, @argv);
 787         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 788                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 789                         or return _help($self, 'bad arguments or options');
 790                 _help($self);
 791         } else {
 792                 fail($self, "`$cmd' is not an lei command");
 793         }
 794 }
 795
 796 sub _lei_cfg ($;$) {
 797         my ($self, $creat) = @_;
 798         return $self->{cfg} if $self->{cfg};
 799         my $f = _config_path($self);
 800         my @st = stat($f);
 801         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 802         my ($sto, $sto_dir, $watches, $lne);
 803         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 804                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 805                 ($sto, $sto_dir, $watches, $lne) =
 806                                 @$cfg{qw(-lei_store leistore.dir -watches
 807                                         -lei_note_event)};
 808         }
 809         if (!@st) {
 810                 unless ($creat) {
 811                         delete $self->{cfg};
 812                         return bless {}, 'PublicInbox::Config';
 813                 }
 814                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 815                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 816                 open my $fh, '>>', $f or die "open($f): $!\n";
 817                 @st = stat($fh) or die "fstat($f): $!\n";
 818                 $cur_st = pack('dd', $st[10], $st[7]);
 819                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 820         }
 821         my $cfg = PublicInbox::Config->git_config_dump($f);
 822         $cfg->{-st} = $cur_st;
 823         $cfg->{'-f'} = $f;
 824         if ($sto && canonpath_harder($sto_dir // store_path($self))
 825                         eq canonpath_harder($cfg->{'leistore.dir'} //
 826                                                 store_path($self))) {
 827                 $cfg->{-lei_store} = $sto;
 828                 $cfg->{-lei_note_event} = $lne;
 829                 $cfg->{-watches} = $watches if $watches;
 830         }
 831         if (scalar(keys %PATH2CFG) > 5) {
 832                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 833                 for my $k (keys %PATH2CFG) {
 834                         delete($PATH2CFG{$k}) unless -f $k
 835                 }
 836         }
 837         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 838         refresh_watches($self);
 839         $cfg;
 840 }
 841
 842 sub _lei_store ($;$) {
 843         my ($self, $creat) = @_;
 844         my $cfg = _lei_cfg($self, $creat) // return;
 845         $cfg->{-lei_store} //= do {
 846                 require PublicInbox::LeiStore;
 847                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 848                 return unless $creat || -d $dir;
 849                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 850         };
 851 }
 852
 853 sub _config {
 854         my ($self, @argv) = @_;
 855         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 856         my $cfg = _lei_cfg($self, 1);
 857         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 858         my %rdr = map { $_ => $self->{$_} } (0..2);
 859         waitpid(spawn($cmd, \%env, \%rdr), 0);
 860 }
 861
 862 sub lei_config {
 863         my ($self, @argv) = @_;
 864         $self->{opt}->{'config-file'} and return fail $self,
 865                 "config file switches not supported by `lei config'";
 866         _config(@_);
 867         x_it($self, $?) if $?;
 868 }
 869
 870 sub lei_daemon_pid { puts shift, $$ }
 871
 872 sub lei_daemon_kill {
 873         my ($self) = @_;
 874         my $sig = $self->{opt}->{signal} // 'TERM';
 875         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 876 }
 877
 878 # Shell completion helper.  Used by lei-completion.bash and hopefully
 879 # other shells.  Try to do as much here as possible to avoid redundancy
 880 # and improve maintainability.
 881 sub lei__complete {
 882         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 883         shift @argv; # ignore "lei", the entire command is sent
 884         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 885         my $cmd = shift @argv;
 886         my $info = $CMD{$cmd} // do { # filter matching commands
 887                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 888                 return;
 889         };
 890         my ($proto, undef, @spec) = @$info;
 891         my $cur = pop @argv;
 892         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 893         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 894                 # gross special case since the only git-config options
 895                 # Consider moving to a table if we need more special cases
 896                 # we use Getopt::Long for are the ones we reject, so these
 897                 # are the ones we don't reject:
 898                 if ($cmd eq 'config') {
 899                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 900                         @spec = qw(add z|null get get-all unset unset-all
 901                                 replace-all get-urlmatch
 902                                 remove-section rename-section
 903                                 name-only list|l edit|e
 904                                 get-color-name get-colorbool);
 905                         # fall-through
 906                 }
 907                 # generate short/long names from Getopt::Long specs
 908                 puts $self, grep(/$re/, qw(--help -h -C), map {
 909                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 910                         } elsif (s/\+\z//) { # verbose|v+
 911                         } elsif (s/!\z//) {
 912                                 # negation: mail! => no-mail|mail
 913                                 s/([\w\-]+)/$1|no-$1/g
 914                         }
 915                         map {
 916                                 my $x = length > 1 ? "--$_" : "-$_";
 917                                 $x eq $_cur ? () : $x;
 918                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 919                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 920         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 921                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 922         }
 923
 924         # switch args (e.g. lei q -f mbox<TAB>)
 925         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 926                 my $opt = quotemeta $1;
 927                 puts $self, map {
 928                         my $v = $OPTDESC{$_};
 929                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 930                         # get rid of ALL CAPS placeholder (e.g "OUT")
 931                         # (TODO: completion for external paths)
 932                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 933                         @v;
 934                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 935         }
 936         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 937                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 938         }
 939         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 940         # proto parsing.
 941 }
 942
 943 sub exec_buf ($$) {
 944         my ($argv, $env) = @_;
 945         my $argc = scalar @$argv;
 946         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 947         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 948         $buf;
 949 }
 950
 951 sub start_mua {
 952         my ($self) = @_;
 953         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 954                 refresh_watches($self);
 955         }
 956         my $mua = $self->{opt}->{mua} // return;
 957         my $mfolder = $self->{ovv}->{dst};
 958         my (@cmd, $replaced);
 959         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 960                 @cmd = ($mua, '-f');
 961         # TODO: help wanted: other common FOSS MUAs
 962         } else {
 963                 require Text::ParseWords;
 964                 @cmd = Text::ParseWords::shellwords($mua);
 965                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 966                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 967         }
 968         push @cmd, $mfolder unless defined($replaced);
 969         if ($self->{sock}) { # lei(1) client process runs it
 970                 # restore terminal: echo $query | lei q --stdin --mua=...
 971                 my $io = [];
 972                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 973                 send_exec_cmd($self, $io, \@cmd, {});
 974         }
 975         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 976                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 977         }
 978         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 979         $self->{opt}->{quiet} = 1;
 980         delete $self->{-progress};
 981         delete $self->{opt}->{verbose};
 982 }
 983
 984 sub send_exec_cmd { # tell script/lei to execute a command
 985         my ($self, $io, $cmd, $env) = @_;
 986         my $sock = $self->{sock} // die 'lei client gone';
 987         my $fds = [ map { fileno($_) } @$io ];
 988         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 989 }
 990
 991 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 992         my ($self) = @_;
 993         my $alerts = $self->{opt}->{alert} // return;
 994         my $sock = $self->{sock};
 995         while (my $op = shift(@$alerts)) {
 996                 if ($op eq ':WINCH') {
 997                         # hit the process group that started the MUA
 998                         send($sock, '-WINCH', MSG_EOR) if $sock;
 999                 } elsif ($op eq ':bell') {
1000                         out($self, "\a");
1001                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1002                         push @$alerts, split(/(?<!\\),/, $op);
1003                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1004                         my $cmd = $1; # run an arbitrary command
1005                         require Text::ParseWords;
1006                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1007                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1008                 } else {
1009                         err($self, "W: unsupported --alert=$op"); # non-fatal
1010                 }
1011         }
1012 }
1013
1014 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1015 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1016
1017 # this also normalizes the path
1018 sub path_to_fd {
1019         my ($self, $path) = @_;
1020         $path = rel2abs($self, $path);
1021         $path =~ tr!/!/!s;
1022         $path_to_fd{$path} // (
1023                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1024                         fail($self, "cannot open $path from daemon") : -1
1025         );
1026 }
1027
1028 # caller needs to "-t $self->{1}" to check if tty
1029 sub start_pager {
1030         my ($self) = @_;
1031         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1032         chomp(my $pager = <$fh> // '');
1033         close($fh) or warn "`git var PAGER' error: \$?=$?";
1034         return if $pager eq 'cat' || $pager eq '';
1035         my $new_env = { LESS => 'FRX', LV => '-c' };
1036         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1037         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1038         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1039         my $pgr = [ undef, @$rdr{1, 2} ];
1040         my $env = $self->{env};
1041         if ($self->{sock}) { # lei(1) process runs it
1042                 delete @$new_env{keys %$env}; # only set iff unset
1043                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1044         } else {
1045                 die 'BUG: start_pager w/o socket';
1046         }
1047         $self->{1} = $wpager;
1048         $self->{2} = $wpager if -t $self->{2};
1049         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1050         $self->{pgr} = $pgr;
1051 }
1052
1053 sub stop_pager {
1054         my ($self) = @_;
1055         my $pgr = delete($self->{pgr}) or return;
1056         $self->{2} = $pgr->[2];
1057         # do not restore original stdout, just close it so we error out
1058         close(delete($self->{1})) if $self->{1};
1059 }
1060
1061 sub accept_dispatch { # Listener {post_accept} callback
1062         my ($sock) = @_; # ignore other
1063         $sock->autoflush(1);
1064         my $self = bless { sock => $sock }, __PACKAGE__;
1065         vec(my $rvec = '', fileno($sock), 1) = 1;
1066         select($rvec, undef, undef, 60) or
1067                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1068         # (4096 * 33) >MAX_ARG_STRLEN
1069         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1070         if (!defined($fds[0])) {
1071                 warn(my $msg = "recv_cmd failed: $!");
1072                 return send($sock, $msg, MSG_EOR);
1073         } else {
1074                 my $i = 0;
1075                 for my $fd (@fds) {
1076                         open($self->{$i++}, '+<&=', $fd) and next;
1077                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1078                 }
1079                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1080         }
1081         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1082         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1083         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1084                 return send($sock, 'request command truncated', MSG_EOR);
1085         my ($argc, @argv) = split(/\0/, $buf, -1);
1086         undef $buf;
1087         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1088         if (chdir($self->{3})) {
1089                 local %ENV = %env;
1090                 $self->{env} = \%env;
1091                 eval { dispatch($self, @argv) };
1092                 send($sock, $@, MSG_EOR) if $@;
1093         } else {
1094                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1095         }
1096 }
1097
1098 sub dclose {
1099         my ($self) = @_;
1100         delete $self->{-progress};
1101         _drop_wq($self) if $self->{failed};
1102         close(delete $self->{1}) if $self->{1}; # may reap_compress
1103         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1104 }
1105
1106 # for long-running results
1107 sub event_step {
1108         my ($self) = @_;
1109         local %ENV = %{$self->{env}};
1110         my $sock = $self->{sock};
1111         local $current_lei = $self;
1112         eval {
1113                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1114                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1115                                 return if $! == EAGAIN;
1116                                 next if $! == EINTR;
1117                                 last if $! == ECONNRESET;
1118                                 die "recvmsg: $!";
1119                         }
1120                         for my $fd (@fds) {
1121                                 open my $rfh, '+<&=', $fd;
1122                         }
1123                         die "unrecognized client signal: $buf";
1124                 }
1125                 _drop_wq($self); # EOF, client disconnected
1126                 dclose($self);
1127         };
1128         if (my $err = $@) {
1129                 eval { $self->fail($err) };
1130                 dclose($self);
1131         }
1132 }
1133
1134 sub event_step_init {
1135         my ($self) = @_;
1136         my $sock = $self->{sock} or return;
1137         $self->{-event_init_done} //= do { # persist til $ops done
1138                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1139                 $sock;
1140         };
1141 }
1142
1143 sub noop {}
1144
1145 sub oldset { $oldset }
1146
1147 sub dump_and_clear_log {
1148         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1149                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1150                 chomp(my @lines = <STDIN>);
1151                 truncate(STDIN, 0) or
1152                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1153                 for my $l (@lines) { syslog('warning', '%s', $l) }
1154                 closelog(); # don't share across fork
1155         }
1156 }
1157
1158 sub cfg2lei ($) {
1159         my ($cfg) = @_;
1160         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1161         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1162         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1163         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1164         open($lei->{3}, '/') or die "open /: $!";
1165         chdir($lei->{3}) or die "chdir /': $!";
1166         my ($x, $y);
1167         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1168         $lei->{sock} = $x;
1169         require PublicInbox::LeiSelfSocket;
1170         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1171         $lei;
1172 }
1173
1174 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1175         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1176         my $fn = $ev->fullname;
1177         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1178                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1179                 $nc = '' if $ev->IN_DELETE;
1180                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1181                         my $cfg = $PATH2CFG{$f} // next;
1182                         eval {
1183                                 local %ENV = %{$cfg->{-env}};
1184                                 my $lei = cfg2lei($cfg);
1185                                 $lei->dispatch('note-event',
1186                                                 "maildir:$mdir", $nc, $bn, $fn);
1187                         };
1188                         warn "E note-event $f: $@\n" if $@;
1189                 }
1190         }
1191         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1192                 $ev->cancel;
1193         }
1194         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1195                 delete $MDIR2CFGPATH->{$1};
1196         }
1197         if (!-e $fn) { # config file or Maildir gone
1198                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1199                         delete $cfgpaths->{$fn};
1200                 }
1201                 delete $PATH2CFG{$fn};
1202         }
1203 }
1204
1205 # lei(1) calls this when it can't connect
1206 sub lazy_start {
1207         my ($path, $errno, $narg) = @_;
1208         local ($errors_log, $listener);
1209         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1210         $errors_log = "$sock_dir/errors.log";
1211         my $addr = pack_sockaddr_un($path);
1212         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1213         $lk->lock_acquire;
1214         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1215         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1216                 return if connect($listener, $addr); # another process won
1217                 if ($errno == ECONNREFUSED && -S $path) {
1218                         unlink($path) or die "unlink($path): $!";
1219                 }
1220         } else {
1221                 $! = $errno; # allow interpolation to stringify in die
1222                 die "connect($path): $!";
1223         }
1224         umask(077) // die("umask(077): $!");
1225         bind($listener, $addr) or die "bind($path): $!";
1226         $lk->lock_release;
1227         undef $lk;
1228         my @st = stat($path) or die "stat($path): $!";
1229         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1230         local $oldset = PublicInbox::DS::block_signals();
1231         if ($narg == 5) {
1232                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1233                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1234                         require PublicInbox::CmdIPC4;
1235                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1236                         PublicInbox::CmdIPC4->can('recv_cmd4');
1237                 };
1238         }
1239         $recv_cmd or die <<"";
1240 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1241
1242         require PublicInbox::Listener;
1243         require PublicInbox::PktOp;
1244         (-p STDOUT) or die "E: stdout must be a pipe\n";
1245         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1246         STDIN->autoflush(1);
1247         dump_and_clear_log();
1248         POSIX::setsid() > 0 or die "setsid: $!";
1249         my $pid = fork // die "fork: $!";
1250         return if $pid;
1251         $0 = "lei-daemon $path";
1252         local %PATH2CFG;
1253         local $MDIR2CFGPATH;
1254         $listener->blocking(0);
1255         my $exit_code;
1256         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1257         local $quit = do {
1258                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1259                 sub {
1260                         $exit_code //= shift;
1261                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1262                         my $lis = $pil or exit($exit_code);
1263                         # closing eof_p triggers \&noop wakeup
1264                         $listener = $eof_p = $pil = $path = undef;
1265                         $lis->close; # DS::close
1266                         PublicInbox::DS->SetLoopTimeout(1000);
1267                 };
1268         };
1269         my $sig = {
1270                 CHLD => \&PublicInbox::DS::enqueue_reap,
1271                 QUIT => $quit,
1272                 INT => $quit,
1273                 TERM => $quit,
1274                 HUP => \&noop,
1275                 USR1 => \&noop,
1276                 USR2 => \&noop,
1277         };
1278         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1279         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1280         undef $sig;
1281         local $SIG{PIPE} = 'IGNORE';
1282         require PublicInbox::DirIdle;
1283         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1284                 # just rely on wakeup to hit PostLoopCallback set below
1285                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1286         }, 1);
1287         if ($sigfd) {
1288                 undef $sigfd; # unref, already in DS::DescriptorMap
1289         } else {
1290                 # wake up every second to accept signals if we don't
1291                 # have signalfd or IO::KQueue:
1292                 PublicInbox::DS::sig_setmask($oldset);
1293                 PublicInbox::DS->SetLoopTimeout(1000);
1294         }
1295         PublicInbox::DS->SetPostLoopCallback(sub {
1296                 my ($dmap, undef) = @_;
1297                 if (@st = defined($path) ? stat($path) : ()) {
1298                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1299                                 warn "$path dev/ino changed, quitting\n";
1300                                 $path = undef;
1301                         }
1302                 } elsif (defined($path)) { # ENOENT is common
1303                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1304                         undef $path;
1305                         $quit->();
1306                 }
1307                 return 1 if defined($path);
1308                 my $now = now();
1309                 my $n = 0;
1310                 for my $s (values %$dmap) {
1311                         $s->can('busy') or next;
1312                         if ($s->busy($now)) {
1313                                 ++$n;
1314                         } else {
1315                                 $s->close;
1316                         }
1317                 }
1318                 $n; # true: continue, false: stop
1319         });
1320
1321         # STDIN was redirected to /dev/null above, closing STDERR and
1322         # STDOUT will cause the calling `lei' client process to finish
1323         # reading the <$daemon> pipe.
1324         local $SIG{__WARN__} = sub {
1325                 $current_lei ? err($current_lei, @_) : warn(
1326                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1327         };
1328         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1329         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1330         # $daemon pipe to `lei' closed, main loop begins:
1331         PublicInbox::DS->EventLoop;
1332         exit($exit_code // 0);
1333 }
1334
1335 sub busy { 1 } # prevent daemon-shutdown if client is connected
1336
1337 # ensures stdout hits the FS before sock disconnects so a client
1338 # can immediately reread it
1339 sub DESTROY {
1340         my ($self) = @_;
1341         if (my $counters = delete $self->{counters}) {
1342                 for my $k (sort keys %$counters) {
1343                         my $nr = $counters->{$k};
1344                         $self->child_error(1 << 8, "$nr $k messages");
1345                 }
1346         }
1347         $self->{1}->autoflush(1) if $self->{1};
1348         stop_pager($self);
1349         dump_and_clear_log();
1350         # preserve $? for ->fail or ->x_it code
1351 }
1352
1353 sub wq_done_wait { # dwaitpid callback
1354         my ($arg, $pid) = @_;
1355         my ($wq, $lei) = @$arg;
1356         my $err_type = $lei->{-err_type};
1357         $? and $lei->child_error($?,
1358                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1359         $lei->dclose;
1360 }
1361
1362 sub fchdir {
1363         my ($lei) = @_;
1364         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1365         chdir($dh) || $lei->fail("fchdir: $!");
1366 }
1367
1368 sub wq_eof { # EOF callback for main daemon
1369         my ($lei) = @_;
1370         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1371         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1372 }
1373
1374 sub watch_state_ok ($) {
1375         my ($state) = $_[-1]; # $_[0] may be $self
1376         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1377 }
1378
1379 sub cancel_maildir_watch ($$) {
1380         my ($d, $cfg_f) = @_;
1381         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1382         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1383                 delete $MDIR2CFGPATH->{$d};
1384         for my $x (@{$w // []}) { $x->cancel }
1385 }
1386
1387 sub add_maildir_watch ($$) {
1388         my ($d, $cfg_f) = @_;
1389         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1390                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1391                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1392         }
1393 }
1394
1395 sub refresh_watches {
1396         my ($lei) = @_;
1397         my $cfg = _lei_cfg($lei) or return;
1398         my $old = $cfg->{-watches};
1399         my $watches = $cfg->{-watches} //= {};
1400         my %seen;
1401         my $cfg_f = $cfg->{'-f'};
1402         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1403                 my $url = substr($w, length('watch.'), -length('.state'));
1404                 require PublicInbox::LeiWatch;
1405                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1406                 $seen{$url} = undef;
1407                 my $state = $cfg->get_1("watch.$url", 'state');
1408                 if (!watch_state_ok($state)) {
1409                         $lei->err("watch.$url.state=$state not supported");
1410                         next;
1411                 }
1412                 if ($url =~ /\Amaildir:(.+)/i) {
1413                         my $d = canonpath_harder($1);
1414                         if ($state eq 'pause') {
1415                                 cancel_maildir_watch($d, $cfg_f);
1416                         } else {
1417                                 add_maildir_watch($d, $cfg_f);
1418                         }
1419                 } else { # TODO: imap/nntp/jmap
1420                         $lei->child_error(1, "E: watch $url not supported, yet")
1421                 }
1422         }
1423
1424         # add all known Maildir folders as implicit watches
1425         my $sto = $lei->_lei_store;
1426         my $renames = 0;
1427         if (my $lms = $sto ? $sto->search->lms : undef) {
1428                 for my $d ($lms->folders('maildir:')) {
1429                         substr($d, 0, length('maildir:')) = '';
1430                         my $cd = canonpath_harder($d);
1431                         my $f = "maildir:$cd";
1432
1433                         # fixup old bugs while we're iterating:
1434                         if ($d ne $cd) {
1435                                 $sto->ipc_do('lms_rename_folder',
1436                                                 "maildir:$d", $f);
1437                                 ++$renames;
1438                         }
1439                         next if $watches->{$f}; # may be set to pause
1440                         require PublicInbox::LeiWatch;
1441                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1442                         $seen{$f} = undef;
1443                         add_maildir_watch($cd, $cfg_f);
1444                 }
1445         }
1446         $lei->sto_done_request if $renames;
1447         if ($old) { # cull old non-existent entries
1448                 for my $url (keys %$old) {
1449                         next if exists $seen{$url};
1450                         delete $old->{$url};
1451                         if ($url =~ /\Amaildir:(.+)/i) {
1452                                 my $d = canonpath_harder($1);
1453                                 cancel_maildir_watch($d, $cfg_f);
1454                         } else { # TODO: imap/nntp/jmap
1455                                 $lei->child_error(1, "E: watch $url TODO");
1456                         }
1457                 }
1458         }
1459         if (scalar keys %$watches) {
1460                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1461         } else {
1462                 delete $cfg->{-watches};
1463         }
1464 }
1465
1466 sub git_blob_id {
1467         my ($lei, $eml) = @_;
1468         ($lei->{sto} // _lei_store($lei, 1))->git_blob_id($eml);
1469 }
1470
1471 sub lms { # read-only LeiMailSync
1472         my ($lei) = @_;
1473         my $lse = $lei->{lse} // do {
1474                 my $sto = $lei->{sto} // _lei_store($lei);
1475                 $sto ? $sto->search : undef
1476         };
1477         $lse ? $lse->lms : undef;
1478 }
1479
1480 sub sto_done_request { # only call this from lei-daemon process (not workers)
1481         my ($lei, $sock) = @_;
1482         if ($sock //= $lei->{sock}) {
1483                 $LIVE_SOCK{"$sock"} = $sock;
1484                 $lei->{sto}->ipc_do('done', "$sock"); # issue, async wait
1485         } else { # forcibly wait
1486                 my $wait = $lei->{sto}->ipc_do('done');
1487         }
1488 }
1489
1490 sub sto_done_complete { # called in lei-daemon when LeiStore->done is complete
1491         my ($sock_str) = @_;
1492         delete $LIVE_SOCK{$sock_str}; # frees {sock} for waiting lei clients
1493 }
1494
1495 1;