lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX ();
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use Sys::Syslog qw(syslog openlog);
  21 use PublicInbox::Config;
  22 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  23 use PublicInbox::Sigfd;
  24 use PublicInbox::DS qw(now dwaitpid);
  25 use PublicInbox::Spawn qw(spawn popen_rd);
  26 use PublicInbox::OnDestroy;
  27 use Text::Wrap qw(wrap);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener);
  33 my ($recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40
  41 # TBD: this is a documentation mechanism to show a subcommand
  42 # (may) pass options through to another command:
  43 sub pass_through { $GLP_PASS }
  44
  45 my $OPT;
  46 sub opt_dash ($$) {
  47         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  48         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  49         my $cb = sub { # Getopt::Long "<>" catch-all handler
  50                 my ($arg) = @_;
  51                 if ($arg =~ /\A-($re_str)\z/) {
  52                         $OPT->{$key} = $1;
  53                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  54                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  55                 # lone (single) dash is handled elsewhere
  56                 } elsif (substr($arg, 0, 1) eq '-') {
  57                         if ($OPT->{'--'}) {
  58                                 push @{$OPT->{-argv}}, $arg;
  59                         } else {
  60                                 die "bad argument: $arg\n";
  61                         }
  62                 } else {
  63                         push @{$OPT->{-argv}}, $arg;
  64                 }
  65         };
  66         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  67 }
  68
  69 sub rel2abs ($$) {
  70         my ($self, $p) = @_;
  71         return $p if index($p, '/') == 0; # already absolute
  72         my $pwd = $self->{env}->{PWD};
  73         if (defined $pwd) {
  74                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  75                 if (my @st_pwd = stat($pwd)) {
  76                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  77                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  78                                 $self->{env}->{PWD} = $pwd = $cwd;
  79                 } else { # PWD was invalid
  80                         delete $self->{env}->{PWD};
  81                         undef $pwd;
  82                 }
  83         }
  84         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  85         File::Spec->rel2abs($p, $pwd);
  86 }
  87
  88 sub _store_path ($) {
  89         my ($self) = @_;
  90         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  91                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  92                 .'/lei/store');
  93 }
  94
  95 sub _config_path ($) {
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  99                 .'/lei/config');
 100 }
 101
 102 # TODO: generate shell completion + help using %CMD and %OPTDESC
 103 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 104 our %CMD = ( # sorted in order of importance/use:
 105 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 106         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 107         sort|s=s reverse|r offset=i remote! local! external! pretty mua-cmd=s
 108         torsocks=s no-torsocks verbose|v since|after=s until|before=s),
 109         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 110
 111 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 112         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 113         pass_through('git show') ],
 114
 115 'add-external' => [ 'URL_OR_PATHNAME',
 116         'add/set priority of a publicinbox|extindex for extra matches',
 117         qw(boost=i quiet|q) ],
 118 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 119         qw(format|f=s z|0 local remote quiet|q) ],
 120 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 121         'exclude further results from a publicinbox|extindex',
 122         qw(prune quiet|q) ],
 123
 124 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 125                 qw(name-only format|f=s z) ],
 126 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 127 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 128
 129 'plonk' => [ '--thread|--from=IDENT',
 130         'exclude mail matching From: or thread from non-Message-ID searches',
 131         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 132 'mark' => [ 'MESSAGE_FLAGS...',
 133         'set/unset flags on message(s) from stdin',
 134         qw(stdin| oid=s exact by-mid|mid:s) ],
 135 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 136         "exclude message(s) on stdin from `q' search results",
 137         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 138
 139 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 140         'remove imported messages from IMAP, Maildirs, and MH',
 141         qw(exact! all jobs:i indexed) ],
 142
 143 # code repos are used for `show' to solve blobs from patch mails
 144 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 145         qw(boost=i) ],
 146 'ls-coderepo' => [ '[FILTER_TERMS...]',
 147                 'list known code repos', qw(format|f=s z) ],
 148 'forget-coderepo' => [ 'PATHNAME',
 149         'stop using repo to solve blobs from patches',
 150         qw(prune) ],
 151
 152 'add-watch' => [ '[URL_OR_PATHNAME]',
 153                 'watch for new messages and flag changes',
 154         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 155 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 156                 qw(format|f=s z) ],
 157 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 158 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 160         qw(prune) ],
 161
 162 'import' => [ 'URL_OR_PATHNAME|--stdin',
 163         'one-shot import/update from URL or filesystem',
 164         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 165         ],
 166
 167 'config' => [ '[...]', sub {
 168                 'git-config(1) wrapper for '._config_path($_[0]);
 169         }, qw(config-file|system|global|file|f=s), # for conflict detection
 170         pass_through('git config') ],
 171 'init' => [ '[PATHNAME]', sub {
 172                 'initialize storage, default: '._store_path($_[0]);
 173         }, qw(quiet|q) ],
 174 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 175         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 176 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 177 'help' => [ '[SUBCOMMAND]', 'show help' ],
 178
 179 # XXX do we need this?
 180 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 181
 182 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 183         'rewrite git history in an attempt to improve compression',
 184         'gc!' ],
 185
 186 # internal commands are prefixed with '_'
 187 '_complete' => [ '[...]', 'internal shell completion helper',
 188                 pass_through('everything') ],
 189 ); # @CMD
 190
 191 # switch descriptions, try to keep consistent across commands
 192 # $spec: Getopt::Long option specification
 193 # $spec => [@ALLOWED_VALUES (default is first), $description],
 194 # $spec => $description
 195 # "$SUB_COMMAND TAB $spec" => as above
 196 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 197                 'specify message input format' ];
 198 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 199
 200 my %OPTDESC = (
 201 'help|h' => 'show this built-in help',
 202 'quiet|q' => 'be quiet',
 203 'solve!' => 'do not attempt to reconstruct blobs from emails',
 204 'save-as=s' => ['NAME', 'save a search terms by given name'],
 205
 206 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 207
 208 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 209                 'deduplication strategy'],
 210 'show   thread|t' => 'display entire thread a message belongs to',
 211 'q      thread|t' =>
 212         'return all messages in the same thread as the actual match(es)',
 213 'augment|a' => 'augment --output destination instead of clobbering',
 214
 215 'output|o=s' => [ 'DEST',
 216         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 217 'mua-cmd|mua=s' => [ 'COMMAND',
 218         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 219
 220 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 221                         'message/object output format' ],
 222 'mark   format|f=s' => $stdin_formats,
 223 'forget format|f=s' => $stdin_formats,
 224 'q      format|f=s' => [
 225         'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|json|jsonl|concatjson',
 226                 'specify output format, default depends on --output'],
 227 'ls-query       format|f=s' => $ls_format,
 228 'ls-external    format|f=s' => $ls_format,
 229
 230 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 231 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 232
 233 'sort|s=s' => [ 'VAL|received,relevance,docid',
 234                 "order of results `--output'-dependent"],
 235 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 236
 237 'boost=i' => 'increase/decrease priority of results (default: 0)',
 238
 239 'local' => 'limit operations to the local filesystem',
 240 'local!' => 'exclude results from the local filesystem',
 241 'remote' => 'limit operations to those requiring network access',
 242 'remote!' => 'prevent operations requiring network access',
 243
 244 'mid=s' => 'specify the Message-ID of a message',
 245 'oid=s' => 'specify the git object ID of a message',
 246
 247 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 248 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 249 'include=s' => 'include mailboxes/newsgroups based on pattern',
 250
 251 'exact' => 'operate on exact header matches only',
 252 'exact!' => 'rely on content match instead of exact header matches',
 253
 254 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 255 'jobs:i' => 'set parallelism level',
 256
 257 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 258 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 259
 260 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 261 ); # %OPTDESC
 262
 263 my %CONFIG_KEYS = (
 264         'leistore.dir' => 'top-level storage location',
 265 );
 266
 267 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 268 sub x_it ($$) {
 269         my ($self, $code) = @_;
 270         # make sure client sees stdout before exit
 271         $self->{1}->autoflush(1) if $self->{1};
 272         dump_and_clear_log();
 273         if (my $sock = $self->{sock}) {
 274                 send($sock, "x_it $code", MSG_EOR);
 275         } elsif (!($code & 127)) { # oneshot, ignore signals
 276                 # don't want to end up using $? from child processes
 277                 for my $f (qw(lxs l2m)) {
 278                         my $wq = delete $self->{$f} or next;
 279                         $wq->DESTROY;
 280                 }
 281                 $quit->($code >> 8);
 282         }
 283 }
 284
 285 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 286
 287 sub out ($;@) { print { shift->{1} } @_ }
 288
 289 sub err ($;@) {
 290         my $self = shift;
 291         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 292         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 293 }
 294
 295 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 296
 297 sub fail ($$;$) {
 298         my ($self, $buf, $exit_code) = @_;
 299         err($self, $buf);
 300         x_it($self, ($exit_code // 1) << 8);
 301         undef;
 302 }
 303
 304 sub child_error { # passes non-fatal curl exit codes to user
 305         my ($self, $child_error) = @_; # child_error is $?
 306         if (my $sock = $self->{sock}) { # send to lei(1) client
 307                 send($sock, "child_error $child_error", MSG_EOR);
 308         } else { # oneshot
 309                 $self->{child_error} = $child_error;
 310         }
 311         undef;
 312 }
 313
 314 sub atfork_prepare_wq {
 315         my ($self, $wq) = @_;
 316         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 317         if (my $sock = $self->{sock}) {
 318                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 319         }
 320         if (my $pgr = $self->{pgr}) {
 321                 push @$tcafc, @$pgr[1,2];
 322         }
 323         if (my $old_1 = $self->{old_1}) {
 324                 push @$tcafc, $old_1;
 325         }
 326         for my $f (qw(lxs l2m)) {
 327                 my $ipc = $self->{$f} or next;
 328                 push @$tcafc, grep { defined }
 329                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 330         }
 331 }
 332
 333 # usage: my %sig = $lei->atfork_child_wq($wq);
 334 #        local @SIG{keys %sig} = values %sig;
 335 sub atfork_child_wq {
 336         my ($self, $wq) = @_;
 337         my ($sock, $l2m_wq_s1);
 338         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 339         $self->{sock} = $sock if -S $sock;
 340         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 341         %PATH2CFG = ();
 342         undef $errors_log;
 343         $quit = \&CORE::exit;
 344         (__WARN__ => sub { err($self, @_) },
 345         PIPE => sub {
 346                 $self->x_it(13); # SIGPIPE = 13
 347                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 348                 for my $i (1, 2) {
 349                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 350                         close(delete $self->{$i});
 351                 }
 352                 # trigger the LeiXSearch $done OpPipe:
 353                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 354                 $SIG{PIPE} = 'DEFAULT';
 355                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 356         });
 357 }
 358
 359 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 360 sub atfork_parent_wq {
 361         my ($self, $wq) = @_;
 362         my $env = delete $self->{env}; # env is inherited at fork
 363         my $ret = bless { %$self }, ref($self);
 364         if (my $dedupe = delete $ret->{dedupe}) {
 365                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 366         }
 367         $self->{env} = $env;
 368         delete @$ret{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 369         my @io = delete @$ret{0..2};
 370         $io[3] = delete($ret->{sock}) // $io[2];
 371         my $l2m = $ret->{l2m};
 372         if ($l2m && $l2m != $wq) { # $wq == lxs
 373                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 374                 $l2m->wq_close(1);
 375         }
 376         ($ret, @io);
 377 }
 378
 379 sub _help ($;$) {
 380         my ($self, $errmsg) = @_;
 381         my $cmd = $self->{cmd} // 'COMMAND';
 382         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 383         my @top = ($cmd, shift(@info) // ());
 384         my $cmd_desc = shift(@info);
 385         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 386         my @opt_desc;
 387         my $lpad = 2;
 388         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 389                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 390                 my $arg_vals = '';
 391                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 392
 393                 # lower-case is a keyword (e.g. `content', `oid'),
 394                 # ALL_CAPS is a string description (e.g. `PATH')
 395                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 396                         $desc .= "\ndefault: `$1'";
 397                 }
 398                 my (@vals, @s, @l);
 399                 my $x = $sw;
 400                 if ($x =~ s/!\z//) { # solve! => --no-solve
 401                         $x = "no-$x";
 402                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 403                         @vals = (' [', undef, ']');
 404                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 405                         @vals = (' ', undef);
 406                 } # else: no args $x = 'thread|t'
 407                 for (split(/\|/, $x)) { # help|h
 408                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 409                 }
 410                 if (!scalar(@vals)) { # no args 'thread|t'
 411                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 412                         $vals[1] = $1;
 413                 } else {
 414                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 415                 }
 416                 if ($arg_vals =~ /([,\|])/) {
 417                         my $sep = $1;
 418                         my @allow = split(/\Q$sep\E/, $arg_vals);
 419                         my $must = $sep eq '|' ? 'Must' : 'Can';
 420                         @allow = map { "`$_'" } @allow;
 421                         my $last = pop @allow;
 422                         $desc .= "\n$must be one of: " .
 423                                 join(', ', @allow) . " or $last";
 424                 }
 425                 my $lhs = join(', ', @s, @l) . join('', @vals);
 426                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 427                         $lhs =~ s/\A--/- , --/;
 428                 } else {
 429                         $lhs =~ s/\A--/    --/; # pad if no short options
 430                 }
 431                 $lpad = length($lhs) if length($lhs) > $lpad;
 432                 push @opt_desc, $lhs, $desc;
 433         }
 434         my $msg = $errmsg ? "E: $errmsg\n" : '';
 435         $msg .= <<EOF;
 436 usage: lei @top
 437   $cmd_desc
 438
 439 EOF
 440         $lpad += 2;
 441         local $Text::Wrap::columns = 78 - $lpad;
 442         my $padding = ' ' x ($lpad + 2);
 443         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 444                 $msg .= '  '.pack("A$lpad", $lhs);
 445                 $rhs = wrap('', '', $rhs);
 446                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 447                 $msg .= $rhs;
 448                 $msg .= "\n";
 449         }
 450         print { $self->{$errmsg ? 2 : 1} } $msg;
 451         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 452         undef;
 453 }
 454
 455 sub optparse ($$$) {
 456         my ($self, $cmd, $argv) = @_;
 457         $self->{cmd} = $cmd;
 458         $OPT = $self->{opt} = {};
 459         my $info = $CMD{$cmd} // [ '[...]' ];
 460         my ($proto, undef, @spec) = @$info;
 461         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 462         push @spec, qw(help|h);
 463         my $lone_dash;
 464         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 465                 $lone_dash = $spec[0];
 466                 $OPT->{$spec[0]} = \(my $var);
 467                 push @spec, '' => \$var;
 468         }
 469         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 470                 return _help($self, "bad arguments or options for $cmd");
 471         return _help($self) if $OPT->{help};
 472
 473         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 474
 475         # "-" aliases "stdin" or "clear"
 476         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 477
 478         my $i = 0;
 479         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 480         my ($err, $inf);
 481         my @args = split(/ /, $proto);
 482         for my $var (@args) {
 483                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 484                         $inf = defined($argv->[$i]) and last;
 485                         $var =~ s/\.\.\.\z//;
 486                         $err = "$var not supplied";
 487                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 488                         $argv->[$i++] // ($err = "$var not supplied");
 489                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 490                         $inf = 1;
 491                         last;
 492                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 493                         $i++;
 494                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 495                         my @or = split(/\|/, $var);
 496                         my $ok;
 497                         for my $o (@or) {
 498                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 499                                         $ok = defined($OPT->{$1});
 500                                         last;
 501                                 } elsif (defined($argv->[$i])) {
 502                                         $ok = 1;
 503                                         $i++;
 504                                         last;
 505                                 } # else continue looping
 506                         }
 507                         last if $ok;
 508                         my $last = pop @or;
 509                         $err = join(', ', @or) . " or $last must be set";
 510                 } else {
 511                         warn "BUG: can't parse `$var' in $proto";
 512                 }
 513                 last if $err;
 514         }
 515         if (!$inf && scalar(@$argv) > scalar(@args)) {
 516                 $err //= 'too many arguments';
 517         }
 518         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 519 }
 520
 521 sub dispatch {
 522         my ($self, $cmd, @argv) = @_;
 523         local $current_lei = $self; # for __WARN__
 524         dump_and_clear_log("from previous run\n");
 525         return _help($self, 'no command given') unless defined($cmd);
 526         my $func = "lei_$cmd";
 527         $func =~ tr/-/_/;
 528         if (my $cb = __PACKAGE__->can($func)) {
 529                 optparse($self, $cmd, \@argv) or return;
 530                 $cb->($self, @argv);
 531         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 532                 my $opt = {};
 533                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 534                         return _help($self, 'bad arguments or options');
 535                 _help($self);
 536         } else {
 537                 fail($self, "`$cmd' is not an lei command");
 538         }
 539 }
 540
 541 sub _lei_cfg ($;$) {
 542         my ($self, $creat) = @_;
 543         my $f = _config_path($self);
 544         my @st = stat($f);
 545         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 546         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 547                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 548         }
 549         if (!@st) {
 550                 unless ($creat) {
 551                         delete $self->{cfg};
 552                         return;
 553                 }
 554                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 555                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 556                 open my $fh, '>>', $f or die "open($f): $!\n";
 557                 @st = stat($fh) or die "fstat($f): $!\n";
 558                 $cur_st = pack('dd', $st[10], $st[7]);
 559                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 560         }
 561         my $cfg = PublicInbox::Config::git_config_dump($f);
 562         $cfg->{-st} = $cur_st;
 563         $cfg->{'-f'} = $f;
 564         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 565 }
 566
 567 sub _lei_store ($;$) {
 568         my ($self, $creat) = @_;
 569         my $cfg = _lei_cfg($self, $creat);
 570         $cfg->{-lei_store} //= do {
 571                 require PublicInbox::LeiStore;
 572                 my $dir = $cfg->{'leistore.dir'};
 573                 $dir //= $creat ? _store_path($self) : return;
 574                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 575         };
 576 }
 577
 578 sub lei_show {
 579         my ($self, @argv) = @_;
 580 }
 581
 582 sub lei_mark {
 583         my ($self, @argv) = @_;
 584 }
 585
 586 sub _config {
 587         my ($self, @argv) = @_;
 588         my $env = $self->{env};
 589         delete local $env->{GIT_CONFIG};
 590         delete local $ENV{GIT_CONFIG};
 591         my $cfg = _lei_cfg($self, 1);
 592         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 593         my %rdr = map { $_ => $self->{$_} } (0..2);
 594         waitpid(spawn($cmd, $env, \%rdr), 0);
 595 }
 596
 597 sub lei_config {
 598         my ($self, @argv) = @_;
 599         $self->{opt}->{'config-file'} and return fail $self,
 600                 "config file switches not supported by `lei config'";
 601         _config(@_);
 602         x_it($self, $?) if $?;
 603 }
 604
 605 sub lei_init {
 606         my ($self, $dir) = @_;
 607         my $cfg = _lei_cfg($self, 1);
 608         my $cur = $cfg->{'leistore.dir'};
 609         $dir //= _store_path($self);
 610         $dir = rel2abs($self, $dir);
 611         my @cur = stat($cur) if defined($cur);
 612         $cur = File::Spec->canonpath($cur // $dir);
 613         my @dir = stat($dir);
 614         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 615         if (@cur) {
 616                 if ($cur eq $dir) {
 617                         _lei_store($self, 1)->done;
 618                         return qerr($self, $exists);
 619                 }
 620
 621                 # some folks like symlinks and bind mounts :P
 622                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 623                         lei_config($self, 'leistore.dir', $dir);
 624                         _lei_store($self, 1)->done;
 625                         return qerr($self, "$exists (as $cur)");
 626                 }
 627                 return fail($self, <<"");
 628 E: leistore.dir=$cur already initialized and it is not $dir
 629
 630         }
 631         lei_config($self, 'leistore.dir', $dir);
 632         _lei_store($self, 1)->done;
 633         $exists //= "I: leistore.dir=$dir newly initialized";
 634         return qerr($self, $exists);
 635 }
 636
 637 sub lei_daemon_pid { puts shift, $$ }
 638
 639 sub lei_daemon_kill {
 640         my ($self) = @_;
 641         my $sig = $self->{opt}->{signal} // 'TERM';
 642         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 643 }
 644
 645 sub lei_help { _help($_[0]) }
 646
 647 # Shell completion helper.  Used by lei-completion.bash and hopefully
 648 # other shells.  Try to do as much here as possible to avoid redundancy
 649 # and improve maintainability.
 650 sub lei__complete {
 651         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 652         shift @argv; # ignore "lei", the entire command is sent
 653         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 654         my $cmd = shift @argv;
 655         my $info = $CMD{$cmd} // do { # filter matching commands
 656                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 657                 return;
 658         };
 659         my ($proto, undef, @spec) = @$info;
 660         my $cur = pop @argv;
 661         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 662         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 663                 # gross special case since the only git-config options
 664                 # Consider moving to a table if we need more special cases
 665                 # we use Getopt::Long for are the ones we reject, so these
 666                 # are the ones we don't reject:
 667                 if ($cmd eq 'config') {
 668                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 669                         @spec = qw(add z|null get get-all unset unset-all
 670                                 replace-all get-urlmatch
 671                                 remove-section rename-section
 672                                 name-only list|l edit|e
 673                                 get-color-name get-colorbool);
 674                         # fall-through
 675                 }
 676                 # TODO: arg support
 677                 puts $self, grep(/$re/, map { # generate short/long names
 678                         my $eq = '';
 679                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 680                                 $eq = '=';
 681                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 682                         } else { # negation: solve! => no-solve|solve
 683                                 s/\A(.+)!\z/no-$1|$1/;
 684                         }
 685                         map {
 686                                 length > 1 ? "--$_$eq" : "-$_"
 687                         } split(/\|/, $_, -1) # help|h
 688                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 689         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 690                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 691         }
 692         $cmd =~ tr/-/_/;
 693         if (my $sub = $self->can("_complete_$cmd")) {
 694                 puts $self, $sub->($self, @argv, $cur);
 695         }
 696         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 697         # proto parsing.
 698 }
 699
 700 sub exec_buf ($$) {
 701         my ($argv, $env) = @_;
 702         my $argc = scalar @$argv;
 703         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 704         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 705         $buf;
 706 }
 707
 708 sub start_mua {
 709         my ($self) = @_;
 710         my $mua = $self->{opt}->{'mua-cmd'} // return;
 711         my $mfolder = $self->{ovv}->{dst};
 712         my (@cmd, $replaced);
 713         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 714                 @cmd = ($mua, '-f');
 715         # TODO: help wanted: other common FOSS MUAs
 716         } else {
 717                 require Text::ParseWords;
 718                 my @cmd = Text::ParseWords::shellwords($mua);
 719                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 720                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 721         }
 722         push @cmd, $mfolder unless defined($replaced);
 723         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 724                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 725         } else { # oneshot
 726                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 727         }
 728 }
 729
 730 # caller needs to "-t $self->{1}" to check if tty
 731 sub start_pager {
 732         my ($self) = @_;
 733         my $env = $self->{env};
 734         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 735         chomp(my $pager = <$fh> // '');
 736         close($fh) or warn "`git var PAGER' error: \$?=$?";
 737         return if $pager eq 'cat' || $pager eq '';
 738         # TODO TIOCGWINSZ
 739         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 740         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 741         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 742         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 743         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 744         if (my $sock = $self->{sock}) { # lei(1) process runs it
 745                 delete @$new_env{keys %$env}; # only set iff unset
 746                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 747                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 748         } else {
 749                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 750         }
 751         $self->{1} = $wpager;
 752         $self->{2} = $wpager if -t $self->{2};
 753         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 754         $self->{pgr} = $pgr;
 755 }
 756
 757 sub stop_pager {
 758         my ($self) = @_;
 759         my $pgr = delete($self->{pgr}) or return;
 760         $self->{2} = $pgr->[2];
 761         # do not restore original stdout, just close it so we error out
 762         close(delete($self->{1})) if $self->{1};
 763         my $pid = $pgr->[0];
 764         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 765 }
 766
 767 sub accept_dispatch { # Listener {post_accept} callback
 768         my ($sock) = @_; # ignore other
 769         $sock->autoflush(1);
 770         my $self = bless { sock => $sock }, __PACKAGE__;
 771         vec(my $rvec = '', fileno($sock), 1) = 1;
 772         select($rvec, undef, undef, 1) or
 773                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 774         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 775         if (scalar(@fds) == 4) {
 776                 for my $i (0..3) {
 777                         my $fd = shift(@fds);
 778                         open($self->{$i}, '+<&=', $fd) and next;
 779                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 780                 }
 781         } else {
 782                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 783         }
 784         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 785         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 786         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 787         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 788                 return send($sock, 'request command truncated', MSG_EOR);
 789         my ($argc, @argv) = split(/\0/, $buf, -1);
 790         undef $buf;
 791         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 792         if (chdir($self->{3})) {
 793                 local %ENV = %env;
 794                 $self->{env} = \%env;
 795                 eval { dispatch($self, @argv) };
 796                 send($sock, $@, MSG_EOR) if $@;
 797         } else {
 798                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 799         }
 800 }
 801
 802 sub dclose {
 803         my ($self) = @_;
 804         for my $f (qw(lxs l2m)) {
 805                 my $wq = delete $self->{$f} or next;
 806                 if ($wq->wq_kill) {
 807                         $self->wq_close
 808                 } elsif ($wq->wq_kill_old) {
 809                         $wq->wq_wait_old;
 810                 }
 811         }
 812         close(delete $self->{1}) if $self->{1}; # may reap_compress
 813         $self->close if $self->{sock}; # PublicInbox::DS::close
 814 }
 815
 816 # for long-running results
 817 sub event_step {
 818         my ($self) = @_;
 819         local %ENV = %{$self->{env}};
 820         my $sock = $self->{sock};
 821         local $current_lei = $self;
 822         eval {
 823                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 824                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 825                                 return if $! == EAGAIN;
 826                                 next if $! == EINTR;
 827                                 last if $! == ECONNRESET;
 828                                 die "recvmsg: $!";
 829                         }
 830                         for my $fd (@fds) {
 831                                 open my $rfh, '+<&=', $fd;
 832                         }
 833                         die "unrecognized client signal: $buf";
 834                 }
 835                 dclose($self);
 836         };
 837         if (my $err = $@) {
 838                 eval { $self->fail($err) };
 839                 dclose($self);
 840         }
 841 }
 842
 843 sub event_step_init {
 844         my ($self) = @_;
 845         if (my $sock = $self->{sock}) { # using DS->EventLoop
 846                 $sock->blocking(0);
 847                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 848         }
 849 }
 850
 851 sub noop {}
 852
 853 our $oldset; sub oldset { $oldset }
 854
 855 sub dump_and_clear_log {
 856         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 857                 my @pfx = @_;
 858                 unshift(@pfx, "$errors_log ") if @pfx;
 859                 warn @pfx, do { local $/; <STDIN> };
 860                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 861         }
 862 }
 863
 864 # lei(1) calls this when it can't connect
 865 sub lazy_start {
 866         my ($path, $errno, $narg) = @_;
 867         if ($errno == ECONNREFUSED) {
 868                 unlink($path) or die "unlink($path): $!";
 869         } elsif ($errno != ENOENT) {
 870                 $! = $errno; # allow interpolation to stringify in die
 871                 die "connect($path): $!";
 872         }
 873         umask(077) // die("umask(077): $!");
 874         local $listener;
 875         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 876         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 877         listen($listener, 1024) or die "listen: $!";
 878         my @st = stat($path) or die "stat($path): $!";
 879         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 880         local $oldset = PublicInbox::DS::block_signals();
 881         if ($narg == 5) {
 882                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 883                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 884                         require PublicInbox::CmdIPC4;
 885                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 886                         PublicInbox::CmdIPC4->can('recv_cmd4');
 887                 };
 888         }
 889         $recv_cmd or die <<"";
 890 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 891
 892         require PublicInbox::Listener;
 893         require PublicInbox::EOFpipe;
 894         (-p STDOUT) or die "E: stdout must be a pipe\n";
 895         local $errors_log;
 896         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 897         $errors_log .= 'errors.log';
 898         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 899         STDIN->autoflush(1);
 900         dump_and_clear_log("from previous daemon process:\n");
 901         POSIX::setsid() > 0 or die "setsid: $!";
 902         my $pid = fork // die "fork: $!";
 903         return if $pid;
 904         $0 = "lei-daemon $path";
 905         local %PATH2CFG;
 906         $listener->blocking(0);
 907         my $exit_code;
 908         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 909         local $quit = do {
 910                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 911                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 912                 sub {
 913                         $exit_code //= shift;
 914                         my $lis = $pil or exit($exit_code);
 915                         # closing eof_w triggers \&noop wakeup
 916                         $listener = $eof_w = $pil = $path = undef;
 917                         $lis->close; # DS::close
 918                         PublicInbox::DS->SetLoopTimeout(1000);
 919                 };
 920         };
 921         my $sig = {
 922                 CHLD => \&PublicInbox::DS::enqueue_reap,
 923                 QUIT => $quit,
 924                 INT => $quit,
 925                 TERM => $quit,
 926                 HUP => \&noop,
 927                 USR1 => \&noop,
 928                 USR2 => \&noop,
 929         };
 930         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 931         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 932         undef $sig;
 933         local $SIG{PIPE} = 'IGNORE';
 934         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 935                 undef $sigfd;
 936                 PublicInbox::DS->SetLoopTimeout(5000);
 937         } else {
 938                 # wake up every second to accept signals if we don't
 939                 # have signalfd or IO::KQueue:
 940                 PublicInbox::DS::sig_setmask($oldset);
 941                 PublicInbox::DS->SetLoopTimeout(1000);
 942         }
 943         PublicInbox::DS->SetPostLoopCallback(sub {
 944                 my ($dmap, undef) = @_;
 945                 if (@st = defined($path) ? stat($path) : ()) {
 946                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 947                                 warn "$path dev/ino changed, quitting\n";
 948                                 $path = undef;
 949                         }
 950                 } elsif (defined($path)) {
 951                         warn "stat($path): $!, quitting ...\n";
 952                         undef $path; # don't unlink
 953                         $quit->();
 954                 }
 955                 return 1 if defined($path);
 956                 my $now = now();
 957                 my $n = 0;
 958                 for my $s (values %$dmap) {
 959                         $s->can('busy') or next;
 960                         if ($s->busy($now)) {
 961                                 ++$n;
 962                         } else {
 963                                 $s->close;
 964                         }
 965                 }
 966                 $n; # true: continue, false: stop
 967         });
 968
 969         # STDIN was redirected to /dev/null above, closing STDERR and
 970         # STDOUT will cause the calling `lei' client process to finish
 971         # reading the <$daemon> pipe.
 972         openlog($path, 'pid', 'user');
 973         local $SIG{__WARN__} = sub {
 974                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 975         };
 976         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 977                 syslog('crit', "$@") if $@;
 978         });
 979         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 980         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 981         # $daemon pipe to `lei' closed, main loop begins:
 982         PublicInbox::DS->EventLoop;
 983         @$on_destroy = (); # cancel on_destroy if we get here
 984         exit($exit_code // 0);
 985 }
 986
 987 # for users w/o Socket::Msghdr installed or Inline::C enabled
 988 sub oneshot {
 989         my ($main_pkg) = @_;
 990         my $exit = $main_pkg->can('exit'); # caller may override exit()
 991         local $quit = $exit if $exit;
 992         local %PATH2CFG;
 993         umask(077) // die("umask(077): $!");
 994         my $self = bless {
 995                 0 => *STDIN{GLOB},
 996                 1 => *STDOUT{GLOB},
 997                 2 => *STDERR{GLOB},
 998                 env => \%ENV
 999         }, __PACKAGE__;
1000         dispatch($self, @ARGV);
1001         x_it($self, $self->{child_error}) if $self->{child_error};
1002 }
1003
1004 # ensures stdout hits the FS before sock disconnects so a client
1005 # can immediately reread it
1006 sub DESTROY {
1007         my ($self) = @_;
1008         $self->{1}->autoflush(1) if $self->{1};
1009         stop_pager($self);
1010         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1011                 waitpid($mua_pid, 0);
1012         }
1013 }
1014
1015 1;