lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX ();
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use Sys::Syslog qw(syslog openlog);
  21 use PublicInbox::Config;
  22 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  23 use PublicInbox::Sigfd;
  24 use PublicInbox::DS qw(now dwaitpid);
  25 use PublicInbox::Spawn qw(spawn popen_rd);
  26 use PublicInbox::OnDestroy;
  27 use Text::Wrap qw(wrap);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 our $quit = \&CORE::exit;
  32 our ($current_lei, $errors_log, $listener);
  33 my ($recv_cmd, $send_cmd);
  34 my $GLP = Getopt::Long::Parser->new;
  35 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  36 my $GLP_PASS = Getopt::Long::Parser->new;
  37 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  38
  39 our %PATH2CFG; # persistent for socket daemon
  40
  41 # TBD: this is a documentation mechanism to show a subcommand
  42 # (may) pass options through to another command:
  43 sub pass_through { $GLP_PASS }
  44
  45 my $OPT;
  46 sub opt_dash ($$) {
  47         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  48         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  49         my $cb = sub { # Getopt::Long "<>" catch-all handler
  50                 my ($arg) = @_;
  51                 if ($arg =~ /\A-($re_str)\z/) {
  52                         $OPT->{$key} = $1;
  53                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  54                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  55                 # lone (single) dash is handled elsewhere
  56                 } elsif (substr($arg, 0, 1) eq '-') {
  57                         if ($OPT->{'--'}) {
  58                                 push @{$OPT->{-argv}}, $arg;
  59                         } else {
  60                                 die "bad argument: $arg\n";
  61                         }
  62                 } else {
  63                         push @{$OPT->{-argv}}, $arg;
  64                 }
  65         };
  66         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  67 }
  68
  69 sub rel2abs ($$) {
  70         my ($self, $p) = @_;
  71         return $p if index($p, '/') == 0; # already absolute
  72         my $pwd = $self->{env}->{PWD};
  73         if (defined $pwd) {
  74                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  75                 if (my @st_pwd = stat($pwd)) {
  76                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  77                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  78                                 $self->{env}->{PWD} = $pwd = $cwd;
  79                 } else { # PWD was invalid
  80                         delete $self->{env}->{PWD};
  81                         undef $pwd;
  82                 }
  83         }
  84         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  85         File::Spec->rel2abs($p, $pwd);
  86 }
  87
  88 sub _store_path ($) {
  89         my ($self) = @_;
  90         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  91                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  92                 .'/lei/store');
  93 }
  94
  95 sub _config_path ($) {
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  99                 .'/lei/config');
 100 }
 101
 102 # TODO: generate shell completion + help using %CMD and %OPTDESC
 103 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 104 our %CMD = ( # sorted in order of importance/use:
 105 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 106         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 107         sort|s=s reverse|r offset=i remote! local! external! pretty
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'verbose|v' => 'be more verbose',
 205 'solve!' => 'do not attempt to reconstruct blobs from emails',
 206 'torsocks=s' => ['auto|no|yes',
 207                 'whether or not to wrap git and curl commands with torsocks'],
 208 'no-torsocks' => 'alias for --torsocks=no',
 209 'save-as=s' => ['NAME', 'save a search terms by given name'],
 210
 211 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 212
 213 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 214                 'deduplication strategy'],
 215 'show   thread|t' => 'display entire thread a message belongs to',
 216 'q      thread|t' =>
 217         'return all messages in the same thread as the actual match(es)',
 218 'augment|a' => 'augment --output destination instead of clobbering',
 219
 220 'output|mfolder|o=s' => [ 'DEST',
 221         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 222 'mua-cmd|mua=s' => [ 'COMMAND',
 223         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 224
 225 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 226                         'message/object output format' ],
 227 'mark   format|f=s' => $stdin_formats,
 228 'forget format|f=s' => $stdin_formats,
 229 'q      format|f=s' => [
 230         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 231                 'specify output format, default depends on --output'],
 232 'ls-query       format|f=s' => $ls_format,
 233 'ls-external    format|f=s' => $ls_format,
 234
 235 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 236 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 237
 238 'sort|s=s' => [ 'VAL|received,relevance,docid',
 239                 "order of results `--output'-dependent"],
 240 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 241
 242 'boost=i' => 'increase/decrease priority of results (default: 0)',
 243
 244 'local' => 'limit operations to the local filesystem',
 245 'local!' => 'exclude results from the local filesystem',
 246 'remote' => 'limit operations to those requiring network access',
 247 'remote!' => 'prevent operations requiring network access',
 248
 249 'mid=s' => 'specify the Message-ID of a message',
 250 'oid=s' => 'specify the git object ID of a message',
 251
 252 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 253 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 254 'include=s' => 'include mailboxes/newsgroups based on pattern',
 255
 256 'exact' => 'operate on exact header matches only',
 257 'exact!' => 'rely on content match instead of exact header matches',
 258
 259 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 260 'jobs:i' => 'set parallelism level',
 261
 262 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 263 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 264
 265 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 266 ); # %OPTDESC
 267
 268 my %CONFIG_KEYS = (
 269         'leistore.dir' => 'top-level storage location',
 270 );
 271
 272 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 273 sub x_it ($$) {
 274         my ($self, $code) = @_;
 275         # make sure client sees stdout before exit
 276         $self->{1}->autoflush(1) if $self->{1};
 277         dump_and_clear_log();
 278         if (my $sock = $self->{sock}) {
 279                 send($sock, "x_it $code", MSG_EOR);
 280         } elsif (!($code & 127)) { # oneshot, ignore signals
 281                 # don't want to end up using $? from child processes
 282                 for my $f (qw(lxs l2m)) {
 283                         my $wq = delete $self->{$f} or next;
 284                         $wq->DESTROY;
 285                 }
 286                 $quit->($code >> 8);
 287         }
 288 }
 289
 290 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 291
 292 sub out ($;@) { print { shift->{1} } @_ }
 293
 294 sub err ($;@) {
 295         my $self = shift;
 296         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 297         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 298 }
 299
 300 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 301
 302 sub fail ($$;$) {
 303         my ($self, $buf, $exit_code) = @_;
 304         err($self, $buf);
 305         x_it($self, ($exit_code // 1) << 8);
 306         undef;
 307 }
 308
 309 sub child_error { # passes non-fatal curl exit codes to user
 310         my ($self, $child_error) = @_; # child_error is $?
 311         if (my $sock = $self->{sock}) { # send to lei(1) client
 312                 send($sock, "child_error $child_error", MSG_EOR);
 313         } else { # oneshot
 314                 $self->{child_error} = $child_error;
 315         }
 316         undef;
 317 }
 318
 319 sub atfork_prepare_wq {
 320         my ($self, $wq) = @_;
 321         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 322         if (my $sock = $self->{sock}) {
 323                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 324         }
 325         if (my $pgr = $self->{pgr}) {
 326                 push @$tcafc, @$pgr[1,2];
 327         }
 328         if (my $old_1 = $self->{old_1}) {
 329                 push @$tcafc, $old_1;
 330         }
 331         for my $f (qw(lxs l2m)) {
 332                 my $ipc = $self->{$f} or next;
 333                 push @$tcafc, grep { defined }
 334                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 335         }
 336 }
 337
 338 sub io_restore ($$) {
 339         my ($dst, $src) = @_;
 340         for my $i (0..2) { # standard FDs
 341                 my $io = delete $src->{$i} or next;
 342                 $dst->{$i} = $io;
 343         }
 344         for my $i (3..9) { # named (non-standard) FDs
 345                 my $io = $src->{$i} or next;
 346                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 347                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 348                 $dst->{$f} = $io;
 349                 delete $src->{$i};
 350         }
 351 }
 352
 353 # usage: my %sig = $lei->atfork_child_wq($wq);
 354 #        local @SIG{keys %sig} = values %sig;
 355 sub atfork_child_wq {
 356         my ($self, $wq) = @_;
 357         io_restore($self, $wq);
 358         io_restore($self->{l2m}, $wq);
 359         %PATH2CFG = ();
 360         undef $errors_log;
 361         $quit = \&CORE::exit;
 362         (PIPE => sub {
 363                 $self->x_it(13); # SIGPIPE = 13
 364                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 365                 for my $i (1, 2) {
 366                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 367                         close(delete $self->{$i});
 368                 }
 369                 # trigger the LeiXSearch $done OpPipe:
 370                 syswrite($self->{op_pipe}, '!') if $self->{op_pipe};
 371                 $SIG{PIPE} = 'DEFAULT';
 372                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 373         });
 374 }
 375
 376 sub io_extract ($;@) {
 377         my ($obj, @fields) = @_;
 378         my @io;
 379         for my $f (@fields) {
 380                 my $io = delete $obj->{$f} or next;
 381                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 382                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 383                 push @io, $io;
 384         }
 385         @io
 386 }
 387
 388 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 389 sub atfork_parent_wq {
 390         my ($self, $wq) = @_;
 391         my $env = delete $self->{env}; # env is inherited at fork
 392         my $lei = bless { %$self }, ref($self);
 393         if (my $dedupe = delete $lei->{dedupe}) {
 394                 $lei->{dedupe} = $wq->deep_clone($dedupe);
 395         }
 396         $self->{env} = $env;
 397         delete @$lei{qw(3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 398         my @io = (delete(@$lei{qw(0 1 2)}),
 399                         io_extract($lei, qw(sock op_pipe startq)));
 400         my $l2m = $lei->{l2m};
 401         if ($l2m && $l2m != $wq) { # $wq == lxs
 402                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 403                         push @io, io_extract($l2m, '-wq_s1');
 404                         $l2m->{-wq_s1} = $wq_s1;
 405                 }
 406                 $l2m->wq_close(1);
 407         }
 408         ($lei, @io);
 409 }
 410
 411 sub _help ($;$) {
 412         my ($self, $errmsg) = @_;
 413         my $cmd = $self->{cmd} // 'COMMAND';
 414         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 415         my @top = ($cmd, shift(@info) // ());
 416         my $cmd_desc = shift(@info);
 417         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 418         my @opt_desc;
 419         my $lpad = 2;
 420         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 421                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 422                 my $arg_vals = '';
 423                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 424
 425                 # lower-case is a keyword (e.g. `content', `oid'),
 426                 # ALL_CAPS is a string description (e.g. `PATH')
 427                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 428                         $desc .= "\ndefault: `$1'";
 429                 }
 430                 my (@vals, @s, @l);
 431                 my $x = $sw;
 432                 if ($x =~ s/!\z//) { # solve! => --no-solve
 433                         $x = "no-$x";
 434                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 435                         @vals = (' [', undef, ']');
 436                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 437                         @vals = (' ', undef);
 438                 } # else: no args $x = 'thread|t'
 439                 for (split(/\|/, $x)) { # help|h
 440                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 441                 }
 442                 if (!scalar(@vals)) { # no args 'thread|t'
 443                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 444                         $vals[1] = $1;
 445                 } else {
 446                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 447                 }
 448                 if ($arg_vals =~ /([,\|])/) {
 449                         my $sep = $1;
 450                         my @allow = split(/\Q$sep\E/, $arg_vals);
 451                         my $must = $sep eq '|' ? 'Must' : 'Can';
 452                         @allow = map { "`$_'" } @allow;
 453                         my $last = pop @allow;
 454                         $desc .= "\n$must be one of: " .
 455                                 join(', ', @allow) . " or $last";
 456                 }
 457                 my $lhs = join(', ', @s, @l) . join('', @vals);
 458                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 459                         $lhs =~ s/\A--/- , --/;
 460                 } else {
 461                         $lhs =~ s/\A--/    --/; # pad if no short options
 462                 }
 463                 $lpad = length($lhs) if length($lhs) > $lpad;
 464                 push @opt_desc, $lhs, $desc;
 465         }
 466         my $msg = $errmsg ? "E: $errmsg\n" : '';
 467         $msg .= <<EOF;
 468 usage: lei @top
 469   $cmd_desc
 470
 471 EOF
 472         $lpad += 2;
 473         local $Text::Wrap::columns = 78 - $lpad;
 474         my $padding = ' ' x ($lpad + 2);
 475         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 476                 $msg .= '  '.pack("A$lpad", $lhs);
 477                 $rhs = wrap('', '', $rhs);
 478                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 479                 $msg .= $rhs;
 480                 $msg .= "\n";
 481         }
 482         print { $self->{$errmsg ? 2 : 1} } $msg;
 483         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 484         undef;
 485 }
 486
 487 sub optparse ($$$) {
 488         my ($self, $cmd, $argv) = @_;
 489         $self->{cmd} = $cmd;
 490         $OPT = $self->{opt} = {};
 491         my $info = $CMD{$cmd} // [ '[...]' ];
 492         my ($proto, undef, @spec) = @$info;
 493         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 494         push @spec, qw(help|h);
 495         my $lone_dash;
 496         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 497                 $lone_dash = $spec[0];
 498                 $OPT->{$spec[0]} = \(my $var);
 499                 push @spec, '' => \$var;
 500         }
 501         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 502                 return _help($self, "bad arguments or options for $cmd");
 503         return _help($self) if $OPT->{help};
 504
 505         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 506
 507         # "-" aliases "stdin" or "clear"
 508         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 509
 510         my $i = 0;
 511         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 512         my ($err, $inf);
 513         my @args = split(/ /, $proto);
 514         for my $var (@args) {
 515                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 516                         $inf = defined($argv->[$i]) and last;
 517                         $var =~ s/\.\.\.\z//;
 518                         $err = "$var not supplied";
 519                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 520                         $argv->[$i++] // ($err = "$var not supplied");
 521                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 522                         $inf = 1;
 523                         last;
 524                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 525                         $i++;
 526                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 527                         my @or = split(/\|/, $var);
 528                         my $ok;
 529                         for my $o (@or) {
 530                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 531                                         $ok = defined($OPT->{$1});
 532                                         last;
 533                                 } elsif (defined($argv->[$i])) {
 534                                         $ok = 1;
 535                                         $i++;
 536                                         last;
 537                                 } # else continue looping
 538                         }
 539                         last if $ok;
 540                         my $last = pop @or;
 541                         $err = join(', ', @or) . " or $last must be set";
 542                 } else {
 543                         warn "BUG: can't parse `$var' in $proto";
 544                 }
 545                 last if $err;
 546         }
 547         if (!$inf && scalar(@$argv) > scalar(@args)) {
 548                 $err //= 'too many arguments';
 549         }
 550         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 551 }
 552
 553 sub dispatch {
 554         my ($self, $cmd, @argv) = @_;
 555         local $current_lei = $self; # for __WARN__
 556         dump_and_clear_log("from previous run\n");
 557         return _help($self, 'no command given') unless defined($cmd);
 558         my $func = "lei_$cmd";
 559         $func =~ tr/-/_/;
 560         if (my $cb = __PACKAGE__->can($func)) {
 561                 optparse($self, $cmd, \@argv) or return;
 562                 $cb->($self, @argv);
 563         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 564                 my $opt = {};
 565                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 566                         return _help($self, 'bad arguments or options');
 567                 _help($self);
 568         } else {
 569                 fail($self, "`$cmd' is not an lei command");
 570         }
 571 }
 572
 573 sub _lei_cfg ($;$) {
 574         my ($self, $creat) = @_;
 575         my $f = _config_path($self);
 576         my @st = stat($f);
 577         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 578         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 579                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 580         }
 581         if (!@st) {
 582                 unless ($creat) {
 583                         delete $self->{cfg};
 584                         return;
 585                 }
 586                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 587                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 588                 open my $fh, '>>', $f or die "open($f): $!\n";
 589                 @st = stat($fh) or die "fstat($f): $!\n";
 590                 $cur_st = pack('dd', $st[10], $st[7]);
 591                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 592         }
 593         my $cfg = PublicInbox::Config::git_config_dump($f);
 594         $cfg->{-st} = $cur_st;
 595         $cfg->{'-f'} = $f;
 596         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 597 }
 598
 599 sub _lei_store ($;$) {
 600         my ($self, $creat) = @_;
 601         my $cfg = _lei_cfg($self, $creat);
 602         $cfg->{-lei_store} //= do {
 603                 require PublicInbox::LeiStore;
 604                 my $dir = $cfg->{'leistore.dir'};
 605                 $dir //= $creat ? _store_path($self) : return;
 606                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 607         };
 608 }
 609
 610 sub lei_show {
 611         my ($self, @argv) = @_;
 612 }
 613
 614 sub lei_mark {
 615         my ($self, @argv) = @_;
 616 }
 617
 618 sub _config {
 619         my ($self, @argv) = @_;
 620         my $env = $self->{env};
 621         delete local $env->{GIT_CONFIG};
 622         delete local $ENV{GIT_CONFIG};
 623         my $cfg = _lei_cfg($self, 1);
 624         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 625         my %rdr = map { $_ => $self->{$_} } (0..2);
 626         waitpid(spawn($cmd, $env, \%rdr), 0);
 627 }
 628
 629 sub lei_config {
 630         my ($self, @argv) = @_;
 631         $self->{opt}->{'config-file'} and return fail $self,
 632                 "config file switches not supported by `lei config'";
 633         _config(@_);
 634         x_it($self, $?) if $?;
 635 }
 636
 637 sub lei_init {
 638         my ($self, $dir) = @_;
 639         my $cfg = _lei_cfg($self, 1);
 640         my $cur = $cfg->{'leistore.dir'};
 641         $dir //= _store_path($self);
 642         $dir = rel2abs($self, $dir);
 643         my @cur = stat($cur) if defined($cur);
 644         $cur = File::Spec->canonpath($cur // $dir);
 645         my @dir = stat($dir);
 646         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 647         if (@cur) {
 648                 if ($cur eq $dir) {
 649                         _lei_store($self, 1)->done;
 650                         return qerr($self, $exists);
 651                 }
 652
 653                 # some folks like symlinks and bind mounts :P
 654                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 655                         lei_config($self, 'leistore.dir', $dir);
 656                         _lei_store($self, 1)->done;
 657                         return qerr($self, "$exists (as $cur)");
 658                 }
 659                 return fail($self, <<"");
 660 E: leistore.dir=$cur already initialized and it is not $dir
 661
 662         }
 663         lei_config($self, 'leistore.dir', $dir);
 664         _lei_store($self, 1)->done;
 665         $exists //= "I: leistore.dir=$dir newly initialized";
 666         return qerr($self, $exists);
 667 }
 668
 669 sub lei_daemon_pid { puts shift, $$ }
 670
 671 sub lei_daemon_kill {
 672         my ($self) = @_;
 673         my $sig = $self->{opt}->{signal} // 'TERM';
 674         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 675 }
 676
 677 sub lei_help { _help($_[0]) }
 678
 679 # Shell completion helper.  Used by lei-completion.bash and hopefully
 680 # other shells.  Try to do as much here as possible to avoid redundancy
 681 # and improve maintainability.
 682 sub lei__complete {
 683         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 684         shift @argv; # ignore "lei", the entire command is sent
 685         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 686         my $cmd = shift @argv;
 687         my $info = $CMD{$cmd} // do { # filter matching commands
 688                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 689                 return;
 690         };
 691         my ($proto, undef, @spec) = @$info;
 692         my $cur = pop @argv;
 693         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 694         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 695                 # gross special case since the only git-config options
 696                 # Consider moving to a table if we need more special cases
 697                 # we use Getopt::Long for are the ones we reject, so these
 698                 # are the ones we don't reject:
 699                 if ($cmd eq 'config') {
 700                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 701                         @spec = qw(add z|null get get-all unset unset-all
 702                                 replace-all get-urlmatch
 703                                 remove-section rename-section
 704                                 name-only list|l edit|e
 705                                 get-color-name get-colorbool);
 706                         # fall-through
 707                 }
 708                 puts $self, grep(/$re/, map { # generate short/long names
 709                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 710                         } else { # negation: solve! => no-solve|solve
 711                                 s/\A(.+)!\z/no-$1|$1/;
 712                         }
 713                         map {
 714                                 my $x = length > 1 ? "--$_" : "-$_";
 715                                 $x eq $cur ? () : $x;
 716                         } split(/\|/, $_, -1) # help|h
 717                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 718         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 719                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 720         }
 721
 722         # switch args (e.g. lei q -f mbox<TAB>)
 723         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 724                 my $opt = quotemeta $1;
 725                 puts $self, map {
 726                         my $v = $OPTDESC{$_};
 727                         $v = $v->[0] if ref($v);
 728                         my @v = split(/\|/, $v);
 729                         # get rid of ALL CAPS placeholder (e.g "OUT")
 730                         # (TODO: completion for external paths)
 731                         shift(@v) if uc($v[0]) eq $v[0];
 732                         @v;
 733                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 734         }
 735         $cmd =~ tr/-/_/;
 736         if (my $sub = $self->can("_complete_$cmd")) {
 737                 puts $self, $sub->($self, @argv, $cur);
 738         }
 739         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 740         # proto parsing.
 741 }
 742
 743 sub exec_buf ($$) {
 744         my ($argv, $env) = @_;
 745         my $argc = scalar @$argv;
 746         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 747         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 748         $buf;
 749 }
 750
 751 sub start_mua {
 752         my ($self) = @_;
 753         my $mua = $self->{opt}->{'mua-cmd'} // return;
 754         my $mfolder = $self->{ovv}->{dst};
 755         my (@cmd, $replaced);
 756         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 757                 @cmd = ($mua, '-f');
 758         # TODO: help wanted: other common FOSS MUAs
 759         } else {
 760                 require Text::ParseWords;
 761                 my @cmd = Text::ParseWords::shellwords($mua);
 762                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 763                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 764         }
 765         push @cmd, $mfolder unless defined($replaced);
 766         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 767                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 768         } else { # oneshot
 769                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 770         }
 771 }
 772
 773 # caller needs to "-t $self->{1}" to check if tty
 774 sub start_pager {
 775         my ($self) = @_;
 776         my $env = $self->{env};
 777         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 778         chomp(my $pager = <$fh> // '');
 779         close($fh) or warn "`git var PAGER' error: \$?=$?";
 780         return if $pager eq 'cat' || $pager eq '';
 781         # TODO TIOCGWINSZ
 782         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 783         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 784         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 785         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 786         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 787         if (my $sock = $self->{sock}) { # lei(1) process runs it
 788                 delete @$new_env{keys %$env}; # only set iff unset
 789                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 790                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 791         } else {
 792                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 793         }
 794         $self->{1} = $wpager;
 795         $self->{2} = $wpager if -t $self->{2};
 796         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 797         $self->{pgr} = $pgr;
 798 }
 799
 800 sub stop_pager {
 801         my ($self) = @_;
 802         my $pgr = delete($self->{pgr}) or return;
 803         $self->{2} = $pgr->[2];
 804         # do not restore original stdout, just close it so we error out
 805         close(delete($self->{1})) if $self->{1};
 806         my $pid = $pgr->[0];
 807         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 808 }
 809
 810 sub accept_dispatch { # Listener {post_accept} callback
 811         my ($sock) = @_; # ignore other
 812         $sock->autoflush(1);
 813         my $self = bless { sock => $sock }, __PACKAGE__;
 814         vec(my $rvec = '', fileno($sock), 1) = 1;
 815         select($rvec, undef, undef, 1) or
 816                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 817         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 818         if (scalar(@fds) == 4) {
 819                 for my $i (0..3) {
 820                         my $fd = shift(@fds);
 821                         open($self->{$i}, '+<&=', $fd) and next;
 822                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 823                 }
 824         } else {
 825                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 826         }
 827         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 828         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 829         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 830         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 831                 return send($sock, 'request command truncated', MSG_EOR);
 832         my ($argc, @argv) = split(/\0/, $buf, -1);
 833         undef $buf;
 834         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 835         if (chdir($self->{3})) {
 836                 local %ENV = %env;
 837                 $self->{env} = \%env;
 838                 eval { dispatch($self, @argv) };
 839                 send($sock, $@, MSG_EOR) if $@;
 840         } else {
 841                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 842         }
 843 }
 844
 845 sub dclose {
 846         my ($self) = @_;
 847         for my $f (qw(lxs l2m)) {
 848                 my $wq = delete $self->{$f} or next;
 849                 if ($wq->wq_kill) {
 850                         $wq->wq_close
 851                 } elsif ($wq->wq_kill_old) {
 852                         $wq->wq_wait_old;
 853                 }
 854         }
 855         close(delete $self->{1}) if $self->{1}; # may reap_compress
 856         $self->close if $self->{sock}; # PublicInbox::DS::close
 857 }
 858
 859 # for long-running results
 860 sub event_step {
 861         my ($self) = @_;
 862         local %ENV = %{$self->{env}};
 863         my $sock = $self->{sock};
 864         local $current_lei = $self;
 865         eval {
 866                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 867                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 868                                 return if $! == EAGAIN;
 869                                 next if $! == EINTR;
 870                                 last if $! == ECONNRESET;
 871                                 die "recvmsg: $!";
 872                         }
 873                         for my $fd (@fds) {
 874                                 open my $rfh, '+<&=', $fd;
 875                         }
 876                         die "unrecognized client signal: $buf";
 877                 }
 878                 dclose($self);
 879         };
 880         if (my $err = $@) {
 881                 eval { $self->fail($err) };
 882                 dclose($self);
 883         }
 884 }
 885
 886 sub event_step_init {
 887         my ($self) = @_;
 888         if (my $sock = $self->{sock}) { # using DS->EventLoop
 889                 $sock->blocking(0);
 890                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 891         }
 892 }
 893
 894 sub noop {}
 895
 896 our $oldset; sub oldset { $oldset }
 897
 898 sub dump_and_clear_log {
 899         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 900                 my @pfx = @_;
 901                 unshift(@pfx, "$errors_log ") if @pfx;
 902                 warn @pfx, do { local $/; <STDIN> };
 903                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 904         }
 905 }
 906
 907 # lei(1) calls this when it can't connect
 908 sub lazy_start {
 909         my ($path, $errno, $narg) = @_;
 910         if ($errno == ECONNREFUSED) {
 911                 unlink($path) or die "unlink($path): $!";
 912         } elsif ($errno != ENOENT) {
 913                 $! = $errno; # allow interpolation to stringify in die
 914                 die "connect($path): $!";
 915         }
 916         umask(077) // die("umask(077): $!");
 917         local $listener;
 918         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 919         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 920         listen($listener, 1024) or die "listen: $!";
 921         my @st = stat($path) or die "stat($path): $!";
 922         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 923         local $oldset = PublicInbox::DS::block_signals();
 924         if ($narg == 5) {
 925                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 926                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 927                         require PublicInbox::CmdIPC4;
 928                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 929                         PublicInbox::CmdIPC4->can('recv_cmd4');
 930                 };
 931         }
 932         $recv_cmd or die <<"";
 933 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 934
 935         require PublicInbox::Listener;
 936         require PublicInbox::EOFpipe;
 937         (-p STDOUT) or die "E: stdout must be a pipe\n";
 938         local $errors_log;
 939         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 940         $errors_log .= 'errors.log';
 941         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 942         STDIN->autoflush(1);
 943         dump_and_clear_log("from previous daemon process:\n");
 944         POSIX::setsid() > 0 or die "setsid: $!";
 945         my $pid = fork // die "fork: $!";
 946         return if $pid;
 947         $0 = "lei-daemon $path";
 948         local %PATH2CFG;
 949         $listener->blocking(0);
 950         my $exit_code;
 951         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 952         local $quit = do {
 953                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 954                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 955                 sub {
 956                         $exit_code //= shift;
 957                         my $lis = $pil or exit($exit_code);
 958                         # closing eof_w triggers \&noop wakeup
 959                         $listener = $eof_w = $pil = $path = undef;
 960                         $lis->close; # DS::close
 961                         PublicInbox::DS->SetLoopTimeout(1000);
 962                 };
 963         };
 964         my $sig = {
 965                 CHLD => \&PublicInbox::DS::enqueue_reap,
 966                 QUIT => $quit,
 967                 INT => $quit,
 968                 TERM => $quit,
 969                 HUP => \&noop,
 970                 USR1 => \&noop,
 971                 USR2 => \&noop,
 972         };
 973         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 974         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 975         undef $sig;
 976         local $SIG{PIPE} = 'IGNORE';
 977         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 978                 undef $sigfd;
 979                 PublicInbox::DS->SetLoopTimeout(5000);
 980         } else {
 981                 # wake up every second to accept signals if we don't
 982                 # have signalfd or IO::KQueue:
 983                 PublicInbox::DS::sig_setmask($oldset);
 984                 PublicInbox::DS->SetLoopTimeout(1000);
 985         }
 986         PublicInbox::DS->SetPostLoopCallback(sub {
 987                 my ($dmap, undef) = @_;
 988                 if (@st = defined($path) ? stat($path) : ()) {
 989                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 990                                 warn "$path dev/ino changed, quitting\n";
 991                                 $path = undef;
 992                         }
 993                 } elsif (defined($path)) {
 994                         warn "stat($path): $!, quitting ...\n";
 995                         undef $path; # don't unlink
 996                         $quit->();
 997                 }
 998                 return 1 if defined($path);
 999                 my $now = now();
1000                 my $n = 0;
1001                 for my $s (values %$dmap) {
1002                         $s->can('busy') or next;
1003                         if ($s->busy($now)) {
1004                                 ++$n;
1005                         } else {
1006                                 $s->close;
1007                         }
1008                 }
1009                 $n; # true: continue, false: stop
1010         });
1011
1012         # STDIN was redirected to /dev/null above, closing STDERR and
1013         # STDOUT will cause the calling `lei' client process to finish
1014         # reading the <$daemon> pipe.
1015         openlog($path, 'pid', 'user');
1016         local $SIG{__WARN__} = sub {
1017                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
1018         };
1019         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
1020                 syslog('crit', "$@") if $@;
1021         });
1022         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1023         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1024         # $daemon pipe to `lei' closed, main loop begins:
1025         PublicInbox::DS->EventLoop;
1026         @$on_destroy = (); # cancel on_destroy if we get here
1027         exit($exit_code // 0);
1028 }
1029
1030 # for users w/o Socket::Msghdr installed or Inline::C enabled
1031 sub oneshot {
1032         my ($main_pkg) = @_;
1033         my $exit = $main_pkg->can('exit'); # caller may override exit()
1034         local $quit = $exit if $exit;
1035         local %PATH2CFG;
1036         umask(077) // die("umask(077): $!");
1037         my $self = bless {
1038                 0 => *STDIN{GLOB},
1039                 1 => *STDOUT{GLOB},
1040                 2 => *STDERR{GLOB},
1041                 env => \%ENV
1042         }, __PACKAGE__;
1043         dispatch($self, @ARGV);
1044         x_it($self, $self->{child_error}) if $self->{child_error};
1045 }
1046
1047 # ensures stdout hits the FS before sock disconnects so a client
1048 # can immediately reread it
1049 sub DESTROY {
1050         my ($self) = @_;
1051         $self->{1}->autoflush(1) if $self->{1};
1052         stop_pager($self);
1053         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1054                 waitpid($mua_pid, 0);
1055         }
1056 }
1057
1058 1;