lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 return $p;
  74         }
  75         my $pwd = $self->{env}->{PWD};
  76         my $cwd;
  77         if (defined $pwd) {
  78                 my $xcwd = $self->{3} //
  79                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  99                 .'/lei');
 100 }
 101
 102 sub store_path ($) { share_path($_[0]) . '/store' }
 103
 104 sub _config_path ($) {
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 108                 .'/lei/config');
 109 }
 110
 111 sub cache_dir ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 115                 .'/lei');
 116 }
 117
 118 sub ale {
 119         my ($self) = @_;
 120         $self->{ale} //= do {
 121                 require PublicInbox::LeiALE;
 122                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 123         };
 124 }
 125
 126 sub index_opt {
 127         # TODO: drop underscore variants everywhere, they're undocumented
 128         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 129         max_size|max-size=s sequential_shard|sequential-shard
 130         batch_size|batch-size=s skip-docdata)
 131 }
 132
 133 my @c_opt = qw(c=s@ C=s@ quiet|q);
 134 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 135         import-remote! no-torsocks torsocks=s),
 136         PublicInbox::LeiQuery::curl_opt());
 137
 138 # we generate shell completion + help using %CMD and %OPTDESC,
 139 # see lei__complete() and PublicInbox::LeiHelp
 140 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 141 our %CMD = ( # sorted in order of importance/use:
 142 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 143         'stdin|', # /|\z/ must be first for lone dash
 144         @lxs_opt,
 145         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 146         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 147         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 148         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 149
 150 'up' => [ 'OUTPUT|--all', 'update saved search',
 151         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 152
 153 'lcat' => [ '--stdin|MSGID_OR_URL..', 'display local copy of message(s)',
 154         'stdin|', # /|\z/ must be first for lone dash
 155         # some of these options are ridiculous for lcat
 156         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 157         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 158         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 159         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 160
 161 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 162         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 163         @lxs_opt, @c_opt ],
 164
 165 'add-external' => [ 'LOCATION',
 166         'add/set priority of a publicinbox|extindex for extra matches',
 167         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 168         verbose|v+), @c_opt, index_opt(),
 169         PublicInbox::LeiQuery::curl_opt() ],
 170 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 171         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 172 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 173 'ls-sync' => [ '', 'list sync folders',
 174                 qw(z|0 z|0 globoff|g invert-match|v local remote), @c_opt ],
 175 'forget-external' => [ 'LOCATION...|--prune',
 176         'exclude further results from a publicinbox|extindex',
 177         qw(prune), @c_opt ],
 178
 179 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 180                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 181 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 182                 qw(verbose|v+), @c_opt ],
 183 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 184                         @c_opt ],
 185
 186 'plonk' => [ '--threads|--from=IDENT',
 187         'exclude mail matching From: or threads from non-Message-ID searches',
 188         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 189 'tag' => [ 'KEYWORDS...',
 190         'set/unset keywords and/or labels on message(s)',
 191         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 192         pass_through('-kw:foo for delete') ],
 193 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 194         "exclude message(s) on stdin from `q' search results",
 195         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 196
 197 'purge-mailsource' => [ 'LOCATION|--all',
 198         'remove imported messages from IMAP, Maildirs, and MH',
 199         qw(exact! all jobs:i indexed), @c_opt ],
 200
 201 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 202         qw(import! kw! interval=s recursive|r
 203         exclude=s include=s), @c_opt ],
 204 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 205                 qw(format|f=s z), @c_opt ],
 206 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 207 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 208 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 209         qw(prune), @c_opt ],
 210
 211 'import' => [ 'LOCATION...|--stdin',
 212         'one-time import/update from URL or filesystem',
 213         qw(stdin| offset=i recursive|r exclude=s include|I=s
 214         lock=s@ in-format|F=s kw! verbose|v+ incremental! sync!), @c_opt ],
 215 'convert' => [ 'LOCATION...|--stdin',
 216         'one-time conversion from URL or filesystem to another format',
 217         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 218         lock=s@ kw!), @c_opt ],
 219 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 220         "use a patch to generate a query for `lei q --stdin'",
 221         qw(stdin| want|w=s@ uri debug), @c_opt ],
 222 'config' => [ '[...]', sub {
 223                 'git-config(1) wrapper for '._config_path($_[0]);
 224         }, qw(config-file|system|global|file|f=s), # for conflict detection
 225          qw(c=s@ C=s@), pass_through('git config') ],
 226 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 227         qw(pretty ascii dir=s), @c_opt ],
 228
 229 'init' => [ '[DIRNAME]', sub {
 230         "initialize storage, default: ".store_path($_[0]);
 231         }, @c_opt ],
 232 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 233         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 234         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 235 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 236 'help' => [ '[SUBCOMMAND]', 'show help' ],
 237
 238 # XXX do we need this?
 239 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 240
 241 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 242         'rewrite git history in an attempt to improve compression',
 243         qw(gc!), @c_opt ],
 244
 245 # internal commands are prefixed with '_'
 246 '_complete' => [ '[...]', 'internal shell completion helper',
 247                 pass_through('everything') ],
 248 ); # @CMD
 249
 250 # switch descriptions, try to keep consistent across commands
 251 # $spec: Getopt::Long option specification
 252 # $spec => [@ALLOWED_VALUES (default is first), $description],
 253 # $spec => $description
 254 # "$SUB_COMMAND TAB $spec" => as above
 255 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 256                         'specify message input format' ];
 257 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 258
 259 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 260 my %OPTDESC = (
 261 'help|h' => 'show this built-in help',
 262 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 263 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 264 'quiet|q' => 'be quiet',
 265 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 266         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 267
 268 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 269 'globoff|g' => "do not match locations using '*?' wildcards ".
 270                 "and\xa0'[]'\x{a0}ranges",
 271 'color!' => 'disable color (for --format=text)',
 272 'verbose|v+' => 'be more verbose',
 273 'external!' => 'do not use externals',
 274 'mail!' => 'do not look in mail storage for OID',
 275 'cwd!' => 'do not look in git repo of current working directory',
 276 'oid-a|A=s' => 'pre-image OID',
 277 'path-a|a=s' => 'pre-image pathname associated with OID',
 278 'path-b|b=s' => 'post-image pathname associated with OID',
 279 'git-dir=s@' => 'additional git repository to scan',
 280 'torsocks=s' => ['VAL|auto|no|yes',
 281                 'whether or not to wrap git and curl commands with torsocks'],
 282 'no-torsocks' => 'alias for --torsocks=no',
 283 'save' =>  "save a search for `lei up'",
 284 'import-remote!' => 'do not memoize remote messages into local store',
 285
 286 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 287
 288 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 289                 'deduplication strategy'],
 290 'threads|t+' =>
 291         'return all messages in the same threads as the actual match(es)',
 292
 293 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 294                 'search prefixes to extract (default: dfpost7)' ],
 295
 296 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 297         'run command(s) or perform ops when done writing to output ' .
 298         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 299         'nothing otherwise)' ],
 300
 301 'augment|a' => 'augment --output destination instead of clobbering',
 302
 303 'output|mfolder|o=s' => [ 'MFOLDER',
 304         "destination (e.g.\xa0`/path/to/Maildir', ".
 305         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 306 'mua=s' => [ 'CMD',
 307         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 308
 309 'inbox-version=i' => [ 'NUM|1|2',
 310                 'force a public-inbox version with --mirror'],
 311 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 312
 313 # public-inbox-index options
 314 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 315 'compact' => 'run compact index after mirroring',
 316 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 317         "indexlevel with --mirror (default: full)" ],
 318 'max_size|max-size=s' => [ 'SIZE',
 319         'do not index messages larger than SIZE (default: infinity)' ],
 320 'batch_size|batch-size=s' => [ 'SIZE',
 321         'flush changes to OS after given number of bytes (default: 1m)' ],
 322 'sequential_shard|sequential-shard' =>
 323         'index Xapian shards sequentially for slow storage',
 324 'skip-docdata' =>
 325         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 326
 327 'format|f=s     q' => [
 328         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 329                 'specify output format, default depends on --output'],
 330 'exclude=s@     q' => [ 'LOCATION',
 331                 'exclude specified external(s) from search' ],
 332 'include|I=s@   q' => [ 'LOCATION',
 333                 'include specified external(s) in search' ],
 334 'only=s@        q' => [ 'LOCATION',
 335                 'only use specified external(s) for search' ],
 336 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 337                 'control number of search and writer jobs' ],
 338 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 339
 340 'in-format|F=s' => $stdin_formats,
 341 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 342                         'listing output format' ],
 343 'l      ls-search' => 'long listing format',
 344 'format|f=s     ls-external' => $ls_format,
 345
 346 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 347 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 348
 349 'sort|s=s' => [ 'VAL|received|relevance|docid',
 350                 "order of results is `--output'-dependent"],
 351 'reverse|r' => 'reverse search results', # like sort(1)
 352
 353 'boost=i' => 'increase/decrease priority of results (default: 0)',
 354
 355 'local' => 'limit operations to the local filesystem',
 356 'local!' => 'exclude results from the local filesystem',
 357 'remote' => 'limit operations to those requiring network access',
 358 'remote!' => 'prevent operations requiring network access',
 359
 360 'all:s  up' => ['local', 'update all (local) saved searches' ],
 361
 362 'mid=s' => 'specify the Message-ID of a message',
 363 'oid=s' => 'specify the git object ID of a message',
 364
 365 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 366 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 367 'include=s' => 'include mailboxes/newsgroups based on pattern',
 368
 369 'exact' => 'operate on exact header matches only',
 370 'exact!' => 'rely on content match instead of exact header matches',
 371
 372 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 373
 374 'kw!' => 'disable/enable importing keywords (aka "flags")',
 375
 376 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 377 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 378
 379 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 380 ); # %OPTDESC
 381
 382 my %CONFIG_KEYS = (
 383         'leistore.dir' => 'top-level storage location',
 384 );
 385
 386 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 387
 388 sub _drop_wq {
 389         my ($self) = @_;
 390         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) { $wq->DESTROY }
 391 }
 392
 393 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 394 sub x_it ($$) {
 395         my ($self, $code) = @_;
 396         # make sure client sees stdout before exit
 397         $self->{1}->autoflush(1) if $self->{1};
 398         dump_and_clear_log();
 399         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 400                 send($s, "x_it $code", MSG_EOR);
 401         } elsif ($self->{oneshot}) {
 402                 # don't want to end up using $? from child processes
 403                 _drop_wq($self);
 404                 # cleanup anything that has tempfiles or open file handles
 405                 %PATH2CFG = ();
 406                 delete @$self{qw(ovv dedupe sto cfg)};
 407                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 408                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 409                         kill $signum, $$;
 410                         sleep(1) while 1; # wait for signal
 411                 } else {
 412                         $quit->($code >> 8);
 413                 }
 414         } # else ignore if client disconnected
 415 }
 416
 417 sub err ($;@) {
 418         my $self = shift;
 419         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 420         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 421         print $err @_, @eor and return;
 422         my $old_err = delete $self->{2};
 423         close($old_err) if $! == EPIPE && $old_err;
 424         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 425         print $err @_, @eor or print STDERR @_, @eor;
 426 }
 427
 428 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 429
 430 sub fail_handler ($;$$) {
 431         my ($lei, $code, $io) = @_;
 432         close($io) if $io; # needed to avoid warnings on SIGPIPE
 433         _drop_wq($lei);
 434         x_it($lei, $code // (1 << 8));
 435 }
 436
 437 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 438         fail_handler($_[0], 13, delete $_[0]->{1});
 439 }
 440
 441 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 442 sub sigint_reap {
 443         my ($pgid) = @_;
 444         dwaitpid($pgid) if kill('-INT', $pgid);
 445 }
 446
 447 sub fail ($$;$) {
 448         my ($self, $buf, $exit_code) = @_;
 449         err($self, $buf) if defined $buf;
 450         # calls fail_handler:
 451         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 452         x_it($self, ($exit_code // 1) << 8);
 453         undef;
 454 }
 455
 456 sub out ($;@) {
 457         my $self = shift;
 458         return if print { $self->{1} // return } @_; # likely
 459         return note_sigpipe($self, 1) if $! == EPIPE;
 460         my $err = "error writing to output: $!";
 461         delete $self->{1};
 462         fail($self, $err);
 463 }
 464
 465 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 466
 467 sub child_error { # passes non-fatal curl exit codes to user
 468         my ($self, $child_error, $msg) = @_; # child_error is $?
 469         $self->err($msg) if $msg;
 470         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 471                 # send to the parent lei-daemon or to lei(1) client
 472                 send($s, "child_error $child_error", MSG_EOR);
 473         } elsif (!$PublicInbox::DS::in_loop) {
 474                 $self->{child_error} = $child_error;
 475         } # else noop if client disconnected
 476 }
 477
 478 sub note_sigpipe { # triggers sigpipe_handler
 479         my ($self, $fd) = @_;
 480         close(delete($self->{$fd})); # explicit close silences Perl warning
 481         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 482         x_it($self, 13);
 483 }
 484
 485 sub _lei_atfork_child {
 486         my ($self, $persist) = @_;
 487         # we need to explicitly close things which are on stack
 488         if ($persist) {
 489                 chdir '/' or die "chdir(/): $!";
 490                 my @io = delete @$self{qw(0 1 2 sock)};
 491                 unless ($self->{oneshot}) {
 492                         close($_) for @io;
 493                 }
 494                 if (my $cfg = $self->{cfg}) {
 495                         delete $cfg->{-lei_store};
 496                 }
 497         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 498                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 499         }
 500         for (delete @$self{qw(3 old_1 au_done)}) {
 501                 close($_) if defined($_);
 502         }
 503         if (my $op_c = delete $self->{pkt_op_c}) {
 504                 close(delete $op_c->{sock});
 505         }
 506         if (my $pgr = delete $self->{pgr}) {
 507                 close($_) for (@$pgr[1,2]);
 508         }
 509         close $listener if $listener;
 510         undef $listener;
 511         %PATH2CFG = ();
 512         undef $errors_log;
 513         $quit = \&CORE::exit;
 514         $self->{-eml_noisy} or # only "lei import" sets this atm
 515                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 516         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 517 }
 518
 519 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 520         my ($self) = @_;
 521         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 522                 $op->close; # PublicInbox::PktOp::close
 523         }
 524         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 525         close $unclosed_after_die;
 526 }
 527
 528 sub pkt_op_pair {
 529         my ($self) = @_;
 530         require PublicInbox::OnDestroy;
 531         require PublicInbox::PktOp;
 532         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 533         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 534         $end;
 535 }
 536
 537 sub workers_start {
 538         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 539         $ops = {
 540                 '!' => [ \&fail_handler, $lei ],
 541                 '|' => [ \&sigpipe_handler, $lei ],
 542                 'x_it' => [ \&x_it, $lei ],
 543                 'child_error' => [ \&child_error, $lei ],
 544                 ($ops ? %$ops : ()),
 545         };
 546         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 547         my $end = $lei->pkt_op_pair;
 548         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 549         delete $lei->{pkt_op_p};
 550         my $op_c = delete $lei->{pkt_op_c};
 551         @$end = ();
 552         $lei->event_step_init;
 553         ($op_c, $ops);
 554 }
 555
 556 sub _help {
 557         require PublicInbox::LeiHelp;
 558         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 559 }
 560
 561 sub optparse ($$$) {
 562         my ($self, $cmd, $argv) = @_;
 563         # allow _complete --help to complete, not show help
 564         return 1 if substr($cmd, 0, 1) eq '_';
 565         $self->{cmd} = $cmd;
 566         $OPT = $self->{opt} //= {};
 567         my $info = $CMD{$cmd} // [ '[...]' ];
 568         my ($proto, undef, @spec) = @$info;
 569         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 570         push @spec, qw(help|h);
 571         my $lone_dash;
 572         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 573                 $lone_dash = $spec[0];
 574                 $OPT->{$spec[0]} = \(my $var);
 575                 push @spec, '' => \$var;
 576         }
 577         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 578                 return _help($self, "bad arguments or options for $cmd");
 579         return _help($self) if $OPT->{help};
 580
 581         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 582
 583         # "-" aliases "stdin" or "clear"
 584         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 585
 586         my $i = 0;
 587         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 588         my ($err, $inf);
 589         my @args = split(/ /, $proto);
 590         for my $var (@args) {
 591                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 592                         $inf = defined($argv->[$i]) and last;
 593                         $var =~ s/\.\.\.\z//;
 594                         $err = "$var not supplied";
 595                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 596                         $argv->[$i++] // ($err = "$var not supplied");
 597                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 598                         $inf = 1;
 599                         last;
 600                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 601                         $i++;
 602                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 603                         $inf = 1 if index($var, '...') > 0;
 604                         my @or = split(/\|/, $var);
 605                         my $ok;
 606                         for my $o (@or) {
 607                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 608                                         $ok = defined($OPT->{$1});
 609                                         last if $ok;
 610                                 } elsif (defined($argv->[$i])) {
 611                                         $ok = 1;
 612                                         $i++;
 613                                         last;
 614                                 } # else continue looping
 615                         }
 616                         last if $ok;
 617                         my $last = pop @or;
 618                         $err = join(', ', @or) . " or $last must be set";
 619                 } else {
 620                         warn "BUG: can't parse `$var' in $proto";
 621                 }
 622                 last if $err;
 623         }
 624         if (!$inf && scalar(@$argv) > scalar(@args)) {
 625                 $err //= 'too many arguments';
 626         }
 627         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 628 }
 629
 630 sub _tmp_cfg { # for lei -c <name>=<value> ...
 631         my ($self) = @_;
 632         my $cfg = _lei_cfg($self, 1);
 633         require File::Temp;
 634         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 635         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 636         $ft->autoflush(1);
 637         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 638 [include]
 639         path = $cfg->{-f}
 640 EOM
 641         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 642         for (@{$self->{opt}->{c}}) {
 643                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 644 `-c $_' is not of the form -c <name>=<value>'
 645 EOM
 646                 my $name = $1;
 647                 my $value = $2 // 1;
 648                 _config($self, '--add', $name, $value);
 649                 if (defined(my $v = $tmp->{$name})) {
 650                         if (ref($v) eq 'ARRAY') {
 651                                 push @$v, $value;
 652                         } else {
 653                                 $tmp->{$name} = [ $v, $value ];
 654                         }
 655                 } else {
 656                         $tmp->{$name} = $value;
 657                 }
 658         }
 659 }
 660
 661 sub lazy_cb ($$$) {
 662         my ($self, $cmd, $pfx) = @_;
 663         my $ucmd = $cmd;
 664         $ucmd =~ tr/-/_/;
 665         my $cb;
 666         $cb = $self->can($pfx.$ucmd) and return $cb;
 667         my $base = $ucmd;
 668         $base =~ s/_([a-z])/\u$1/g;
 669         my $pkg = "PublicInbox::Lei\u$base";
 670         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 671                 $pkg->can($pfx.$ucmd) : undef;
 672 }
 673
 674 sub dispatch {
 675         my ($self, $cmd, @argv) = @_;
 676         local $current_lei = $self; # for __WARN__
 677         dump_and_clear_log("from previous run\n");
 678         return _help($self, 'no command given') unless defined($cmd);
 679         # do not support Getopt bundling for this
 680         while ($cmd eq '-C' || $cmd eq '-c') {
 681                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 682                                         '-C DIRECTORY' : '-c <name>=<value>');
 683                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 684                 $cmd = shift(@argv) // return _help($self, 'no command given');
 685         }
 686         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 687                 optparse($self, $cmd, \@argv) or return;
 688                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 689                 if (my $chdir = $self->{opt}->{C}) {
 690                         for my $d (@$chdir) {
 691                                 next if $d eq ''; # same as git(1)
 692                                 chdir $d or return fail($self, "cd $d: $!");
 693                         }
 694                         if (delete $self->{3}) { # update cwd for rel2abs
 695                                 opendir my $dh, '.' or
 696                                         return fail($self, "opendir . $!");
 697                                 $self->{3} = $dh;
 698                         }
 699                 }
 700                 $cb->($self, @argv);
 701         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 702                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 703                         or return _help($self, 'bad arguments or options');
 704                 _help($self);
 705         } else {
 706                 fail($self, "`$cmd' is not an lei command");
 707         }
 708 }
 709
 710 sub _lei_cfg ($;$) {
 711         my ($self, $creat) = @_;
 712         return $self->{cfg} if $self->{cfg};
 713         my $f = _config_path($self);
 714         my @st = stat($f);
 715         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 716         my ($sto, $sto_dir);
 717         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 718                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 719                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 720         }
 721         if (!@st) {
 722                 unless ($creat) {
 723                         delete $self->{cfg};
 724                         return bless {}, 'PublicInbox::Config';
 725                 }
 726                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 727                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 728                 open my $fh, '>>', $f or die "open($f): $!\n";
 729                 @st = stat($fh) or die "fstat($f): $!\n";
 730                 $cur_st = pack('dd', $st[10], $st[7]);
 731                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 732         }
 733         my $cfg = PublicInbox::Config->git_config_dump($f);
 734         $cfg->{-st} = $cur_st;
 735         $cfg->{'-f'} = $f;
 736         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 737                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 738                                                 store_path($self))) {
 739                 $cfg->{-lei_store} = $sto;
 740         }
 741         if (scalar(keys %PATH2CFG) > 5) {
 742                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 743                 for my $k (keys %PATH2CFG) {
 744                         delete($PATH2CFG{$k}) unless -f $k
 745                 }
 746         }
 747         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 748 }
 749
 750 sub _lei_store ($;$) {
 751         my ($self, $creat) = @_;
 752         my $cfg = _lei_cfg($self, $creat);
 753         $cfg->{-lei_store} //= do {
 754                 require PublicInbox::LeiStore;
 755                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 756                 return unless $creat || -d $dir;
 757                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 758         };
 759 }
 760
 761 sub _config {
 762         my ($self, @argv) = @_;
 763         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 764         my $cfg = _lei_cfg($self, 1);
 765         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 766         my %rdr = map { $_ => $self->{$_} } (0..2);
 767         waitpid(spawn($cmd, \%env, \%rdr), 0);
 768 }
 769
 770 sub lei_config {
 771         my ($self, @argv) = @_;
 772         $self->{opt}->{'config-file'} and return fail $self,
 773                 "config file switches not supported by `lei config'";
 774         _config(@_);
 775         x_it($self, $?) if $?;
 776 }
 777
 778 sub lei_daemon_pid { puts shift, $$ }
 779
 780 sub lei_daemon_kill {
 781         my ($self) = @_;
 782         my $sig = $self->{opt}->{signal} // 'TERM';
 783         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 784 }
 785
 786 # Shell completion helper.  Used by lei-completion.bash and hopefully
 787 # other shells.  Try to do as much here as possible to avoid redundancy
 788 # and improve maintainability.
 789 sub lei__complete {
 790         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 791         shift @argv; # ignore "lei", the entire command is sent
 792         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 793         my $cmd = shift @argv;
 794         my $info = $CMD{$cmd} // do { # filter matching commands
 795                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 796                 return;
 797         };
 798         my ($proto, undef, @spec) = @$info;
 799         my $cur = pop @argv;
 800         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 801         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 802                 # gross special case since the only git-config options
 803                 # Consider moving to a table if we need more special cases
 804                 # we use Getopt::Long for are the ones we reject, so these
 805                 # are the ones we don't reject:
 806                 if ($cmd eq 'config') {
 807                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 808                         @spec = qw(add z|null get get-all unset unset-all
 809                                 replace-all get-urlmatch
 810                                 remove-section rename-section
 811                                 name-only list|l edit|e
 812                                 get-color-name get-colorbool);
 813                         # fall-through
 814                 }
 815                 # generate short/long names from Getopt::Long specs
 816                 puts $self, grep(/$re/, qw(--help -h -C), map {
 817                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 818                         } elsif (s/\+\z//) { # verbose|v+
 819                         } elsif (s/!\z//) {
 820                                 # negation: mail! => no-mail|mail
 821                                 s/([\w\-]+)/$1|no-$1/g
 822                         }
 823                         map {
 824                                 my $x = length > 1 ? "--$_" : "-$_";
 825                                 $x eq $_cur ? () : $x;
 826                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 827                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 828         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 829                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 830         }
 831
 832         # switch args (e.g. lei q -f mbox<TAB>)
 833         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 834                 my $opt = quotemeta $1;
 835                 puts $self, map {
 836                         my $v = $OPTDESC{$_};
 837                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 838                         # get rid of ALL CAPS placeholder (e.g "OUT")
 839                         # (TODO: completion for external paths)
 840                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 841                         @v;
 842                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 843         }
 844         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 845                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 846         }
 847         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 848         # proto parsing.
 849 }
 850
 851 sub exec_buf ($$) {
 852         my ($argv, $env) = @_;
 853         my $argc = scalar @$argv;
 854         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 855         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 856         $buf;
 857 }
 858
 859 sub start_mua {
 860         my ($self) = @_;
 861         my $mua = $self->{opt}->{mua} // return;
 862         my $mfolder = $self->{ovv}->{dst};
 863         my (@cmd, $replaced);
 864         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 865                 @cmd = ($mua, '-f');
 866         # TODO: help wanted: other common FOSS MUAs
 867         } else {
 868                 require Text::ParseWords;
 869                 @cmd = Text::ParseWords::shellwords($mua);
 870                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 871                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 872         }
 873         push @cmd, $mfolder unless defined($replaced);
 874         if ($self->{sock}) { # lei(1) client process runs it
 875                 # restore terminal: echo $query | lei q -stdin --mua=...
 876                 my $io = [];
 877                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 878                 send_exec_cmd($self, $io, \@cmd, {});
 879         } elsif ($self->{oneshot}) {
 880                 my $pid = fork // die "fork: $!";
 881                 if ($pid > 0) { # original process
 882                         if ($self->{opt}->{stdin} && -t STDOUT) {
 883                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 884                         }
 885                         exec(@cmd);
 886                         warn "exec @cmd: $!\n";
 887                         POSIX::_exit(1);
 888                 }
 889                 POSIX::setsid() > 0 or die "setsid: $!";
 890         }
 891         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 892                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 893         }
 894         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 895         $self->{opt}->{quiet} = 1;
 896         delete $self->{-progress};
 897         delete $self->{opt}->{verbose};
 898 }
 899
 900 sub send_exec_cmd { # tell script/lei to execute a command
 901         my ($self, $io, $cmd, $env) = @_;
 902         my $sock = $self->{sock} // die 'lei client gone';
 903         my $fds = [ map { fileno($_) } @$io ];
 904         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 905 }
 906
 907 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 908         my ($self) = @_;
 909         my $alerts = $self->{opt}->{alert} // return;
 910         while (my $op = shift(@$alerts)) {
 911                 if ($op eq ':WINCH') {
 912                         # hit the process group that started the MUA
 913                         if ($self->{sock}) {
 914                                 send($self->{sock}, '-WINCH', MSG_EOR);
 915                         } elsif ($self->{oneshot}) {
 916                                 kill('-WINCH', $$);
 917                         }
 918                 } elsif ($op eq ':bell') {
 919                         out($self, "\a");
 920                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 921                         push @$alerts, split(/(?<!\\),/, $op);
 922                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 923                         my $cmd = $1; # run an arbitrary command
 924                         require Text::ParseWords;
 925                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 926                         if (my $s = $self->{sock}) {
 927                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 928                         } elsif ($self->{oneshot}) {
 929                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 930                         }
 931                 } else {
 932                         err($self, "W: unsupported --alert=$op"); # non-fatal
 933                 }
 934         }
 935 }
 936
 937 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 938 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 939
 940 # this also normalizes the path
 941 sub path_to_fd {
 942         my ($self, $path) = @_;
 943         $path = rel2abs($self, $path);
 944         $path =~ tr!/!/!s;
 945         $path_to_fd{$path} // (
 946                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 947                         fail($self, "cannot open $path from daemon") : -1
 948         );
 949 }
 950
 951 # caller needs to "-t $self->{1}" to check if tty
 952 sub start_pager {
 953         my ($self) = @_;
 954         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 955         chomp(my $pager = <$fh> // '');
 956         close($fh) or warn "`git var PAGER' error: \$?=$?";
 957         return if $pager eq 'cat' || $pager eq '';
 958         my $new_env = { LESS => 'FRX', LV => '-c' };
 959         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 960         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 961         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 962         my $pgr = [ undef, @$rdr{1, 2} ];
 963         my $env = $self->{env};
 964         if ($self->{sock}) { # lei(1) process runs it
 965                 delete @$new_env{keys %$env}; # only set iff unset
 966                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 967         } elsif ($self->{oneshot}) {
 968                 my $cmd = [$pager];
 969                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 970         } else {
 971                 die 'BUG: start_pager w/o socket';
 972         }
 973         $self->{1} = $wpager;
 974         $self->{2} = $wpager if -t $self->{2};
 975         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 976         $self->{pgr} = $pgr;
 977 }
 978
 979 sub stop_pager {
 980         my ($self) = @_;
 981         my $pgr = delete($self->{pgr}) or return;
 982         $self->{2} = $pgr->[2];
 983         # do not restore original stdout, just close it so we error out
 984         close(delete($self->{1})) if $self->{1};
 985 }
 986
 987 sub accept_dispatch { # Listener {post_accept} callback
 988         my ($sock) = @_; # ignore other
 989         $sock->autoflush(1);
 990         my $self = bless { sock => $sock }, __PACKAGE__;
 991         vec(my $rvec = '', fileno($sock), 1) = 1;
 992         select($rvec, undef, undef, 60) or
 993                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 994         # (4096 * 33) >MAX_ARG_STRLEN
 995         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 996         if (!defined($fds[0])) {
 997                 warn(my $msg = "recv_cmd failed: $!");
 998                 return send($sock, $msg, MSG_EOR);
 999         } else {
1000                 my $i = 0;
1001                 for my $fd (@fds) {
1002                         open($self->{$i++}, '+<&=', $fd) and next;
1003                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1004                 }
1005                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1006         }
1007         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
1008         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1009         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1010         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1011                 return send($sock, 'request command truncated', MSG_EOR);
1012         my ($argc, @argv) = split(/\0/, $buf, -1);
1013         undef $buf;
1014         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1015         if (chdir($self->{3})) {
1016                 local %ENV = %env;
1017                 $self->{env} = \%env;
1018                 eval { dispatch($self, @argv) };
1019                 send($sock, $@, MSG_EOR) if $@;
1020         } else {
1021                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1022         }
1023 }
1024
1025 sub dclose {
1026         my ($self) = @_;
1027         delete $self->{-progress};
1028         _drop_wq($self);
1029         close(delete $self->{1}) if $self->{1}; # may reap_compress
1030         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1031 }
1032
1033 # for long-running results
1034 sub event_step {
1035         my ($self) = @_;
1036         local %ENV = %{$self->{env}};
1037         my $sock = $self->{sock};
1038         local $current_lei = $self;
1039         eval {
1040                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1041                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1042                                 return if $! == EAGAIN;
1043                                 next if $! == EINTR;
1044                                 last if $! == ECONNRESET;
1045                                 die "recvmsg: $!";
1046                         }
1047                         for my $fd (@fds) {
1048                                 open my $rfh, '+<&=', $fd;
1049                         }
1050                         die "unrecognized client signal: $buf";
1051                 }
1052                 dclose($self);
1053         };
1054         if (my $err = $@) {
1055                 eval { $self->fail($err) };
1056                 dclose($self);
1057         }
1058 }
1059
1060 sub event_step_init {
1061         my ($self) = @_;
1062         return if $self->{-event_init_done}++;
1063         if (my $sock = $self->{sock}) { # using DS->EventLoop
1064                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1065         }
1066 }
1067
1068 sub noop {}
1069
1070 sub oldset { $oldset }
1071
1072 sub dump_and_clear_log {
1073         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1074                 my @pfx = @_;
1075                 unshift(@pfx, "$errors_log ") if @pfx;
1076                 warn @pfx, do { local $/; <STDIN> };
1077                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1078         }
1079 }
1080
1081 # lei(1) calls this when it can't connect
1082 sub lazy_start {
1083         my ($path, $errno, $narg) = @_;
1084         local ($errors_log, $listener);
1085         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1086         $errors_log .= 'errors.log';
1087         my $addr = pack_sockaddr_un($path);
1088         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1089         $lk->lock_acquire;
1090         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1091         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1092                 return if connect($listener, $addr); # another process won
1093                 if ($errno == ECONNREFUSED && -S $path) {
1094                         unlink($path) or die "unlink($path): $!";
1095                 }
1096         } else {
1097                 $! = $errno; # allow interpolation to stringify in die
1098                 die "connect($path): $!";
1099         }
1100         umask(077) // die("umask(077): $!");
1101         bind($listener, $addr) or die "bind($path): $!";
1102         listen($listener, 1024) or die "listen: $!";
1103         $lk->lock_release;
1104         undef $lk;
1105         my @st = stat($path) or die "stat($path): $!";
1106         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1107         local $oldset = PublicInbox::DS::block_signals();
1108         if ($narg == 5) {
1109                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1110                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1111                         require PublicInbox::CmdIPC4;
1112                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1113                         PublicInbox::CmdIPC4->can('recv_cmd4');
1114                 };
1115         }
1116         $recv_cmd or die <<"";
1117 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1118
1119         require PublicInbox::Listener;
1120         require PublicInbox::EOFpipe;
1121         (-p STDOUT) or die "E: stdout must be a pipe\n";
1122         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1123         STDIN->autoflush(1);
1124         dump_and_clear_log("from previous daemon process:\n");
1125         POSIX::setsid() > 0 or die "setsid: $!";
1126         my $pid = fork // die "fork: $!";
1127         return if $pid;
1128         $0 = "lei-daemon $path";
1129         local %PATH2CFG;
1130         $listener->blocking(0);
1131         my $exit_code;
1132         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1133         local $quit = do {
1134                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1135                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1136                 sub {
1137                         $exit_code //= shift;
1138                         my $lis = $pil or exit($exit_code);
1139                         # closing eof_w triggers \&noop wakeup
1140                         $listener = $eof_w = $pil = $path = undef;
1141                         $lis->close; # DS::close
1142                         PublicInbox::DS->SetLoopTimeout(1000);
1143                 };
1144         };
1145         my $sig = {
1146                 CHLD => \&PublicInbox::DS::enqueue_reap,
1147                 QUIT => $quit,
1148                 INT => $quit,
1149                 TERM => $quit,
1150                 HUP => \&noop,
1151                 USR1 => \&noop,
1152                 USR2 => \&noop,
1153         };
1154         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1155         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1156         undef $sig;
1157         local $SIG{PIPE} = 'IGNORE';
1158         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1159                 undef $sigfd;
1160                 PublicInbox::DS->SetLoopTimeout(5000);
1161         } else {
1162                 # wake up every second to accept signals if we don't
1163                 # have signalfd or IO::KQueue:
1164                 PublicInbox::DS::sig_setmask($oldset);
1165                 PublicInbox::DS->SetLoopTimeout(1000);
1166         }
1167         PublicInbox::DS->SetPostLoopCallback(sub {
1168                 my ($dmap, undef) = @_;
1169                 if (@st = defined($path) ? stat($path) : ()) {
1170                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1171                                 warn "$path dev/ino changed, quitting\n";
1172                                 $path = undef;
1173                         }
1174                 } elsif (defined($path)) { # ENOENT is common
1175                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1176                         undef $path;
1177                         $quit->();
1178                 }
1179                 return 1 if defined($path);
1180                 my $now = now();
1181                 my $n = 0;
1182                 for my $s (values %$dmap) {
1183                         $s->can('busy') or next;
1184                         if ($s->busy($now)) {
1185                                 ++$n;
1186                         } else {
1187                                 $s->close;
1188                         }
1189                 }
1190                 $n; # true: continue, false: stop
1191         });
1192
1193         # STDIN was redirected to /dev/null above, closing STDERR and
1194         # STDOUT will cause the calling `lei' client process to finish
1195         # reading the <$daemon> pipe.
1196         local $SIG{__WARN__} = sub {
1197                 $current_lei ? err($current_lei, @_) : warn(
1198                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1199         };
1200         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1201         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1202         # $daemon pipe to `lei' closed, main loop begins:
1203         PublicInbox::DS->EventLoop;
1204         exit($exit_code // 0);
1205 }
1206
1207 sub busy { 1 } # prevent daemon-shutdown if client is connected
1208
1209 # for users w/o Socket::Msghdr installed or Inline::C enabled
1210 sub oneshot {
1211         my ($main_pkg) = @_;
1212         my $exit = $main_pkg->can('exit'); # caller may override exit()
1213         local $quit = $exit if $exit;
1214         local %PATH2CFG;
1215         umask(077) // die("umask(077): $!");
1216         my $self = bless {
1217                 oneshot => 1,
1218                 0 => *STDIN{GLOB},
1219                 1 => *STDOUT{GLOB},
1220                 2 => *STDERR{GLOB},
1221                 env => \%ENV
1222         }, __PACKAGE__;
1223         dispatch($self, @ARGV);
1224         x_it($self, $self->{child_error}) if $self->{child_error};
1225 }
1226
1227 # ensures stdout hits the FS before sock disconnects so a client
1228 # can immediately reread it
1229 sub DESTROY {
1230         my ($self) = @_;
1231         $self->{1}->autoflush(1) if $self->{1};
1232         stop_pager($self);
1233         my $err = $?;
1234         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1235         waitpid($_, 0) for keys %$oneshot_pids;
1236         $? = $err if $err; # preserve ->fail or ->x_it code
1237 }
1238
1239 sub wq_done_wait { # dwaitpid callback
1240         my ($arg, $pid) = @_;
1241         my ($wq, $lei) = @$arg;
1242         my $err_type = $lei->{-err_type};
1243         $? and $lei->child_error($?,
1244                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1245         $lei->dclose;
1246 }
1247
1248 sub wq_eof { # EOF callback for main daemon
1249         my ($lei) = @_;
1250         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1251         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1252 }
1253
1254 1;