lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub url_folder_cache {
 120         my ($self) = @_;
 121         require PublicInbox::SharedKV; # URI => updated_at_sec_
 122         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 123 }
 124
 125 sub ale {
 126         my ($self) = @_;
 127         $self->{ale} //= do {
 128                 require PublicInbox::LeiALE;
 129                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 130         };
 131 }
 132
 133 sub index_opt {
 134         # TODO: drop underscore variants everywhere, they're undocumented
 135         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 136         max_size|max-size=s sequential_shard|sequential-shard
 137         batch_size|batch-size=s skip-docdata)
 138 }
 139
 140 my @c_opt = qw(c=s@ C=s@ quiet|q);
 141 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 142         import-remote! no-torsocks torsocks=s),
 143         PublicInbox::LeiQuery::curl_opt());
 144
 145 # we don't support -C as an alias for --find-copies since it's already
 146 # used for chdir
 147 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 148         output-indicator-context=s indent-heuristic!
 149         minimal patience histogram anchored=s@ diff-algorithm=s
 150         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 151         word-diff:s word-diff-regex=s color-words:s no-renames
 152         rename-empty! check ws-error-highlight=s full-index binary
 153         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 154         find-copies-harder irreversible-delete|D l=i diff-filter=s
 155         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 156         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 157         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 158         inter-hunk-context=i function-context|W exit-code ext-diff
 159         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 160         line-prefix=s);
 161
 162 # we generate shell completion + help using %CMD and %OPTDESC,
 163 # see lei__complete() and PublicInbox::LeiHelp
 164 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 165 our %CMD = ( # sorted in order of importance/use:
 166 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 167         'stdin|', # /|\z/ must be first for lone dash
 168         @lxs_opt,
 169         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 170         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 171         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 172         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 173
 174 'up' => [ 'OUTPUT|--all', 'update saved search',
 175         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 176
 177 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 178         'stdin|', # /|\z/ must be first for lone dash
 179         # some of these options are ridiculous for lcat
 180         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 181         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 182         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 183         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 184
 185 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 186         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 187         @lxs_opt, @c_opt ],
 188
 189 'rediff' => [ '--stdin|LOCATION...',
 190                 'regenerate a diff with different options',
 191         'stdin|', # /|\z/ must be first for lone dash
 192         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 193         @diff_opt, @lxs_opt, @c_opt ],
 194
 195 'add-external' => [ 'LOCATION',
 196         'add/set priority of a publicinbox|extindex for extra matches',
 197         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 198         verbose|v+), @c_opt, index_opt(),
 199         PublicInbox::LeiQuery::curl_opt() ],
 200 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 201         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 202 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 203 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 204                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 205 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 206                 qw(z|0 ascii l url), @c_opt ],
 207 'forget-external' => [ 'LOCATION...|--prune',
 208         'exclude further results from a publicinbox|extindex',
 209         qw(prune), @c_opt ],
 210
 211 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 212                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 213 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 214                 qw(verbose|v+), @c_opt ],
 215 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 216                         @c_opt ],
 217 'rm' => [ '--stdin|LOCATION...',
 218         'remove a message from the index and prevent reindexing',
 219         'stdin|', # /|\z/ must be first for lone dash
 220         @c_opt ],
 221 'plonk' => [ '--threads|--from=IDENT',
 222         'exclude mail matching From: or threads from non-Message-ID searches',
 223         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 224 'tag' => [ 'KEYWORDS...',
 225         'set/unset keywords and/or labels on message(s)',
 226         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 227         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 228         pass_through('-kw:foo for delete') ],
 229
 230 'purge-mailsource' => [ 'LOCATION|--all',
 231         'remove imported messages from IMAP, Maildirs, and MH',
 232         qw(exact! all jobs:i indexed), @c_opt ],
 233
 234 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 235         qw(import! kw! interval=s recursive|r
 236         exclude=s include=s), @c_opt ],
 237 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 238                 qw(format|f=s z), @c_opt ],
 239 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 240 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 241 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 242         qw(prune), @c_opt ],
 243
 244 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 245         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 246         verbose|v+ incremental!),
 247          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 248          @c_opt ],
 249 'import' => [ 'LOCATION...|--stdin',
 250         'one-time import/update from URL or filesystem',
 251         qw(stdin| offset=i recursive|r exclude=s include|I=s jobs=s new-only
 252         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 253         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 254 'forget-mail-sync' => [ 'LOCATION...',
 255         'forget sync information for a mail folder', @c_opt ],
 256 'prune-mail-sync' => [ 'LOCATION...|--all',
 257         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 258 'export-kw' => [ 'LOCATION...|--all',
 259         'one-time export of keywords of sync sources',
 260         qw(all:s mode=s), @c_opt ],
 261 'convert' => [ 'LOCATION...|--stdin',
 262         'one-time conversion from URL or filesystem to another format',
 263         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 264         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 265 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 266         "use a patch to generate a query for `lei q --stdin'",
 267         qw(stdin| want|w=s@ uri debug), @c_opt ],
 268 'config' => [ '[...]', sub {
 269                 'git-config(1) wrapper for '._config_path($_[0]);
 270         }, qw(config-file|system|global|file|f=s), # for conflict detection
 271          qw(c=s@ C=s@), pass_through('git config') ],
 272 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 273         qw(pretty ascii dir=s), @c_opt ],
 274
 275 'init' => [ '[DIRNAME]', sub {
 276         "initialize storage, default: ".store_path($_[0]);
 277         }, @c_opt ],
 278 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 279         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 280         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 281 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 282 'help' => [ '[SUBCOMMAND]', 'show help' ],
 283
 284 # TODO
 285 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 286 #       'rewrite git history in an attempt to improve compression',
 287 #       qw(gc!), @c_opt ],
 288 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 289 #
 290 # internal commands are prefixed with '_'
 291 '_complete' => [ '[...]', 'internal shell completion helper',
 292                 pass_through('everything') ],
 293 ); # @CMD
 294
 295 # switch descriptions, try to keep consistent across commands
 296 # $spec: Getopt::Long option specification
 297 # $spec => [@ALLOWED_VALUES (default is first), $description],
 298 # $spec => $description
 299 # "$SUB_COMMAND TAB $spec" => as above
 300 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 301                         'specify message input format' ];
 302 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 303
 304 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 305 my %OPTDESC = (
 306 'help|h' => 'show this built-in help',
 307 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 308 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 309 'quiet|q' => 'be quiet',
 310 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 311         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 312
 313 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 314 'globoff|g' => "do not match locations using '*?' wildcards ".
 315                 "and\xa0'[]'\x{a0}ranges",
 316 'invert-match|v' => 'select non-matching lines',
 317 'color!' => 'disable color (for --format=text)',
 318 'verbose|v+' => 'be more verbose',
 319 'external!' => 'do not use externals',
 320 'mail!' => 'do not look in mail storage for OID',
 321 'cwd!' => 'do not look in git repo of current working directory',
 322 'oid-a|A=s' => 'pre-image OID',
 323 'path-a|a=s' => 'pre-image pathname associated with OID',
 324 'path-b|b=s' => 'post-image pathname associated with OID',
 325 'git-dir=s@' => 'additional git repository to scan',
 326 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 327         "proxy for (e.g. `socks5h://0:9050')" ],
 328 'torsocks=s' => ['VAL|auto|no|yes',
 329                 'whether or not to wrap git and curl commands with torsocks'],
 330 'no-torsocks' => 'alias for --torsocks=no',
 331 'save' =>  "save a search for `lei up'",
 332 'import-remote!' => 'do not memoize remote messages into local store',
 333
 334 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 335
 336 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 337                 'deduplication strategy'],
 338 'threads|t+' =>
 339         'return all messages in the same threads as the actual match(es)',
 340
 341 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 342                 'search prefixes to extract (default: dfpost7)' ],
 343
 344 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 345         'run command(s) or perform ops when done writing to output ' .
 346         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 347         'nothing otherwise)' ],
 348
 349 'augment|a' => 'augment --output destination instead of clobbering',
 350
 351 'output|mfolder|o=s' => [ 'MFOLDER',
 352         "destination (e.g.\xa0`/path/to/Maildir', ".
 353         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 354 'mua=s' => [ 'CMD',
 355         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 356 'new-only       import' => 'only import new messages from IMAP source',
 357
 358 'inbox-version=i' => [ 'NUM|1|2',
 359                 'force a public-inbox version with --mirror'],
 360 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 361
 362 # public-inbox-index options
 363 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 364 'compact' => 'run compact index after mirroring',
 365 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 366         "indexlevel with --mirror (default: full)" ],
 367 'max_size|max-size=s' => [ 'SIZE',
 368         'do not index messages larger than SIZE (default: infinity)' ],
 369 'batch_size|batch-size=s' => [ 'SIZE',
 370         'flush changes to OS after given number of bytes (default: 1m)' ],
 371 'sequential_shard|sequential-shard' =>
 372         'index Xapian shards sequentially for slow storage',
 373 'skip-docdata' =>
 374         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 375
 376 'format|f=s     q' => [
 377         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 378                 'specify output format, default depends on --output'],
 379 'exclude=s@     q' => [ 'LOCATION',
 380                 'exclude specified external(s) from search' ],
 381 'include|I=s@   q' => [ 'LOCATION',
 382                 'include specified external(s) in search' ],
 383 'only=s@        q' => [ 'LOCATION',
 384                 'only use specified external(s) for search' ],
 385 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 386                 'control number of search and writer jobs' ],
 387 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 388
 389 'in-format|F=s' => $stdin_formats,
 390 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 391                         'listing output format' ],
 392 'l      ls-search' => 'long listing format',
 393 'l      ls-mail-source' => 'long listing format',
 394 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 395 'format|f=s     ls-external' => $ls_format,
 396
 397 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 398 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 399
 400 'sort|s=s' => [ 'VAL|received|relevance|docid',
 401                 "order of results is `--output'-dependent"],
 402 'reverse|r' => 'reverse search results', # like sort(1)
 403
 404 'boost=i' => 'increase/decrease priority of results (default: 0)',
 405
 406 'local' => 'limit operations to the local filesystem',
 407 'local!' => 'exclude results from the local filesystem',
 408 'remote' => 'limit operations to those requiring network access',
 409 'remote!' => 'prevent operations requiring network access',
 410
 411 'all:s  up' => ['local', 'update all (local) saved searches' ],
 412
 413 'mid=s' => 'specify the Message-ID of a message',
 414 'oid=s' => 'specify the git object ID of a message',
 415
 416 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 417 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 418 'include=s' => 'include mailboxes/newsgroups based on pattern',
 419
 420 'exact' => 'operate on exact header matches only',
 421 'exact!' => 'rely on content match instead of exact header matches',
 422
 423 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 424
 425 'kw!' => 'disable/enable importing keywords (aka "flags")',
 426
 427 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 428 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 429
 430 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 431 ); # %OPTDESC
 432
 433 my %CONFIG_KEYS = (
 434         'leistore.dir' => 'top-level storage location',
 435 );
 436
 437 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1); # internal workers
 438
 439 sub _drop_wq {
 440         my ($self) = @_;
 441         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 442                 if ($wq->wq_kill) {
 443                         $wq->wq_close(0, undef, $self);
 444                 } elsif ($wq->wq_kill_old) {
 445                         $wq->wq_wait_old(undef, $self);
 446                 }
 447                 $wq->DESTROY;
 448         }
 449 }
 450
 451 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 452 sub x_it ($$) {
 453         my ($self, $code) = @_;
 454         # make sure client sees stdout before exit
 455         $self->{1}->autoflush(1) if $self->{1};
 456         dump_and_clear_log();
 457         stop_pager($self);
 458         if ($self->{pkt_op_p}) { # to top lei-daemon
 459                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 460         } elsif ($self->{sock}) { # to lei(1) client
 461                 send($self->{sock}, "x_it $code", MSG_EOR);
 462         } # else ignore if client disconnected
 463 }
 464
 465 sub err ($;@) {
 466         my $self = shift;
 467         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 468         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 469         print $err @_, @eor and return;
 470         my $old_err = delete $self->{2};
 471         close($old_err) if $! == EPIPE && $old_err;
 472         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 473         print $err @_, @eor or print STDERR @_, @eor;
 474 }
 475
 476 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 477
 478 sub fail_handler ($;$$) {
 479         my ($lei, $code, $io) = @_;
 480         close($io) if $io; # needed to avoid warnings on SIGPIPE
 481         _drop_wq($lei);
 482         x_it($lei, $code // (1 << 8));
 483 }
 484
 485 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 486         fail_handler($_[0], 13, delete $_[0]->{1});
 487 }
 488
 489 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 490 sub sigint_reap {
 491         my ($pgid) = @_;
 492         dwaitpid($pgid) if kill('-INT', $pgid);
 493 }
 494
 495 sub fail ($$;$) {
 496         my ($self, $buf, $exit_code) = @_;
 497         $self->{failed}++;
 498         err($self, $buf) if defined $buf;
 499         # calls fail_handler:
 500         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 501         x_it($self, ($exit_code // 1) << 8);
 502         undef;
 503 }
 504
 505 sub out ($;@) {
 506         my $self = shift;
 507         return if print { $self->{1} // return } @_; # likely
 508         return note_sigpipe($self, 1) if $! == EPIPE;
 509         my $err = "error writing to output: $!";
 510         delete $self->{1};
 511         fail($self, $err);
 512 }
 513
 514 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 515
 516 sub child_error { # passes non-fatal curl exit codes to user
 517         my ($self, $child_error, $msg) = @_; # child_error is $?
 518         $self->err($msg) if $msg;
 519         if ($self->{pkt_op_p}) { # to top lei-daemon
 520                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 521         } elsif ($self->{sock}) { # to lei(1) client
 522                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 523         } # else noop if client disconnected
 524 }
 525
 526 sub note_sigpipe { # triggers sigpipe_handler
 527         my ($self, $fd) = @_;
 528         close(delete($self->{$fd})); # explicit close silences Perl warning
 529         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 530         x_it($self, 13);
 531 }
 532
 533 sub _lei_atfork_child {
 534         my ($self, $persist) = @_;
 535         # we need to explicitly close things which are on stack
 536         if ($persist) {
 537                 chdir '/' or die "chdir(/): $!";
 538                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 539                 if (my $cfg = $self->{cfg}) {
 540                         delete $cfg->{-lei_store};
 541                 }
 542         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 543                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 544                 STDERR->autoflush(1);
 545         }
 546         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 547         if (my $op_c = delete $self->{pkt_op_c}) {
 548                 close(delete $op_c->{sock});
 549         }
 550         if (my $pgr = delete $self->{pgr}) {
 551                 close($_) for (@$pgr[1,2]);
 552         }
 553         close $listener if $listener;
 554         undef $listener;
 555         undef $dir_idle;
 556         %PATH2CFG = ();
 557         undef $errors_log;
 558         $quit = \&CORE::exit;
 559         $self->{-eml_noisy} or # only "lei import" sets this atm
 560                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 561         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 562 }
 563
 564 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 565         my ($self) = @_;
 566         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 567                 $op->close; # PublicInbox::PktOp::close
 568         }
 569         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 570         close $pkt_op_p->{op_p};
 571 }
 572
 573 sub pkt_op_pair {
 574         my ($self) = @_;
 575         require PublicInbox::OnDestroy;
 576         require PublicInbox::PktOp;
 577         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 578         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 579         $end;
 580 }
 581
 582 sub incr {
 583         my ($self, $field, $nr) = @_;
 584         $self->{counters}->{$field} += $nr;
 585 }
 586
 587 sub workers_start {
 588         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 589         $ops = {
 590                 '!' => [ \&fail_handler, $lei ],
 591                 '|' => [ \&sigpipe_handler, $lei ],
 592                 'x_it' => [ \&x_it, $lei ],
 593                 'child_error' => [ \&child_error, $lei ],
 594                 'incr' => [ \&incr, $lei ],
 595                 ($ops ? %$ops : ()),
 596         };
 597         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 598         my $end = $lei->pkt_op_pair;
 599         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 600         $flds->{lei} = $lei;
 601         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 602         delete $lei->{pkt_op_p};
 603         my $op_c = delete $lei->{pkt_op_c};
 604         @$end = ();
 605         $lei->event_step_init;
 606         ($op_c, $ops);
 607 }
 608
 609 # call this when we're ready to wait on events and yield to other clients
 610 sub wait_wq_events {
 611         my ($lei, $op_c, $ops) = @_;
 612         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 613                 $wq->wq_close(1);
 614         }
 615         $op_c->{ops} = $ops;
 616 }
 617
 618 sub _help {
 619         require PublicInbox::LeiHelp;
 620         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 621 }
 622
 623 sub optparse ($$$) {
 624         my ($self, $cmd, $argv) = @_;
 625         # allow _complete --help to complete, not show help
 626         return 1 if substr($cmd, 0, 1) eq '_';
 627         $self->{cmd} = $cmd;
 628         $OPT = $self->{opt} //= {};
 629         my $info = $CMD{$cmd} // [ '[...]' ];
 630         my ($proto, undef, @spec) = @$info;
 631         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 632         push @spec, qw(help|h);
 633         my $lone_dash;
 634         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 635                 $lone_dash = $spec[0];
 636                 $OPT->{$spec[0]} = \(my $var);
 637                 push @spec, '' => \$var;
 638         }
 639         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 640                 return _help($self, "bad arguments or options for $cmd");
 641         return _help($self) if $OPT->{help};
 642
 643         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 644
 645         # "-" aliases "stdin" or "clear"
 646         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 647
 648         my $i = 0;
 649         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 650         my ($err, $inf);
 651         my @args = split(/ /, $proto);
 652         for my $var (@args) {
 653                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 654                         $inf = defined($argv->[$i]) and last;
 655                         $var =~ s/\.\.\.\z//;
 656                         $err = "$var not supplied";
 657                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 658                         $argv->[$i++] // ($err = "$var not supplied");
 659                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 660                         $inf = 1;
 661                         last;
 662                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 663                         $i++;
 664                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 665                         $inf = 1 if index($var, '...') > 0;
 666                         my @or = split(/\|/, $var);
 667                         my $ok;
 668                         for my $o (@or) {
 669                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 670                                         my $sw = $1;
 671                                         # assume pipe/regular file on stdin
 672                                         # w/o args means stdin
 673                                         if ($sw eq 'stdin' && !@$argv &&
 674                                                         (-p $self->{0} ||
 675                                                          -f _) && -r _) {
 676                                                 $OPT->{stdin} //= 1;
 677                                         }
 678                                         $ok = defined($OPT->{$sw});
 679                                         last if $ok;
 680                                 } elsif (defined($argv->[$i])) {
 681                                         $ok = 1;
 682                                         $i++;
 683                                         last;
 684                                 } # else continue looping
 685                         }
 686                         last if $ok;
 687                         my $last = pop @or;
 688                         $err = join(', ', @or) . " or $last must be set";
 689                 } else {
 690                         warn "BUG: can't parse `$var' in $proto";
 691                 }
 692                 last if $err;
 693         }
 694         if (!$inf && scalar(@$argv) > scalar(@args)) {
 695                 $err //= 'too many arguments';
 696         }
 697         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 698 }
 699
 700 sub _tmp_cfg { # for lei -c <name>=<value> ...
 701         my ($self) = @_;
 702         my $cfg = _lei_cfg($self, 1);
 703         require File::Temp;
 704         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 705         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 706         $ft->autoflush(1);
 707         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 708 [include]
 709         path = $cfg->{-f}
 710 EOM
 711         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 712         for (@{$self->{opt}->{c}}) {
 713                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 714 `-c $_' is not of the form -c <name>=<value>'
 715 EOM
 716                 my $name = $1;
 717                 my $value = $2 // 1;
 718                 _config($self, '--add', $name, $value);
 719                 if (defined(my $v = $tmp->{$name})) {
 720                         if (ref($v) eq 'ARRAY') {
 721                                 push @$v, $value;
 722                         } else {
 723                                 $tmp->{$name} = [ $v, $value ];
 724                         }
 725                 } else {
 726                         $tmp->{$name} = $value;
 727                 }
 728         }
 729 }
 730
 731 sub lazy_cb ($$$) {
 732         my ($self, $cmd, $pfx) = @_;
 733         my $ucmd = $cmd;
 734         $ucmd =~ tr/-/_/;
 735         my $cb;
 736         $cb = $self->can($pfx.$ucmd) and return $cb;
 737         my $base = $ucmd;
 738         $base =~ s/_([a-z])/\u$1/g;
 739         my $pkg = "PublicInbox::Lei\u$base";
 740         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 741                 $pkg->can($pfx.$ucmd) : undef;
 742 }
 743
 744 sub dispatch {
 745         my ($self, $cmd, @argv) = @_;
 746         local $current_lei = $self; # for __WARN__
 747         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 748         dump_and_clear_log("from previous run\n");
 749         return _help($self, 'no command given') unless defined($cmd);
 750         # do not support Getopt bundling for this
 751         while ($cmd eq '-C' || $cmd eq '-c') {
 752                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 753                                         '-C DIRECTORY' : '-c <name>=<value>');
 754                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 755                 $cmd = shift(@argv) // return _help($self, 'no command given');
 756         }
 757         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 758                 optparse($self, $cmd, \@argv) or return;
 759                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 760                 if (my $chdir = $self->{opt}->{C}) {
 761                         for my $d (@$chdir) {
 762                                 next if $d eq ''; # same as git(1)
 763                                 chdir $d or return fail($self, "cd $d: $!");
 764                         }
 765                         if (delete $self->{3}) { # update cwd for rel2abs
 766                                 opendir my $dh, '.' or
 767                                         return fail($self, "opendir . $!");
 768                                 $self->{3} = $dh;
 769                         }
 770                 }
 771                 $cb->($self, @argv);
 772         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 773                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 774                         or return _help($self, 'bad arguments or options');
 775                 _help($self);
 776         } else {
 777                 fail($self, "`$cmd' is not an lei command");
 778         }
 779 }
 780
 781 sub _lei_cfg ($;$) {
 782         my ($self, $creat) = @_;
 783         return $self->{cfg} if $self->{cfg};
 784         my $f = _config_path($self);
 785         my @st = stat($f);
 786         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 787         my ($sto, $sto_dir);
 788         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 789                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 790                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 791         }
 792         if (!@st) {
 793                 unless ($creat) {
 794                         delete $self->{cfg};
 795                         return bless {}, 'PublicInbox::Config';
 796                 }
 797                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 798                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 799                 open my $fh, '>>', $f or die "open($f): $!\n";
 800                 @st = stat($fh) or die "fstat($f): $!\n";
 801                 $cur_st = pack('dd', $st[10], $st[7]);
 802                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 803         }
 804         my $cfg = PublicInbox::Config->git_config_dump($f);
 805         $cfg->{-st} = $cur_st;
 806         $cfg->{'-f'} = $f;
 807         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 808                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 809                                                 store_path($self))) {
 810                 $cfg->{-lei_store} = $sto;
 811         }
 812         if (scalar(keys %PATH2CFG) > 5) {
 813                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 814                 for my $k (keys %PATH2CFG) {
 815                         delete($PATH2CFG{$k}) unless -f $k
 816                 }
 817         }
 818         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 819 }
 820
 821 sub _lei_store ($;$) {
 822         my ($self, $creat) = @_;
 823         my $cfg = _lei_cfg($self, $creat);
 824         $cfg->{-lei_store} //= do {
 825                 require PublicInbox::LeiStore;
 826                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 827                 return unless $creat || -d $dir;
 828                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 829         };
 830 }
 831
 832 sub _config {
 833         my ($self, @argv) = @_;
 834         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 835         my $cfg = _lei_cfg($self, 1);
 836         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 837         my %rdr = map { $_ => $self->{$_} } (0..2);
 838         waitpid(spawn($cmd, \%env, \%rdr), 0);
 839 }
 840
 841 sub lei_config {
 842         my ($self, @argv) = @_;
 843         $self->{opt}->{'config-file'} and return fail $self,
 844                 "config file switches not supported by `lei config'";
 845         _config(@_);
 846         x_it($self, $?) if $?;
 847 }
 848
 849 sub lei_daemon_pid { puts shift, $$ }
 850
 851 sub lei_daemon_kill {
 852         my ($self) = @_;
 853         my $sig = $self->{opt}->{signal} // 'TERM';
 854         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 855 }
 856
 857 # Shell completion helper.  Used by lei-completion.bash and hopefully
 858 # other shells.  Try to do as much here as possible to avoid redundancy
 859 # and improve maintainability.
 860 sub lei__complete {
 861         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 862         shift @argv; # ignore "lei", the entire command is sent
 863         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 864         my $cmd = shift @argv;
 865         my $info = $CMD{$cmd} // do { # filter matching commands
 866                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 867                 return;
 868         };
 869         my ($proto, undef, @spec) = @$info;
 870         my $cur = pop @argv;
 871         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 872         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 873                 # gross special case since the only git-config options
 874                 # Consider moving to a table if we need more special cases
 875                 # we use Getopt::Long for are the ones we reject, so these
 876                 # are the ones we don't reject:
 877                 if ($cmd eq 'config') {
 878                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 879                         @spec = qw(add z|null get get-all unset unset-all
 880                                 replace-all get-urlmatch
 881                                 remove-section rename-section
 882                                 name-only list|l edit|e
 883                                 get-color-name get-colorbool);
 884                         # fall-through
 885                 }
 886                 # generate short/long names from Getopt::Long specs
 887                 puts $self, grep(/$re/, qw(--help -h -C), map {
 888                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 889                         } elsif (s/\+\z//) { # verbose|v+
 890                         } elsif (s/!\z//) {
 891                                 # negation: mail! => no-mail|mail
 892                                 s/([\w\-]+)/$1|no-$1/g
 893                         }
 894                         map {
 895                                 my $x = length > 1 ? "--$_" : "-$_";
 896                                 $x eq $_cur ? () : $x;
 897                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 898                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 899         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 900                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 901         }
 902
 903         # switch args (e.g. lei q -f mbox<TAB>)
 904         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 905                 my $opt = quotemeta $1;
 906                 puts $self, map {
 907                         my $v = $OPTDESC{$_};
 908                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 909                         # get rid of ALL CAPS placeholder (e.g "OUT")
 910                         # (TODO: completion for external paths)
 911                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 912                         @v;
 913                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 914         }
 915         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 916                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 917         }
 918         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 919         # proto parsing.
 920 }
 921
 922 sub exec_buf ($$) {
 923         my ($argv, $env) = @_;
 924         my $argc = scalar @$argv;
 925         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 926         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 927         $buf;
 928 }
 929
 930 sub start_mua {
 931         my ($self) = @_;
 932         my $mua = $self->{opt}->{mua} // return;
 933         my $mfolder = $self->{ovv}->{dst};
 934         my (@cmd, $replaced);
 935         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 936                 @cmd = ($mua, '-f');
 937         # TODO: help wanted: other common FOSS MUAs
 938         } else {
 939                 require Text::ParseWords;
 940                 @cmd = Text::ParseWords::shellwords($mua);
 941                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 942                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 943         }
 944         push @cmd, $mfolder unless defined($replaced);
 945         if ($self->{sock}) { # lei(1) client process runs it
 946                 # restore terminal: echo $query | lei q --stdin --mua=...
 947                 my $io = [];
 948                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 949                 send_exec_cmd($self, $io, \@cmd, {});
 950         }
 951         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 952                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 953         }
 954         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 955         $self->{opt}->{quiet} = 1;
 956         delete $self->{-progress};
 957         delete $self->{opt}->{verbose};
 958 }
 959
 960 sub send_exec_cmd { # tell script/lei to execute a command
 961         my ($self, $io, $cmd, $env) = @_;
 962         my $sock = $self->{sock} // die 'lei client gone';
 963         my $fds = [ map { fileno($_) } @$io ];
 964         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 965 }
 966
 967 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 968         my ($self) = @_;
 969         my $alerts = $self->{opt}->{alert} // return;
 970         my $sock = $self->{sock};
 971         while (my $op = shift(@$alerts)) {
 972                 if ($op eq ':WINCH') {
 973                         # hit the process group that started the MUA
 974                         send($sock, '-WINCH', MSG_EOR) if $sock;
 975                 } elsif ($op eq ':bell') {
 976                         out($self, "\a");
 977                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 978                         push @$alerts, split(/(?<!\\),/, $op);
 979                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 980                         my $cmd = $1; # run an arbitrary command
 981                         require Text::ParseWords;
 982                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 983                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 984                 } else {
 985                         err($self, "W: unsupported --alert=$op"); # non-fatal
 986                 }
 987         }
 988 }
 989
 990 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 991 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 992
 993 # this also normalizes the path
 994 sub path_to_fd {
 995         my ($self, $path) = @_;
 996         $path = rel2abs($self, $path);
 997         $path =~ tr!/!/!s;
 998         $path_to_fd{$path} // (
 999                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1000                         fail($self, "cannot open $path from daemon") : -1
1001         );
1002 }
1003
1004 # caller needs to "-t $self->{1}" to check if tty
1005 sub start_pager {
1006         my ($self) = @_;
1007         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1008         chomp(my $pager = <$fh> // '');
1009         close($fh) or warn "`git var PAGER' error: \$?=$?";
1010         return if $pager eq 'cat' || $pager eq '';
1011         my $new_env = { LESS => 'FRX', LV => '-c' };
1012         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1013         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1014         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1015         my $pgr = [ undef, @$rdr{1, 2} ];
1016         my $env = $self->{env};
1017         if ($self->{sock}) { # lei(1) process runs it
1018                 delete @$new_env{keys %$env}; # only set iff unset
1019                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1020         } else {
1021                 die 'BUG: start_pager w/o socket';
1022         }
1023         $self->{1} = $wpager;
1024         $self->{2} = $wpager if -t $self->{2};
1025         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1026         $self->{pgr} = $pgr;
1027 }
1028
1029 sub stop_pager {
1030         my ($self) = @_;
1031         my $pgr = delete($self->{pgr}) or return;
1032         $self->{2} = $pgr->[2];
1033         # do not restore original stdout, just close it so we error out
1034         close(delete($self->{1})) if $self->{1};
1035 }
1036
1037 sub accept_dispatch { # Listener {post_accept} callback
1038         my ($sock) = @_; # ignore other
1039         $sock->autoflush(1);
1040         my $self = bless { sock => $sock }, __PACKAGE__;
1041         vec(my $rvec = '', fileno($sock), 1) = 1;
1042         select($rvec, undef, undef, 60) or
1043                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1044         # (4096 * 33) >MAX_ARG_STRLEN
1045         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1046         if (!defined($fds[0])) {
1047                 warn(my $msg = "recv_cmd failed: $!");
1048                 return send($sock, $msg, MSG_EOR);
1049         } else {
1050                 my $i = 0;
1051                 for my $fd (@fds) {
1052                         open($self->{$i++}, '+<&=', $fd) and next;
1053                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1054                 }
1055                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1056         }
1057         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1058         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1059         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1060                 return send($sock, 'request command truncated', MSG_EOR);
1061         my ($argc, @argv) = split(/\0/, $buf, -1);
1062         undef $buf;
1063         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1064         if (chdir($self->{3})) {
1065                 local %ENV = %env;
1066                 $self->{env} = \%env;
1067                 eval { dispatch($self, @argv) };
1068                 send($sock, $@, MSG_EOR) if $@;
1069         } else {
1070                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1071         }
1072 }
1073
1074 sub dclose {
1075         my ($self) = @_;
1076         delete $self->{-progress};
1077         _drop_wq($self) if $self->{failed};
1078         close(delete $self->{1}) if $self->{1}; # may reap_compress
1079         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1080 }
1081
1082 # for long-running results
1083 sub event_step {
1084         my ($self) = @_;
1085         local %ENV = %{$self->{env}};
1086         my $sock = $self->{sock};
1087         local $current_lei = $self;
1088         eval {
1089                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1090                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1091                                 return if $! == EAGAIN;
1092                                 next if $! == EINTR;
1093                                 last if $! == ECONNRESET;
1094                                 die "recvmsg: $!";
1095                         }
1096                         for my $fd (@fds) {
1097                                 open my $rfh, '+<&=', $fd;
1098                         }
1099                         die "unrecognized client signal: $buf";
1100                 }
1101                 dclose($self);
1102         };
1103         if (my $err = $@) {
1104                 eval { $self->fail($err) };
1105                 dclose($self);
1106         }
1107 }
1108
1109 sub event_step_init {
1110         my ($self) = @_;
1111         my $sock = $self->{sock} or return;
1112         $self->{-event_init_done} //= do { # persist til $ops done
1113                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1114                 $sock;
1115         };
1116 }
1117
1118 sub noop {}
1119
1120 sub oldset { $oldset }
1121
1122 sub dump_and_clear_log {
1123         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1124                 my @pfx = @_;
1125                 unshift(@pfx, "$errors_log ") if @pfx;
1126                 warn @pfx, do { local $/; <STDIN> };
1127                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1128         }
1129 }
1130
1131 # lei(1) calls this when it can't connect
1132 sub lazy_start {
1133         my ($path, $errno, $narg) = @_;
1134         local ($errors_log, $listener);
1135         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1136         $errors_log = "$sock_dir/errors.log";
1137         my $addr = pack_sockaddr_un($path);
1138         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1139         $lk->lock_acquire;
1140         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1141         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1142                 return if connect($listener, $addr); # another process won
1143                 if ($errno == ECONNREFUSED && -S $path) {
1144                         unlink($path) or die "unlink($path): $!";
1145                 }
1146         } else {
1147                 $! = $errno; # allow interpolation to stringify in die
1148                 die "connect($path): $!";
1149         }
1150         umask(077) // die("umask(077): $!");
1151         bind($listener, $addr) or die "bind($path): $!";
1152         listen($listener, 1024) or die "listen: $!";
1153         $lk->lock_release;
1154         undef $lk;
1155         my @st = stat($path) or die "stat($path): $!";
1156         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1157         local $oldset = PublicInbox::DS::block_signals();
1158         if ($narg == 5) {
1159                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1160                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1161                         require PublicInbox::CmdIPC4;
1162                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1163                         PublicInbox::CmdIPC4->can('recv_cmd4');
1164                 };
1165         }
1166         $recv_cmd or die <<"";
1167 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1168
1169         require PublicInbox::Listener;
1170         require PublicInbox::PktOp;
1171         (-p STDOUT) or die "E: stdout must be a pipe\n";
1172         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1173         STDIN->autoflush(1);
1174         dump_and_clear_log("from previous daemon process:\n");
1175         POSIX::setsid() > 0 or die "setsid: $!";
1176         my $pid = fork // die "fork: $!";
1177         return if $pid;
1178         $0 = "lei-daemon $path";
1179         local %PATH2CFG;
1180         $listener->blocking(0);
1181         my $exit_code;
1182         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1183         local $quit = do {
1184                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1185                 sub {
1186                         $exit_code //= shift;
1187                         my $lis = $pil or exit($exit_code);
1188                         # closing eof_p triggers \&noop wakeup
1189                         $listener = $eof_p = $pil = $path = undef;
1190                         $lis->close; # DS::close
1191                         PublicInbox::DS->SetLoopTimeout(1000);
1192                 };
1193         };
1194         my $sig = {
1195                 CHLD => \&PublicInbox::DS::enqueue_reap,
1196                 QUIT => $quit,
1197                 INT => $quit,
1198                 TERM => $quit,
1199                 HUP => \&noop,
1200                 USR1 => \&noop,
1201                 USR2 => \&noop,
1202         };
1203         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1204         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1205         undef $sig;
1206         local $SIG{PIPE} = 'IGNORE';
1207         require PublicInbox::DirIdle;
1208         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1209                 # just rely on wakeup ot hit PostLoopCallback set below
1210                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1211         }, 1);
1212         if ($sigfd) {
1213                 undef $sigfd; # unref, already in DS::DescriptorMap
1214         } else {
1215                 # wake up every second to accept signals if we don't
1216                 # have signalfd or IO::KQueue:
1217                 PublicInbox::DS::sig_setmask($oldset);
1218                 PublicInbox::DS->SetLoopTimeout(1000);
1219         }
1220         PublicInbox::DS->SetPostLoopCallback(sub {
1221                 my ($dmap, undef) = @_;
1222                 if (@st = defined($path) ? stat($path) : ()) {
1223                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1224                                 warn "$path dev/ino changed, quitting\n";
1225                                 $path = undef;
1226                         }
1227                 } elsif (defined($path)) { # ENOENT is common
1228                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1229                         undef $path;
1230                         $quit->();
1231                 }
1232                 return 1 if defined($path);
1233                 my $now = now();
1234                 my $n = 0;
1235                 for my $s (values %$dmap) {
1236                         $s->can('busy') or next;
1237                         if ($s->busy($now)) {
1238                                 ++$n;
1239                         } else {
1240                                 $s->close;
1241                         }
1242                 }
1243                 $n; # true: continue, false: stop
1244         });
1245
1246         # STDIN was redirected to /dev/null above, closing STDERR and
1247         # STDOUT will cause the calling `lei' client process to finish
1248         # reading the <$daemon> pipe.
1249         local $SIG{__WARN__} = sub {
1250                 $current_lei ? err($current_lei, @_) : warn(
1251                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1252         };
1253         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1254         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1255         # $daemon pipe to `lei' closed, main loop begins:
1256         PublicInbox::DS->EventLoop;
1257         exit($exit_code // 0);
1258 }
1259
1260 sub busy { 1 } # prevent daemon-shutdown if client is connected
1261
1262 # ensures stdout hits the FS before sock disconnects so a client
1263 # can immediately reread it
1264 sub DESTROY {
1265         my ($self) = @_;
1266         if (my $counters = delete $self->{counters}) {
1267                 for my $k (sort keys %$counters) {
1268                         my $nr = $counters->{$k};
1269                         $self->child_error(1 << 8, "$nr $k messages");
1270                 }
1271         }
1272         $self->{1}->autoflush(1) if $self->{1};
1273         stop_pager($self);
1274         # preserve $? for ->fail or ->x_it code
1275 }
1276
1277 sub wq_done_wait { # dwaitpid callback
1278         my ($arg, $pid) = @_;
1279         my ($wq, $lei) = @$arg;
1280         my $err_type = $lei->{-err_type};
1281         $? and $lei->child_error($?,
1282                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1283         $lei->dclose;
1284 }
1285
1286 sub fchdir {
1287         my ($lei) = @_;
1288         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1289         chdir($dh) || $lei->fail("fchdir: $!");
1290 }
1291
1292 sub wq_eof { # EOF callback for main daemon
1293         my ($lei) = @_;
1294         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1295         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1296 }
1297
1298 1;