lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Fcntl qw(SEEK_SET);
  19 use Sys::Syslog qw(syslog openlog);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote! local! external! pretty mua-cmd=s
  87         torsocks=s no-torsocks verbose|v since|after=s until|before=s),
  88         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
  89
  90 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  91         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  92         pass_through('git show') ],
  93
  94 'add-external' => [ 'URL_OR_PATHNAME',
  95         'add/set priority of a publicinbox|extindex for extra matches',
  96         qw(boost=i quiet|q) ],
  97 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  98         qw(format|f=s z|0 local remote quiet|q) ],
  99 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 100         'exclude further results from a publicinbox|extindex',
 101         qw(prune quiet|q) ],
 102
 103 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 104                 qw(name-only format|f=s z) ],
 105 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 106 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 107
 108 'plonk' => [ '--thread|--from=IDENT',
 109         'exclude mail matching From: or thread from non-Message-ID searches',
 110         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 111 'mark' => [ 'MESSAGE_FLAGS...',
 112         'set/unset flags on message(s) from stdin',
 113         qw(stdin| oid=s exact by-mid|mid:s) ],
 114 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 115         "exclude message(s) on stdin from `q' search results",
 116         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 117
 118 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 119         'remove imported messages from IMAP, Maildirs, and MH',
 120         qw(exact! all jobs:i indexed) ],
 121
 122 # code repos are used for `show' to solve blobs from patch mails
 123 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 124         qw(boost=i) ],
 125 'ls-coderepo' => [ '[FILTER_TERMS...]',
 126                 'list known code repos', qw(format|f=s z) ],
 127 'forget-coderepo' => [ 'PATHNAME',
 128         'stop using repo to solve blobs from patches',
 129         qw(prune) ],
 130
 131 'add-watch' => [ '[URL_OR_PATHNAME]',
 132                 'watch for new messages and flag changes',
 133         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 134 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 135                 qw(format|f=s z) ],
 136 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 138 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 139         qw(prune) ],
 140
 141 'import' => [ 'URL_OR_PATHNAME|--stdin',
 142         'one-shot import/update from URL or filesystem',
 143         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 144         ],
 145
 146 'config' => [ '[...]', sub {
 147                 'git-config(1) wrapper for '._config_path($_[0]);
 148         }, qw(config-file|system|global|file|f=s), # for conflict detection
 149         pass_through('git config') ],
 150 'init' => [ '[PATHNAME]', sub {
 151                 'initialize storage, default: '._store_path($_[0]);
 152         }, qw(quiet|q) ],
 153 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 154         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 155 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 156 'help' => [ '[SUBCOMMAND]', 'show help' ],
 157
 158 # XXX do we need this?
 159 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 160
 161 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 162         'rewrite git history in an attempt to improve compression',
 163         'gc!' ],
 164
 165 # internal commands are prefixed with '_'
 166 '_complete' => [ '[...]', 'internal shell completion helper',
 167                 pass_through('everything') ],
 168 ); # @CMD
 169
 170 # switch descriptions, try to keep consistent across commands
 171 # $spec: Getopt::Long option specification
 172 # $spec => [@ALLOWED_VALUES (default is first), $description],
 173 # $spec => $description
 174 # "$SUB_COMMAND TAB $spec" => as above
 175 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 176                 'specify message input format' ];
 177 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 178
 179 my %OPTDESC = (
 180 'help|h' => 'show this built-in help',
 181 'quiet|q' => 'be quiet',
 182 'solve!' => 'do not attempt to reconstruct blobs from emails',
 183 'save-as=s' => ['NAME', 'save a search terms by given name'],
 184
 185 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 186
 187 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 188                 'deduplication strategy'],
 189 'show   thread|t' => 'display entire thread a message belongs to',
 190 'q      thread|t' =>
 191         'return all messages in the same thread as the actual match(es)',
 192 'augment|a' => 'augment --output destination instead of clobbering',
 193
 194 'output|o=s' => [ 'DEST',
 195         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 196 'mua-cmd|mua=s' => [ 'COMMAND',
 197         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 198
 199 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 200                         'message/object output format' ],
 201 'mark   format|f=s' => $stdin_formats,
 202 'forget format|f=s' => $stdin_formats,
 203 'q      format|f=s' => [
 204         'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|json|jsonl|concatjson',
 205                 'specify output format, default depends on --output'],
 206 'ls-query       format|f=s' => $ls_format,
 207 'ls-external    format|f=s' => $ls_format,
 208
 209 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 210 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 211
 212 'sort|s=s' => [ 'VAL|received,relevance,docid',
 213                 "order of results `--output'-dependent"],
 214 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 215
 216 'boost=i' => 'increase/decrease priority of results (default: 0)',
 217
 218 'local' => 'limit operations to the local filesystem',
 219 'local!' => 'exclude results from the local filesystem',
 220 'remote' => 'limit operations to those requiring network access',
 221 'remote!' => 'prevent operations requiring network access',
 222
 223 'mid=s' => 'specify the Message-ID of a message',
 224 'oid=s' => 'specify the git object ID of a message',
 225
 226 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 227 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 228 'include=s' => 'include mailboxes/newsgroups based on pattern',
 229
 230 'exact' => 'operate on exact header matches only',
 231 'exact!' => 'rely on content match instead of exact header matches',
 232
 233 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 234 'jobs:i' => 'set parallelism level',
 235
 236 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 237 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 238
 239 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 240 ); # %OPTDESC
 241
 242 my %CONFIG_KEYS = (
 243         'leistore.dir' => 'top-level storage location',
 244 );
 245
 246 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 247 sub x_it ($$) {
 248         my ($self, $code) = @_;
 249         # make sure client sees stdout before exit
 250         $self->{1}->autoflush(1) if $self->{1};
 251         dump_and_clear_log();
 252         if (my $sock = $self->{sock}) {
 253                 send($sock, "x_it $code", MSG_EOR);
 254         } elsif (!($code & 127)) { # oneshot, ignore signals
 255                 # don't want to end up using $? from child processes
 256                 for my $f (qw(lxs l2m)) {
 257                         my $wq = delete $self->{$f} or next;
 258                         $wq->DESTROY;
 259                 }
 260                 $quit->($code >> 8);
 261         }
 262 }
 263
 264 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 265
 266 sub out ($;@) { print { shift->{1} } @_ }
 267
 268 sub err ($;@) {
 269         my $self = shift;
 270         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 271         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 272 }
 273
 274 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 275
 276 sub fail ($$;$) {
 277         my ($self, $buf, $exit_code) = @_;
 278         err($self, $buf);
 279         x_it($self, ($exit_code // 1) << 8);
 280         undef;
 281 }
 282
 283 sub child_error { # passes non-fatal curl exit codes to user
 284         my ($self, $child_error) = @_; # child_error is $?
 285         if (my $sock = $self->{sock}) { # send to lei(1) client
 286                 send($sock, "child_error $child_error", MSG_EOR);
 287         } else { # oneshot
 288                 $self->{child_error} = $child_error;
 289         }
 290         undef;
 291 }
 292
 293 sub atfork_prepare_wq {
 294         my ($self, $wq) = @_;
 295         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 296         if (my $sock = $self->{sock}) {
 297                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 298         }
 299         if (my $pgr = $self->{pgr}) {
 300                 push @$tcafc, @$pgr[1,2];
 301         }
 302         if (my $old_1 = $self->{old_1}) {
 303                 push @$tcafc, $old_1;
 304         }
 305         for my $f (qw(lxs l2m)) {
 306                 my $ipc = $self->{$f} or next;
 307                 push @$tcafc, grep { defined }
 308                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 309         }
 310 }
 311
 312 # usage: my %sig = $lei->atfork_child_wq($wq);
 313 #        local @SIG{keys %sig} = values %sig;
 314 sub atfork_child_wq {
 315         my ($self, $wq) = @_;
 316         my ($sock, $l2m_wq_s1);
 317         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 318         $self->{sock} = $sock if -S $sock;
 319         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 320         %PATH2CFG = ();
 321         undef $errors_log;
 322         $quit = \&CORE::exit;
 323         (__WARN__ => sub { err($self, @_) },
 324         PIPE => sub {
 325                 $self->x_it(13); # SIGPIPE = 13
 326                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 327                 for my $i (1, 2) {
 328                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 329                         close(delete $self->{$i});
 330                 }
 331                 # trigger the LeiXSearch $done OpPipe:
 332                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 333                 $SIG{PIPE} = 'DEFAULT';
 334                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 335         });
 336 }
 337
 338 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 339 sub atfork_parent_wq {
 340         my ($self, $wq) = @_;
 341         my $env = delete $self->{env}; # env is inherited at fork
 342         my $ret = bless { %$self }, ref($self);
 343         if (my $dedupe = delete $ret->{dedupe}) {
 344                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 345         }
 346         $self->{env} = $env;
 347         delete @$ret{qw(-lei_store cfg old_1 pgr lxs)}; # keep l2m
 348         my @io = delete @$ret{0..2};
 349         $io[3] = delete($ret->{sock}) // $io[2];
 350         my $l2m = $ret->{l2m};
 351         if ($l2m && $l2m != $wq) { # $wq == lxs
 352                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 353                 $l2m->wq_close(1);
 354         }
 355         ($ret, @io);
 356 }
 357
 358 sub _help ($;$) {
 359         my ($self, $errmsg) = @_;
 360         my $cmd = $self->{cmd} // 'COMMAND';
 361         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 362         my @top = ($cmd, shift(@info) // ());
 363         my $cmd_desc = shift(@info);
 364         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 365         my @opt_desc;
 366         my $lpad = 2;
 367         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 368                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 369                 my $arg_vals = '';
 370                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 371
 372                 # lower-case is a keyword (e.g. `content', `oid'),
 373                 # ALL_CAPS is a string description (e.g. `PATH')
 374                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 375                         $desc .= "\ndefault: `$1'";
 376                 }
 377                 my (@vals, @s, @l);
 378                 my $x = $sw;
 379                 if ($x =~ s/!\z//) { # solve! => --no-solve
 380                         $x = "no-$x";
 381                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 382                         @vals = (' [', undef, ']');
 383                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 384                         @vals = (' ', undef);
 385                 } # else: no args $x = 'thread|t'
 386                 for (split(/\|/, $x)) { # help|h
 387                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 388                 }
 389                 if (!scalar(@vals)) { # no args 'thread|t'
 390                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 391                         $vals[1] = $1;
 392                 } else {
 393                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 394                 }
 395                 if ($arg_vals =~ /([,\|])/) {
 396                         my $sep = $1;
 397                         my @allow = split(/\Q$sep\E/, $arg_vals);
 398                         my $must = $sep eq '|' ? 'Must' : 'Can';
 399                         @allow = map { "`$_'" } @allow;
 400                         my $last = pop @allow;
 401                         $desc .= "\n$must be one of: " .
 402                                 join(', ', @allow) . " or $last";
 403                 }
 404                 my $lhs = join(', ', @s, @l) . join('', @vals);
 405                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 406                         $lhs =~ s/\A--/- , --/;
 407                 } else {
 408                         $lhs =~ s/\A--/    --/; # pad if no short options
 409                 }
 410                 $lpad = length($lhs) if length($lhs) > $lpad;
 411                 push @opt_desc, $lhs, $desc;
 412         }
 413         my $msg = $errmsg ? "E: $errmsg\n" : '';
 414         $msg .= <<EOF;
 415 usage: lei @top
 416   $cmd_desc
 417
 418 EOF
 419         $lpad += 2;
 420         local $Text::Wrap::columns = 78 - $lpad;
 421         my $padding = ' ' x ($lpad + 2);
 422         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 423                 $msg .= '  '.pack("A$lpad", $lhs);
 424                 $rhs = wrap('', '', $rhs);
 425                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 426                 $msg .= $rhs;
 427                 $msg .= "\n";
 428         }
 429         print { $self->{$errmsg ? 2 : 1} } $msg;
 430         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 431         undef;
 432 }
 433
 434 sub optparse ($$$) {
 435         my ($self, $cmd, $argv) = @_;
 436         $self->{cmd} = $cmd;
 437         $OPT = $self->{opt} = {};
 438         my $info = $CMD{$cmd} // [ '[...]' ];
 439         my ($proto, undef, @spec) = @$info;
 440         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 441         push @spec, qw(help|h);
 442         my $lone_dash;
 443         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 444                 $lone_dash = $spec[0];
 445                 $OPT->{$spec[0]} = \(my $var);
 446                 push @spec, '' => \$var;
 447         }
 448         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 449                 return _help($self, "bad arguments or options for $cmd");
 450         return _help($self) if $OPT->{help};
 451
 452         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 453
 454         # "-" aliases "stdin" or "clear"
 455         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 456
 457         my $i = 0;
 458         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 459         my ($err, $inf);
 460         my @args = split(/ /, $proto);
 461         for my $var (@args) {
 462                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 463                         $inf = defined($argv->[$i]) and last;
 464                         $var =~ s/\.\.\.\z//;
 465                         $err = "$var not supplied";
 466                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 467                         $argv->[$i++] // ($err = "$var not supplied");
 468                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 469                         $inf = 1;
 470                         last;
 471                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 472                         $i++;
 473                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 474                         my @or = split(/\|/, $var);
 475                         my $ok;
 476                         for my $o (@or) {
 477                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 478                                         $ok = defined($OPT->{$1});
 479                                         last;
 480                                 } elsif (defined($argv->[$i])) {
 481                                         $ok = 1;
 482                                         $i++;
 483                                         last;
 484                                 } # else continue looping
 485                         }
 486                         last if $ok;
 487                         my $last = pop @or;
 488                         $err = join(', ', @or) . " or $last must be set";
 489                 } else {
 490                         warn "BUG: can't parse `$var' in $proto";
 491                 }
 492                 last if $err;
 493         }
 494         if (!$inf && scalar(@$argv) > scalar(@args)) {
 495                 $err //= 'too many arguments';
 496         }
 497         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 498 }
 499
 500 sub dispatch {
 501         my ($self, $cmd, @argv) = @_;
 502         local $current_lei = $self; # for __WARN__
 503         dump_and_clear_log("from previous run\n");
 504         return _help($self, 'no command given') unless defined($cmd);
 505         my $func = "lei_$cmd";
 506         $func =~ tr/-/_/;
 507         if (my $cb = __PACKAGE__->can($func)) {
 508                 optparse($self, $cmd, \@argv) or return;
 509                 $cb->($self, @argv);
 510         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 511                 my $opt = {};
 512                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 513                         return _help($self, 'bad arguments or options');
 514                 _help($self);
 515         } else {
 516                 fail($self, "`$cmd' is not an lei command");
 517         }
 518 }
 519
 520 sub _lei_cfg ($;$) {
 521         my ($self, $creat) = @_;
 522         my $f = _config_path($self->{env});
 523         my @st = stat($f);
 524         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 525         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 526                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 527         }
 528         if (!@st) {
 529                 unless ($creat) {
 530                         delete $self->{cfg};
 531                         return;
 532                 }
 533                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 534                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 535                 open my $fh, '>>', $f or die "open($f): $!\n";
 536                 @st = stat($fh) or die "fstat($f): $!\n";
 537                 $cur_st = pack('dd', $st[10], $st[7]);
 538                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 539         }
 540         my $cfg = PublicInbox::Config::git_config_dump($f);
 541         $cfg->{-st} = $cur_st;
 542         $cfg->{'-f'} = $f;
 543         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 544 }
 545
 546 sub _lei_store ($;$) {
 547         my ($self, $creat) = @_;
 548         my $cfg = _lei_cfg($self, $creat);
 549         $cfg->{-lei_store} //= do {
 550                 require PublicInbox::LeiStore;
 551                 my $dir = $cfg->{'leistore.dir'};
 552                 $dir //= _store_path($self->{env}) if $creat;
 553                 return unless $dir;
 554                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 555         };
 556 }
 557
 558 sub lei_show {
 559         my ($self, @argv) = @_;
 560 }
 561
 562 sub lei_mark {
 563         my ($self, @argv) = @_;
 564 }
 565
 566 sub _config {
 567         my ($self, @argv) = @_;
 568         my $env = $self->{env};
 569         delete local $env->{GIT_CONFIG};
 570         delete local $ENV{GIT_CONFIG};
 571         my $cfg = _lei_cfg($self, 1);
 572         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 573         my %rdr = map { $_ => $self->{$_} } (0..2);
 574         waitpid(spawn($cmd, $env, \%rdr), 0);
 575 }
 576
 577 sub lei_config {
 578         my ($self, @argv) = @_;
 579         $self->{opt}->{'config-file'} and return fail $self,
 580                 "config file switches not supported by `lei config'";
 581         _config(@_);
 582         x_it($self, $?) if $?;
 583 }
 584
 585 sub lei_init {
 586         my ($self, $dir) = @_;
 587         my $cfg = _lei_cfg($self, 1);
 588         my $cur = $cfg->{'leistore.dir'};
 589         my $env = $self->{env};
 590         $dir //= _store_path($env);
 591         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 592         my @cur = stat($cur) if defined($cur);
 593         $cur = File::Spec->canonpath($cur // $dir);
 594         my @dir = stat($dir);
 595         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 596         if (@cur) {
 597                 if ($cur eq $dir) {
 598                         _lei_store($self, 1)->done;
 599                         return qerr($self, $exists);
 600                 }
 601
 602                 # some folks like symlinks and bind mounts :P
 603                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 604                         lei_config($self, 'leistore.dir', $dir);
 605                         _lei_store($self, 1)->done;
 606                         return qerr($self, "$exists (as $cur)");
 607                 }
 608                 return fail($self, <<"");
 609 E: leistore.dir=$cur already initialized and it is not $dir
 610
 611         }
 612         lei_config($self, 'leistore.dir', $dir);
 613         _lei_store($self, 1)->done;
 614         $exists //= "I: leistore.dir=$dir newly initialized";
 615         return qerr($self, $exists);
 616 }
 617
 618 sub lei_daemon_pid { puts shift, $$ }
 619
 620 sub lei_daemon_kill {
 621         my ($self) = @_;
 622         my $sig = $self->{opt}->{signal} // 'TERM';
 623         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 624 }
 625
 626 sub lei_help { _help($_[0]) }
 627
 628 # Shell completion helper.  Used by lei-completion.bash and hopefully
 629 # other shells.  Try to do as much here as possible to avoid redundancy
 630 # and improve maintainability.
 631 sub lei__complete {
 632         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 633         shift @argv; # ignore "lei", the entire command is sent
 634         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 635         my $cmd = shift @argv;
 636         my $info = $CMD{$cmd} // do { # filter matching commands
 637                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 638                 return;
 639         };
 640         my ($proto, undef, @spec) = @$info;
 641         my $cur = pop @argv;
 642         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 643         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 644                 # gross special case since the only git-config options
 645                 # Consider moving to a table if we need more special cases
 646                 # we use Getopt::Long for are the ones we reject, so these
 647                 # are the ones we don't reject:
 648                 if ($cmd eq 'config') {
 649                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 650                         @spec = qw(add z|null get get-all unset unset-all
 651                                 replace-all get-urlmatch
 652                                 remove-section rename-section
 653                                 name-only list|l edit|e
 654                                 get-color-name get-colorbool);
 655                         # fall-through
 656                 }
 657                 # TODO: arg support
 658                 puts $self, grep(/$re/, map { # generate short/long names
 659                         my $eq = '';
 660                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 661                                 $eq = '=';
 662                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 663                         } else { # negation: solve! => no-solve|solve
 664                                 s/\A(.+)!\z/no-$1|$1/;
 665                         }
 666                         map {
 667                                 length > 1 ? "--$_$eq" : "-$_"
 668                         } split(/\|/, $_, -1) # help|h
 669                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 670         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 671                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 672         }
 673         $cmd =~ tr/-/_/;
 674         if (my $sub = $self->can("_complete_$cmd")) {
 675                 puts $self, $sub->($self, @argv, $cur);
 676         }
 677         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 678         # proto parsing.
 679 }
 680
 681 sub reap_exec { # dwaitpid callback
 682         my ($self, $pid) = @_;
 683         x_it($self, $?);
 684 }
 685
 686 sub lei_git { # support passing through random git commands
 687         my ($self, @argv) = @_;
 688         my %rdr = map { $_ => $self->{$_} } (0..2);
 689         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 690         dwaitpid($pid, \&reap_exec, $self);
 691 }
 692
 693 sub exec_buf ($$) {
 694         my ($argv, $env) = @_;
 695         my $argc = scalar @$argv;
 696         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 697         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 698         $buf;
 699 }
 700
 701 sub start_mua {
 702         my ($self) = @_;
 703         my $mua = $self->{opt}->{'mua-cmd'} // return;
 704         my $mfolder = $self->{ovv}->{dst};
 705         my (@cmd, $replaced);
 706         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 707                 @cmd = ($mua, '-f');
 708         # TODO: help wanted: other common FOSS MUAs
 709         } else {
 710                 require Text::ParseWords;
 711                 my @cmd = Text::ParseWords::shellwords($mua);
 712                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 713                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 714         }
 715         push @cmd, $mfolder unless defined($replaced);
 716         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 717                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 718         } else { # oneshot
 719                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 720         }
 721 }
 722
 723 # caller needs to "-t $self->{1}" to check if tty
 724 sub start_pager {
 725         my ($self) = @_;
 726         my $env = $self->{env};
 727         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 728         chomp(my $pager = <$fh> // '');
 729         close($fh) or warn "`git var PAGER' error: \$?=$?";
 730         return if $pager eq 'cat' || $pager eq '';
 731         # TODO TIOCGWINSZ
 732         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 733         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 734         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 735         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 736         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 737         if (my $sock = $self->{sock}) { # lei(1) process runs it
 738                 delete @$new_env{keys %$env}; # only set iff unset
 739                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 740                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 741         } else {
 742                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 743         }
 744         $self->{1} = $wpager;
 745         $self->{2} = $wpager if -t $self->{2};
 746         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 747         $self->{pgr} = $pgr;
 748 }
 749
 750 sub stop_pager {
 751         my ($self) = @_;
 752         my $pgr = delete($self->{pgr}) or return;
 753         $self->{2} = $pgr->[2];
 754         # do not restore original stdout, just close it so we error out
 755         close(delete($self->{1})) if $self->{1};
 756         my $pid = $pgr->[0];
 757         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 758 }
 759
 760 sub accept_dispatch { # Listener {post_accept} callback
 761         my ($sock) = @_; # ignore other
 762         $sock->autoflush(1);
 763         my $self = bless { sock => $sock }, __PACKAGE__;
 764         vec(my $rvec = '', fileno($sock), 1) = 1;
 765         select($rvec, undef, undef, 1) or
 766                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 767         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 768         if (scalar(@fds) == 4) {
 769                 for my $i (0..3) {
 770                         my $fd = shift(@fds);
 771                         open($self->{$i}, '+<&=', $fd) and next;
 772                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 773                 }
 774         } else {
 775                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 776         }
 777         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 778         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 779         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 780         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 781                 return send($sock, 'request command truncated', MSG_EOR);
 782         my ($argc, @argv) = split(/\0/, $buf, -1);
 783         undef $buf;
 784         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 785         if (chdir(delete($self->{3}))) {
 786                 local %ENV = %env;
 787                 $self->{env} = \%env;
 788                 eval { dispatch($self, @argv) };
 789                 send($sock, $@, MSG_EOR) if $@;
 790         } else {
 791                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 792         }
 793 }
 794
 795 sub dclose {
 796         my ($self) = @_;
 797         for my $f (qw(lxs l2m)) {
 798                 my $wq = delete $self->{$f} or next;
 799                 if ($wq->wq_kill) {
 800                         $self->wq_close
 801                 } elsif ($wq->wq_kill_old) {
 802                         $wq->wq_wait_old;
 803                 }
 804         }
 805         close(delete $self->{1}) if $self->{1}; # may reap_compress
 806         $self->close if $self->{sock}; # PublicInbox::DS::close
 807 }
 808
 809 # for long-running results
 810 sub event_step {
 811         my ($self) = @_;
 812         local %ENV = %{$self->{env}};
 813         my $sock = $self->{sock};
 814         local $current_lei = $self;
 815         eval {
 816                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 817                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 818                                 return if $! == EAGAIN;
 819                                 next if $! == EINTR;
 820                                 last if $! == ECONNRESET;
 821                                 die "recvmsg: $!";
 822                         }
 823                         for my $fd (@fds) {
 824                                 open my $rfh, '+<&=', $fd;
 825                         }
 826                         die "unrecognized client signal: $buf";
 827                 }
 828                 dclose($self);
 829         };
 830         if (my $err = $@) {
 831                 eval { $self->fail($err) };
 832                 dclose($self);
 833         }
 834 }
 835
 836 sub event_step_init {
 837         my ($self) = @_;
 838         if (my $sock = $self->{sock}) { # using DS->EventLoop
 839                 $sock->blocking(0);
 840                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 841         }
 842 }
 843
 844 sub noop {}
 845
 846 our $oldset; sub oldset { $oldset }
 847
 848 sub dump_and_clear_log {
 849         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 850                 my @pfx = @_;
 851                 unshift(@pfx, "$errors_log ") if @pfx;
 852                 warn @pfx, do { local $/; <STDIN> };
 853                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 854         }
 855 }
 856
 857 # lei(1) calls this when it can't connect
 858 sub lazy_start {
 859         my ($path, $errno, $narg) = @_;
 860         if ($errno == ECONNREFUSED) {
 861                 unlink($path) or die "unlink($path): $!";
 862         } elsif ($errno != ENOENT) {
 863                 $! = $errno; # allow interpolation to stringify in die
 864                 die "connect($path): $!";
 865         }
 866         umask(077) // die("umask(077): $!");
 867         local $listener;
 868         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 869         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 870         listen($listener, 1024) or die "listen: $!";
 871         my @st = stat($path) or die "stat($path): $!";
 872         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 873         local $oldset = PublicInbox::DS::block_signals();
 874         if ($narg == 5) {
 875                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 876                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 877                         require PublicInbox::CmdIPC4;
 878                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 879                         PublicInbox::CmdIPC4->can('recv_cmd4');
 880                 };
 881         }
 882         $recv_cmd or die <<"";
 883 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 884
 885         require PublicInbox::Listener;
 886         require PublicInbox::EOFpipe;
 887         (-p STDOUT) or die "E: stdout must be a pipe\n";
 888         local $errors_log;
 889         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 890         $errors_log .= 'errors.log';
 891         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 892         STDIN->autoflush(1);
 893         dump_and_clear_log("from previous daemon process:\n");
 894         POSIX::setsid() > 0 or die "setsid: $!";
 895         my $pid = fork // die "fork: $!";
 896         return if $pid;
 897         $0 = "lei-daemon $path";
 898         local %PATH2CFG;
 899         $listener->blocking(0);
 900         my $exit_code;
 901         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 902         local $quit = do {
 903                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 904                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 905                 sub {
 906                         $exit_code //= shift;
 907                         my $lis = $pil or exit($exit_code);
 908                         # closing eof_w triggers \&noop wakeup
 909                         $listener = $eof_w = $pil = $path = undef;
 910                         $lis->close; # DS::close
 911                         PublicInbox::DS->SetLoopTimeout(1000);
 912                 };
 913         };
 914         my $sig = {
 915                 CHLD => \&PublicInbox::DS::enqueue_reap,
 916                 QUIT => $quit,
 917                 INT => $quit,
 918                 TERM => $quit,
 919                 HUP => \&noop,
 920                 USR1 => \&noop,
 921                 USR2 => \&noop,
 922         };
 923         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 924         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 925         undef $sig;
 926         local $SIG{PIPE} = 'IGNORE';
 927         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 928                 undef $sigfd;
 929                 PublicInbox::DS->SetLoopTimeout(5000);
 930         } else {
 931                 # wake up every second to accept signals if we don't
 932                 # have signalfd or IO::KQueue:
 933                 PublicInbox::DS::sig_setmask($oldset);
 934                 PublicInbox::DS->SetLoopTimeout(1000);
 935         }
 936         PublicInbox::DS->SetPostLoopCallback(sub {
 937                 my ($dmap, undef) = @_;
 938                 if (@st = defined($path) ? stat($path) : ()) {
 939                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 940                                 warn "$path dev/ino changed, quitting\n";
 941                                 $path = undef;
 942                         }
 943                 } elsif (defined($path)) {
 944                         warn "stat($path): $!, quitting ...\n";
 945                         undef $path; # don't unlink
 946                         $quit->();
 947                 }
 948                 return 1 if defined($path);
 949                 my $now = now();
 950                 my $n = 0;
 951                 for my $s (values %$dmap) {
 952                         $s->can('busy') or next;
 953                         if ($s->busy($now)) {
 954                                 ++$n;
 955                         } else {
 956                                 $s->close;
 957                         }
 958                 }
 959                 $n; # true: continue, false: stop
 960         });
 961
 962         # STDIN was redirected to /dev/null above, closing STDERR and
 963         # STDOUT will cause the calling `lei' client process to finish
 964         # reading the <$daemon> pipe.
 965         openlog($path, 'pid', 'user');
 966         local $SIG{__WARN__} = sub {
 967                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 968         };
 969         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 970                 syslog('crit', "$@") if $@;
 971         });
 972         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 973         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 974         # $daemon pipe to `lei' closed, main loop begins:
 975         PublicInbox::DS->EventLoop;
 976         @$on_destroy = (); # cancel on_destroy if we get here
 977         exit($exit_code // 0);
 978 }
 979
 980 # for users w/o Socket::Msghdr installed or Inline::C enabled
 981 sub oneshot {
 982         my ($main_pkg) = @_;
 983         my $exit = $main_pkg->can('exit'); # caller may override exit()
 984         local $quit = $exit if $exit;
 985         local %PATH2CFG;
 986         umask(077) // die("umask(077): $!");
 987         my $self = bless {
 988                 0 => *STDIN{GLOB},
 989                 1 => *STDOUT{GLOB},
 990                 2 => *STDERR{GLOB},
 991                 env => \%ENV
 992         }, __PACKAGE__;
 993         dispatch($self, @ARGV);
 994         x_it($self, $self->{child_error}) if $self->{child_error};
 995 }
 996
 997 # ensures stdout hits the FS before sock disconnects so a client
 998 # can immediately reread it
 999 sub DESTROY {
1000         my ($self) = @_;
1001         $self->{1}->autoflush(1) if $self->{1};
1002         stop_pager($self);
1003         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1004                 waitpid($mua_pid, 0);
1005         }
1006 }
1007
1008 1;